Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT

pragma solidity >=0.8.4;
pragma experimental ABIEncoderV2;

import '@openzeppelin/contracts/access/Ownable.sol';

error WithdrawToOwnerUnsuccessful();

/// @title MintingMulticall
/// @notice Aggregate results from multiple function calls derived from MultiCall3
contract MintingMulticall is Ownable {
  // events mostly for typechain abi generation
  event Transfer(
    address indexed from,
    address indexed to,
    uint256 indexed tokenId
  );

  struct Call3Value {
    address target;
    bool allowFailure;
    uint256 value;
    bytes callData;
  }

  struct Result {
    bool success;
    bytes returnData;
  }

  constructor() Ownable(msg.sender) {}

  function safeAggregate3Value(
    Call3Value[] calldata calls
  ) public payable returns (Result[] memory returnData) {
    uint256 valAccumulator;
    uint256 length = calls.length;
    returnData = new Result[](length);
    Call3Value calldata calli;
    for (uint256 i = 0; i < length; ) {
      Result memory result = returnData[i];
      calli = calls[i];
      uint256 val = calli.value;
      // Humanity will be a Type V Kardashev Civilization before this overflows - andreas
      // ~ 10^25 Wei in existence << ~ 10^76 size uint fits in a uint256
      unchecked {
        valAccumulator += val;
      }
      (result.success, result.returnData) = calli.target.call{value: val}(
        calli.callData
      );
      assembly {
        // Revert if the call fails and failure is not allowed
        // `allowFailure := calldataload(add(calli, 0x20))` and `success := mload(result)`
        if iszero(or(calldataload(add(calli, 0x20)), mload(result))) {
          // set "Error(string)" signature: bytes32(bytes4(keccak256("Error(string)")))
          mstore(
            0x00,
            0x08c379a000000000000000000000000000000000000000000000000000000000
          )
          // set data offset
          mstore(
            0x04,
            0x0000000000000000000000000000000000000000000000000000000000000020
          )
          // set length of revert string
          mstore(
            0x24,
            0x0000000000000000000000000000000000000000000000000000000000000017
          )
          // set revert string: bytes32(abi.encodePacked("MintingMulticall: call failed"))
          mstore(
            0x44,
            0x4d756c746963616c6c333a2063616c6c206661696c6564000000000000000000
          )
          revert(0x00, 0x84)
        }
      }
      unchecked {
        ++i;
      }
    }
    // Finally, make sure the msg.value = SUM(call[0...i].value)
    require(msg.value == valAccumulator, 'MintingMulticall: value mismatch');
    if (address(this).balance > 0) {
      (bool success, ) = msg.sender.call{value: address(this).balance}('');
      require(success, 'MintingMulticall: refund failed');
    }
  }

  receive() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}