Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: UNLICENSED
// Copyright 2025 US Fintech LLC and DelNorte Holdings.
// 
// Permission to use, copy, modify, or distribute this software is strictly prohibited
// without prior written consent from both copyright holders.
// 
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
// INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
// PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE COPYRIGHT HOLDERS BE LIABLE FOR ANY
// CLAIM, DAMAGES, OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT, OR OTHERWISE,
// ARISING FROM, OUT OF, OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
// OFFICIAL DEL NORTE NETWORK COMPONENT 
// This component is minimally tested. Use at your own risk.   
// Designed by Ken Silverman as part of his ElasticTreasury (HUB and SPOKE), PeerTreasury and Controller model.  
// This deployment is for Trueviewchain Inc. a Panama entity and Del Norte El Salvador S.A  a subsidiary of Del Norte Holdings, Delaware USA.  
// Permission to change metadata stored on blockchain explorers and elsewheregranted to Del Norte Holdings, DE only.
// Compilation help from Tony Sparks and Maleeha Naveed. Deployed by Maleeha Naveed on behalf of Del Norte. May 5th,2025
pragma solidity 0.8.29;
import "./Recoverable.sol";

interface IERC20SymbolAndName {
        function symbol() external view returns (string memory);
        function name() external view returns (string memory);
}


