Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/draft-IERC6093.sol)
pragma solidity >=0.8.4;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /// @inheritdoc IERC20
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /// @inheritdoc IERC20
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /// @inheritdoc IERC20
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

pragma solidity >=0.6.2;

interface IUniswapV2Router01 {
    function factory() external pure returns (address);
    function WETH() external pure returns (address);

    function addLiquidity(
        address tokenA,
        address tokenB,
        uint amountADesired,
        uint amountBDesired,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB, uint liquidity);
    function addLiquidityETH(
        address token,
        uint amountTokenDesired,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external payable returns (uint amountToken, uint amountETH, uint liquidity);
    function removeLiquidity(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETH(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountToken, uint amountETH);
    function removeLiquidityWithPermit(
        address tokenA,
        address tokenB,
        uint liquidity,
        uint amountAMin,
        uint amountBMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountA, uint amountB);
    function removeLiquidityETHWithPermit(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountToken, uint amountETH);
    function swapExactTokensForTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapTokensForExactTokens(
        uint amountOut,
        uint amountInMax,
        address[] calldata path,
        address to,
        uint deadline
    ) external returns (uint[] memory amounts);
    function swapExactETHForTokens(uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);
    function swapTokensForExactETH(uint amountOut, uint amountInMax, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapExactTokensForETH(uint amountIn, uint amountOutMin, address[] calldata path, address to, uint deadline)
        external
        returns (uint[] memory amounts);
    function swapETHForExactTokens(uint amountOut, address[] calldata path, address to, uint deadline)
        external
        payable
        returns (uint[] memory amounts);

    function quote(uint amountA, uint reserveA, uint reserveB) external pure returns (uint amountB);
    function getAmountOut(uint amountIn, uint reserveIn, uint reserveOut) external pure returns (uint amountOut);
    function getAmountIn(uint amountOut, uint reserveIn, uint reserveOut) external pure returns (uint amountIn);
    function getAmountsOut(uint amountIn, address[] calldata path) external view returns (uint[] memory amounts);
    function getAmountsIn(uint amountOut, address[] calldata path) external view returns (uint[] memory amounts);
}

pragma solidity >=0.6.2;

import './IUniswapV2Router01.sol';

interface IUniswapV2Router02 is IUniswapV2Router01 {
    function removeLiquidityETHSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline
    ) external returns (uint amountETH);
    function removeLiquidityETHWithPermitSupportingFeeOnTransferTokens(
        address token,
        uint liquidity,
        uint amountTokenMin,
        uint amountETHMin,
        address to,
        uint deadline,
        bool approveMax, uint8 v, bytes32 r, bytes32 s
    ) external returns (uint amountETH);

    function swapExactTokensForTokensSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
    function swapExactETHForTokensSupportingFeeOnTransferTokens(
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external payable;
    function swapExactTokensForETHSupportingFeeOnTransferTokens(
        uint amountIn,
        uint amountOutMin,
        address[] calldata path,
        address to,
        uint deadline
    ) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "./Unigate.sol";

contract MockUnigateToken is UnigateToken {
    IUniswapV2Router02 private immutable _uniswapV2Router02;

    constructor(
        address treasury_,
        uint256 treasuryAllocationToken_,
        address liquidityReserve_,
        uint256 liquidityReserveAllocationToken_,
        address rewardReserve_,
        uint256 rewardReserveAllocationToken_,
        uint256 saleEndTime_,
        uint256 salePriceETH_,
        uint256 presaleEndTime_,
        uint256 presalePriceETH_,
        uint256 presaleReferralRewardFactor_,
        uint256 presaleBuybackGuaranteeEndTime_,
        IUniswapV2Router02 uniswapV2Router02_
    )
        UnigateToken(
            treasury_,
            treasuryAllocationToken_,
            liquidityReserve_,
            liquidityReserveAllocationToken_,
            rewardReserve_,
            rewardReserveAllocationToken_,
            saleEndTime_,
            salePriceETH_,
            presaleEndTime_,
            presalePriceETH_,
            presaleReferralRewardFactor_,
            presaleBuybackGuaranteeEndTime_
        )
    {
        _uniswapV2Router02 = uniswapV2Router02_;
    }

    function uniswapV2Router02() public view override returns (IUniswapV2Router02) {
        return _uniswapV2Router02;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

import "@uniswap/v2-periphery/contracts/interfaces/IUniswapV2Router02.sol";

/**
 * @title Unigate Bridge Token
 * @author Unigate
 * @notice Unigate bridge token base contract.
 */
abstract contract UnigateBridgeToken is ERC20 {
    /**
     * @notice Master token contract address.
     */
    address public immutable masterToken;

    /**
     * @notice Initializes token parameters.
     *
     * @param name_ Token name.
     * @param symbol_ Token symbol.
     * @param masterToken_ Master token contract address.
     */
    constructor(
        string memory name_,
        string memory symbol_,
        address masterToken_
    ) ERC20(name_, symbol_) {
        require(masterToken_ != address(0), "Master token contract address is zero");
        masterToken = masterToken_;
    }

    /**
     * @notice Checks that the caller (`_msgSender()`) is master token (`masterToken`).
     */
    modifier onlyMaster() {
        require(_msgSender() == masterToken, "Access denied");

        _;
    }

    /**
     * @notice Buys bridge tokens for ETH and transfers them to the caller (`_msgSender()`).
     *
     *         ONLY avaiable to master token caller (`masterToken`).
     *
     * @return Token amount (in base units) transferred.
     */
    function buyTokensForETH() external payable onlyMaster returns (uint256) {
        // Calculate token amount
        uint256 amountToken = (msg.value * (10 ** decimals())) / _priceETH();

        // Transfer tokens from token reserve (token balance if `this`) to caller
        _transfer(address(this), _msgSender(), amountToken);

        return amountToken;
    }

    /**
     * @notice Sells bridge tokens for ETH and transfers ETH to the caller (`_msgSender()`).
     *
     *         ONLY avaiable to master token caller (`masterToken`).
     *
     * @param amountToken Token amount (in base units) to sell.
     *
     * @return ETH amount (in wei) transferred.
     */
    function sellTokensForETH(uint256 amountToken) external onlyMaster returns (uint256) {
        // Calculate ETH amount
        uint256 amountETH = (amountToken * _priceETH()) / (10 ** decimals());

        // Transfer tokens from caller to token reserve (token balance if `this`)
        _transfer(_msgSender(), address(this), amountToken);

        // Transfer ETH to caller
        payable(_msgSender()).transfer(amountETH);

        return amountETH;
    }

    /**
     * @notice Gets token price.
     *
     * @return ETH amount (in wei) for 1 token.
     */
    function _priceETH() internal virtual returns (uint256);
}

/**
 * @title Unigate Token
 * @author Unigate
 * @notice Unigate token contract.
 */
contract UnigateToken is ERC20, ReentrancyGuard {
    /**
     * @notice Treasury address.
     */
    address public immutable treasury;

    /**
     * @notice Liquidity reserve address.
     */
    address public immutable liquidityReserve;

    /**
     * @notice Reward reserve address.
     */
    address public immutable rewardReserve;

    /**
     * @notice Sale end time.
     */
    uint256 public immutable saleEndTime;

    /**
     * @notice Sale price in ETH amount (in wei) for 1 token.
     */
    uint256 public immutable salePriceETH;

    /**
     * @notice Presale end time.
     */
    uint256 public immutable presaleEndTime;

    /**
     * @notice Presale price in ETH amount (in wei) for 1 token.
     */
    uint256 public immutable presalePriceETH;

    /**
     * @notice Presale referral reward factor in percent (with two decimals).
     *
     *         A value of 10000 represents 100.00%.
     */
    uint256 public immutable presaleReferralRewardFactorPercent;

    /**
     * @notice Presale buyback end time.
     */
    uint256 public immutable presaleBuybackEndTime;

    /**
     * @notice Token amount (in base units) eligible for presale buyback per account.
     */
    mapping(address => uint256) private _presaleBuybackEligibileToken;

    /**
     * @notice Initializes token parameters.
     *
     * @param treasury_ Treasury address.
     * @param treasuryAllocationToken_ Treasury initial allocation token amount (in base units).
     * @param liquidityReserve_ Liquidity reserve address.
     * @param liquidityReserveAllocationToken_ Liquidity reserve initial allocation token amount (in base units).
     * @param rewardReserve_ Reward reserve address.
     * @param rewardReserveAllocationToken_ Reward reserve initial allocation token amount (in base units).
     * @param saleEndTime_ Sale end time.
     * @param salePriceETH_ Sale price in ETH amount (in wei) per 1 token.
     * @param presaleEndTime_ Presale end time.
     * @param presalePriceETH_ Presale price in ETH amount (in wei) per 1 token.
     * @param presaleReferralRewardFactorPercent_ Presale referral reward factor in percent (with two decimals).
     * @param presaleBuybackEndTime_ Presale buyback end time.
     */
    constructor(
        address treasury_,
        uint256 treasuryAllocationToken_,
        address liquidityReserve_,
        uint256 liquidityReserveAllocationToken_,
        address rewardReserve_,
        uint256 rewardReserveAllocationToken_,
        uint256 saleEndTime_,
        uint256 salePriceETH_,
        uint256 presaleEndTime_,
        uint256 presalePriceETH_,
        uint256 presaleReferralRewardFactorPercent_,
        uint256 presaleBuybackEndTime_
    ) ERC20("UnigateToken", "UGTT") {
        // Set up treasury
        require(treasury_ != address(0), "Treasury address is zero");
        treasury = treasury_;
        _mint(treasury_, treasuryAllocationToken_);

        // Set up liquidity reserve
        require(liquidityReserve_ != address(0), "Liquidity reserve address is zero");
        require(liquidityReserveAllocationToken_ > 0, "Liquidity reserve allocation is zero");
        liquidityReserve = liquidityReserve_;
        _mint(liquidityReserve_, liquidityReserveAllocationToken_);

        // Set up reward reserve
        require(rewardReserve_ != address(0), "Reward reserve address is zero");
        rewardReserve = rewardReserve_;
        _mint(rewardReserve_, rewardReserveAllocationToken_);

        // Set up sale
        require(saleEndTime_ > block.timestamp, "Sale end time already passed");
        require(salePriceETH_ > 0, "Sale price is zero");
        saleEndTime = saleEndTime_;
        salePriceETH = salePriceETH_;

        // Set up presale
        require(presaleEndTime_ > block.timestamp, "Presale end time already passed");
        require(presaleEndTime_ < saleEndTime, "Presale end time later than sale end time");
        require(presalePriceETH_ > 0, "Presale price is zero");
        require(
            presaleBuybackEndTime_ > presaleEndTime_,
            "Buyback end time earlier than presale end time"
        );
        presaleEndTime = presaleEndTime_;
        presalePriceETH = presalePriceETH_;
        presaleReferralRewardFactorPercent = presaleReferralRewardFactorPercent_;
        presaleBuybackEndTime = presaleBuybackEndTime_;
    }

    /**
     * @notice Calculates token amount for ETH amount.
     *
     * @param amountETH ETH amount (in wei).
     * @param rateETH Conversion rate in ETH amount (in wei) per 1 token.
     *
     * @return Token amount (in base units).
     */
    function calcTokenFromETH(uint256 amountETH, uint256 rateETH) public view returns (uint256) {
        return (amountETH * (10 ** decimals())) / rateETH;
    }

    /**
     * @notice Calculates ETH amount for token amount.
     *
     * @param amountToken Token amount (in base units).
     * @param rateETH Conversion rate in ETH amount (in wei) per 1 token.
     *
     * @return ETH amount (in wei).
     */
    function calcETHFromToken(uint256 amountToken, uint256 rateETH) public view returns (uint256) {
        return (amountToken * rateETH) / (10 ** decimals());
    }

    /**
     * @notice Checks that the caller (`_msgSender()`) is treasury (`treasury`).
     */
    modifier onlyTreasury() {
        require(_msgSender() == treasury, "Access denied");

        _;
    }

    /**
     * @notice Checks that sale is running.
     */
    modifier onlyDuringSale() {
        require(block.timestamp <= saleEndTime, "Sale ended");

        _;
    }

    /**
     * @notice Checks that sale has ended.
     */
    modifier onlyAfterSale() {
        require(block.timestamp > saleEndTime, "Sale not ended");

        _;
    }

    /**
     * @notice Checks that presale is running.
     */
    modifier onlyDuringPresale() {
        require(block.timestamp <= presaleEndTime, "Presale ended");

        _;
    }

    /**
     * @notice Checks that presale has ended.
     */
    modifier onlyAfterPresale() {
        require(block.timestamp > presaleEndTime, "Presale not ended");

        _;
    }

    /**
     * @notice Checks that presale buyback is running.
     */
    modifier onlyDuringPresaleBuyback() {
        require(block.timestamp < presaleBuybackEndTime, "Presale buyback ended");

        _;
    }

    /**
     * @inheritdoc ERC20
     *
     * @notice ONLY available AFTER sale ends (`saleEndTime`).
     */
    function transfer(address to, uint256 value) public override onlyAfterSale returns (bool) {
        return super.transfer(to, value);
    }

    /**
     * @inheritdoc ERC20
     *
     * @notice ONLY available AFTER sale ends (`saleEndTime`).
     */
    function approve(address spender, uint256 value) public override onlyAfterSale returns (bool) {
        return super.approve(spender, value);
    }

    /**
     * @inheritdoc ERC20
     *
     * @notice ONLY available AFTER sale ends (`saleEndTime`).
     */
    function transferFrom(
        address from,
        address to,
        uint256 value
    ) public override onlyAfterSale returns (bool) {
        return super.transferFrom(from, to, value);
    }

    /**
     * @notice Gets balance of reward reserve (`rewardReserve`).
     *
     * @return Token amount (in base units).
     */
    function balanceOfRewardReserve() external view returns (uint256) {
        return balanceOf(rewardReserve);
    }

    /**
     * @notice Gets balance of sale reserve (`this`).
     *
     *         ONLY available BEFORE sale ends (`saleEndTime`).
     *
     * @return Token amount (in base units).
     */
    function balanceOfSaleReserve() external view onlyDuringSale returns (uint256) {
        return balanceOf(address(this));
    }

    /**
     * @notice Buys tokens for ETH at sale price (`salePriceETH`) and
     *         transfers them to the caller (`_msgSender()`).
     *
     *         ONLY available AFTER presale ends (`presaleEndTime`) and
     *         BEFORE sale ends (`saleEndTime`).
     *
     * @return Token amount (in base units) transferred.
     */
    function buyTokensForETH() external payable onlyDuringSale onlyAfterPresale returns (uint256) {
        // Credit tokens - ETH is received directly by contract
        return _commitSale(_msgSender(), msg.value);
    }

    /**
     * @notice Buys tokens for input tokens at sale price (`salePriceETH`),
     *         swapping input tokens for ETH via Uniswap (`uniswapV2Router02`) and
     *         transfers them to the caller (`_msgSender()`).
     *
     *         ONLY available AFTER presale ends (`presaleEndTime`) and
     *         BEFORE sale ends (`saleEndTime`).
     *
     * @param inputToken Input token contract address.
     * @param amountInputToken Input token amount (in base units).
     * @param swapPath Intermediate token contract addresses, if any.
     * @param minAmountETH Minimum output ETH amount (in wei).
     *
     * @return Token amount (in base units) transferred.
     */
    function buyTokensForTokens(
        IERC20 inputToken,
        uint256 amountInputToken,
        address[] calldata swapPath,
        uint256 minAmountETH
    ) external onlyDuringSale onlyAfterPresale returns (uint256) {
        // Collect input tokens from caller
        require(
            inputToken.transferFrom(_msgSender(), address(this), amountInputToken),
            "Failed to transfer input tokens"
        );

        IUniswapV2Router02 router = uniswapV2Router02();

        // Set allowance on input tokens for router
        require(
            inputToken.approve(address(router), amountInputToken),
            "Failed to approve input tokens to router"
        );

        // Build full swap path, including input and output tokens
        address[] memory fullSwapPath = new address[](swapPath.length + 2);
        fullSwapPath[0] = address(inputToken);
        for (uint256 i = 0; i < swapPath.length; i++) {
            fullSwapPath[i + 1] = swapPath[i];
        }
        fullSwapPath[fullSwapPath.length - 1] = router.WETH();

        // Store initial balance
        uint256 initialBalanceETH = address(this).balance;

        // Enable direct receive
        _expectReceive = true;

        // Swap input tokens for ETH
        uint256[] memory amounts = router.swapExactTokensForETH(
            amountInputToken,
            minAmountETH,
            fullSwapPath,
            address(this),
            block.timestamp
        );

        // Disable direct receive
        _expectReceive = false;

        // Reset allowance on input tokens for router
        require(
            inputToken.approve(address(router), 0),
            "Failed to reset input tokens approval to router"
        );

        // Determine output ETH amount
        uint256 amountETH = amounts[fullSwapPath.length - 1];
        require(amountETH >= minAmountETH, "Swap output ETH amount is below minimum");

        // Check balance after swap
        require(
            (address(this).balance - initialBalanceETH) >= amountETH,
            "Swap output ETH amount was not received"
        );

        // Credit tokens to caller
        return _commitSale(_msgSender(), amountETH);
    }

    /**
     * @notice Buys tokens for ETH at presale price (`presalePriceETH`) and
     *         transfers them to the caller (`_msgSender()`).
     *
     *         Credits presale buyback eligibility (`presaleBuybackEligibilityOf`) to
     *         caller for purchased token amount.
     *
     *         If referrer (`referrer`) is non-zero, transfers referral reward,
     *         according to referral reward factor (`presaleReferralRewardFactorPercent`)
     *         and the purchased token amount, from reward reserve (`rewardReserve`)
     *         to referrer. Referrer MAY NOT be the same as caller.
     *
     *         ONLY available BEFORE presale ends (`presaleEndTime`).
     *
     * @param referer Referer account address or zero address.
     *
     * @return Token amount (in base units) transferred.
     */
    function presaleBuyTokensForETH(
        address referer
    ) external payable onlyDuringPresale returns (uint256) {
        // Credit tokens - ETH is received directly by contract
        return _commitPresale(_msgSender(), msg.value, referer);
    }

    /**
     * @notice Buys tokens for input tokens at presale price (`presalePriceETH`),
     *         swapping input tokens for ETH via Uniswap (`UniswapV2Router02`) and
     *         transfers them to the caller (`_msgSender()`).
     *
     *         Credits presale buyback eligibility (`presaleBuybackEligibilityOf`) to
     *         caller for purchased tokens.
     *
     *         If referrer (`referrer`) is non-zero, transfers referral reward,
     *         according to referral reward factor (`presaleReferralRewardFactorPercent`)
     *         and the purchased token amount, from reward reserve (`rewardReserve`)
     *         to referrer. Referrer MAY NOT be the same as caller.
     *
     *         ONLY available BEFORE presale ends (`presaleEndTime`).
     *
     * @param inputToken Input token contract address.
     * @param amountInputToken Input token amount (in base units).
     * @param swapPath Intermediate token contract addresses, if any.
     * @param minAmountETH Minimum ETH amount (in wei).
     * @param referer Referer account address or zero address.
     *
     * @return Token amount (in base units) transferred.
     */
    function presaleBuyTokensForTokens(
        IERC20 inputToken,
        uint256 amountInputToken,
        address[] calldata swapPath,
        uint256 minAmountETH,
        address referer
    ) external onlyDuringPresale returns (uint256) {
        // Collect input tokens from caller
        require(
            inputToken.transferFrom(_msgSender(), address(this), amountInputToken),
            "Failed to transfer input tokens"
        );

        IUniswapV2Router02 router = uniswapV2Router02();

        // Set allowance on input tokens for router
        require(
            inputToken.approve(address(router), amountInputToken),
            "Failed to approve input tokens to router"
        );

        // Build full swap path, including input and output tokens
        address[] memory fullSwapPath = new address[](swapPath.length + 2);
        fullSwapPath[0] = address(inputToken);
        for (uint256 i = 0; i < swapPath.length; i++) {
            fullSwapPath[i + 1] = swapPath[i];
        }
        fullSwapPath[fullSwapPath.length - 1] = router.WETH();

        // Store initial balance
        uint256 initialBalanceETH = address(this).balance;

        // Enable direct receive
        _expectReceive = true;

        // Swap input tokens for ETH
        uint256[] memory amounts = router.swapExactTokensForETH(
            amountInputToken,
            minAmountETH,
            fullSwapPath,
            address(this),
            block.timestamp
        );

        // Disable direct receive
        _expectReceive = false;

        // Reset allowance on input tokens for router
        require(
            inputToken.approve(address(router), 0),
            "Failed to reset input tokens approval to router"
        );

        // Determine output ETH amount
        uint256 amountETH = amounts[fullSwapPath.length - 1];
        require(amountETH >= minAmountETH, "Swap output ETH amount is below minimum");

        // Check balance after swap
        require(
            (address(this).balance - initialBalanceETH) >= amountETH,
            "Swap output ETH amount was not received"
        );

        // Credit tokens to caller
        return _commitPresale(_msgSender(), amountETH, referer);
    }

    /**
     * @notice Gets presale buyback eligibility for the specified account.
     *
     *         ONLY available BEFORE presale buyback ends (`presaleBuybackEndTime`).
     *
     * @param account Account address.
     *
     * @return Token amount (in base units) eligible for presale buyback.
     */
    function presaleBuybackEligibilityOf(
        address account
    ) external view onlyDuringPresaleBuyback returns (uint256) {
        return _presaleBuybackEligibileToken[account];
    }

    /**
     * @notice Sells tokens back for ETH at presale price (`presalePriceETH`)
     *         and transfers ETH amount to the caller (`_msgSender()`).
     *
     *         Debits caller presale buyback eligibility (`presaleBuybackEligibilityOf`).
     *         FAILS if insufficient.
     *
     *         ONLY available AFTER sale ends (`saleEndTime`) and
     *         BEFORE presale buyback ends (`presaleBuybackEndTime`).
     *
     * @param amountToken Token amount (in base units) to sell.
     *
     * @return ETH amount (in wei) transferred.
     */
    function sellPresaleBuybackTokensForETH(
        uint256 amountToken
    ) external onlyAfterSale onlyDuringPresaleBuyback nonReentrant returns (uint256) {
        require(amountToken > 0, "Token amount is zero");
        require(
            _presaleBuybackEligibileToken[_msgSender()] >= amountToken,
            "Insufficient presale buyback eligibility"
        );

        // Calculate ETH amount
        uint256 amountETH = calcETHFromToken(amountToken, presalePriceETH);
        require(amountETH > 0, "ETH amount is zero");

        // Presale buyback eligibility already verified via `require`
        unchecked {
            // Debit presale buyback eligibility from caller
            _presaleBuybackEligibileToken[_msgSender()] -= amountToken;
        }

        // Transfer tokens from caller to sale reserve (token balance of `this`)
        _transfer(_msgSender(), address(this), amountToken);

        // Transfer ETH to caller
        payable(_msgSender()).transfer(amountETH);

        return amountETH;
    }

    /**
     * @notice Transfers tokens from sale reserve (`this`) to recipient (`recipient`)
     *         for the specified ETH amount at sale price (`salePriceETH`).
     *
     * @param recipient Recipient account.
     * @param amountETH ETH amount (in wei).
     *
     * @return Token amount (in base units) transferred.
     */
    function _commitSale(address recipient, uint256 amountETH) internal returns (uint256) {
        require(amountETH > 0, "ETH amount is zero");

        // Calculate token amount
        uint256 amountToken = calcTokenFromETH(amountETH, salePriceETH);
        require(amountToken > 0, "Token amount is zero");

        // Transfer tokens to buyer
        // NOTE: Fails if sale reserve (token balance of `this`) is exhausted
        _transfer(address(this), recipient, amountToken);

        return amountToken;
    }

    /**
     * @notice Transfers tokens from sale reserve (`this`) to recipient (`recipient`)
     *         for the specified ETH amount at presale price (`presalePriceETH`).
     *
     *         Credits presale buyback eligibility (`presaleBuybackEligibilityOf`) to
     *         caller for purchased token amount.
     *
     *         If referrer (`referrer`) is non-zero, transfers referral reward,
     *         according to referral reward factor (`presaleReferralRewardFactor`)
     *         and the purchased token amount, from reward reserve (`rewardReserve`)
     *         to referrer. Referrer MAY NOT be the same as caller.
     *
     * @param recipient Recipient account.
     * @param amountETH ETH amount (in wei).
     * @param referer Referer account or zero.
     *
     * @return Token amount (in base units) transferred.
     */
    function _commitPresale(
        address recipient,
        uint256 amountETH,
        address referer
    ) internal returns (uint256) {
        require(amountETH > 0, "ETH amount is zero");
        require(referer != recipient, "Invalid referer");

        // Calculate token amount
        uint256 amountToken = calcTokenFromETH(amountETH, presalePriceETH);
        require(amountToken > 0, "Token amount is zero");

        // Credit presale buyback eligibility to recipient
        _presaleBuybackEligibileToken[recipient] += amountToken;

        // Transfer tokens to buyer
        // NOTE: Fails if sale reserve (token balance of `this`) is exhausted
        _transfer(address(this), recipient, amountToken);

        // Query reward reserve token balance
        uint256 rewardReserveBalanceToken = balanceOf(rewardReserve);

        if (
            referer != address(0) &&
            presaleReferralRewardFactorPercent > 0 &&
            rewardReserveBalanceToken > 0
        ) {
            // Calculate referral reward token amount
            uint256 referralRewardAmountToken = (amountToken * presaleReferralRewardFactorPercent) /
                10000;

            // Clamp referral reward token amount to reward reserve balance
            if (referralRewardAmountToken > rewardReserveBalanceToken) {
                referralRewardAmountToken = rewardReserveBalanceToken;
            }

            // Transfer referral reward
            _transfer(rewardReserve, referer, referralRewardAmountToken);
        }

        return amountToken;
    }

    /**
     * @notice Uniswap router.
     *
     * @dev Returns constant. Exists as a virtual method to facilitate testing.
     *
     * @return Uniswap router instance.
     */
    function uniswapV2Router02() public view virtual returns (IUniswapV2Router02) {
        return IUniswapV2Router02(0x7a250d5630B4cF539739dF2C5dAcb4c659F2488D);
    }

    /**
     * @notice Emitted when sale resereve (`this`) is allocated via `allocateSaleReserve`.
     *
     * @param amountToken Token amount (in base units) allocated.
     */
    event SaleReserveAllocated(uint256 amountToken);

    /**
     * @notice Transfers tokens from liquidity reserve (`liquidityReserve`) to
     *         sale reserve (`this`).
     *
     *         ONLY avaiable to treasury caller (`treasury`) BEFORE sale
     *         ends (`saleEndTime`).
     */
    function allocateSaleReserve(uint256 amountToken) external onlyTreasury onlyDuringSale {
        _transfer(liquidityReserve, address(this), amountToken);

        emit SaleReserveAllocated(amountToken);
    }

    /**
     * @notice Emitted when sale resereve (`this`) is burned via `burnSaleReserve`.
     *
     * @param amountToken Token amount (in base units) burned.
     */
    event SaleReserveBurned(uint256 amountToken);

    /**
     * @notice Burns all tokens on sale reserve (`this`).
     *
     *         ONLY avaiable to treasury caller (`treasury`) AFTER sale
     *         ends (`saleEndTime`).
     */
    function burnSaleReserve() external onlyTreasury onlyAfterSale {
        uint256 saleReserveBalance = balanceOf(address(this));

        _burn(address(this), saleReserveBalance);

        emit SaleReserveBurned(saleReserveBalance);
    }

    /**
     * @notice Emitted when a deposit is received via `deposit`.
     *
     * @param amountETH ETH amount (in wei).
     */
    event DepositReceived(uint256 amountETH);

    /**
     * @notice Deposits ETH.
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     */
    function deposit() external payable onlyTreasury {
        emit DepositReceived(msg.value);
    }

    /**
     * @notice Buys bridge tokens to the token account (`this`).
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     *
     * @param token Bridge token contract address.
     * @param amountETH ETH amount (in wei) to spend.
     *
     * @return Token amount (in base units) transferred.
     */
    function buyBridgeTokens(
        UnigateBridgeToken token,
        uint256 amountETH
    ) external onlyTreasury nonReentrant returns (uint256) {
        require(token.masterToken() == address(this), "Invalid bridge token");

        return token.buyTokensForETH{value: amountETH}();
    }

    /**
     * @notice Sells bridge tokens from the token account (`this`).
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     *
     * @param token Bridge token contract address.
     * @param amountToken Token amount (in base units) to sell.
     *
     * @return ETH amount (in wei) transferred.
     */
    function sellBridgeTokens(
        UnigateBridgeToken token,
        uint256 amountToken
    ) external onlyTreasury nonReentrant returns (uint256) {
        require(token.masterToken() == address(this), "Invalid bridge token");

        return token.sellTokensForETH(amountToken);
    }

    /**
     * @notice Specifies whether raw ETH receipt (via `receive`) is expected.
     *
     *         Currently, only temporarily enabled for swap operations.
     */
    bool private _expectReceive;

    /**
     * @notice Receives ETH.
     *
     *         ONLY allowed when `_expectReceive` is truthy.
     */
    receive() external payable {
        require(_expectReceive, "Prohibited");
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";

import "./Unigate.sol";

/**
 * @title Unigate Treasury Bridge Token
 * @author Unigate
 * @notice Unigate Treasury bridge token contract.
 */
contract UnigateTreasuryBridgeToken is UnigateBridgeToken {
    /**
     * @notice Treasury address.
     */
    address public immutable treasury;

    /**
     * @notice Price in ETH amount (in wei) for 1 token.
     */
    uint256 public immutable priceETH;

    /**
     * @notice Initializes token parameters.
     *
     * @param treasury_ Treasury address.
     * @param priceETH_ ETH amount (in wei) for 1 token.
     * @param initialAllocationToken_ Initial allocation token amount (in base units).
     * @param masterToken_ Master token contract address.
     */
    constructor(
        address treasury_,
        uint256 priceETH_,
        uint256 initialAllocationToken_,
        address masterToken_
    ) UnigateBridgeToken("UnigateTreasuryBridge", "UGTT/T", masterToken_) {
        // Set up treasury
        require(treasury_ != address(0), "Treasury address is zero");
        treasury = treasury_;

        // Set up price
        require(priceETH_ > 0, "Price is zero");
        priceETH = priceETH_;

        // Initial allocation
        _mint(address(this), initialAllocationToken_);
    }

    /**
     * @notice Checks that the caller (`_msgSender()`) is treasury (`treasury`).
     */
    modifier onlyTreasury() {
        require(_msgSender() == treasury, "Access denied");

        _;
    }

    /**
     * @notice Mints tokens to token reserve (`this`).
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     *
     * @param amountToken Token amount (in base units).
     */
    function mint(uint256 amountToken) external onlyTreasury {
        _mint(address(this), amountToken);
    }

    /**
     * @notice Burns tokens from token reserve (`this`).
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     *
     * @param amountToken Token amount (in base units).
     */
    function burn(uint256 amountToken) external onlyTreasury {
        _burn(address(this), amountToken);
    }

    /**
     * @notice Emitted when a deposit is received via `deposit`.
     *
     * @param amountETH ETH amount (in wei).
     */
    event DepositReceived(uint256 amountETH);

    /**
     * @notice Deposits ETH.
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     */
    function deposit() external payable onlyTreasury {
        emit DepositReceived(msg.value);
    }

    /**
     * @notice Emitted when a withdraw is completed via `withdraw`.
     *
     * @param amountETH ETH amount (in wei).
     */
    event WithdrawCompleted(uint256 amountETH);

    /**
     * @notice Withdraws ETH.
     *
     *         ONLY avaiable to treasury caller (`treasury`).
     *
     * @param amountETH ETH amount (in wei).
     */
    function withdraw(uint256 amountETH) external onlyTreasury {
        payable(_msgSender()).transfer(amountETH);

        emit WithdrawCompleted(amountETH);
    }

    /**
     * @notice Gets token price.
     *
     * @return ETH amount (in wei) for 1 token.
     */
    function _priceETH() internal view override returns (uint256) {
        return priceETH;
    }

    /**
     * @notice Receives ETH.
     *
     *         NOT ALLOWED.
     */
    receive() external payable {
        revert("Prohibited");
    }
}