Cryo Explorer Ethereum Mainnet

pragma solidity 0.8.14;

import "./interface/IProofOfDeveloper.sol";
import "./interface/IProofOfAuditor.sol";
import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";

/// @title   Hyacinth Database
/// @notice  Contract that keeps track of pending and completed audits
/// @author  Hyacinth
contract HyacinthDatabase is ReentrancyGuard {
    /// DEPENDENCIES ///

    using SafeERC20 for IERC20;

    /// EVENTS ///

    /// @notice        Emitted after Hyacinth fee has been updated
    /// @param newFee  New Hyacinth fee
    event HyacinthFeeSet(uint256 newFee);

    /// @notice              Emitted after min bounty has been set
    /// @param newMinBounty  New min bounty
    event MinBountySet(uint256 newMinBounty);

    /// @notice            Emittd after mint fee amount has been updated
    /// @param newMintFee  New mint fee amount
    event MintFeeSet(uint256 newMintFee);

    /// @notice             Emitted after deadline time has been updated
    /// @param newDeadline  New deadline time
    event AuditDeadlineUpdated(uint256 newDeadline);

    /// @notice           Emitted after Hyacinth wallet has been updated
    /// @param newWallet  Address of new Hyacinth wallet
    event HyacinthWalletUpdated(address newWallet);

    /// @notice           Emitted after new escrow withdraw buffer has been set
    /// @param newBuffer  New buffer time
    event EscrowWithdrawBufferSet(uint256 newBuffer);

    /// @notice             Emitted after bounty has been added to
    /// @param token        Address of token added to bounty
    /// @param auditId      Audit id of audit bounty is being added to
    /// @param amountAdded  Amount added to bounty
    event AddedToBounty(address indexed token, uint256 indexed auditId, uint256 amountAdded);

    /// @notice          Emitted after audit has been created
    /// @param auditId   Audit id
    /// @param previous  Audit id of previous audit
    /// @param developer Address of developer
    /// @param contracts Address of conrtacts being audited (Off chain audit if empty)
    event AuditCreated(
        uint256 indexed auditId, uint256 indexed previous, address indexed developer, address[] contracts
    );

    /// @notice           Emitted after pod has been minted
    /// @param developer  Address of developer
    /// @param id         Id of POD minted
    event PODMinted(address indexed developer, uint256 id);

    /// @notice           Emitted after audit result has been submitted
    /// @param auditor    Address of auditor
    /// @param developer  Developer of contracts
    /// @param auditId    Id of audit
    /// @param result     Result of audit
    event ResultSubmitted(address indexed auditor, address indexed developer, uint256 indexed auditId, STATUS result);

    /// @notice           Emitted after audit result has been submitted
    /// @param auditId    Id of audit
    /// @param auditor    Address of auditor
    /// @param developer  Developer of `auditId`
    /// @param positive   Bool if positive feedback
    event AuditFeedBackGiven(
        uint256 indexed auditId, address indexed auditor, address indexed developer, bool positive
    );

    /// @notice           Emitted after bounty has been refunded
    /// @param developer  Address of developer being refunded
    /// @param auditId    Id of audit being refunded
    event BountyRefunded(address indexed developer, uint256 indexed auditId);

    /// @notice         Emitted after auditor request has been sent
    /// @param auditor  Address of auditor requesting
    /// @param auditId  Audit id of audit request
    event AuditorRequest(address indexed auditor, uint256 indexed auditId);

    /// @notice           Emitted after auditor has been accepted
    /// @param developer  Address of developer of audit
    /// @param auditor    Address of auditor accepted
    /// @param auditId    Audit id auditor has been accepted for
    event AuditorAccepted(address indexed developer, address indexed auditor, uint256 indexed auditId);

    /// @notice                 Emitted after collaboration has been created
    /// @param auditId          Audit id collaborator is being added to
    /// @param collaborator     Address of collaborator
    /// @param percentOfBounty  Percent of bounty given to collaborator
    event CollaborationCreated(uint256 indexed auditId, address collaborator, uint256 percentOfBounty);

    /// @notice        Emitted after max number of audits for auditor set
    /// @param oldMax  Old max audits for auditor
    /// @param newMax  New max audits for auditor
    event MaxAuditsSet(uint256 oldMax, uint256 newMax);

    /// @notice           Emitted after time to roll over is updated
    /// @param oldPeriod  Old roll over period
    /// @param newPeriod  New roll over period
    event TimeToRollOverSet(uint256 oldPeriod, uint256 newPeriod);

    /// @notice         Emitted after auditor has been added
    /// @param auditor  Address of auditor being added
    event AuditorAdded(address auditor);

    /// @notice         Emitted after auditor has been removed
    /// @param auditor  Address of auditor being removed
    event AuditorRemoved(address auditor);

    /// @notice               Emitted after ownership has been transfered
    /// @param previousOwner  Address of previous owner
    /// @param newOwner       Address of new owner
    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /// ERRORS ///

    /// @notice Error for if contrac was not developed by developer
    error NotDeveloper();
    /// @notice Error for if bounty has been paid out already
    error BountyPaid();
    /// @notice Error for if auditor already requested to audit
    error AlreadyRequested();
    /// @notice Error for if address already set
    error AlreadySet();
    /// @notice Error for if invalid level
    error InvalidLevel();
    /// @notice Error for if auditor has already been assigned
    error AuditorAssigned();
    /// @notice Error for if audit has not been failed
    error AuditNotFailed();
    /// @notice Error for if audit has been rolled over
    error AuditRolledOver();
    /// @notice Error for if refund condition not met
    error CanNotRefund();
    /// @notice Error for if the address is not the owner
    error NotOwner();
    /// @notice Error for if not approved auditor
    error NotApprovedAuditor();
    /// @notice Error for if not requested auditor
    error NotRequestedAuditor();
    /// @notice Error for only auditor
    error OnlyAuditor();
    /// @notice Error for only developer
    error OnlyDeveloper();
    /// @notice Error for if contract is not being audited
    error NotBeingAudited();
    /// @notice Error for if audit has not been passed
    error NotPassed();
    /// @notice Error for if feedback has already been given
    error FeedbackGiven();
    /// @notice Error for if contract is already in system
    error AlreadyInSystem();
    /// @notice Error for invalid audit result
    error InvalidResult();
    /// @notice Error for if address is not a contact
    error NotAContract();
    /// @notice Error for if collaboration has already been created
    error CollaborationAlreadyCreated();
    /// @notice Error for if invalid collaborator
    error InvalidCollaborator();
    /// @notice Error for if trying to give away more of bounty than available
    error MoreThanCanGiveAway();
    /// @notice Error for if address already owns POD NFT
    error AlreadyOwnPOD();
    /// @notice Error for if submitting audit and does not own POD NFT
    error DoesNotOwnPODNFT();
    /// @notice Error for if auditor has max amount of audits
    error MaxAuditsInProgress();
    /// @notice Error for if roll over period is still active
    error RollOverStillActive();
    /// @notice Error for if invalid fee
    error InvalidFee();
    /// @notice Error for if invalid previous
    error InvalidPrevious();
    /// @notice Error for if less than min bounty
    error LessThanMinBounty();

    /// STRUCTS ///

    enum STATUS {
        NOTAUDITED,
        PENDING,
        PASSED,
        FAILED,
        REFUNDED
    }

    /// @notice           Details of contract
    /// @param contracts  Address of contract developer
    /// @param audited    Bool if has been add to audit
    /// @param auditId    Audit id
    struct Contract {
        address developer;
        bool audited;
        uint256 auditId;
    }

    /// @notice                         Details of audited contracts
    /// @param contracts                Contracts being audited
    /// @param auditor                  Address of auditor
    /// @param developer                Address of developer
    /// @param status                   Status of audit
    /// @param auditDescription         Description of audit results
    /// @param deadline                 Deadline auditor has to complete audit
    /// @param escrowWithdrawTimestamp  Timestamp escrow can be withdrawn from
    /// @param feedback                 Bool if feedback has been given to auditor
    struct Audit {
        address[] contracts;
        address auditor;
        address developer;
        STATUS status;
        string auditDescription;
        uint256 deadline;
        uint256 escrowWithdrawTimestamp;
        bool feedback;
    }

    /// @notice                  Details of auditor
    /// @param auditsInProgress  Number of audits in progress
    /// @param positiveFeedback  Number of positive feedback for auditor
    /// @param negativeFeedbac   Number of negative feedback for auditor
    /// @param mintedLevel       Minted level for auditor
    struct Auditor {
        uint256 auditsInProgress;
        uint256 positiveFeedback;
        uint256 negativeFeedback;
        uint256 mintedLevel;
    }

    /// STATE VARIABLES ///

    /// @notice Fee percent for Hyacinth
    uint256 public hyacinthFee;
    /// @notice Fee amount to mint POD NFT
    uint256 public podMintFee;
    /// @notice time to complete audit or can refund
    uint256 public auditDeadline;
    /// @notice Max number of audits an auditor can pick up at one time
    uint256 public maxAuditsForAuditor;
    /// @notice Amount of time dev has to roll over audit until auditor can claim bounty
    uint256 public timeToRollOver;
    /// @notice Buffer before can withdraw from escrow
    uint256 public escrowWithdrawBuffer;
    /// @notice Amount of min bounty
    uint256 public minBounty;
    /// @notice Amount of audits in system
    uint256 public auditId;

    /// @notice Address of owner
    address public owner;
    /// @notice Address of hyacinth wallet
    address public hyacinthWallet;

    /// @notice Address of previous POA
    IProofOfAuditor public previousPOA;

    /// @notice Address of USDC
    address public immutable USDC;
    /// @notice Address of proof of developer NFT
    IProofOfDeveloper public immutable proofOfDeveloper;
    /// @notice Address of proof of auditor NFT
    IProofOfAuditor public immutable proofOfAuditor;

    /// @notice Amount of audits completed at each level for auditor
    mapping(address => uint256[4]) internal _levelsCompleted;

    /// @notice Contract details for contract address
    mapping(address => Contract) public contracts;
    /// @notice Audit details of address
    mapping(uint256 => Audit) public audits;
    /// @notice Auditor details of auditor
    mapping(address => Auditor) public auditors;
    /// @notice Bool if address is an approved auditor
    mapping(address => bool) public approvedAuditor;
    /// @notice Percent of bounty given to collaborators
    mapping(uint256 => uint256) public percentGivenForCollab;
    /// @notice Time rollover of bounty is active till
    mapping(uint256 => uint256) public timeRollOverActive;
    /// @notice Address failed audit rolled over to
    mapping(uint256 => uint256) public rolledOverAudit;
    /// @notice Array of collaborators for audit id
    mapping(uint256 => address[]) public collaborators;
    /// @notice Array of fees collaborators receive
    mapping(uint256 => uint256[]) public collaboratorsPercentOfBounty;
    /// @notice Bounty percent for collaberation of an audit id of a collaborator
    mapping(uint256 => mapping(address => uint256)) public collaborationPercent;
    /// @notice Bool if address requested to be auditor of audit id
    mapping(uint256 => mapping(address => bool)) public requestToBeAuditor;
    /// @notice Bounty amount of token on audit
    mapping(uint256 => mapping(address => uint256)) public bountyOnContract;
    /// @notice Token addresses on bounty
    mapping(uint256 => address[]) public tokenAddressOnBounty;
    /// @notice Bool if bounty has been paid out
    mapping(uint256 => bool) public bountyPaidOut;

    /// CONSTRUCTOR ///

    /// @param hyacinthWallet_  Address of hyacinth wallet
    /// @param owner_           Address of owner
    /// @param pod_             Address of proof of developer NFT
    /// @param poa_             Address of proof of auditor NFT
    /// @param usdc_            Address of USDC
    constructor(address hyacinthWallet_, address owner_, address pod_, address poa_, address usdc_) {
        hyacinthWallet = hyacinthWallet_;
        owner = owner_;
        proofOfDeveloper = IProofOfDeveloper(pod_);
        proofOfAuditor = IProofOfAuditor(poa_);
        USDC = usdc_;
    }

    /// AUDIT FUNCTION ///

    /// @notice               Function that creates audit
    /// @param beingAudited_  Array of addresses to have be audited (If 0 - Off chain audit)
    /// @param previous_      Previous audit id if rolling over
    /// @param bountyAmount_  Starting bounty amount
    /// @return auditId_      Id of audit created
    function createAudit(address[] calldata beingAudited_, uint256 previous_, uint256 bountyAmount_)
        external
        nonReentrant
        returns (uint256 auditId_)
    {
        if (proofOfDeveloper.balanceOf(msg.sender) == 0) mintPOD();
        if (bountyAmount_ < minBounty) revert LessThanMinBounty();

        ++auditId;
        auditId_ = auditId;

        if (beingAudited_.length > 0) {
            for (uint256 i; i < beingAudited_.length; ++i) {
                Contract memory contract_ = contracts[beingAudited_[i]];
                if (contract_.audited) revert AlreadyInSystem();
                if (contract_.developer != msg.sender) revert OnlyDeveloper();
                contracts[beingAudited_[i]].audited = true;
                contracts[beingAudited_[i]].auditId = auditId_;
            }

            if (previous_ != 0) {
                if (timeRollOverActive[previous_] <= block.timestamp || audits[previous_].developer != msg.sender) {
                    revert InvalidPrevious();
                }

                audits[auditId_].auditor = audits[previous_].auditor;
                audits[auditId_].deadline = block.timestamp + auditDeadline;
                collaborators[auditId_] = collaborators[previous_];
                collaboratorsPercentOfBounty[auditId_] = collaboratorsPercentOfBounty[previous_];
                percentGivenForCollab[auditId_] = percentGivenForCollab[previous_];
                rolledOverAudit[previous_] = auditId_;
                _rollOverBounty(previous_, auditId_);
            }

            audits[auditId_].contracts = beingAudited_;
        }

        audits[auditId_].developer = msg.sender;
        audits[auditId_].status = STATUS.PENDING;
        audits[auditId_].escrowWithdrawTimestamp = escrowWithdrawBuffer + block.timestamp;

        if (bountyAmount_ > 0) {
            _addToBounty(auditId_, bountyAmount_, USDC);
        }

        emit AuditCreated(auditId_, previous_, msg.sender, beingAudited_);
    }

    /// @notice  Called upon contract being deployed to be audited
    function beingAudited() external {
        if (proofOfDeveloper.balanceOf(tx.origin) == 0) revert DoesNotOwnPODNFT();
        if (msg.sender == tx.origin) revert NotAContract();
        Contract memory contract_ = contracts[msg.sender];
        if (contract_.developer != address(0)) revert AlreadyInSystem();
        contracts[msg.sender].developer = tx.origin;
    }

    /// DEVELOPER FUNCTION ///

    /// @notice           Add to bounty of `auditId_`
    /// @param auditId_   Audit id to add bounty to
    /// @param amount_    Amount of stable to add to bounty
    /// @param token_     Address of token on bounty
    function addToBounty(uint256 auditId_, uint256 amount_, address token_) external nonReentrant {
        Audit memory audit_ = audits[auditId_];

        if (audit_.developer != msg.sender) revert NotDeveloper();
        if (audit_.status != STATUS.PENDING) revert NotBeingAudited();
        _addToBounty(auditId_, amount_, token_);
    }

    /// @notice      Function that allow address to mint POD NFT
    /// @return id_  POD id minted
    function mintPOD() public returns (uint256 id_) {
        if (podMintFee > 0) {
            IERC20(USDC).safeTransferFrom(msg.sender, hyacinthWallet, podMintFee);
        }
        if (proofOfDeveloper.balanceOf(msg.sender) > 0) revert AlreadyOwnPOD();
        else (id_) = proofOfDeveloper.mint(msg.sender);

        emit PODMinted(msg.sender, id_);
    }

    /// @notice           Function that allows developer to give feedback to auditor
    /// @param auditId_   Audit id feedback given for
    /// @param positive_  Bool if positive or negative feedback
    function giveAuditorFeedback(uint256 auditId_, bool positive_) external {
        Audit memory audit_ = audits[auditId_];

        if (audit_.status != STATUS.PASSED) revert NotPassed();
        if (audit_.developer != msg.sender) revert OnlyDeveloper();
        if (audit_.feedback) revert FeedbackGiven();

        audits[auditId_].feedback = true;

        if (positive_) ++auditors[audit_.auditor].positiveFeedback;
        else ++auditors[audit_.auditor].negativeFeedback;

        emit AuditFeedBackGiven(auditId_, audit_.auditor, audit_.developer, positive_);
    }

    /// @notice           Function that allows developer to get a refund for bounty if no auditor or past deadline
    /// @param auditId_   Audit id to get refund for
    function refundBounty(uint256 auditId_) external nonReentrant {
        Audit memory audit_ = audits[auditId_];
        if (audit_.developer != msg.sender) revert OnlyDeveloper();
        if (
            (audit_.auditor != address(0) && audit_.deadline > block.timestamp) || audit_.status != STATUS.PENDING
                || (audit_.auditor == address(0) && audit_.escrowWithdrawTimestamp > block.timestamp)
        ) {
            revert CanNotRefund();
        }

        if (audit_.auditor != address(0)) auditors[audit_.auditor].auditsInProgress--;
        audits[auditId_].status = STATUS.REFUNDED;

        for (uint256 i; i < tokenAddressOnBounty[auditId_].length; ++i) {
            address token_ = tokenAddressOnBounty[auditId_][i];
            uint256 bounty_ = bountyOnContract[auditId_][token_];
            bountyOnContract[auditId_][token_] = 0;
            IERC20(token_).safeTransfer(audit_.developer, bounty_);
        }

        emit BountyRefunded(msg.sender, auditId_);
    }

    /// @notice          Function that allows developer to accept propose auditor
    /// @param auditId_  Audit Id of audit developer is accepting `auditor_` for
    /// @param auditor_  Address being accepted as auditor for `auditId_`
    function acceptAuditor(uint256 auditId_, address auditor_) external {
        if (audits[auditId_].developer != msg.sender) revert OnlyDeveloper();
        if (audits[auditId_].auditor != address(0)) revert AuditorAssigned();
        if (maxAuditsForAuditor <= auditors[auditor_].auditsInProgress) revert MaxAuditsInProgress();
        if (!requestToBeAuditor[auditId_][auditor_]) revert NotRequestedAuditor();

        ++auditors[auditor_].auditsInProgress;
        audits[auditId_].auditor = auditor_;
        audits[auditId_].deadline = block.timestamp + auditDeadline;

        emit AuditorAccepted(msg.sender, auditor_, auditId_);
    }

    /// AUDITOR FUNCTION ///

    /// @notice          Function that allows approved auditor to request to audit
    /// @param auditId_  Audit id auditor is requesting to audit
    function requestToAudit(uint256 auditId_) external {
        if (audits[auditId_].status != STATUS.PENDING) revert NotBeingAudited();
        if (audits[auditId_].auditor != address(0)) revert AuditorAssigned();
        if (!approvedAuditor[msg.sender]) revert NotApprovedAuditor();
        if (maxAuditsForAuditor <= auditors[msg.sender].auditsInProgress) revert MaxAuditsInProgress();
        if (requestToBeAuditor[auditId_][msg.sender] == true) revert AlreadyRequested();

        requestToBeAuditor[auditId_][msg.sender] = true;

        emit AuditorRequest(msg.sender, auditId_);
    }

    /// @notice              Auditor submits the `result_` of `auditId_`
    /// @param auditId_      Audit Id of audit having `result_` submitted
    /// @param result_       Result of the audit
    /// @param description_  Desecription of the audit
    function submitResult(uint256 auditId_, STATUS result_, string memory description_) external nonReentrant {
        Audit memory audit_ = audits[auditId_];
        if (audit_.status != STATUS.PENDING) revert NotBeingAudited();
        if (audit_.auditor != msg.sender) revert OnlyAuditor();
        if (result_ != STATUS.PASSED && result_ != STATUS.FAILED) revert InvalidResult();
        audit_.status = result_;
        audit_.auditDescription = description_;
        audits[auditId_] = audit_;

        if (result_ == STATUS.PASSED) {
            uint256 level_ = _payBounty(auditId_);
            ++_levelsCompleted[audit_.auditor][level_];
        } else {
            timeRollOverActive[auditId_] = block.timestamp + timeToRollOver;
        }

        emit ResultSubmitted(audit_.auditor, audit_.developer, auditId_, result_);
    }

    /// @notice          Function that pays out bounty if roll over has expired
    /// @param auditId_  Audit id to pay out bounty for
    function rollOverExpired(uint256 auditId_) external nonReentrant {
        Audit memory audit_ = audits[auditId_];
        if (audit_.status != STATUS.FAILED) revert AuditNotFailed();
        if (audit_.auditor != msg.sender) revert OnlyAuditor();
        if (timeRollOverActive[auditId_] > block.timestamp) revert RollOverStillActive();
        if (rolledOverAudit[auditId_] != 0) revert AuditRolledOver();

        _payBounty(auditId_);
    }

    /// @notice                  Function that allows an auditor to propose a collaboration
    /// @param auditId_          Audit id
    /// @param collaborator_     Address of collaborator
    /// @param percentOfBounty_  Percent of bounty `collaborator_` will receive
    function createCollaboration(uint256 auditId_, address collaborator_, uint256 percentOfBounty_) external {
        Audit memory audit_ = audits[auditId_];
        if (audit_.status != STATUS.PENDING) revert NotBeingAudited();
        if (audit_.auditor != msg.sender) revert OnlyAuditor();
        if (!approvedAuditor[collaborator_]) revert NotApprovedAuditor();
        if (percentGivenForCollab[auditId_] + percentOfBounty_ > 100) revert MoreThanCanGiveAway();
        if (collaborator_ == msg.sender || collaborator_ == audit_.developer) revert InvalidCollaborator();

        uint256 collaborationPercent_ = collaborationPercent[auditId_][collaborator_];
        if (collaborationPercent_ > 0) revert CollaborationAlreadyCreated();

        collaborationPercent[auditId_][collaborator_] = percentOfBounty_;

        percentGivenForCollab[auditId_] += percentOfBounty_;
        collaborators[auditId_].push(collaborator_);
        collaboratorsPercentOfBounty[auditId_].push(percentOfBounty_);

        emit CollaborationCreated(auditId_, collaborator_, percentOfBounty_);
    }

    /// OWNER FUNCTION ///

    /// @notice              Add previous auditors
    /// @param previousPOA_  Previous POA address
    function addPreviousAuditors(address previousPOA_) external {
        if (msg.sender != owner) revert NotOwner();
        if (address(previousPOA) != address(0)) revert AlreadySet();

        previousPOA = IProofOfAuditor(previousPOA_);

        for (uint256 i; i < previousPOA.totalSupply(); ++i) {
            _addAuditor(previousPOA.ownerOf(i), previousPOA.level(i));
        }
    }

    /// @notice         Update audit fee
    /// @param newFee_  New Hyacinth audit fee
    function setHyacinthfee(uint256 newFee_) external {
        if (msg.sender != owner) revert NotOwner();
        if (newFee_ > 25) revert InvalidFee();
        hyacinthFee = newFee_;

        emit HyacinthFeeSet(newFee_);
    }

    /// @notice         Min USDC bounty
    /// @param newMin_  New min USDC
    function setMinBounty(uint256 newMin_) external {
        if (msg.sender != owner) revert NotOwner();
        minBounty = newMin_;

        emit MinBountySet(newMin_);
    }

    /// @notice             Set new POD mint fee
    /// @param podMintFee_  New POD mint fee
    function setMintFee(uint256 podMintFee_) external {
        if (msg.sender != owner) revert NotOwner();
        podMintFee = podMintFee_;

        emit MintFeeSet(podMintFee_);
    }

    /// @notice              Set auditor deadline
    /// @param newDeadline_  New auditor deadline
    function setAuditDeadline(uint256 newDeadline_) external {
        if (msg.sender != owner) revert NotOwner();
        auditDeadline = newDeadline_;

        emit AuditDeadlineUpdated(newDeadline_);
    }

    /// @notice                 Set Hyacinth wallet
    /// @param hyacinthWallet_  Hyacinth wallet
    function updateHyacinthWallet(address hyacinthWallet_) external {
        if (msg.sender != owner) revert NotOwner();
        hyacinthWallet = hyacinthWallet_;

        emit HyacinthWalletUpdated(hyacinthWallet_);
    }

    /// @notice                       Set escrow withdraw buffer
    /// @param escrowWithdrawBuffer_  escrow withdraw buffer
    function setEscrowWithdrawBuffer(uint256 escrowWithdrawBuffer_) external {
        if (msg.sender != owner) revert NotOwner();
        escrowWithdrawBuffer = escrowWithdrawBuffer_;

        emit EscrowWithdrawBufferSet(escrowWithdrawBuffer_);
    }

    /// @notice           Transfer ownership of contract
    /// @param newOwner_  Address of the new owner
    function transferOwnership(address newOwner_) external {
        if (msg.sender != owner) revert NotOwner();
        address oldOwner_ = owner;
        owner = newOwner_;

        emit OwnershipTransferred(oldOwner_, newOwner_);
    }

    /// @notice                 Set roll over time for failed audit
    /// @param timeToRollOver_  New roll over time for failed audit
    function setTimeToRollOver(uint256 timeToRollOver_) external {
        if (msg.sender != owner) revert NotOwner();
        uint256 oldPeriod_ = timeToRollOver;
        timeToRollOver = timeToRollOver_;

        emit TimeToRollOverSet(oldPeriod_, timeToRollOver_);
    }

    /// @notice            Set max number of audits
    /// @param maxAudits_  New max number of audits for auditor
    function setMaxAuditsForAuditor(uint256 maxAudits_) external {
        if (msg.sender != owner) revert NotOwner();
        uint256 oldMax_ = maxAuditsForAuditor;
        maxAuditsForAuditor = maxAudits_;

        emit MaxAuditsSet(oldMax_, maxAudits_);
    }

    /// @notice            Add auditor
    /// @param auditor_    Address to add as auditor
    /// @param baseLevel_  Base level to give `auditor_`
    /// @return id_        Id of POA for `auditor_`
    function addAuditor(address auditor_, uint256 baseLevel_) external returns (uint256 id_) {
        if (msg.sender != owner) revert NotOwner();

        id_ = _addAuditor(auditor_, baseLevel_);
    }

    /// @notice          Remove auditor
    /// @param auditor_  Address to remove as auditor
    function removeAuditor(address auditor_) external {
        if (msg.sender != owner) revert NotOwner();
        approvedAuditor[auditor_] = false;

        emit AuditorRemoved(auditor_);
    }

    /// INTERNAL FUNCTIONS ///

    /// @notice            Add auditor
    /// @param auditor_    Address to add as auditor
    /// @param baseLevel_  Base level to give `auditor_`
    /// @return id_        Id of POA for `auditor_`
    function _addAuditor(address auditor_, uint256 baseLevel_) internal returns (uint256 id_) {
        if (baseLevel_ > 3) revert InvalidLevel();

        if (proofOfAuditor.balanceOf(auditor_) == 0) {
            id_ = proofOfAuditor.mint(auditor_);
        } else {
            id_ = proofOfAuditor.idHeld(auditor_);
        }

        auditors[auditor_].mintedLevel = baseLevel_;
        approvedAuditor[auditor_] = true;

        emit AuditorAdded(auditor_);
    }

    /// @notice                  Internal function that pays out bounty
    /// @param auditId_          Bounty Id to pay bounty out for
    function _payBounty(uint256 auditId_) internal returns (uint256 level_) {
        if (bountyPaidOut[auditId_]) revert BountyPaid();
        address[] memory collaborators_ = collaborators[auditId_];
        uint256[] memory percentsOfBounty_ = collaboratorsPercentOfBounty[auditId_];

        bountyPaidOut[auditId_] = true;

        Audit memory audit_ = audits[auditId_];

        (level_,) = currentBountyLevel(auditId_);

        for (uint256 i; i < tokenAddressOnBounty[auditId_].length; ++i) {
            address token_ = tokenAddressOnBounty[auditId_][i];
            uint256 bounty_ = bountyOnContract[auditId_][token_];
            bountyOnContract[auditId_][token_] = 0;
            uint256 bountyToDistribute_ = ((bounty_ * (100 - hyacinthFee)) / 100);
            uint256 hyacinthReceives_ = bounty_ - bountyToDistribute_;
            IERC20(token_).safeTransfer(hyacinthWallet, hyacinthReceives_);

            uint256 collaboratorsReceived_;
            for (uint256 n; n < collaborators_.length; ++n) {
                uint256 collaboratorsReceives_ = (bountyToDistribute_ * percentsOfBounty_[n]) / 100;
                IERC20(token_).safeTransfer(collaborators_[n], collaboratorsReceives_);
                collaboratorsReceived_ += collaboratorsReceives_;
            }

            uint256 auditorReceives_ = bountyToDistribute_ - collaboratorsReceived_;
            IERC20(token_).safeTransfer(audit_.auditor, auditorReceives_);
        }

        --auditors[msg.sender].auditsInProgress;
    }

    /// @notice           Add to bounty of `auditId_`
    /// @param auditId_   Audit id to add bounty to
    /// @param amount_    Amount of stable to add to bounty
    /// @param token_     Address of token on bounty
    function _addToBounty(uint256 auditId_, uint256 amount_, address token_) internal {
        IERC20(token_).safeTransferFrom(msg.sender, address(this), amount_);

        if (bountyOnContract[auditId_][token_] == 0) tokenAddressOnBounty[auditId_].push(token_);
        bountyOnContract[auditId_][token_] += amount_;

        emit AddedToBounty(token_, auditId_, amount_);
    }

    /// @notice           Rolls over bounty of `previous_` to `new_`
    /// @param previous_  Audit id of roll overed audit
    /// @param new_       Audsit id of new audit after roll over
    function _rollOverBounty(uint256 previous_, uint256 new_) internal {
        for (uint256 i; i < tokenAddressOnBounty[previous_].length; ++i) {
            address token_ = tokenAddressOnBounty[previous_][i];
            uint256 bounty_ = bountyOnContract[previous_][token_];

            bountyOnContract[previous_][token_] = 0;
            bountyOnContract[new_][token_] = bounty_;
        }

        tokenAddressOnBounty[new_] = tokenAddressOnBounty[previous_];
    }

    /// EXTERNAL VIEW FUNCTIONS ///

    /// @notice                   Returns amount of audits completed at each level for `auditorAdderss_`
    /// @param auditorAddress_    Address of auditor
    /// @return levelsCompleted_  Array of levels of audits completed for `auditorAddress_`
    function levelsCompleted(address auditorAddress_) external view returns (uint256[4] memory levelsCompleted_) {
        return (_levelsCompleted[auditorAddress_]);
    }

    /// @notice                   Returns audit status for `contractAddress_`
    /// @param contractAddress_   Contract address to check audit status for
    /// @return status_           Audit status of `contractAddress_`
    function auditStatus(address contractAddress_) external view returns (STATUS status_) {
        Contract memory contract_ = contracts[contractAddress_];
        if (contract_.audited) status_ = audits[contract_.auditId].status;
    }

    /// @notice          Returns current `level_` and `bounty_` of `auditId_`
    /// @param auditId_  Audit to check bounty for
    /// @return level_   Current level of `contract_` bounty
    /// @return bounty_  Current bouty of `contract_`
    function currentBountyLevel(uint256 auditId_) public view returns (uint256 level_, uint256 bounty_) {
        bounty_ = bountyOnContract[auditId_][USDC];

        uint256 decimals_ = 10 ** IERC20Metadata(USDC).decimals();
        if (bounty_ >= 1000 * decimals_) {
            if (bounty_ < 10000 * decimals_) level_ = 1;
            else if (bounty_ < 100000 * decimals_) level_ = 2;
            else level_ = 3;
        }
    }
}

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/IERC721.sol";

interface IProofOfAuditor is IERC721 {
    function mint(address auditor_) external returns (uint256 id_);

    function idHeld(address auditor_) external view returns (uint256 id_);

    function level(uint256 tokenId_) external view returns (uint256 level_);

    function totalSupply() external view returns (uint256 totalSupply_);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/IERC721.sol";

interface IProofOfDeveloper is IERC721 {
    function mint(address developer_) external returns (uint256 id_);

    function idHeld(address developer_) external view returns (uint256 id_);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}