contract Controller is Recoverable {


    event TreasuryCreated(address treasuryAddress, string label);
    event UpdateOfficials(
        address indexed entityAddress,
        address indexed updater,
        string entityType,              // "SC,SystemUser,SystemAdmin,BTADmin, etc ..."
        string action,                  // Add,Remove  (nothing is actually removed, only active boolean changed)
        string fullNameOfEntityOrLabel, // person's full name or "SC"
        string nationalIdOfEntity,       // registered to entity or SC address if entity is SC
        uint256 indexed blockTimeStamp,             // block number of the event
        bool remainsActive
    );


    struct OfficialEntityStruct {
        string fullNameOfEntityOrLabel;
        string nationalIdOfEntity; // (if entity is a smart contract, leave empty or provide some other detail here.)
        address pubAddress;   // registered to entity or SC address if entity is SC
        uint256 blockNumber;
        uint256 blockTimestamp;
        bool active;
    }


    struct OfficialEntityGroup {
        mapping(address => OfficialEntityStruct) entitiesByAddress; // Maps entity address to its details
        address[] entityList; // List of entity addresses for iteration
    }


    struct AdminTypeRegistry {
       mapping(string  => bool)  isRegistered;     // internally a hash key but requires string for lookup
       mapping(bytes32 => bool)  isHashRegistered; // slightly faster pre-hahsed lookup
       string[] registeredAdminTypes;
       mapping(bytes32 => string) nameByHash;       // Reverse lookup from hash to original string
    }


    mapping(string => OfficialEntityGroup) private officialEntityGroupsByType;


    // NEW structure to SUPPORT validateAdminType


     AdminTypeRegistry private adminTypeRegistry;


    address public remoteController; // Hub address for admin verification - ALWAYS “this” for now
    string public name;
    bytes32 public constant KECCAK_TREASURY_ADMIN = keccak256(bytes("TreasuryAdmin"));
    bytes32 public constant KECCAK_SMART_CONTRACT = keccak256(bytes("SmartContract"));
    bytes32 public constant KECCAK_SUPER_ADMIN = keccak256(bytes("Super"));

    modifier onlySuper() {
        require(isOfficialEntityFast(KECCAK_SUPER_ADMIN, tx.origin), "caller not Super");
        _;
    }


    // Warning! Any official "Super" can call addEntity directly. This is NOT a first line of defense against that.
    //  The only defense there is to make sure your official SCs have their own calls to this controller’s
    //  isOfficialEntity(“Super”) for example BEFORE calling addEntity() or removeEntity()
    //  init() LOCKS this Controller to only allowing TreasAdmins to adding official SCs to begin with.
    //  REMOTE case now allows a smartContract caller unless tx.origin is used
    //  use case of checking that the original human sender is authorized (even through non-official contract calls) 
    //  may be one of the few legitimate uses of tx.origin
    // ✓ To register as official smartContract → You need to be called by an official entity
    // ✗ because you can't be an official entity smartContract → Until that smatcontract calls init() via its own constructor 
    //  therefore we must USE tx.origin for initial registration of smartContracts as a bootstrap
    modifier onlySuperOrSCExecutives() {
        bool temp = isOfficialEntityFast(KECCAK_SUPER_ADMIN, tx.origin) ||
                    isOfficialEntityFast(KECCAK_SMART_CONTRACT, msg.sender);
        require(temp, "Unauthorized access");
        _;  // run the code block referencing this modifier
    }


    // to meet the 24K limit, BaseTreasury is now instantiated FIRST - however its concept remains the same - as a BASE class
    // for ElasticTreasuryHUB and ElasticTreasurySPOKE  MasterHub is now an optional, later passed “controller” that must be
    // a separate instantiatedController. This will NOT be used for our needs yet.  In other words, controller is ALWAYS
    // this for now.
    constructor(address initialControllerAdmin, string memory _name) Recoverable(address(this)) {
        name = _name;
        remoteController = address(this);  // formerly masterHub, controller is ALWAYS this for now. (see remotelyManage)
        // **Reject if initialControllerAdmin is 0x0000 (formerly as parent, if has no TreasuryAdmin**
        if (initialControllerAdmin == address(0)) {
            revert("Controller: needs at least one TreasuryAdmin");
        }
        // Next line not needed, will be added dynamically. NTL its a kickstart for what we are doing specifically
        string[3] memory defaultTypes = ["TreasuryAdmin", "SmartContract","Super"];  // Registrars/TokenAdmins added in Token SystemAdmins/SystemUsers/SystemEmployees added in 721
        for (uint256 i = 0; i < defaultTypes.length; i++) {
            addAdminType(defaultTypes[i]);
        }
        addOfficialEntityNow("Super", initialControllerAdmin, "Presumed Multi-Sig platform exec", "Initial Execs");
        addOfficialEntityNow("TreasuryAdmin", initialControllerAdmin, "Presumed Multi-Sig platform exec", "Initial Execs");
        // SEE ElasticTreasuryHub transferTreasury() no longer adds SPOKE as SC official - now added here …
        // NO LONGER adding self as Official SC, because SELF is now standalone controller NOT parent due to 24K max mem.
        emit TreasuryCreated(address(this), "Controller");
    }


    //  caller MUST be a HUB or SPOKE because Controller is now deployed separately.
    //  HUB and spoke are no longer Controllers themselves.  addedBTAdmin is optional, HUB and SPOKE pass address(0)
    function init(address officialSmartContractAddress, string calldata contractName) external onlySuperOrSCExecutives {
        addOfficialEntityNow("SmartContract",officialSmartContractAddress, contractName,"");  // may exist, if token, symbol will be added.
    }




    // do not use except for use case as of yet not imagined would need to be called immediately via child constructor
    function remotelyManage(address _controller) external onlySuperOrSCExecutives {
        bool isRemotelyManaged = (_controller != address(0) && _controller != address(this));
        if (isRemotelyManaged) {
            remoteController = _controller;
        }
        else {
            remoteController = address(this);  // not used if isRemotelyManaged is false
        }
        changeController(remoteController);
    }


    // if master is self, it is the same as passing false, because SELF (local) WILL manage in that case.
    // Any controller that is not self must be another instance of BaseTreasury
    // just a formality, if not here,  controller can always be cast to BaseTreasury, even if self.
    //  Ex:  BaseTreasury(controller).someFunction … will always work whether self or another BaseTreasury instance.
    function doesRemoteControllerManageAllOfficials() internal view returns (bool) {
        return controller != address(this);
    }



    ///
    //   OFFICIAL ENTITIES
    //
    //

        

        // Dynamically validate an admin type, and optionally register new ones
        function validateAdminType(string memory adminType) internal view {
            if (!adminTypeRegistry.isRegistered[adminType]) {
                revert("Invalid admin type");
            }
        }


        function addAdminType(string memory adminType) internal returns (bool) {
            if (!adminTypeRegistry.isRegistered[adminType]) {
                // to support remote case, let a TreasuryAdmin add too, since “SmartContract” is not sensed for remote
                // chained transaction caller:  EOA ⇒ contract A == > contract B (here) ⇒ remote controller (A not sensed)
                // require(isOfficialEntity(“SmartContract”,msg.sender),”Only official SC can add new Officl type”);
                bytes32 hash = keccak256(bytes(adminType));
                adminTypeRegistry.isRegistered[adminType] = true;
                adminTypeRegistry.isHashRegistered[hash] = true;
                adminTypeRegistry.nameByHash[hash] = adminType;
                adminTypeRegistry.registeredAdminTypes.push(adminType);
                return true;
            }
            return false;
        }


        // Retrieve all registered admin types
        function getRegisteredAdminTypes() external view returns (string[] memory) {
            return adminTypeRegistry.registeredAdminTypes;
        }

         // "TreasuryAdmin", initialControllerAdmin, "Presumed Multi-Sig platform exec", "Initial Execs"
       function addOfficialEntity(string memory adminType, address entityAddr, string memory label,string memory nationalIdOrSC) public onlySuper  returns (bool) {
            return addOfficialEntityNow(adminType, entityAddr, label, nationalIdOrSC);
        }

       
       function addOfficialEntityNow(string memory adminType, address entityAddr, string memory label, string memory nationalIdOrSCSymbol) internal returns (bool) {
            if (doesRemoteControllerManageAllOfficials()) {
                return Controller(controller).addOfficialEntity(adminType, entityAddr, label, nationalIdOrSCSymbol);
            }
            require(entityAddr != address(0), "Invalid entity address");
            if (bytes(label).length == 0) {
                if (entityAddr.code.length > 0) {
                    try IERC20SymbolAndName(entityAddr).name() returns (string memory s) {
                        label = bytes(s).length > 0 ? s : "SC not token";
                    } catch {
                        label = "SC not token";
                    }
                }
                else {
                    label = "SC not token";
                }
            }
            if (bytes(nationalIdOrSCSymbol).length == 0) {
                if (entityAddr.code.length > 0) {
                    try IERC20SymbolAndName(entityAddr).symbol() returns (string memory s) {
                        nationalIdOrSCSymbol = bytes(s).length > 0 ? s : "SC not token";
                    } catch {
                        nationalIdOrSCSymbol = "SC not token";
                    }
                } else {
                    nationalIdOrSCSymbol = "no label and SC not contract";
                }
            }
            addAdminType(adminType);
            OfficialEntityGroup storage group = officialEntityGroupsByType[adminType];
            if (group.entitiesByAddress[entityAddr].active) {
                return false;
            }
            group.entitiesByAddress[entityAddr] = OfficialEntityStruct(label, nationalIdOrSCSymbol, entityAddr, block.number, block.timestamp, true);
            group.entityList.push(entityAddr);
            emit UpdateOfficials(entityAddr, msg.sender, adminType, "Add", label, nationalIdOrSCSymbol, block.timestamp, true);
            return true;
        }

        function removeOfficialEntity(string calldata adminType, address entityAddr) external onlySuper returns (bool) {
            if (doesRemoteControllerManageAllOfficials()) {
                 return Controller(controller).removeOfficialEntity(adminType, entityAddr);
            }
            require(entityAddr != address(0), "Invalid entity address");
            validateAdminType(adminType);  // 🔹 Ensure valid type
            OfficialEntityGroup storage group = officialEntityGroupsByType[adminType];
            if (!group.entitiesByAddress[entityAddr].active) {
                return false;
            }
            // Soft-delete by marking inactive, but retain in list for history
            group.entitiesByAddress[entityAddr].active = false;
            emit UpdateOfficials(entityAddr, msg.sender, adminType, "Remove",group.entitiesByAddress[entityAddr].fullNameOfEntityOrLabel,group.entitiesByAddress[entityAddr].nationalIdOfEntity,block.timestamp,false);
            return true;
        }

        function isOfficialEntityFast(bytes32 hashedAdminType, address entityAddr) public view returns (bool) {
            if (doesRemoteControllerManageAllOfficials()) {
                 return Controller(controller).isOfficialEntityFast(hashedAdminType, entityAddr);
            }
            require(entityAddr != address(0), "Invalid entity address");
             string memory adminType = adminTypeRegistry.nameByHash[hashedAdminType];
             if (!adminTypeRegistry.isHashRegistered[hashedAdminType]) {
                revert("Invalid admin type");
            }
            return officialEntityGroupsByType[adminType].entitiesByAddress[entityAddr].active;
        }

        function isOfficialEntity(string memory adminType, address entityAddr) public view returns (bool) {
            if (doesRemoteControllerManageAllOfficials()) {
                 return Controller(controller).isOfficialEntity(adminType, entityAddr);
            }
            require(entityAddr != address(0), "Invalid entity address");
            validateAdminType(adminType);  // 🔹 Ensure valid type
            return officialEntityGroupsByType[adminType].entitiesByAddress[entityAddr].active;
        }

        function getOfficialEntity(string calldata adminType, address entityAddr) external view returns (OfficialEntityStruct memory) {
            if (doesRemoteControllerManageAllOfficials()) {
                 return Controller(controller).getOfficialEntity(adminType, entityAddr);
            }
            require(entityAddr != address(0), "Invalid entity addrss");
            validateAdminType(adminType);  // 🔹 Ensure valid type
            OfficialEntityStruct storage entity = officialEntityGroupsByType[adminType].entitiesByAddress[entityAddr];
            require(entity.active, "No Ent or inactve");
            return entity;
        }

        function getAllOfficialEntities(string calldata adminType, bool includeInactive) external view returns (OfficialEntityStruct[] memory) {
            if (doesRemoteControllerManageAllOfficials()) {
                return Controller(controller).getAllOfficialEntities(adminType, includeInactive);
            }
            validateAdminType(adminType);  // 🔹 Ensure valid type
            OfficialEntityGroup storage group = officialEntityGroupsByType[adminType];
            // First count entities based on the includeInactive parameter
            uint256 entityCount = 0;
            for (uint256 i = 0; i < group.entityList.length; i++) {
                address entityAddr = group.entityList[i];
                if (includeInactive || group.entitiesByAddress[entityAddr].active) {
                    entityCount++;
                }
            }
            // Then create array of exactly the right size and fill it
            OfficialEntityStruct[] memory filteredEntities = new OfficialEntityStruct[](entityCount);
            uint256 counter = 0;
            for (uint256 i = 0; i < group.entityList.length; i++) {
                address entityAddr = group.entityList[i];
                if (includeInactive || group.entitiesByAddress[entityAddr].active) {
                    filteredEntities[counter] = group.entitiesByAddress[entityAddr];
                    counter++;
                }
            }
            return filteredEntities;
        }


        // saves a double call
        function isOfficialDoubleEntity(string calldata adminType1, address entityAddr1,
                    string calldata adminType2, address entityAddr2, bool isAnd) public   view returns (bool) {
            if (isAnd) {
               return isOfficialEntity(adminType1,entityAddr1) && isOfficialEntity(adminType2, entityAddr2);
            }
            else {
               return isOfficialEntity(adminType1,entityAddr1) || isOfficialEntity(adminType2, entityAddr2);
            }
        }

        function isOfficialDoubleEntityFast(bytes32 adminType1, address entityAddr1,bytes32 adminType2, address entityAddr2, bool isAnd) external view returns (bool) {
            if (isAnd) {
                return isOfficialEntityFast(adminType1, entityAddr1) && isOfficialEntityFast(adminType2, entityAddr2);
            } else {
                return isOfficialEntityFast(adminType1, entityAddr1) || isOfficialEntityFast(adminType2, entityAddr2);
            }
        }

        // Fast triple entity check with bytes32
        function isOfficialTripleEntityFast(bytes32 adminType1, address entityAddr1, bytes32 adminType2, address entityAddr2,
            bytes32 adminType3, address entityAddr3, bool isAnd) external view returns (bool) {
            if (isAnd) {
                return isOfficialEntityFast(adminType1, entityAddr1) 
                    && isOfficialEntityFast(adminType2, entityAddr2) 
                    && isOfficialEntityFast(adminType3, entityAddr3);
            } else {
                return isOfficialEntityFast(adminType1, entityAddr1) 
                    || isOfficialEntityFast(adminType2, entityAddr2) 
                    || isOfficialEntityFast(adminType3, entityAddr3);
            }
        }


        function isOfficialTripleEntity(string calldata adminType1, address entityAddr1, string calldata adminType2, address entityAddr2,
    	                                string calldata adminType3, address entityAddr3, bool isAnd) external view returns (bool) {
          if (isAnd) {
              return isOfficialEntity(adminType1, entityAddr1) && isOfficialEntity(adminType2, entityAddr2) && isOfficialEntity(adminType3, entityAddr3);
   	      }
          else {
        	  return isOfficialEntity(adminType1, entityAddr1) || isOfficialEntity(adminType2, entityAddr2) || isOfficialEntity(adminType3, entityAddr3);
          }
       }

      function isOfficialQuadrupleEntityFast(bytes32 adminType1, address entityAddr1,bytes32 adminType2, address entityAddr2,bytes32 adminType3, address entityAddr3,
            bytes32 adminType4, address entityAddr4,bool isAnd) external view returns (bool) {
            if (isAnd) {
                return isOfficialEntityFast(adminType1, entityAddr1) 
                    && isOfficialEntityFast(adminType2, entityAddr2)
                    && isOfficialEntityFast(adminType3, entityAddr3) 
                    && isOfficialEntityFast(adminType4, entityAddr4);
            } else {
                return isOfficialEntityFast(adminType1, entityAddr1)
                    || isOfficialEntityFast(adminType2, entityAddr2)
                    || isOfficialEntityFast(adminType3, entityAddr3)
                    || isOfficialEntityFast(adminType4, entityAddr4);
            }
        }

    //
    // END OFFICIAL ENTITIES
    //

        // Returns the name of the controller
        function getName() external view returns (string memory) {
            return name;
        }

        function setName(string memory newName) external onlySuper {
            name = newName;
        }

    // No receiving of accidental or unsolicited eth here
    // See below for a payable method for SALES purposes and OTHER purposes (see BELOW).
    // receive() external payable {  // <== DO NOT IMPLEMENT, LEAVE COMMENTED
    //    ethBalances[msg.sender].totalReceivedThatIsReversible += msg.value;
    //}


}

