Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// File: @openzeppelin/contracts/utils/Context.sol


// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// File: @openzeppelin/contracts/access/Ownable.sol


// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)


/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// File: contracts/GMCounter.sol


contract GMCounter is Ownable {
    address public treasury;
    uint256 public fee;
    uint256 public referralFees;

    uint256 public constant BASIS_POINTS = 10000;

    mapping(address => uint256) public lastGM;

    uint256 public totalGMs;

    event GMSent(address indexed sender, address indexed referral);

    error InsufficientETH();
    error AlreadySentGM();
    error ReferralTransferFailed();
    error FeeTransferFailed();
    error SelfReferral();

    constructor(
        address _treasury,
        uint256 _fee,
        uint256 _referralFees
    ) Ownable(msg.sender) {
        treasury = _treasury;
        fee = _fee;
        referralFees = _referralFees;
    }

    function sayGM(address referral) external payable {
        if (msg.value < fee) {
            revert InsufficientETH();
        }

        if (referral == msg.sender) {
            revert SelfReferral();
        }

        uint256 today = block.timestamp / 86400;

        if (lastGM[msg.sender] == today) {
            revert AlreadySentGM();
        }

        lastGM[msg.sender] = today;
        
        totalGMs += 1;
        
        uint256 referralAmount = 0;

        if (referral != address(0)) {
            referralAmount = (msg.value * referralFees) / BASIS_POINTS;
            (bool refSuccess, ) = referral.call{value: referralAmount}("");
            if (!refSuccess) {
                revert ReferralTransferFailed();
            }
        }

        uint256 remaining = msg.value - referralAmount;

        (bool success, ) = treasury.call{value: remaining}("");

        if (!success) {
            revert FeeTransferFailed();
        }
        
        emit GMSent(msg.sender, referral);
    }

    function nextGMTimer(address user) external view returns (uint256) {
        uint256 today = block.timestamp / 86400;

        if (lastGM[user] < today) {
            return 0;
        }

        uint256 nextDay = (today + 1) * 86400;
        return nextDay - block.timestamp;
    }

    function setTreasury(address _treasury) external onlyOwner {
        require(_treasury != address(0), "Invalid treasury address");
        treasury = _treasury;
    }

    function setFee(uint256 _fee) external onlyOwner {
        require(_fee > 0, "Invalid fee");
        fee = _fee;
    }

    function setReferralFees(uint256 _referralFees) external onlyOwner {
        require(_referralFees < BASIS_POINTS, "Invalid referral fees");
        referralFees = _referralFees;
    }
}