Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

import '@openzeppelin/contracts/access/Ownable.sol';
import '@openzeppelin/contracts/interfaces/IERC20Metadata.sol';
import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import '@openzeppelin/contracts/utils/Context.sol';
import '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';

import './interfaces/IPriceFeed.sol';
import './interfaces/IVaultFactory.sol';
import './interfaces/IVaultFactoryConfig.sol';
import './interfaces/ILiquidationRouter.sol';

import './utils/constants.sol';
import './interfaces/ITokenPriceFeed.sol';
import './interfaces/IVaultExtraSettings.sol';
import './utils/linked-address-list.sol';

/**
 * @title Vault
 * @dev Manages creation, collateralization, borrowing, and liquidation of Vaults.
 */
contract Vault is Context, Constants {
    string public constant VERSION = '1.2.0';

    // Events emitted by the contract
    event CollateralAdded(
        address indexed collateral,
        uint256 amount,
        uint256 newTotalAmount
    );
    event CollateralRemoved(
        address indexed collateral,
        uint256 amount,
        uint256 newTotalAmount
    );
    event CollateralRedeemed(
        address indexed collateral,
        uint256 amount,
        uint256 newTotalAmount,
        uint256 stableAmountUsed,
        uint256 feePaid
    );

    event DebtAdded(uint256 amount, uint256 newTotalDebt);
    event DebtRepaid(uint256 amount, uint256 newTotalDebt);

    modifier onlyFactory() {
        require(_msgSender() == factory, 'only-factory');
        _;
    }

    using SafeERC20 for IERC20;
    using EnumerableSet for EnumerableSet.AddressSet;

    address public immutable stable;
    address public immutable factory;
    address public vaultOwner;

    string public name;

    EnumerableSet.AddressSet private collateralSet;
    EnumerableSet.AddressSet private operators;

    IVaultExtraSettings public vaultExtraSettings;
    mapping(address => uint256) public collateral;

    uint256 public debt;

    modifier onlyVaultOwner() {
        require(_msgSender() == vaultOwner, 'only-vault-owner');
        _;
    }

    /**
     * @dev Constructor to initialize the Vault contract.
     * @param _factory Address of the VaultFactory contract.
     * @param _vaultOwner Address of the initial owner of the Vault.
     * @param _name Name of the Vault.
     */
    constructor(
        address _factory,
        address _vaultOwner,
        string memory _name,
        IVaultExtraSettings _vaultExtraSettings
    ) {
        require(_vaultOwner != address(0x0), 'vault-owner-is-0');
        require(bytes(_name).length > 0, 'name-is-empty');
        require(_factory != address(0x0), 'factory-is-0');
        require(
            address(_vaultExtraSettings) != address(0x0),
            'vault-extra-settings-is-0'
        );

        factory = _factory;
        vaultOwner = _vaultOwner;
        stable = IVaultFactory(factory).stable();
        name = _name;
        vaultExtraSettings = _vaultExtraSettings;
    }

    /**
     * @dev Transfers ownership of the Vault to a new owner.
     * @param _newOwner Address of the new owner.
     */
    function transferVaultOwnership(address _newOwner) external onlyFactory {
        vaultOwner = _newOwner;
    }

    /**
     * @dev Sets a new name for the Vault.
     * @param _name New name for the Vault.
     */
    function setName(string memory _name) external onlyVaultOwner {
        require(bytes(_name).length > 0, 'name-is-empty');
        name = _name;
    }

    /**
     * @dev Adds an operator to the Vault, allowing them certain permissions.
     * @param _operator Address of the operator to be added.
     */
    function addOperator(address _operator) external onlyVaultOwner {
        require(_operator != address(0x0), 'operator-is-0');
        operators.add(_operator);
    }

    /**
     * @dev Removes an operator from the Vault, revoking their permissions.
     * @param _operator Address of the operator to be removed.
     */
    function removeOperator(address _operator) external onlyVaultOwner {
        require(_operator != address(0x0), 'operator-is-0');
        operators.remove(_operator);
    }

    /**
     * @dev Checks if an address is an operator for this Vault.
     * @param _operator Address to check.
     * @return Boolean indicating whether the address is an operator.
     */
    function isOperator(address _operator) external view returns (bool) {
        return operators.contains(_operator);
    }

    /**
     * @dev Returns the number of operators in the Vault.
     * @return Length of the operators set.
     */
    function operatorsLength() external view returns (uint256) {
        return operators.length();
    }

    /**
     * @dev Returns the operator at a given index in the operators set.
     * @param _index Index of the operator.
     * @return Address of the operator at the given index.
     */
    function operatorAt(uint256 _index) external view returns (address) {
        return operators.at(_index);
    }

    /**
     * @dev Checks if a collateral token is added to the Vault.
     * @param _collateral Address of the collateral token to check.
     * @return Boolean indicating whether the collateral token is added.
     */
    function containsCollateral(
        address _collateral
    ) external view returns (bool) {
        return collateralSet.contains(_collateral);
    }

    /**
     * @dev Returns the number of collateral tokens added to the Vault.
     * @return Length of the collateral set.
     */
    function collateralsLength() external view returns (uint256) {
        return collateralSet.length();
    }

    /**
     * @dev Returns the collateral token address at a given index in the collateral set.
     * @param _index Index of the collateral token.
     * @return Address of the collateral token at the given index.
     */
    function collateralAt(uint256 _index) external view returns (address) {
        return collateralSet.at(_index);
    }

    /**
     * @dev Returns an array containing all collateral token addresses in the Vault.
     * @return Array of collateral token addresses.
     */
    function collaterals() external view returns (address[] memory) {
        address[] memory _collaterals = new address[](collateralSet.length());
        for (uint256 i = 0; i < collateralSet.length(); i++) {
            _collaterals[i] = collateralSet.at(i);
        }
        return _collaterals;
    }

    /**
     * @dev Adds a new collateral token to the Vault and updates the collateral amount.
     * @param _collateral Address of the collateral token to add.
     * @param _amount Amount of the collateral token to add.
     */
    function addCollateral(
        address _collateral,
        uint256 _amount
    ) external onlyFactory {
        require(_collateral != address(0x0), 'collateral-is-0');
        require(_amount > 0, 'amount-is-0');

        collateralSet.add(_collateral);
        uint256 _maxTokens = IVaultFactory(factory).MAX_TOKENS_PER_VAULT();
        require(collateralSet.length() <= _maxTokens, 'max-tokens-reached');

        collateral[_collateral] += _amount;

        emit CollateralAdded(_collateral, _amount, collateral[_collateral]);
    }

    /**
     * @dev Removes a collateral token from the Vault and transfers it back to the sender.
     * @param _collateral Address of the collateral token to remove.
     * @param _amount Amount of the collateral token to remove.
     * @param _to Address to receive the removed collateral.
     */
    function removeCollateral(
        address _collateral,
        uint256 _amount,
        address _to
    ) external onlyFactory {
        require(_collateral != address(0x0), 'collateral-is-0');
        require(_amount > 0, 'amount-is-0');

        collateral[_collateral] -= _amount;
        if (collateral[_collateral] == 0) {
            collateralSet.remove(_collateral);
        }

        uint256 _healthFactor = healthFactor(false);
        require(_healthFactor >= DECIMAL_PRECISION, 'health-factor-below-1');

        IERC20(_collateral).safeTransfer(_to, _amount);

        emit CollateralRemoved(_collateral, _amount, collateral[_collateral]);
    }

    /**
     * @dev Adds bad debt to the Vault.
     * @param _amount Amount of bad debt to add.
     */
    function addBadDebt(uint256 _amount) external onlyFactory {
        require(_amount > 0, 'amount-is-0');

        debt += _amount;
        emit DebtAdded(_amount, debt);
    }

    /**
     * @dev Calculates the maximum borrowable amount and the current borrowable amount.
     * @return _maxBorrowable Maximum borrowable amount.
     * @return _borrowable Current borrowable amount.
     */
    function borrowable()
        public
        view
        returns (uint256 _maxBorrowable, uint256 _borrowable)
    {
        (_maxBorrowable, _borrowable) = borrowableWithDiff(
            address(0x0),
            0,
            false,
            false
        );
    }

    /**
     * @dev Borrows a specified amount from the Vault.
     * @param _amount Amount to borrow.
     */
    function borrow(uint256 _amount) external onlyFactory {
        require(_amount > 0, 'amount-is-0');

        (uint256 _maxBorrowable, uint256 _borrowable) = borrowable();
        require(_amount <= _borrowable, 'not-enough-borrowable');

        debt += _amount;
        require(debt <= _maxBorrowable, 'max-borrowable-reached');

        emit DebtAdded(_amount, debt);
    }

    /**
     * @dev Repays a specified amount to the Vault's debt.
     * @param _amount Amount to repay.
     */
    function repay(uint256 _amount) external onlyFactory {
        require(_amount <= debt, 'amount-exceeds-debt');

        debt -= _amount;
        emit DebtRepaid(_amount, debt);
    }

    /**
     * @dev Calculates the stable amount needed and the redemption fee for redeeming collateral.
     * @param _collateral Address of the collateral token.
     * @param _collateralAmount Amount of collateral to redeem.
     * @return _stableAmountNeeded Stablecoin amount required to redeem collateral.
     * @return _redemptionFee Fee charged for the redemption.
     */
    function calcRedeem(
        address _collateral,
        uint256 _collateralAmount
    )
        public
        view
        returns (uint256 _stableAmountNeeded, uint256 _redemptionFee)
    {
        ITokenPriceFeed _priceFeed = ITokenPriceFeed(
            IVaultFactory(factory).priceFeed()
        );
        uint256 _price = _priceFeed.tokenPrice(_collateral);

        uint256 _normalizedCollateralAmount = _collateralAmount *
            (10 ** (18 - _priceFeed.decimals(_collateral)));
        _stableAmountNeeded =
            (_normalizedCollateralAmount * _price) /
            DECIMAL_PRECISION;

        (, , uint256 _redemptionKickbackRate) = vaultExtraSettings
            .getExtraSettings();

        if (_redemptionKickbackRate > 0) {
            uint256 _kickbackAmount = (_stableAmountNeeded *
                _redemptionKickbackRate) / DECIMAL_PRECISION;
            _stableAmountNeeded += _kickbackAmount;
        }
        uint256 _redemptionRate = IVaultFactoryConfig(factory).redemptionRate();
        _redemptionFee =
            (_stableAmountNeeded * _redemptionRate) /
            DECIMAL_PRECISION;
    }

    /**
     * @dev Redeems a specified amount of collateral, repays debt, and transfers collateral back to the redeemer.
     * @param _collateral Address of the collateral token to redeem.
     * @param _collateralAmount Amount of collateral to redeem.
     * @return _debtRepaid Amount of debt repaid.
     * @return _feeCollected Fee collected for the redemption.
     */
    function redeem(
        address _collateral,
        uint256 _collateralAmount
    )
        external
        onlyFactory
        returns (uint256 _debtRepaid, uint256 _feeCollected)
    {
        require(_collateral != address(0x0), 'collateral-is-0');
        require(_collateralAmount > 0, 'amount-is-0');
        require(collateralSet.contains(_collateral), 'collateral-not-added');
        require(
            collateral[_collateral] >= _collateralAmount,
            'not-enough-collateral'
        );

        uint256 _currentHealthFactor = healthFactor(true);
        uint256 _redemptionHealthFactorLimit = IVaultFactoryConfig(factory)
            .redemptionHealthFactorLimit();
        require(
            _currentHealthFactor < _redemptionHealthFactorLimit,
            'health-factor-above-redemption-limit'
        );

        (uint256 _debtTreshold, uint256 _maxRedeemablePercentage, ) = vaultExtraSettings
            .getExtraSettings();

        
        collateral[_collateral] -= _collateralAmount;
        (_debtRepaid, _feeCollected) = calcRedeem(
            _collateral,
            _collateralAmount
        );

        
        if (debt > _debtTreshold) {
            uint256 _redeemableDebt = (debt * _maxRedeemablePercentage) /
                DECIMAL_PRECISION;
            require(_debtRepaid <= _redeemableDebt, 'redeemable-debt-exceeded');

        }

        debt -= _debtRepaid;

        if (collateral[_collateral] == 0) {
            collateralSet.remove(_collateral);
        }

        IERC20(_collateral).safeTransfer(_msgSender(), _collateralAmount);

        emit CollateralRedeemed(
            _collateral,
            _collateralAmount,
            collateral[_collateral],
            _debtRepaid,
            _feeCollected
        );
        emit DebtRepaid(_debtRepaid, debt);
    }

    /**
     * @dev Computes the health factor of the Vault.
     * @param _useMlr Flag to use Minimum Loan Ratio (MLR) in health factor computation.
     * @return _healthFactor Current health factor.
     */
    function healthFactor(
        bool _useMlr
    ) public view returns (uint256 _healthFactor) {
        if (debt == 0) {
            return type(uint256).max;
        }

        (uint256 _maxBorrowable, ) = borrowableWithDiff(
            address(0x0),
            0,
            false,
            _useMlr
        );

        _healthFactor = (_maxBorrowable * DECIMAL_PRECISION) / debt;
    }

    /**
     * @dev Computes a new health factor given a new debt value.
     * @param _newDebt New debt amount to calculate the health factor.
     * @param _useMlr Flag to use Minimum Loan Ratio (MLR) in health factor computation.
     * @return _newHealthFactor Calculated new health factor based on the new debt value.
     */
    function newHealthFactor(
        uint256 _newDebt,
        bool _useMlr
    ) public view returns (uint256 _newHealthFactor) {
        if (_newDebt == 0) {
            return type(uint256).max;
        }

        (uint256 _maxBorrowable, ) = borrowableWithDiff(
            address(0x0),
            0,
            false,
            _useMlr
        );
        _newHealthFactor = (_maxBorrowable * DECIMAL_PRECISION) / _newDebt;
    }

    /**
     * @dev Computes the maximum borrowable amount and the current borrowable amount.
     * @param _collateral Address of the collateral token (0x0 for total vault borrowable).
     * @param _diffAmount Difference in collateral amount when adding/removing collateral.
     * @param _isAdd Flag indicating whether the collateral is added or removed.
     * @param _useMlr Flag to use Minimum Loan Ratio (MLR) in borrowable computation.
     * @return _maxBorrowable Maximum borrowable amount.
     * @return _borrowable Current borrowable amount based on the collateral.
     */
    function borrowableWithDiff(
        address _collateral,
        uint256 _diffAmount,
        bool _isAdd,
        bool _useMlr
    ) public view returns (uint256 _maxBorrowable, uint256 _borrowable) {
        uint256 _newCollateralAmount = collateral[_collateral];

        uint256 _borrowableAmount = 0;

        if (_collateral != address(0x0)) {
            require(
                IVaultFactory(factory).isCollateralSupported(_collateral),
                'collateral-not-supported'
            );
            if (_isAdd) {
                _newCollateralAmount += _diffAmount;
            } else {
                _newCollateralAmount -= _diffAmount;
            }
        }

        ITokenPriceFeed _priceFeed = ITokenPriceFeed(
            IVaultFactory(factory).priceFeed()
        );

        for (uint256 i = 0; i < collateralSet.length(); i++) {
            address _c = collateralSet.at(i);
            uint256 _collateralAmount = _c == _collateral
                ? _newCollateralAmount
                : collateral[_c];
            uint256 _price = _priceFeed.tokenPrice(_c);
            uint256 _divisor = _useMlr
                ? _priceFeed.mlr(_c)
                : _priceFeed.mcr(_c);
            uint256 _normalizedCollateralAmount = _collateralAmount *
                (10 ** (18 - _priceFeed.decimals(_c)));

            uint256 _collateralBorrowable = (_normalizedCollateralAmount *
                _price) / DECIMAL_PRECISION;

            _borrowableAmount +=
                (_collateralBorrowable * DECIMAL_PRECISION) /
                _divisor;
        }

        return (
            _borrowableAmount,
            (_borrowableAmount > debt) ? _borrowableAmount - debt : 0
        );
    }

    /**
     * @dev Liquidates the vault by repaying all debts with seized collateral.
     * @return _forgivenDebt Amount of debt forgiven during liquidation.
     */
    function liquidate() external onlyFactory returns (uint256 _forgivenDebt) {
        require(
            healthFactor(true) < DECIMAL_PRECISION,
            'liquidation-factor-above-1'
        );

        uint256 _debt = debt;
        debt = 0;
        ILiquidationRouter router = ILiquidationRouter(
            IVaultFactory(factory).liquidationRouter()
        );
        for (uint256 i = 0; i < collateralSet.length(); i++) {
            address _collateral = collateralSet.at(i);
            uint256 _collateralAmount = collateral[_collateral];
            uint256 _actualCollateralBalance = IERC20(_collateral).balanceOf(
                address(this)
            );
            if (_actualCollateralBalance < _collateralAmount) {
                _collateralAmount = _actualCollateralBalance;
            }
            collateral[_collateral] = 0;

            IERC20(_collateral).safeIncreaseAllowance(
                IVaultFactory(factory).liquidationRouter(),
                _collateralAmount
            );

            router.addSeizedCollateral(_collateral, _collateralAmount);
        }
        router.addUnderWaterDebt(address(this), _debt);
        router.tryLiquidate();
        _forgivenDebt = _debt;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

/*

                                              
 _____ _____ _____    _____ _____ _____ _____ 
|_   _|  _  |     |  | __  |  _  |   | |  |  |
  | | |     |  |  |  | __ -|     | | | |    -|
  |_| |__|__|_____|  |_____|__|__|_|___|__|__|
                                              
*/

import '@openzeppelin/contracts/interfaces/IERC20Metadata.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';
import '@openzeppelin/contracts/utils/ReentrancyGuard.sol';

import './utils/linked-address-list.sol';
import './Vault.sol';
import './VaultFactoryConfig.sol';
import './VaultFactoryList.sol';
import './interfaces/IWETH.sol';
import './interfaces/ITokenPriceFeed.sol';
import './interfaces/IPriceFeed.sol';
import './interfaces/IMintableTokenOwner.sol';
import './interfaces/IMintableToken.sol';
import './interfaces/IVaultDeployer.sol';
import './interfaces/IVaultBorrowRate.sol';

/**
 * @title VaultFactory
 * @dev Manages the creation, configuration, and operations of Vaults with collateral and borrowing functionality.
 */
contract VaultFactory is ReentrancyGuard, VaultFactoryConfig, VaultFactoryList {
    // Events emitted by the contract
    event NewVault(address indexed vault, string name, address indexed owner);
    event VaultOwnerChanged(
        address indexed vault,
        address indexed oldOwner,
        address indexed newOwner
    );

    // Libraries used by the contract
    using LinkedAddressList for LinkedAddressList.List;
    using SafeERC20 for IERC20;
    using SafeERC20 for IMintableToken;

    // Immutable state variables
    address public immutable stable;
    address public immutable nativeWrapped;
    IMintableTokenOwner public immutable mintableTokenOwner;

    // State variables
    mapping(address => uint256) public collateral;
    uint256 public totalDebt;

    /**
     * @dev Constructor to initialize essential addresses and contracts for VaultFactory.
     * @param _mintableTokenOwner Address of the Mintable Token Owner contract.
     * @param _nativeWrapped Address of the native wrapped token.
     * @param _priceFeed Address of the price feed contract.
     * @param _vaultDeployer Address of the Vault Deployer contract.
     * @param _liquidationRouter Address of the liquidation router contract.
     * @param _borrowRate Address of the borrow rate contract.
     */
    constructor(
        address _mintableTokenOwner,
        address _nativeWrapped,
        address _priceFeed,
        address _vaultDeployer,
        address _liquidationRouter,
        address _borrowRate
    ) VaultFactoryConfig(_vaultDeployer, _liquidationRouter) Ownable(msg.sender) {
        require(
            _mintableTokenOwner != address(0x0),
            'mintable-token-owner-is-0'
        );

        mintableTokenOwner = IMintableTokenOwner(_mintableTokenOwner);
        stable = address(mintableTokenOwner.token());

        require(stable != address(0x0), 'stable-is-0');
        require(_nativeWrapped != address(0x0), 'nativew-is-0');
        require(_priceFeed != address(0x0), 'pricefeed-is-0');
        require(_borrowRate != address(0x0), 'borrow-rate-is-0');

        borrowRate = _borrowRate;
        nativeWrapped = _nativeWrapped;
        priceFeed = _priceFeed;
    }

    /**
     * @dev Fallback function to receive Ether and restricts its usage to a designated sender.
     */
    receive() external payable {
        require(msg.sender == nativeWrapped, 'only-native-wrapped');
    }

    /**
     * @dev Modifier: Allows function execution only by the owner of a specific vault.
     * @param _vault The address of the vault to check ownership.
     */
    modifier onlyVaultOwner(address _vault) {
        require(Vault(_vault).vaultOwner() == _msgSender(), 'only-vault-owner');
        _;
    }

    /**
     * @dev Modifier: Allows function execution by the owner or an operator of a specific vault.
     * @param _vault The address of the vault to check ownership or operator status.
     */
    modifier onlyVaultOwnerOrOperator(address _vault) {
        require(
            Vault(_vault).vaultOwner() == _msgSender() ||
                Vault(_vault).isOperator(_msgSender()),
            'only-vault-owner-or-operator'
        );
        _;
    }

    /**
     * @dev Modifier: Allows function execution only by the liquidation router.
     */
    modifier onlyLiquidationRouter() {
        require(liquidationRouter == _msgSender(), 'only-liquidation-router');
        _;
    }

    /**
     * @dev Checks if a given collateral token is supported.
     * @param _collateral The address of the collateral token.
     * @return A boolean indicating whether the collateral token is supported.
     */
    function isCollateralSupported(
        address _collateral
    ) external view returns (bool) {
        return _isCollateralSupported(_collateral);
    }

    /**
     * @dev Transfers ownership of a vault to a new owner.
     * @param _vault The address of the vault to transfer ownership.
     * @param _newOwner The address of the new owner to receive the vault ownership.
     */
    function transferVaultOwnership(
        address _vault,
        address _newOwner
    ) external onlyVaultOwner(_vault) {
        address _msgSender = _msgSender();
        require(_newOwner != address(0x0), 'new-owner-is-0');
        require(containsVault(_vault), 'vault-not-found');

        emit VaultOwnerChanged(_vault, _msgSender, _newOwner);
        Vault(_vault).transferVaultOwnership(_newOwner);
        _transferVault(_msgSender, _newOwner, _vault);
    }

    /**
     * @dev Creates a new vault with a specified name.
     * @param _name The name of the new vault.
     * @return The address of the newly created vault.
     */
    function createVault(string memory _name) public returns (address) {
        address _msgSender = _msgSender();
        address _vaultAddress = IVaultDeployer(vaultDeployer).deployVault(
            address(this),
            _msgSender,
            _name
        );
        _addVault(_msgSender, _vaultAddress);
        emit NewVault(_vaultAddress, _name, _msgSender);

        return _vaultAddress;
    }

    /**
     * @dev Checks if a specific collateral token is supported for the vault.
     * @param _collateral The address of the collateral token to check.
     * @return A boolean indicating whether the collateral token is supported.
     */
    function _isCollateralSupported(
        address _collateral
    ) internal view returns (bool) {
        ITokenPriceFeed _priceFeed = ITokenPriceFeed(priceFeed);
        return (_priceFeed.tokenPriceFeed(_collateral) != address(0x0));
    }

    /**
     * @dev Adds native-wrapped collateral to a specific vault.
     * @param _vault The address of the vault to add collateral.
     */
    function addCollateralNative(address _vault) external payable {
        require(containsVault(_vault), 'vault-not-found');
        require(
            _isCollateralSupported(nativeWrapped),
            'collateral-not-supported'
        );
        uint256 _amount = msg.value;

        collateral[nativeWrapped] += _amount;

        require(
            collateral[nativeWrapped] <= collateralCap[nativeWrapped],
            'collateral-cap-reached'
        );

        IWETH(nativeWrapped).deposit{value: _amount}();


        IERC20(nativeWrapped).safeTransfer(_vault, _amount);

        Vault(_vault).addCollateral(nativeWrapped, _amount);

    }

    /**
     * @dev Removes native-wrapped collateral from a specific vault.
     * @param _vault The address of the vault to remove collateral.
     * @param _amount The amount of collateral to be removed.
     * @param _to The address where the removed collateral is transferred.
     */
    function removeCollateralNative(
        address _vault,
        uint256 _amount,
        address _to
    ) external onlyVaultOwner(_vault) {
        require(containsVault(_vault), 'vault-not-found');
        require(
            _isCollateralSupported(nativeWrapped),
            'collateral-not-supported'
        );

        Vault(_vault).removeCollateral(nativeWrapped, _amount, address(this));

        collateral[nativeWrapped] -= _amount;

        IWETH(nativeWrapped).withdraw(_amount);
        (bool success, ) = payable(_to).call{value: _amount}("");
        require(success, 'transfer-failed');
    }

    /**
     * @dev Adds a specific collateral to a vault.
     * @param _vault The address of the vault to add collateral.
     * @param _collateral The address of the collateral token to add.
     * @param _amount The amount of collateral to add.
     */
    function addCollateral(
        address _vault,
        address _collateral,
        uint256 _amount
    ) external {
        require(containsVault(_vault), 'vault-not-found');
        require(
            _isCollateralSupported(_collateral),
            'collateral-not-supported'
        );

        collateral[_collateral] += _amount;

        require(
            collateral[_collateral] <= collateralCap[_collateral],
            'collateral-cap-reached'
        );

        IERC20(_collateral).safeTransferFrom(_msgSender(), _vault, _amount);
        Vault(_vault).addCollateral(_collateral, _amount);
    }

    /**
     * @dev Removes a specific collateral from a vault.
     * @param _vault The address of the vault to remove collateral.
     * @param _collateral The address of the collateral token to remove.
     * @param _amount The amount of collateral to remove.
     * @param _to The address where the removed collateral is transferred.
     */
    function removeCollateral(
        address _vault,
        address _collateral,
        uint256 _amount,
        address _to
    ) external onlyVaultOwner(_vault) {
        require(containsVault(_vault), 'vault-not-found');
        require(
            _isCollateralSupported(_collateral),
            'collateral-not-supported'
        );

        collateral[_collateral] -= _amount;
        Vault(_vault).removeCollateral(_collateral, _amount, _to);
    }

    /**
     * @dev Borrows funds from a vault by its owner or an operator.
     * @param _vault The address of the vault from which funds are borrowed.
     * @param _amount The amount of funds to borrow.
     * @param _to The address where borrowed funds are sent.
     */
    function borrow(
        address _vault,
        uint256 _amount,
        address _to
    ) external onlyVaultOwnerOrOperator(_vault) {
        require(containsVault(_vault), 'vault-not-found');
        require(_to != address(0x0), 'to-is-0');

        totalDebt += _amount;
        _updateDebtWindow(_amount);
        Vault(_vault).borrow(_amount);
        uint256 _borrowRate = IVaultBorrowRate(borrowRate).getBorrowRate(
            _vault
        );
        uint256 _feeAmount = (_amount * _borrowRate) / DECIMAL_PRECISION;

        mintableTokenOwner.mint(_to, _amount - _feeAmount);
        mintableTokenOwner.mint(borrowFeeRecipient, _feeAmount);
    }

    /**
     * @dev Distributes bad debt to a specific vault.
     * @param _vault The address of the vault to distribute bad debt.
     * @param _amount The amount of bad debt to be distributed.
     */
    function distributeBadDebt(
        address _vault,
        uint256 _amount
    ) external nonReentrant onlyLiquidationRouter {
        require(containsVault(_vault), 'vault-not-found');
        totalDebt += _amount;
        Vault(_vault).addBadDebt(_amount);
    }

    /**
     * @dev Closes a vault if it meets specific conditions.
     * @param _vault The address of the vault to close.
     */
    function closeVault(address _vault) external onlyVaultOwner(_vault) {
        require(containsVault(_vault), 'vault-not-found');
        require(Vault(_vault).debt() == 0, 'debt-not-0');
        require(Vault(_vault).collateralsLength() == 0, 'collateral-not-0');

        _removeVault(_msgSender(), _vault);
    }

    /**
     * @dev Repays borrowed funds for a specific vault.
     * @param _vault The address of the vault for which funds are repaid.
     * @param _amount The amount of funds to repay.
     */
    function repay(address _vault, uint256 _amount) external onlyVaultOwner(_vault) {
        require(containsVault(_vault), 'vault-not-found');
        totalDebt -= _amount;
        Vault(_vault).repay(_amount);

        IMintableToken(stable).safeTransferFrom(
            _msgSender(),
            address(this),
            _amount
        );
        IMintableToken(stable).burn(_amount);
    }

    /**
     * @dev Redeems collateral from a vault after meeting specific conditions.
     * @param _vault The address of the vault from which collateral is redeemed.
     * @param _collateral The address of the collateral token to redeem.
     * @param _collateralAmount The amount of collateral to redeem.
     * @param _to The address where the redeemed collateral is transferred.
     */
    function redeem(
        address _vault,
        address _collateral,
        uint256 _collateralAmount,
        address _to
    ) external nonReentrant {
        require(publicRedemptions || isAddressRedemptionAllowed[_msgSender()], 'redemption-not-allowed');
        require(containsVault(_vault), 'vault-not-found');
        require(_to != address(0x0), 'to-is-0');

        require(isReedemable(_vault, _collateral), 'not-redeemable');

        (uint256 _debtRepaid, uint256 _feeCollected) = Vault(_vault).redeem(
            _collateral,
            _collateralAmount
        );

        totalDebt -= _debtRepaid;
        collateral[_collateral] -= _collateralAmount;

        IMintableToken(stable).safeTransferFrom(
            _msgSender(),
            address(this),
            _debtRepaid + _feeCollected
        );
        IMintableToken(stable).burn(_debtRepaid);
        IMintableToken(stable).transfer(redemptionFeeRecipient, _feeCollected);

        IERC20(_collateral).safeTransfer(_to, _collateralAmount);
    }

    /**
     * @dev Liquidates a specific vault if it is eligible for liquidation.
     * @param _vault The address of the vault to be liquidated.
     */
    function liquidate(address _vault) external nonReentrant {
        require(containsVault(_vault), 'vault-not-found');

        address _vaultOwner = Vault(_vault).vaultOwner();
        uint256 _forgivenDebt = Vault(_vault).liquidate();

        totalDebt -= _forgivenDebt;

        _removeVault(_vaultOwner, _vault);
    }

    /**
     * @dev Checks if a vault is eligible for liquidation.
     * @param _vault The address of the vault to check for liquidation eligibility.
     * @return A boolean indicating whether the vault is liquidatable.
     */
    function isLiquidatable(address _vault) external view returns (bool) {
        require(containsVault(_vault), 'vault-not-found');
        return Vault(_vault).healthFactor(true) < DECIMAL_PRECISION;
    }

    /**
     * @dev Checks if a specific collateral can be redeemed from a vault based on conditions.
     * @param _vault The address of the vault to check for collateral redemption.
     * @param _collateral The address of the collateral token to check for redemption.
     * @notice Collateral with higher MCR can be redeemed first
     * @return A boolean indicating whether the collateral is redeemable.
     */
    function isReedemable(
        address _vault,
        address _collateral
    ) public view returns (bool) {
        require(
            _isCollateralSupported(_collateral),
            'collateral-not-supported'
        );
        if (!Vault(_vault).containsCollateral(_collateral)) {
            return false;
        }
        uint256 _healthFactor = Vault(_vault).healthFactor(false);
        if (_healthFactor >= redemptionHealthFactorLimit) {
            return false;
        }

        ITokenPriceFeed _priceFeed = ITokenPriceFeed(priceFeed);
        uint256 _collateralMcr = _priceFeed.mcr(_collateral);

        address[] memory _collaterals = Vault(_vault).collaterals();
        uint256 _length = _collaterals.length;

        for (uint256 i; i < _length; i++) {
            if (_collaterals[i] != _collateral) {
                uint256 _mcr = _priceFeed.mcr(_collaterals[i]);
                if (_mcr > _collateralMcr) {
                    return false;
                }
            }
        }
        return true;
    }

    /**
     * @dev Updates the debt window with the newly incurred debt.
     * @param _newDebt The amount of new debt to update in the debt window.
     */
    function _updateDebtWindow(uint256 _newDebt) internal {
        require(totalDebt <= debtCeiling, 'debt-ceiling-reached');

        if (block.timestamp > lastDebtWindow + debtWindowSize) {
            debtWindowAmount = _newDebt;
            lastDebtWindow = block.timestamp;
        } else {
            debtWindowAmount += _newDebt;
        }
        require(
            debtWindowAmount <= maxDebtPerWindow,
            'debt-window-amount-reached'
        );
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

/**
 * @title Constants
 * @dev This contract defines various constants used within the system.
 */
contract Constants {
    // Precision used for decimal calculations
    uint256 public constant DECIMAL_PRECISION = 1e18;

    // Reserve required for liquidation purposes
    uint256 public constant LIQUIDATION_RESERVE = 1e18;

    // Maximum value for uint256
    uint256 public constant MAX_INT = 2 ** 256 - 1;

    // Constants for percentage calculations
    uint256 public constant PERCENT = (DECIMAL_PRECISION * 1) / 100; // Represents 1%
    uint256 public constant PERCENT10 = PERCENT * 10; // Represents 10%
    uint256 public constant PERCENT_05 = PERCENT / 2; // Represents 0.5%

    // Maximum borrowing and redemption rates
    uint256 public constant MAX_BORROWING_RATE = (DECIMAL_PRECISION * 5) / 100; // Represents 5%
    uint256 public constant MAX_REDEMPTION_RATE =
        (DECIMAL_PRECISION * 10) / 100; // Represents 10%
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;
import './utils/constants.sol';
import './utils/linked-address-list.sol';
// import openzeppelin context
import '@openzeppelin/contracts/utils/Context.sol';
import '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';

/**
 * @title VaultFactoryList
 * @dev Manages a list of vaults by their owners, allowing addition, removal, and transfer of vaults.
 */
abstract contract VaultFactoryList is Context {
    using LinkedAddressList for LinkedAddressList.List;
    using EnumerableSet for EnumerableSet.AddressSet;

    LinkedAddressList.List _vaults;
    mapping(address => EnumerableSet.AddressSet) private _vaultsByOwner;

    function vaultsByOwnerLength(
        address _owner
    ) external view returns (uint256) {
        return _vaultsByOwner[_owner].length();
    }

    function vaultsByOwner(
        address _owner,
        uint256 _index
    ) external view returns (address) {
        return _vaultsByOwner[_owner].at(_index);
    }

    function _addVault(address _owner, address _vault) internal {
        require(
            _vaults.add(_vault, address(0x0), false),
            'vault-could-not-be-added'
        );
        _vaultsByOwner[_owner].add(_vault);
    }

    function _transferVault(
        address _from,
        address _to,
        address _vault
    ) internal {
        _vaultsByOwner[_from].remove(_vault);
        _vaultsByOwner[_to].add(_vault);
    }

    function _removeVault(address _owner, address _vault) internal {
        require(_vaults.remove(_vault), 'vault-could-not-be-removed');
        _vaultsByOwner[_owner].remove(_vault);
    }

    /**
     * @dev returns the number of vaults for specific token
     */
    function vaultCount() public view returns (uint256) {
        return _vaults._size;
    }

    /**
     * @dev returns the last vault by maximum collaterization ratio
     */
    function lastVault() public view returns (address) {
        return _vaults._last;
    }

    /**
     * @dev returns the first vault by minimal collaterization ratio
     */
    function firstVault() public view returns (address) {
        return _vaults._first;
    }

    /**
     * @dev returns the next vault by collaterization ratio
     */
    function nextVault(address _vault) public view returns (address) {
        return _vaults._values[_vault].next;
    }

    /**
     * @dev returns the previous vault by collaterization ratio
     */
    function prevVault(address _vault) public view returns (address) {
        return _vaults._values[_vault].prev;
    }

    /**
     * @dev Checks if a vault exists for a specific token.
     * @param _vault The address of the vault to check.
     * @return A boolean indicating whether the vault exists.
     */
    function containsVault(address _vault) public view returns (bool) {
        return _vaults._values[_vault].next != address(0x0);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IWETH {
    function deposit() external payable;

    function approve(address, uint256) external returns (bool);

    function transfer(address _to, uint256 _value) external returns (bool);

    function withdraw(uint256) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;
import './utils/constants.sol';
import '@openzeppelin/contracts/access/Ownable.sol';

abstract contract VaultFactoryConfig is Constants, Ownable {
    event PriceFeedUpdated(address indexed priceFeed);
    event MaxTokensPerVaultUpdated(
        uint256 oldMaxTokensPerVault,
        uint256 newMaxTokensPerVault
    );
    event RedemptionRateUpdated(
        uint256 oldRedemptionRate,
        uint256 newRedemptionRate
    );
    event BorrowRateUpdated(address oldBorrowRate, address newBorrowRate);
    event RedemptionHealthFactorLimitUpdated(
        uint256 oldRedemptionHealthFactorLimit,
        uint256 newRedemptionHealthFactorLimit
    );
    event DebtCeilingUpdated(uint256 oldDebtCeiling, uint256 newDebtCeiling);
    event MaxDebtPerWindowUpdated(
        uint256 oldMaxDebtPerWindow,
        uint256 newMaxDebtPerWindow
    );
    event DebtWindowSizeUpdated(
        uint256 oldDebtWindowSize,
        uint256 newDebtWindowSize
    );
    event CollateralCapacityUpdated(
        address indexed collateral,
        uint256 oldCapacity,
        uint256 newCapacity
    );
    event liquidationRouterUpdated(address indexed liquidationRouter);

    event publicRedemptionsUpdated(bool publicRedemptions);

    // Various configuration parameters
    address public priceFeed;
    address public borrowRate;

    uint256 public MAX_TOKENS_PER_VAULT = 5;
    uint256 public redemptionRate = PERCENT_05; // 0.5%

    uint256 public redemptionHealthFactorLimit = 1.5 ether; // 1.5 HF

    address public borrowFeeRecipient;
    address public redemptionFeeRecipient;

    mapping(address => uint256) public collateralCap;

    uint256 public debtCeiling = type(uint256).max; // max stablecoin debt issued by the protocol

    uint256 public maxDebtPerWindow = 200_000 ether; // 200K
    uint256 public debtWindowSize = 1 hours;
    uint256 public lastDebtWindow;
    uint256 public debtWindowAmount;

    address public vaultDeployer;
    address public liquidationRouter;

    bool public publicRedemptions;

    mapping(address => bool) public isAddressRedemptionAllowed;

    /**
     * @dev Set the public redemptions flag
     * @param _publicRedemptions The new public redemptions flag to be set.
     */
    function setPublicRedemptions(bool _publicRedemptions) external onlyOwner {
        publicRedemptions = _publicRedemptions;
        emit publicRedemptionsUpdated(_publicRedemptions);
    }

    /**
     * @dev Set the redemption allowed for a specific address
     * @param _address Address of the account
     * @param _allowed The new redemption allowed flag to be set.
     */
    function setRedemptionAllowed(address _address, bool _allowed)
        external
        onlyOwner
    {
        isAddressRedemptionAllowed[_address] = _allowed;
    }

    /**
     * @dev Set the address for the Vault Deployer
     * @param _vaultDeployer Address of the Vault Deployer
     */
    function setVaultDeployer(address _vaultDeployer) external onlyOwner {
        require(_vaultDeployer != address(0x0), 'vault-deployer-is-0');
        vaultDeployer = _vaultDeployer;
    }

    /**
     * @dev Set the address for the Liquidation Router
     * @param _liquidationRouter Address of the Liquidation Router
     */
    function setLiquidationRouter(
        address _liquidationRouter
    ) external onlyOwner {
        require(_liquidationRouter != address(0x0), 'liquidation-router-is-0');
        liquidationRouter = _liquidationRouter;
        emit liquidationRouterUpdated(_liquidationRouter);
    }

    /**
     * @dev Set the collateral capacity for a specific collateral token
     * @param _collateral Address of the collateral token
     * @param _cap The new capacity for the collateral token
     */
    function setCollateralCapacity(
        address _collateral,
        uint256 _cap
    ) external onlyOwner {
        require(_collateral != address(0x0), 'collateral-is-0');
        emit CollateralCapacityUpdated(
            _collateral,
            collateralCap[_collateral],
            _cap
        );
        collateralCap[_collateral] = _cap;
    }

    /**
     * @dev Set the debt ceiling value.
     * @param _debtCeiling The new debt ceiling value to be set.
     */
    function setDebtCeiling(uint256 _debtCeiling) external onlyOwner {
        emit DebtCeilingUpdated(debtCeiling, _debtCeiling);
        debtCeiling = _debtCeiling;
    }

    /**
     * @dev Set the maximum debt allowed per window.
     * @param _maxDebtPerWindow The new maximum debt per window value to be set.
     */
    function setMaxDebtPerWindow(uint256 _maxDebtPerWindow) external onlyOwner {
        emit MaxDebtPerWindowUpdated(maxDebtPerWindow, _maxDebtPerWindow);
        maxDebtPerWindow = _maxDebtPerWindow;
    }

    /**
     * @dev Set the window size for debt.
     * @param _debtWindowSize The new debt window size value to be set.
     */
    function setDebtWindowSize(uint256 _debtWindowSize) external onlyOwner {
        emit DebtWindowSizeUpdated(debtWindowSize, _debtWindowSize);
        debtWindowSize = _debtWindowSize;
    }

    /**
     * @dev Set the maximum tokens allowed per vault.
     * @param _maxTokensPerVault The new maximum tokens per vault value to be set.
     */
    function setMaxTokensPerVault(
        uint256 _maxTokensPerVault
    ) external onlyOwner {
        require(_maxTokensPerVault > 0, 'max-tokens-per-vault-is-0');
        emit MaxTokensPerVaultUpdated(MAX_TOKENS_PER_VAULT, _maxTokensPerVault);
        MAX_TOKENS_PER_VAULT = _maxTokensPerVault;
    }

    /**
     * @dev Set the address for the price feed.
     * @param _priceFeed Address of the new price feed contract.
     */
    function setPriceFeed(address _priceFeed) external onlyOwner {
        require(_priceFeed != address(0x0), 'pricefeed-is-0');
        priceFeed = _priceFeed;
        emit PriceFeedUpdated(_priceFeed);
    }

    /**
     * @dev Set the redemption rate for the protocol.
     * @param _redemptionRate The new redemption rate value to be set.
     */
    function setRedemptionRate(uint256 _redemptionRate) external onlyOwner {
        require(
            _redemptionRate <= MAX_REDEMPTION_RATE,
            'redemption-rate-too-high'
        );
        emit RedemptionRateUpdated(redemptionRate, _redemptionRate);
        redemptionRate = _redemptionRate;
    }

    /**
     * @dev Set the address for the borrow rate.
     * @param _borrowRate Address of the new borrow rate contract.
     */
    function setBorrowRate(address _borrowRate) external onlyOwner {
        require(_borrowRate != address(0), 'borrow-rate-is-0');
        emit BorrowRateUpdated(borrowRate, _borrowRate);
        borrowRate = _borrowRate;
    }

    /**
     * @dev Set the redemption health factor limit.
     * @param _redemptionHealthFactorLimit The new redemption health factor limit to be set.
     */
    function setRedemptionHealthFactorLimit(
        uint256 _redemptionHealthFactorLimit
    ) external onlyOwner {
        emit RedemptionHealthFactorLimitUpdated(
            redemptionHealthFactorLimit,
            _redemptionHealthFactorLimit
        );
        redemptionHealthFactorLimit = _redemptionHealthFactorLimit;
    }

    /**
     * @dev Set the address for the borrow fee recipient.
     * @param _borrowFeeRecipient Address of the new borrow fee recipient.
     */
    function setBorrowFeeRecipient(
        address _borrowFeeRecipient
    ) external onlyOwner {
        require(
            _borrowFeeRecipient != address(0x0),
            'borrow-fee-recipient-is-0'
        );
        borrowFeeRecipient = _borrowFeeRecipient;
    }

    /**
     * @dev Set the address for the redemption fee recipient.
     * @param _redemptionFeeRecipient Address of the new redemption fee recipient.
     */
    function setRedemptionFeeRecipient(
        address _redemptionFeeRecipient
    ) external onlyOwner {
        require(
            _redemptionFeeRecipient != address(0x0),
            'redemption-fee-recipient-is-0'
        );
        redemptionFeeRecipient = _redemptionFeeRecipient;
    }

    /**
     * @dev Constructor to initialize the configuration settings upon deployment
     * @param _vaultDeployer Address of the Vault Deployer
     * @param _liquidationRouter Address of the Liquidation Router
     */
    constructor(address _vaultDeployer, address _liquidationRouter) {
        require(_vaultDeployer != address(0x0), 'vault-deployer-is-0');
        require(_liquidationRouter != address(0x0), 'liquidation-factory-is-0');
        vaultDeployer = _vaultDeployer;
        borrowFeeRecipient = _msgSender();
        redemptionFeeRecipient = _msgSender();
        lastDebtWindow = block.timestamp;
        liquidationRouter = _liquidationRouter;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IOwnable {
    /**
     * @dev Returns the address of the current owner.
     */
    function owner() external view returns (address);

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IPriceFeed {
    function token() external view returns (address);

    function price() external view returns (uint256);

    function pricePoint() external view returns (uint256);

    function emitPriceSignal() external;

    event PriceUpdate(address token, uint256 price, uint256 average);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IVaultFactory {
    event NewVault(address indexed vault, string name, address indexed owner);
    event PriceFeedUpdated(address indexed priceFeed);

    function setPriceFeed(address _priceFeed) external;
    function vaultCount() external view returns (uint256);
    function lastVault() external view returns (address);
    function firstVault() external view returns (address);
    function nextVault(address _vault) external view returns (address);
    function prevVault(address _vault) external view returns (address);
    function liquidationRouter() external view returns (address);
    function MAX_TOKENS_PER_VAULT() external view returns (uint256);
    function priceFeed() external view returns (address);
    function transferVaultOwnership(address _vault, address _newOwner) external;
    function createVault(string memory _name) external returns (address);
    function addCollateralNative(address _vault) external payable;
    function removeCollateralNative(
        address _vault,
        uint256 _amount,
        address _to
    ) external;
    function addCollateral(
        address _vault,
        address _collateral,
        uint256 _amount
    ) external;
    function removeCollateral(
        address _vault,
        address _collateral,
        uint256 _amount,
        address _to
    ) external;
    function borrow(address _vault, uint256 _amount, address _to) external;
    function distributeBadDebt(address _vault, uint256 _amount) external;
    function closeVault(address _vault) external;
    function repay(address _vault, uint256 _amount) external;
    function redeem(
        address _vault,
        address _collateral,
        uint256 _collateralAmount,
        address _to
    ) external;
    function liquidate(address _vault) external;
    function isLiquidatable(address _vault) external view returns (bool);
    function isReedemable(
        address _vault,
        address _collateral
    ) external view returns (bool);
    function containsVault(address _vault) external view returns (bool);
    function stable() external view returns (address);
    function isCollateralSupported(
        address _collateral
    ) external view returns (bool);
    function vaultsByOwnerLength(
        address _owner
    ) external view returns (uint256);
    function redemptionHealthFactorLimit() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import './IOwnable.sol';

interface IMintableToken is IERC20, IOwnable {
    function mint(address recipient, uint256 amount) external;

    function burn(uint256 amount) external;

    function name() external view returns (string memory);

    function symbol() external view returns (string memory);

    function approve(
        address spender,
        uint256 amount
    ) external override returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IVaultDeployer {
    function deployVault(
        address _factory,
        address _vaultOwner,
        string memory _name
    ) external returns (address);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.21;

/**
 * @title LinkedAddressList
 * @dev Library implementing a linked list structure to store and operate sorted Troves.
 */
library LinkedAddressList {
    struct EntryLink {
        address prev;
        address next;
    }

    struct List {
        address _last;
        address _first;
        uint256 _size;
        mapping(address => EntryLink) _values;
    }

    /**
     * @dev Adds an element to the linked list.
     * @param _list The storage pointer to the linked list.
     * @param _element The element to be added.
     * @param _reference The reference element to determine the position for addition.
     * @param _before A boolean indicating whether to add the element before the reference.
     * @return A boolean indicating the success of the addition.
     */
    function add(
        List storage _list,
        address _element,
        address _reference,
        bool _before
    ) internal returns (bool) {
        require(
            _reference == address(0x0) ||
                _list._values[_reference].next != address(0x0),
            '79d3d _ref neither valid nor 0x'
        );

        // Element must not exist to be added
        EntryLink storage element_values = _list._values[_element];
        if (element_values.prev == address(0x0)) {
            if (_list._last == address(0x0)) {
                // If the list is empty, set the element as both first and last
                element_values.prev = _element;
                element_values.next = _element;
                _list._first = _element;
                _list._last = _element;
            } else {
                if (
                    _before &&
                    (_reference == address(0x0) || _reference == _list._first)
                ) {
                    // Adding the element as the first element
                    address first = _list._first;
                    _list._values[first].prev = _element;
                    element_values.prev = _element;
                    element_values.next = first;
                    _list._first = _element;
                } else if (
                    !_before &&
                    (_reference == address(0x0) || _reference == _list._last)
                ) {
                    // Adding the element as the last element
                    address last = _list._last;
                    _list._values[last].next = _element;
                    element_values.prev = last;
                    element_values.next = _element;
                    _list._last = _element;
                } else {
                    // Inserting the element between two elements
                    EntryLink memory ref = _list._values[_reference];
                    if (_before) {
                        element_values.prev = ref.prev;
                        element_values.next = _reference;
                        _list._values[_reference].prev = _element;
                        _list._values[ref.prev].next = _element;
                    } else {
                        element_values.prev = _reference;
                        element_values.next = ref.next;
                        _list._values[_reference].next = _element;
                        _list._values[ref.next].prev = _element;
                    }
                }
            }
            _list._size = _list._size + 1;
            return true;
        }
        return false;
    }

    /**
     * @dev Removes an element from the linked list.
     * @param _list The storage pointer to the linked list.
     * @param _element The element to be removed.
     * @return A boolean indicating the success of the removal.
     */
    function remove(
        List storage _list,
        address _element
    ) internal returns (bool) {
        EntryLink memory element_values = _list._values[_element];
        if (element_values.next != address(0x0)) {
            if (_element == _list._last && _element == _list._first) {
                // Removing the last and only element in the list
                delete _list._last;
                delete _list._first;
            } else if (_element == _list._first) {
                // Removing the first element
                address next = element_values.next;
                _list._values[next].prev = next;
                _list._first = next;
            } else if (_element == _list._last) {
                // Removing the last element
                address new_list_last = element_values.prev;
                _list._last = new_list_last;
                _list._values[new_list_last].next = new_list_last;
            } else {
                // Removing an element in between two other elements
                address next = element_values.next;
                address prev = element_values.prev;
                _list._values[next].prev = prev;
                _list._values[prev].next = next;
            }
            // Delete the element itself
            delete _list._values[_element];
            _list._size = _list._size - 1;
            return true;
        }
        return false;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

import './IOwnable.sol';

interface ITokenPriceFeed is IOwnable {
    struct TokenInfo {
        address priceFeed;
        uint256 mcr; // Minimum Collateralization Ratio
        uint256 mlr; // Minimum Liquidation Ratio
        uint256 borrowRate;
        uint256 decimals;
    }

    function tokenPriceFeed(address) external view returns (address);

    function tokenPrice(address _token) external view returns (uint256);

    function mcr(address _token) external view returns (uint256);

    function decimals(address _token) external view returns (uint256);

    function mlr(address _token) external view returns (uint256);

    function borrowRate(address _token) external view returns (uint256);

    function setTokenPriceFeed(
        address _token,
        address _priceFeed,
        uint256 _mcr,
        uint256 _mlr,
        uint256 _borrowRate,
        uint256 /* _decimals */
    ) external;

    event NewTokenPriceFeed(
        address _token,
        address _priceFeed,
        string _name,
        string _symbol,
        uint256 _mcr,
        uint256 _mlr,
        uint256 _borrowRate,
        uint256 _decimals
    );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IVaultBorrowRate {
    function getBorrowRate(
        address _vaultAddress
    ) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface ILiquidationRouter {
    function addSeizedCollateral(address _collateral, uint256 _amount) external;

    function addUnderWaterDebt(address _vault, uint256 _amount) external;

    function removeUnderWaterDebt(uint256 _amount) external;

    function underWaterDebt() external view returns (uint256);

    function collaterals() external view returns (address[] memory);

    function collateral(address _collateral) external view returns (uint256);

    function tryLiquidate() external;

    function stabilityPool() external view returns (address);
    function auctionManager() external view returns (address);
    function lastResortLiquidation() external view returns (address);
    function distributeBadDebt(address _vault, uint256 _amount) external;
    function transferOwnership(address newOwner) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import './IOwnable.sol';
import './IMintableToken.sol';

interface IMintableTokenOwner is IOwnable {
    function token() external view returns (IMintableToken);

    function mint(address _recipient, uint256 _amount) external;

    function transferTokenOwnership(address _newOwner) external;

    function addMinter(address _newMinter) external;

    function revokeMinter(address _minter) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IVaultExtraSettings {
    function setMaxRedeemablePercentage(
        uint256 _debtTreshold,
        uint256 _maxRedeemablePercentage
    ) external;
    function setRedemptionKickback(uint256 _redemptionKickback) external;

    function getExtraSettings()
        external
        view
        returns (
            uint256 _debtTreshold,
            uint256 _maxRedeemablePercentage,
            uint256 _redemptionKickback
        );
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.21;

interface IVaultFactoryConfig {
    event PriceFeedUpdated(address indexed priceFeed);
    event MaxTokensPerVaultUpdated(
        uint256 oldMaxTokensPerVault,
        uint256 newMaxTokensPerVault
    );
    event RedemptionRateUpdated(
        uint256 oldRedemptionRate,
        uint256 newRedemptionRate
    );
    event BorrowRateUpdated(uint256 oldBorrowRate, uint256 newBorrowRate);
    event RedemptionHealthFactorLimitUpdated(
        uint256 oldRedemptionHealthFactorLimit,
        uint256 newRedemptionHealthFactorLimit
    );

    function setMaxTokensPerVault(uint256 _maxTokensPerVault) external;
    function setPriceFeed(address _priceFeed) external;
    function setRedemptionRate(uint256 _redemptionRate) external;
    function setBorrowRate(uint256 _borrowRate) external;
    function setRedemptionHealthFactorLimit(
        uint256 _redemptionHealthFactorLimit
    ) external;
    function setBorrowFeeRecipient(address _borrowFeeRecipient) external;
    function setRedemptionFeeRecipient(
        address _redemptionFeeRecipient
    ) external;

    function priceFeed() external view returns (address);
    function MAX_TOKENS_PER_VAULT() external view returns (uint256);
    function redemptionRate() external view returns (uint256);
    function borrowRate() external view returns (uint256);
    function redemptionHealthFactorLimit() external view returns (uint256);
    function borrowFeeRecipient() external view returns (address);
    function redemptionFeeRecipient() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20Metadata} from "../token/ERC20/extensions/IERC20Metadata.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position is the index of the value in the `values` array plus 1.
        // Position 0 is used to mean a value is not in the set.
        mapping(bytes32 value => uint256) _positions;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._positions[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We cache the value's position to prevent multiple reads from the same storage slot
        uint256 position = set._positions[value];

        if (position != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 valueIndex = position - 1;
            uint256 lastIndex = set._values.length - 1;

            if (valueIndex != lastIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the lastValue to the index where the value to delete is
                set._values[valueIndex] = lastValue;
                // Update the tracked position of the lastValue (that was just moved)
                set._positions[lastValue] = position;
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the tracked position for the deleted slot
            delete set._positions[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._positions[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}