// SPDX-License-Identifier: CLOSED LICENSE COPYRIGHT 2025
// OFFICAL DEL NORTE NETWORK COMPONENT
// Designed By Ken Silverman for Del Norte.  Implementation help from Tony Sparks
// Compilation help from Maleeha Naveed. May 5th, 2025

pragma solidity 0.8.29;


import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "../interfaces/IController.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";


/// @title ReversibleRecoveryBase
/// @notice Base contract tracking / reversing accidental ETH/ERC20 transfers with admin authorization
abstract contract Recoverable {

    using SafeERC20 for IERC20;

    // STRUCTS


    struct ReversibleUserBalance {
        uint256 totalReceivedThatIsReversible;
        uint256 totalReversed;
        uint256 totalReversals;
    }


    // -----------------------------
    // STORAGE
    // -----------------------------


    address public controller;  // Address of the Controller contract (must implement IController)
    uint256 public ADMIN_FEE_FIXED = 10 ** 17; // 0.1 ETH
    uint256 public totalAdminFeesCollected;


    mapping(address => ReversibleUserBalance) public reversibleEthBalances;
    mapping(address => mapping(address => ReversibleUserBalance)) public reversibleTokenBalances;


    // -----------------------------
    // EVENTS
    // -----------------------------
    event TransferReversed(address indexed user, uint256 refundAmount, address tokenSC, uint256 adminFee);
    event AdminFeeUpdated(uint256 newFee);
    event ControllerChanged(address newController);


     modifier onlyBTExecutives() {
        bool temp = IController(controller).isOfficialEntity("TreasuryAdmin", msg.sender) ||
                    IController(controller).isOfficialEntity("SmartContract", msg.sender);
        require(temp, "Unauthorized access");
        _;  // run the code block referencing this modifier
    }


    // -----------------------------
    // CONSTRUCTOR
    // -----------------------------
    constructor(address _controller) {
        require(_controller != address(0), "Controller address cannot be zero");
        controller = _controller;
    }


    // -----------------------------
    // EXTERNAL METHODS
    // -----------------------------
    function manualUpdateReversibleBalanceETH(address userAddress, uint256 amount)
        external onlyBTExecutives  {
        reversibleEthBalances[userAddress].totalReceivedThatIsReversible += amount;
    }




    function manualUpdateReversibleBalanceERC20(address userAddress, uint256 amount, address tokenSC)
        external onlyBTExecutives {
        reversibleTokenBalances[tokenSC][userAddress].totalReceivedThatIsReversible += amount;
    }


    function reverseAccidentalETH() external payable  {
        require(msg.value >= ADMIN_FEE_FIXED, "Insufficient admin fee");
        require(!IController(controller).isOfficialEntity("Registrar", msg.sender),
            "Registrars/launchpads may not be allowed to reverse any amounts they send.");
        ReversibleUserBalance storage balance = reversibleEthBalances[msg.sender];
        uint256 refundAmount = balance.totalReceivedThatIsReversible - balance.totalReversed;
        require(refundAmount > 0, "Nothing to refund");
        // Update state before external call
        balance.totalReversed += refundAmount;
        balance.totalReversals += 1;
        totalAdminFeesCollected += msg.value;
        // Perform the external call
        (bool success, ) = msg.sender.call{value: refundAmount}("");
        require(success, "Ether transfer failed");
        emit TransferReversed(msg.sender, refundAmount, address(0), msg.value);
    }



    function reverseAccidentalERC20(address tokenSC) external payable {
        require(msg.value >= ADMIN_FEE_FIXED, "Insufficient admin fee");
        require(!IController(controller).isOfficialEntity("Registrar", msg.sender), "Registrars/launchpads may not reverse any amounts they send.");
        ReversibleUserBalance storage balance = reversibleTokenBalances[tokenSC][msg.sender];
        uint256 refundAmount = balance.totalReceivedThatIsReversible - balance.totalReversed;
        require(refundAmount > 0, "Nothing to refund");
        // Update state before external call
        balance.totalReversed += refundAmount;
        balance.totalReversals += 1;
        totalAdminFeesCollected += msg.value;
        // Perform the external call
        IERC20(tokenSC).safeTransfer(msg.sender, refundAmount);
        emit TransferReversed(msg.sender, refundAmount, tokenSC, msg.value);
  }


    function changeAdminFee(uint256 newFee) external onlyBTExecutives {
        ADMIN_FEE_FIXED = newFee;
        emit AdminFeeUpdated(newFee);
    }


   function changeController(address remote) internal {
        controller = remote;
        emit ControllerChanged(remote);
   }
}

