Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: GPL-3.0
// solhint-disable-next-line
pragma solidity 0.8.12;

import "./interface/IERC1155Factory.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

/// @title Bulls and Apes Project - Traits Burner Helper
/// @author BAP Dev Team
/// @notice Handle the burning of Traits as deposit to be used off-chain
contract TraitsBurner is Ownable {
    /// @notice Master contract instance
    IERC1155Factory public traitsContract;

    /// @notice Event for Utilities burned on chain as deposit
    event TraitsBurnedOnChain(
        address user,
        uint256[] utilityIds,
        uint256[] amounts,
        uint256 timestamp
    );

    /// @notice Deploys the contract and sets the instances addresses
    /// @param traitsContractAddress: Address of the Master Contract
    constructor(
        address traitsContractAddress
    ) {
       traitsContract = IERC1155Factory(traitsContractAddress);
    }


    /// @notice Handle the burning of Traits as deposit to be used off-chain
    /// @param traitsIds: IDs of the Traits to burn
    /// @param amounts: Amounts to burn for each Utility
    /// @dev This contract must be approved by the user to spend the Traits
    function burnTraits(
        uint256[] memory traitsIds,
        uint256[] memory amounts
    ) external {
        require(
            traitsIds.length == amounts.length,
            "burnTraits: Arrays length mismatch"
        );

        for (uint256 i = 0; i < traitsIds.length; i++) {
            traitsContract.burn(msg.sender, traitsIds[i], amounts[i]);
        }

        emit TraitsBurnedOnChain(
            msg.sender,
            traitsIds,
            amounts,
            block.timestamp
        );
    }

    /// @notice Set the Traits Contract address   
    /// @param traitsContractAddress: Address of the Traits Contract
    function setTraitsContractAddress(
        address traitsContractAddress
    ) external onlyOwner {
        traitsContract = IERC1155Factory(traitsContractAddress);
    } 
}

// SPDX-License-Identifier: GPL-3.0
// solhint-disable-next-line
pragma solidity 0.8.12;

interface IERC1155Factory {
    function burn(
        address account,
        uint256 id,
        uint256 value
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}