Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import "@openzeppelin/contracts/access/Ownable2Step.sol";

/**
 * @title Authorizable
 * @dev Contract module which provides a basic authorization control mechanism, 
 * where there is an account (an owner) that can grant exclusive access to 
 * specific functions to authorised accounts.
 */
contract Authorizable is Ownable2Step {
    error UnAuthorised();

    mapping(address => bool) private authorised;

    /**
     * @dev Modifier to make a function callable only by authorised accounts.
     */
    modifier onlyAuthorised() {
        if (!isAuthorised(msg.sender)) {
            revert UnAuthorised();
        }
        _;
    }

    /**
     * @dev Adds an address to the list of authorised accounts.
     * Can only be called by the current owner.
     * @param _toAdd The address to add to the authorised list.
     */
    function addAuthorised(address _toAdd) public onlyOwner {
        require(_toAdd != address(0), "Zero Address inserted");
        authorised[_toAdd] = true;
    }

    /**
     * @dev Removes an address from the list of authorised accounts.
     * Can only be called by the current owner.
     * @param _toRemove The address to remove from the authorised list.
     */
    function removeAuthorised(address _toRemove) public onlyOwner {
        require(_toRemove != msg.sender, "Owner cannot be removed");
        authorised[_toRemove] = false;
    }

    /**
     * @dev Checks if an address is authorised.
     * @param _authAdd The address to check.
     * @return _isAuth True if the address is authorised, false otherwise.
     */
    function isAuthorised(address _authAdd) public view returns (bool _isAuth) {
        _isAuth = (authorised[_authAdd] || owner() == _authAdd);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/security/Pausable.sol";
import "./Authorizable.sol";
import "./interfaces/IStakingPool.sol";

/// @title StakingFactory
/// @notice This contract manages multiple StakingPool contracts and distributes rewards to users who stake their LP tokens.
contract StakingFactory is Authorizable, ReentrancyGuard, Pausable {
    using SafeERC20 for IERC20;

    error ZeroAmountInserted();
    error ZeroAllocPointInserted();
    error InvalidPoolId();
    error ZeroAddressInserted();
    error InvalidPID();
    error UserSharesZero();
    error TotalSharesZero();
    error RewardTokenTransfer();
    error TokenAlreadyAdded();
    error PoolAlreadyAdded();
    error ZeroAmountWithdraw();

    /// @dev Struct to store information about each user's stake in a pool.
    struct UserInfo {
        uint256 shares; // How many LP tokens the user has provided.
        uint256 rewardDebt; // Reward debt.
    }

    /// @dev Struct to store information about each staking pool.
    struct PoolInfo {
        IERC20 token; // Address of the pool token.
        uint256 allocPoint; // Allocation points assigned to the pool.
        uint256 lastRewardBlock; // Last block number where reward distribution occurred.
        uint256 accRewardTokenPerShare; // Accumulated reward tokens per share, times 1e12.
        address pool; // Staking Pool address.
    }

    /// @notice Emitted when a user deposits LP tokens into a pool.
    event Deposit(address indexed user, uint256 indexed pid, uint256 amount);
    /// @notice Emitted when a user withdraws LP tokens from a pool.
    event Withdraw(address indexed user, uint256 indexed pid, uint256 amount);
    /// @notice Emitted when a user performs an emergency withdrawal from a pool.
    event EmergencyWithdraw(
        address indexed user,
        uint256 indexed pid,
        uint256 amount
    );
    /// @notice Emitted when admin adds a pool
    event PoolAdded(
        address indexed token,
        address indexed pool,
        uint256 allocPoint
    );
    /// @notice Emitted when admin update alloc of a pool
    event AllocUpdated(uint256 pid, uint256 allocPoint);
    /// @notice Emitted when admin update reward per block
    event AllocUpdated(uint256 rewardPerBlock);
    /// @notice Emitted when admin update fund source
    event FundSourceUpdated(address _fundSource);
    /// @notice Emitted when admin update reward token
    event RewardTokenUpdated(address _rewardToken);

    /// @notice Address of the reward token.
    address public reward_token;

    /// @notice Address of the source of reward tokens.
    address public fundSource;

    /// @notice Reward tokens distributed per block.
    uint256 public rewardTokenPerBlock;

    /// @notice Array containing information about all pools.
    PoolInfo[] public poolInfo;

    /// @notice Mapping of user stake information for each pool.
    /// @dev Maps pool ID to user address to UserInfo struct.
    mapping(uint256 => mapping(address => UserInfo)) public userInfo;

    /// @notice Tracks if a pool has already been added.
    /// @dev Maps pool address to boolean indicating if the pool is added.
    mapping(address => bool) public poolsAdded;

    /// @notice Tracks if a token has already been added.
    /// @dev Maps token address to boolean indicating if the pool is added.
    mapping(address => bool) public tokensAdded;

    /// @notice Total allocation points across all pools.
    uint256 public totalAllocPoint;

    modifier zeroAmountCheck(uint256 amount) {
        if (amount == 0) {
            revert ZeroAmountInserted();
        }
        _;
    }

    modifier zeroAddressCheck(address _address) {
        if (_address == address(0)) {
            revert ZeroAddressInserted();
        }
        _;
    }

    modifier validPID(uint256 _pid) {
        if (_pid >= poolInfo.length) {
            revert InvalidPID();
        }
        _;
    }

    /// @notice Initializes the StakingFactory contract with the reward token and fund source addresses.
    /// @param _rewardToken The address of the reward token.
    /// @param _fundSource The address from which reward tokens will be pulled for distribution.
    constructor(address _rewardToken, address _fundSource) Ownable() {
        reward_token = _rewardToken;
        fundSource = _fundSource;
    }

    /// @notice Adds a new staking pool to the factory.
    /// @dev Only callable by the contract owner.
    /// @param _allocPoint Allocation points assigned to the new pool. This determines the share of rewards the pool receives.
    /// @param poolToken The address of the LP token that will be staked in the pool.
    /// @param _withUpdate Boolean indicating whether to update reward variables before adding the pool.
    /// @param _pool The address of the `StakingPool` contract associated with the new pool.
    function add(
        uint256 _allocPoint,
        address poolToken,
        bool _withUpdate,
        address _pool
    ) external zeroAddressCheck(poolToken) zeroAddressCheck(_pool) onlyOwner {
        if (poolsAdded[_pool]) revert PoolAlreadyAdded();
        if (tokensAdded[poolToken]) revert TokenAlreadyAdded();

        if (_withUpdate) {
            massUpdatePools();
        }
        uint256 lastRewardBlock = block.number;
        totalAllocPoint = totalAllocPoint + (_allocPoint);
        poolInfo.push(
            PoolInfo({
                token: IERC20(poolToken),
                allocPoint: _allocPoint,
                lastRewardBlock: lastRewardBlock,
                accRewardTokenPerShare: 0,
                pool: _pool
            })
        );
        poolsAdded[_pool] = true;
        tokensAdded[poolToken] = true;
        emit PoolAdded(poolToken, _pool, _allocPoint);
    }

    /// @notice Updates the allocation points of an existing pool.
    /// @dev Only callable by the contract owner.
    /// @param _pid The pool ID (index in the `poolInfo` array).
    /// @param _allocPoint The new allocation point for the pool.
    /// @param _withUpdate Boolean indicating whether to update reward variables before updating the allocation points.
    function set(
        uint256 _pid,
        uint256 _allocPoint,
        bool _withUpdate
    ) external validPID(_pid) onlyAuthorised {
        if (_withUpdate) {
            massUpdatePools();
        }
        totalAllocPoint =
            totalAllocPoint -
            (poolInfo[_pid].allocPoint) +
            (_allocPoint);
        poolInfo[_pid].allocPoint = _allocPoint;
        emit AllocUpdated(_pid, _allocPoint);
    }

    /// @notice Sets the number of reward tokens to be distributed per block.
    /// @dev Only callable by the contract owner.
    /// @param _rewardTokenPerBlock The new reward token amount per block.
    function setRewardTokenPerBlock(
        uint256 _rewardTokenPerBlock
    ) external onlyAuthorised {
        massUpdatePools();
        rewardTokenPerBlock = _rewardTokenPerBlock;
        emit AllocUpdated(_rewardTokenPerBlock);
    }

    /// @notice Sets the address from which reward tokens will be pulled for distribution.
    /// @dev Only callable by the contract owner.
    /// @param _fundSource The new fund source address.
    function setFundSource(
        address _fundSource
    ) external onlyOwner zeroAddressCheck(_fundSource) {
        fundSource = _fundSource;
        emit FundSourceUpdated(_fundSource);
    }

    /// @notice Allows the contract owner to recover tokens (other than the reward token) accidentally sent to the contract.
    /// @param _token The address of the stuck token.
    /// @param _amount The amount of tokens to recover.
    function inCaseTokensGetStuck(
        address _token,
        uint256 _amount
    ) external zeroAddressCheck(_token) zeroAmountCheck(_amount) onlyOwner {
        if (_token == reward_token) revert RewardTokenTransfer();
        IERC20(_token).safeTransfer(msg.sender, _amount);
    }

    /// @notice Allows the owner to change the reward token address
    /// @param _tokenAddress The address of the reward token.
    function changeRewardToken(address _tokenAddress) external onlyOwner {
        reward_token = _tokenAddress;
        emit RewardTokenUpdated(_tokenAddress);
    }

    /// @notice Allows a user to deposit LP tokens into a specific pool for staking.
    /// @param _pid The pool ID.
    /// @param poolTokenAmt The amount of LP tokens to deposit.
    function deposit(
        uint256 _pid,
        uint256 poolTokenAmt
    )
        external
        nonReentrant
        whenNotPaused
        validPID(_pid)
        zeroAmountCheck(poolTokenAmt)
    {
        updatePool(_pid);
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        if (user.shares > 0) {
            uint256 pending = (user.shares * (pool.accRewardTokenPerShare)) /
                (1e12) -
                (user.rewardDebt);
            if (pending > 0) {
                safeRewardTokenTransfer(msg.sender, pending);
            }
        }
        if (poolTokenAmt > 0) {
            pool.token.safeTransferFrom(
                address(msg.sender),
                address(this),
                poolTokenAmt
            );

            pool.token.approve(pool.pool, poolTokenAmt);
            uint256 sharesAdded = IStakingPool(poolInfo[_pid].pool).deposit(
                msg.sender,
                poolTokenAmt
            );
            user.shares = user.shares + (sharesAdded);
        }
        user.rewardDebt =
            (user.shares * (pool.accRewardTokenPerShare)) /
            (1e12);
        emit Deposit(msg.sender, _pid, poolTokenAmt);
    }

    /// @notice Allows a user to withdraw all their staked LP tokens and accrued rewards from a specific pool.
    /// @param _pid The pool ID.
    function withdrawAll(uint256 _pid) external {
        withdraw(_pid, type(uint256).max);
    }

    /// @notice Allows a user to claim their accrued rewards from a specific pool without withdrawing LP tokens.
    /// @param _pid The pool ID.
    function claimReward(uint256 _pid) external nonReentrant validPID(_pid) {
        updatePool(_pid);

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        uint256 sharesTotal = IStakingPool(poolInfo[_pid].pool).sharesTotal();
        if (user.shares == 0) revert UserSharesZero();
        if (sharesTotal == 0) revert TotalSharesZero();

        // Withdraw pending rewardToken
        uint256 pending = (user.shares * (pool.accRewardTokenPerShare)) /
            (1e12) -
            (user.rewardDebt);
        if (pending > 0) {
            safeRewardTokenTransfer(msg.sender, pending);
        }
        user.rewardDebt =
            (user.shares * (pool.accRewardTokenPerShare)) /
            (1e12);
    }

    /// @notice Allows a user to claim their accrued rewards from multiple pools.
    /// @param _pids An array of pool IDs.
    function claimRewardMultiple(uint256[] memory _pids) external nonReentrant {
        for (uint256 i = 0; i < _pids.length; i++) {
            uint256 _pid = _pids[i];
            if (_pid >= poolInfo.length) revert InvalidPID();
            updatePool(_pid);

            PoolInfo storage pool = poolInfo[_pid];
            UserInfo storage user = userInfo[_pid][msg.sender];

            uint256 sharesTotal = IStakingPool(poolInfo[_pid].pool)
                .sharesTotal();
            if (user.shares == 0) revert UserSharesZero();
            if (sharesTotal == 0) revert TotalSharesZero();

            // Withdraw pending rewardToken
            uint256 pending = (user.shares * (pool.accRewardTokenPerShare)) /
                (1e12) -
                (user.rewardDebt);
            if (pending > 0) {
                safeRewardTokenTransfer(msg.sender, pending);
            }
            user.rewardDebt =
                (user.shares * (pool.accRewardTokenPerShare)) /
                (1e12);
        }
    }

    /// @notice Allows a user to withdraw their staked LP tokens from a specific pool without claiming rewards.
    /// @dev This function is for emergency situations and should be used with caution.
    /// @param _pid The pool ID.
    function emergencyWithdraw(
        uint256 _pid
    ) external nonReentrant validPID(_pid) {
        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        uint256 tokenLockedTotal = IStakingPool(poolInfo[_pid].pool)
            .tokenLockedTotal();
        uint256 sharesTotal = IStakingPool(poolInfo[_pid].pool).sharesTotal();
        uint256 amount = (user.shares * (tokenLockedTotal)) / (sharesTotal);

        IStakingPool(poolInfo[_pid].pool).withdraw(msg.sender, amount);

        uint256 poolBalance = IERC20(pool.token).balanceOf(address(this));
        if (amount > poolBalance) {
            amount = poolBalance;
        }

        if (amount == 0) revert ZeroAmountWithdraw();
        pool.token.safeTransfer(address(msg.sender), amount);
        user.shares = 0;
        user.rewardDebt = 0;
        emit EmergencyWithdraw(msg.sender, _pid, amount);
    }

    /**
     * @dev Triggers stopped state.
     * - The contract must not be paused.
     */
    function pause() external onlyOwner whenNotPaused {
        _pause();
    }

    /**
     * @dev Returns to normal state.
     * - The contract must be paused.
     */
    function unpause() external onlyOwner whenPaused {
        _unpause();
    }

    /// @notice Returns the number of pools managed by the factory.
    /// @return The length of the `poolInfo` array.
    function poolLength() external view returns (uint256) {
        return poolInfo.length;
    }

    /// @notice Returns the pending reward tokens for a user in a specific pool.
    /// @param _pid The pool ID.
    /// @param _user The address of the user.
    /// @return The amount of pending reward tokens.
    function pendingRewardToken(
        uint256 _pid,
        address _user
    ) external view validPID(_pid) returns (uint256) {
        PoolInfo memory pool = poolInfo[_pid];
        UserInfo memory user = userInfo[_pid][_user];
        uint256 accRewardTokenPerShare = pool.accRewardTokenPerShare;
        uint256 sharesTotal = IStakingPool(pool.pool).sharesTotal();
        if (block.number > pool.lastRewardBlock && sharesTotal != 0) {
            uint256 multiplier = getMultiplier(
                pool.lastRewardBlock,
                block.number
            );
            uint256 rewardTokenReward = (multiplier *
                (rewardTokenPerBlock) *
                (pool.allocPoint)) / (totalAllocPoint);
            accRewardTokenPerShare =
                accRewardTokenPerShare +
                ((rewardTokenReward * (1e12)) / (sharesTotal));
        }
        return
            (user.shares * (accRewardTokenPerShare)) /
            (1e12) -
            (user.rewardDebt);
    }

    /// @notice Returns the amount of staked LP tokens for a user in a specific pool.
    /// @param _pid The pool ID.
    /// @param _user The address of the user.
    /// @return The amount of staked LP tokens.
    function stakedTokensAmount(
        uint256 _pid,
        address _user
    ) external view validPID(_pid) returns (uint256) {
        PoolInfo memory pool = poolInfo[_pid];
        UserInfo memory user = userInfo[_pid][_user];

        uint256 sharesTotal = IStakingPool(pool.pool).sharesTotal();
        uint256 tokenLockedTotal = IStakingPool(poolInfo[_pid].pool)
            .tokenLockedTotal();
        if (sharesTotal == 0) {
            return 0;
        }
        return (user.shares * (tokenLockedTotal)) / (sharesTotal);
    }

    /// @notice Allows a user to withdraw their staked LP tokens from a specific pool.
    /// @param _pid The pool ID.
    /// @param poolTokenAmt The amount of LP tokens to withdraw.
    function withdraw(
        uint256 _pid,
        uint256 poolTokenAmt
    ) public nonReentrant validPID(_pid) zeroAmountCheck(poolTokenAmt) {
        updatePool(_pid);

        PoolInfo storage pool = poolInfo[_pid];
        UserInfo storage user = userInfo[_pid][msg.sender];

        if (user.shares == 0) revert UserSharesZero();

        uint256 tokenLockedTotal = IStakingPool(poolInfo[_pid].pool)
            .tokenLockedTotal();
        uint256 sharesTotal = IStakingPool(poolInfo[_pid].pool).sharesTotal();

        if (sharesTotal == 0) revert TotalSharesZero();
        // Withdraw pending rewardToken
        uint256 pending = (user.shares * (pool.accRewardTokenPerShare)) /
            (1e12) -
            (user.rewardDebt);
        if (pending > 0) {
            safeRewardTokenTransfer(msg.sender, pending);
        }

        // Withdraw pool tokens
        uint256 amount = (user.shares * (tokenLockedTotal)) / (sharesTotal);
        if (poolTokenAmt > amount) {
            poolTokenAmt = amount;
        }
        if (poolTokenAmt > 0) {
            uint256 sharesRemoved = IStakingPool(poolInfo[_pid].pool).withdraw(
                msg.sender,
                poolTokenAmt
            );

            if (sharesRemoved > user.shares) {
                user.shares = 0;
            } else {
                user.shares = user.shares - (sharesRemoved);
            }

            uint256 tokenBal = IERC20(pool.token).balanceOf(address(this));
            if (tokenBal < poolTokenAmt) {
                poolTokenAmt = tokenBal;
            }
            if (address(pool.token) == address(reward_token)) {
                if (sharesRemoved == 0) revert ZeroAmountWithdraw();
                pool.token.safeTransfer(address(msg.sender), sharesRemoved);
            } else {
                if (poolTokenAmt == 0) revert ZeroAmountWithdraw();
                pool.token.safeTransfer(address(msg.sender), poolTokenAmt);
            }
        }
        user.rewardDebt =
            (user.shares * (pool.accRewardTokenPerShare)) /
            (1e12);
        emit Withdraw(msg.sender, _pid, poolTokenAmt);
    }

    /// @notice Updates the reward variables of a specific pool.
    /// @param _pid The pool ID.
    function updatePool(uint256 _pid) public validPID(_pid) {
        PoolInfo storage pool = poolInfo[_pid];
        if (block.number <= pool.lastRewardBlock) {
            return;
        }
        uint256 sharesTotal = IStakingPool(pool.pool).sharesTotal();
        if (sharesTotal == 0) {
            pool.lastRewardBlock = block.number;
            return;
        }
        uint256 multiplier = getMultiplier(pool.lastRewardBlock, block.number);
        if (multiplier <= 0) {
            return;
        }
        uint256 rewardTokenReward = (multiplier *
            (rewardTokenPerBlock) *
            (pool.allocPoint)) / (totalAllocPoint);
        if (rewardTokenReward > 0) {
            getRewardToken(rewardTokenReward);
        }
        pool.accRewardTokenPerShare =
            pool.accRewardTokenPerShare +
            ((rewardTokenReward * (1e12)) / (sharesTotal));
        pool.lastRewardBlock = block.number;
    }

    /// @notice Updates reward variables for all pools.
    /// @dev This function can be expensive in terms of gas, so use it carefully.
    function massUpdatePools() public {
        uint256 length = poolInfo.length;
        for (uint256 pid = 0; pid < length; ++pid) {
            updatePool(pid);
        }
    }

    /// @notice Calculates the reward multiplier over a given block range.
    /// @param _from The starting block number.
    /// @param _to The ending block number.
    /// @return The calculated reward multiplier.
    function getMultiplier(
        uint256 _from,
        uint256 _to
    ) public pure returns (uint256) {
        return _to - (_from);
    }

    /// @dev Internal function to safely transfer reward tokens to a user.
    /// @param _to The address of the recipient.
    /// @param _rewardTokenAmt The amount of reward tokens to transfer.
    function safeRewardTokenTransfer(
        address _to,
        uint256 _rewardTokenAmt
    ) internal zeroAddressCheck(_to) zeroAmountCheck(_rewardTokenAmt) {
        uint256 rewardTokenBal = IERC20(reward_token).balanceOf(address(this));
        if (_rewardTokenAmt > rewardTokenBal) {
            IERC20(reward_token).transfer(_to, rewardTokenBal);
        } else {
            IERC20(reward_token).transfer(_to, _rewardTokenAmt);
        }
    }

    /// @dev Internal function to transfer reward tokens from the `fundSource` to the factory contract.
    /// @param _rewardTokenAmt The amount of reward tokens to transfer.
    function getRewardToken(uint256 _rewardTokenAmt) internal {
        IERC20(reward_token).transferFrom(
            fundSource,
            address(this),
            _rewardTokenAmt
        );
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.20;

interface IStakingPool {
    // Total want tokens managed by stratfegy
    function tokenLockedTotal() external view returns (uint256);

    // Sum of all shares of users to wantLockedTotal
    function sharesTotal() external view returns (uint256);

    // Main want token compounding function
    function earn() external;

    // Transfer want tokens autoFarm -> strategy
    function deposit(
        address _userAddress,
        uint256 _wantAmt
    ) external returns (uint256);

    // Transfer want tokens strategy -> autoFarm
    function withdraw(
        address _userAddress,
        uint256 _wantAmt
    ) external returns (uint256);

    function inCaseTokensGetStuck(
        address _token,
        uint256 _amount,
        address _to
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.0;

import "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() external {
        address sender = _msgSender();
        require(pendingOwner() == sender, "Ownable2Step: caller is not the new owner");
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}