// SPDX-License-Identifier: UNLICENSED
// Copyright 2025 US Fintech LLC and DelNorte Holdings.
// 
// Permission to use, copy, modify, or distribute this software is strictly prohibited
// without prior written consent from both copyright holders.
// 
// THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
// INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY, FITNESS FOR A PARTICULAR
// PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE COPYRIGHT HOLDERS BE LIABLE FOR ANY
// CLAIM, DAMAGES, OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT, OR OTHERWISE,
// ARISING FROM, OUT OF, OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
// OFFICIAL DEL NORTE NETWORK COMPONENT 
// Provides immediate membership access to platform at different levels. 
// Required Non US or accredited US registration to swap for DTV token. Registration available within 180 days per terms.delnorte.io . 
// Minimally tesed Conroller Tree for world-wide government administration of, well, anything, including property ownership.
// Designed by Ken Silverman as part of his ElasticTreasury (HUB and SPOKE), PeerTreasury and Controller model. 
// @author Ken Silverman
// This deployment is for Del Norte Holdings, Delaware and US Fintech, LLC NY.  
// Permission to change metadata stored on blockchain explorers and elsewhere granted to:
// Del Norte Holdings, DE only and/or US Fintech, LLC NY independently
pragma solidity 0.8.29;

interface IController {
    struct OfficialEntityStruct {
        string fullNameOfEntityOrLabel;
        string nationalIdOfEntity;
        address pubAddress;
        uint256 blockNumber;
        uint256 blockTimestamp;
        bool active;
    }

    function addOfficialEntity(string memory, address, string memory, string memory) external returns (bool);
    function removeOfficialEntity(string memory, address) external returns (bool);
    function isOfficialEntity(string memory, address) external view returns (bool);
    function isOfficialEntityFast(bytes32, address) external view returns (bool);
    function isOfficialDoubleEntity(string calldata, address, string calldata, address, bool) external view returns (bool);
    function isOfficialDoubleEntityFast(bytes32, address, bytes32, address, bool) external view returns (bool);
    function isOfficialTripleEntityFast(bytes32, address, bytes32, address, bytes32, address, bool) external view returns (bool);
    function isOfficialTripleEntity(string calldata, address, string calldata, address, string calldata, address, bool) external view returns (bool);
    function isOfficialQuadrupleEntityFast(bytes32, address,  bytes32, address, bytes32, address, bytes32, address, bool) external view returns (bool);
    function getOfficialEntity(string calldata, address) external view returns (OfficialEntityStruct memory);
    function getAllOfficialEntities(string calldata) external view returns (OfficialEntityStruct[] memory);
    function init(address, string calldata) external;
}