Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT

pragma solidity 0.8.27;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

contract MiraiStaking is ReentrancyGuard, Ownable {
    IERC20 public immutable Token;

    uint256 public totalTokensStaked;
    uint256 public totalStakedAccruingRewards;
    uint256 public currentRewardRate;
    uint256 public lastRewardCalculationTime;
    uint256 public rewardPerTokenStored;
    uint256 public stakingWithdrawalTimeLock  = 3 days; 
    uint256 public withdrawalFeePercentage  = 0; 
    uint256 public rewardsEmissionStart;
    uint256 public rewardsEmissionEnd;
    uint256 public feesAccrued;
    uint256 public storedPendingRewards;

    uint256 private constant MAX_FEE = 200;
    uint256 private constant BASIS_POINTS = 10000;
    uint256 private constant MAX_TIMELOCK = 15 days;

    struct Staker {
        uint256 amountStaked;
        uint256 rewardDebt;
        uint256 rewards;
        uint256 unstakeInitTime;
    }

    mapping(address => Staker) public stakers;

    event UnstakeInitiated(address indexed user);
    event Staked(address indexed user, uint256 amount);
    event Unstaked(address indexed user, uint256 amount);
    event RewardPaid(address indexed user, uint256 reward);
    event UnstakeFeePercentUpdated(uint256 newFeePercent);
    event UnstakeTimeLockUpdated(uint256 newTimeLock);

    modifier updateReward(address account) {
        rewardPerTokenStored = calculateRewardPerToken();
        storedPendingRewards = calculatePendingRewards();
        lastRewardCalculationTime = getLastActiveTime();
        Staker storage staker = stakers[account];
        if (staker.unstakeInitTime == 0) {
            staker.rewards = calculateEarnedRewards(account);
            staker.rewardDebt = rewardPerTokenStored;
        }
        _;
    }

    constructor(
        address _Mirai,
        uint256 _rewardRate,
        uint256 _rewardsEmissionStart,
        uint256 _emissionDuration
    ) Ownable(msg.sender) {
        Token = IERC20(_Mirai);
        currentRewardRate = _rewardRate;
        rewardsEmissionStart = _rewardsEmissionStart;
        rewardsEmissionEnd = rewardsEmissionStart + _emissionDuration;
    }

    function getLastActiveTime() public view returns (uint256) {
        return block.timestamp < rewardsEmissionEnd ? block.timestamp : rewardsEmissionEnd;
    }

    function calculatePendingRewards() public view returns (uint256) {
        uint256 totalStakedAccruingRewardsCached = totalStakedAccruingRewards;
        if (totalStakedAccruingRewardsCached == 0) return storedPendingRewards;
        uint256 fullPendingRewards = (getLastActiveTime() - lastRewardCalculationTime) *
            currentRewardRate *
            1e18;
        uint256 roundingError = fullPendingRewards %
            totalStakedAccruingRewardsCached;
        return storedPendingRewards + fullPendingRewards - roundingError;
    }

    function calculateRewardPerToken() public view returns (uint256) {
        if (totalStakedAccruingRewards == 0) {
            return rewardPerTokenStored;
        }
        return
            rewardPerTokenStored +
            (((getLastActiveTime() - lastRewardCalculationTime) * currentRewardRate * 1e18) /
                totalStakedAccruingRewards);
    }

    function calculateEarnedRewards(address account) public view returns (uint256) {
        Staker storage staker = stakers[account];
        if (staker.unstakeInitTime != 0) {
            return staker.rewards;
        }
        return
            ((staker.amountStaked * (calculateRewardPerToken() - staker.rewardDebt)) /
                1e18) + staker.rewards;
    }

    function depositStake(
        uint256 _amount
    ) external nonReentrant updateReward(msg.sender) {
        require(_amount > 0, "Cannot stake 0");
        require(block.timestamp >= rewardsEmissionStart, "Staking not yet started");
        require(block.timestamp <= rewardsEmissionEnd, "Staking period has ended");
        Staker storage staker = stakers[msg.sender];
        require(
            staker.unstakeInitTime == 0,
            "Cannot stake after initiating unstake."
        );
        totalTokensStaked += _amount;
        totalStakedAccruingRewards += _amount;
        staker.amountStaked += _amount;
        require(
            Token.transferFrom(msg.sender, address(this), _amount),
            "Token deposit failed"
        );
        emit Staked(msg.sender, _amount);
    }

    function beginUnstaking() external updateReward(msg.sender) {
        Staker storage staker = stakers[msg.sender];
        require(staker.amountStaked > 0, "No tokens staked");
        require(staker.unstakeInitTime == 0, "Unstake already initiated");
        staker.unstakeInitTime = block.timestamp;
        totalStakedAccruingRewards -= staker.amountStaked;
        emit UnstakeInitiated(msg.sender);
    }

    function finalizeUnstaking() external nonReentrant updateReward(msg.sender) {
        Staker storage staker = stakers[msg.sender];
        require(staker.amountStaked > 0, "No tokens staked");
        require(staker.unstakeInitTime > 0, "Unstake not initiated");
        require(
            block.timestamp >= staker.unstakeInitTime + stakingWithdrawalTimeLock ,
            "Timelock not yet passed"
        );

        uint256 amount = staker.amountStaked;
        uint256 reward = staker.rewards;
        uint256 fee = (amount * withdrawalFeePercentage ) / BASIS_POINTS;
        uint256 amountAfterFee = amount - fee;

        uint256 availableForRewards = _calculateAvailableBalance();

        feesAccrued += fee;
        totalTokensStaked -= amount;
        staker.amountStaked = 0;
        staker.rewardDebt = 0;
        staker.unstakeInitTime = 0;

        uint256 totalAmount = amountAfterFee;
        // If there are rewards, combine them with the staked amount after fees for a single transfer
        if (reward > 0 && availableForRewards >= reward) {
            if (storedPendingRewards >= reward * 1e18)
                storedPendingRewards -= reward * 1e18;
            totalAmount += reward;
            staker.rewards = 0;
            emit RewardPaid(msg.sender, reward);
        }
        require(
            Token.transfer(msg.sender, totalAmount),
            "Unstake transfer failed"
        );
        emit Unstaked(msg.sender, amount);
    }

    function withdrawRewards() external nonReentrant updateReward(msg.sender) {
        Staker storage staker = stakers[msg.sender];
        uint256 reward = staker.rewards;
        require(reward > 0, "No rewards to claim");

        // Calculate the available balance for rewards
        uint256 availableForRewards = _calculateAvailableBalance();
        require(availableForRewards >= reward, "Insufficient funds for reward");
        if (storedPendingRewards >= reward * 1e18)
            storedPendingRewards -= reward * 1e18;
        staker.rewards = 0;
        require(Token.transfer(msg.sender, reward), "Reward transfer failed");
        emit RewardPaid(msg.sender, reward);
    }

    function updateUnstakingFee(uint256 _newFee) external onlyOwner {
        require(_newFee <= MAX_FEE, "Unstake fee exceeds 2%, maximum allowed");
        withdrawalFeePercentage  = _newFee;
        emit UnstakeFeePercentUpdated(_newFee);
    }

    function updateWithdrawalLock(uint256 _newTimeLock) external onlyOwner {
        require(
            _newTimeLock <= MAX_TIMELOCK,
            "Time lock must be between 0 to 15 days"
        );
        stakingWithdrawalTimeLock  = _newTimeLock;
        emit UnstakeTimeLockUpdated(_newTimeLock);
    }

    function checkRemainingLockTime(
        address _staker
    ) external view returns (uint256) {
        Staker storage staker = stakers[_staker];
        if (block.timestamp < staker.unstakeInitTime + stakingWithdrawalTimeLock ) {
            return (staker.unstakeInitTime + stakingWithdrawalTimeLock ) - block.timestamp;
        } else {
            return 0;
        }
    }

    function retrieveAccruedFees(uint256 amount) external onlyOwner {
        require(amount <= feesAccrued, "Amount exceeds accrued fees");
        feesAccrued -= amount;
        require(Token.transfer(msg.sender, amount), "Fee withdrawal failed");
    }

    function retrieveRemainingTokens()
        external
        updateReward(address(0))
        onlyOwner
    {
        require(
            block.timestamp > rewardsEmissionEnd,
            "Cannot withdraw before emission end"
        );
        uint256 freeContractBalanceCached = _calculateAvailableBalance();
        uint256 pendingRewardsCached = calculatePendingRewards() / 1e18;

        require(
            freeContractBalanceCached > pendingRewardsCached,
            "No remaining tokens to withdraw"
        );
        uint256 remainingBalance = freeContractBalanceCached -
            pendingRewardsCached;
        require(
            Token.transfer(msg.sender, remainingBalance),
            "Token withdrawal failed"
        );
    }

    function _calculateAvailableBalance() public view returns (uint256) {
        return Token.balanceOf(address(this)) - totalTokensStaked - feesAccrued;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}