Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/Strings.sol";
import "../libraries/PendingRequest.sol";
import "../interfaces/IMetadata.sol";

/**
 * @dev Implementation of the investor's proof token {ERC721}.
 * We distinguish between deposit proof token and withdrawal proof token.
 * The investor receives the deposit/withdrawal proof token when he makes his deposit/withdrawal
 * request, waiting to be validated by the manager.
 */

contract Proof is ERC721Enumerable, Ownable, AccessControlEnumerable {
    using Strings for uint256;
    using PendingRequest for PendingRequestData;

    bytes32 public constant INVESTMENT = keccak256("INVESTMENT");
    uint256 public constant TOLERANCE_MAX = 1000; // To handel rounding errors
    uint256 public totalAmount;
    uint256 public tolerance;
    uint8 public immutable id;
    bool public isOnChainMetadata;
    string public baseURI;
    address public investment;
    mapping(uint256 => PendingRequestData) public pendingRequests;
    mapping(uint256 => uint256) public pendingIdIndex;
    uint256[] public pendingIds;
    IMetadata public metadata;

    event UpdateInvestment(address indexed investment_);
    event UpdateMetadata(address indexed metadata_);
    event UpdateBaseURI(string baseURI_);
    event UpdateTolerance(uint256 tolerance_);
    event UpdateIsOnChainMetadata(bool isOnChainMetadata_);
    event Mint(address indexed account_, uint256 tokenId_, uint256 amount_);
    event Burn(uint256 tokenId_);

    constructor(
        string memory name_,
        string memory symbol_,
        uint8 id_,
        address admin_
    ) ERC721(name_, symbol_) {
        require(id_ <= 1, "Every.finance: out of range");
        require(admin_ != address(0), "Every.finance: zero address");
        id = id_;
        _setupRole(DEFAULT_ADMIN_ROLE, admin_);
    }

    /**
     * @dev get the size of array pendingIds.
     */
    function getPendingIdsSize() public view returns (uint256) {
        return pendingIds.length;
    }

    /**
     * @dev Update investment.
     * @param investment_.
     * Emits an {UpdateInvestment} event indicating the updated investment `investment_`.
     */
    function updateInvestment(
        address investment_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(investment_ != address(0), "Every.finance: zero address");
        require(investment_ != investment, "Every.finance: no change");
        _revokeRole(INVESTMENT, investment);
        _grantRole(INVESTMENT, investment_);
        investment = investment_;
        emit UpdateInvestment(investment_);
    }

    /**
     * @dev Update metadata.
     * @param metadata_.
     * Emits an {UpdateMetadata} event indicating the updated metadata `metadata_`.
     */
    function updateMetadata(
        address metadata_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(metadata_ != address(0), "Every.finance: zero address");
        require(metadata_ != address(metadata), "Every.finance: no change");
        metadata = IMetadata(metadata_);
        emit UpdateMetadata(metadata_);
    }

    /**
     * @dev Update baseURI.
     * @param uri_ new baseURI.
     * Emits an {UpdateBaseURI} event indicating the updated baseURI `uri_`.
     */
    function setBaseURI(
        string calldata uri_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        baseURI = uri_;
        emit UpdateBaseURI(uri_);
    }

    /**
     * @dev Update tolerance.
     * @param tolerance_.
     * Emits an {UpdateTolerance} event indicating the updated tolerance `tolerance_`.
     */
    function updateTolerance(
        uint256 tolerance_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(tolerance_ <= TOLERANCE_MAX, "Every.finance: tolerance max");
        require(tolerance_ != tolerance, "Every.finance: no change");
        tolerance = tolerance_;
        emit UpdateTolerance(tolerance_);
    }

    /**
     * @dev Update isOnChainMetadata.
     * @param isOnChainMetadata_.
     * Emits an {UpdateIsOnChainMetadata} event indicating the updated isOnChainMetadata `isOnChainMetadata_`.
     */
    function updateIsOnChainMetadata(
        bool isOnChainMetadata_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(
            isOnChainMetadata != isOnChainMetadata_,
            "Every.finance: no change"
        );
        isOnChainMetadata = isOnChainMetadata_;
        emit UpdateIsOnChainMetadata(isOnChainMetadata_);
    }

    /**
     * @dev mint a Proof token.
     * The investor receives a proof Token when he makes
     * a deposit/withdrawal request.
     * @param account_ investor's address.
     * @param tokenId_  id of the token.
     * @param amount_ amount to mint.
     * @param minPrice_ minimum price of the yield-bearing token.
     * @param maxPrice_ maximum price  of the yield-bearing token
     * @param currentEventId_  id of the next manager event (process).
     * Emits an {Mint} event with `account_`, `tokenId_`, and `amount`.
     */
    function mint(
        address account_,
        uint256 tokenId_,
        uint256 amount_,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 currentEventId_
    ) external onlyRole(INVESTMENT) {
        _safeMint(account_, tokenId_);
        pendingIds.push(tokenId_);
        pendingIdIndex[tokenId_] = pendingIds.length - 1;
        _increasePendingRequest(
            tokenId_,
            amount_,
            minPrice_,
            maxPrice_,
            currentEventId_
        );
        emit Mint(account_, tokenId_, amount_);
    }

    /**
     * @dev increase the pending request balance of token `tokenId_` by `amount`.
     * @param tokenId_  id of the token.
     * @param amount_ amount to add.
     * @param minPrice_ minimum price of the yield-bearing token.
     * @param maxPrice_ maximum price  of the yield-bearing token
     * @param currentEventId_  id of the next manager event (process).
     */

    function increasePendingRequest(
        uint256 tokenId_,
        uint256 amount_,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 currentEventId_
    ) external onlyRole(INVESTMENT) {
        _increasePendingRequest(
            tokenId_,
            amount_,
            minPrice_,
            maxPrice_,
            currentEventId_
        );
    }

    /**
     * @dev decrease the pending request balance of token `tokenId_` by `amount`.
     * @param tokenId_  id of the token.
     * @param amount_ amount to remove.
     * @param currentEventId_  id of the next manager event (process).
     */
    function decreasePendingRequest(
        uint256 tokenId_,
        uint256 amount_,
        uint256 currentEventId_
    ) external onlyRole(INVESTMENT) {
        _decreasePendingRequest(tokenId_, amount_, currentEventId_);
    }

    /**
     * @dev update event Id
     * @param tokenId_  id of the token.
     * @param currentEventId_  current event Id.
     */
    function updateEventId(
        uint256 tokenId_,
        uint256 currentEventId_
    ) external onlyRole(INVESTMENT) {
        pendingRequests[tokenId_].updateEventId(currentEventId_);
    }

    /**
     * @dev update the locked and available pending balances before the manager validation.
     * @param tokenId_  id of the token.
     * @param currentEventId_  id of the next manager event (process).
     */
    function preValidatePendingRequest(
        uint256 tokenId_,
        uint256 currentEventId_
    ) external onlyRole(INVESTMENT) {
        pendingRequests[tokenId_].preValidate(currentEventId_);
    }

    /**
     * @dev update the locked pending balance after the manager validation.
     * @param tokenId_  id of the token.
     * @param amount_  amount to remove from the locked pending balance.
     * @param currentEventId_  id of the next manager event (process).
     */
    function validatePendingRequest(
        uint256 tokenId_,
        uint256 amount_,
        uint256 currentEventId_
    ) external onlyRole(INVESTMENT) {
        pendingRequests[tokenId_].validate(amount_, currentEventId_);
        _decreaseTotalAmount(tokenId_, amount_);
    }

    /**
     * @dev  get tokenURI of token `tokenId`.
     * If `isOnChainMetadata`, the token metadata is generated on chain.
     *  Otherwise, see {IERC721Metadata-tokenURI}.
     * @param tokenId  token id .
     */
    function tokenURI(
        uint256 tokenId
    ) public view virtual override returns (string memory) {
        _requireMinted(tokenId);
        if (isOnChainMetadata) {
            return metadata.render(tokenId);
        } else {
            string memory string_ = _baseURI();
            return
                bytes(string_).length > 0
                    ? string(abi.encodePacked(string_, tokenId.toString()))
                    : "";
        }
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(
        bytes4 interfaceId
    )
        public
        view
        override(ERC721Enumerable, AccessControlEnumerable)
        returns (bool)
    {
        return
            ERC721Enumerable.supportsInterface(interfaceId) ||
            AccessControlEnumerable.supportsInterface(interfaceId);
    }

    /**
     * @dev increase the pending request balance of token `tokenId_` by `amount`.
     * This internal function is called when an investor makes a deposit/withdrawal request.
     * @param tokenId_  id of the token.
     * @param amount_ amount to add.
     * @param minPrice_ minimum price of the yield-bearing token.
     * @param maxPrice_ maximum price  of the yield-bearing token
     * @param currentEventId_  id of the next manager event (process).
     */

    function _increasePendingRequest(
        uint256 tokenId_,
        uint256 amount_,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 currentEventId_
    ) internal {
        pendingRequests[tokenId_].increase(
            amount_,
            minPrice_,
            maxPrice_,
            currentEventId_
        );
        totalAmount += amount_;
    }

    /**
     * @dev decrease the pending request balance of token `tokenId_` by `amount`.
     * This internal function is called when an investor cancel a deposit/withdrawal request.
     * @param tokenId_  id of the token.
     * @param amount_ amount to remove.
     * @param currentEventId_  id of the next manager event (process).
     */
    function _decreasePendingRequest(
        uint256 tokenId_,
        uint256 amount_,
        uint256 currentEventId_
    ) internal {
        pendingRequests[tokenId_].decrease(amount_, currentEventId_);
        _decreaseTotalAmount(tokenId_, amount_);
    }

    /**
     * @dev burn token `tokenId_.
     * a proof token is burned when its corresponding investor pending request is fully validated by the manager.
     * @param tokenId_  id of the token.
     * Emits a {Burn} event with `owner_` and `tokenId_ `.
     */
    function burn(uint256 tokenId_) internal {
        _burn(tokenId_);
        _deleteId(tokenId_);
        emit Burn(tokenId_);
    }

    function _deleteId(uint256 id_) internal {
        uint256 index_ = pendingIdIndex[id_];
        uint256 lastId_ = pendingIds[pendingIds.length - 1];
        pendingIds[index_] = lastId_;
        pendingIds.pop();
        pendingIdIndex[lastId_] = index_;
        delete pendingIdIndex[id_];
        delete pendingRequests[id_];
    }

    /**
     * @dev decrease totalAmount at least by `amount`.
     * This internal function decreases totalAmount at least by `amount` when an investor cancels his
     * deposit/withdrawal request `tokenId_` or the manager validates it.
     * If the remaining pending request balance of `tokenId_` is lower than `tolerance`,
     * the proof token `tokenId_` is burned and this remaining balance amount is removed also from totalAmount.
     * @param tokenId_  id of the token.
     */
    function _decreaseTotalAmount(uint256 tokenId_, uint256 amount_) internal {
        uint256 amountToRemove_ = amount_;
        uint256 remainingAmount_ = pendingRequests[tokenId_].lockedAmount +
            pendingRequests[tokenId_].availableAmount;

        if (remainingAmount_ <= tolerance) {
            amountToRemove_ += remainingAmount_;
            burn(tokenId_);
        }
        require(totalAmount >= amountToRemove_, "Every.finance: max amount");
        unchecked {
            totalAmount -= amountToRemove_;
        }
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
import "./HoldTime.sol";

/**
 * @dev Implementation of the yield-bearing tokens {ERC20}.
 */

contract Token is ERC20, AccessControlEnumerable {
    bytes32 public constant INVESTMENT = keccak256("INVESTMENT");
    address public investment;
    mapping(address => bool) public whitelist;
    HoldTime public holdTime;

    event UpdateInvestment(address indexed investment_);
    event UpdateHoldTime(address indexed holdTime_);
    event AddToWhiteList(address indexed address_);
    event RemoveFromWhiteList(address indexed address_);
    event Mint(address indexed to_, uint256 amount_);
    event Burn(address indexed account_, uint256 amount_);

    constructor(
        string memory _name,
        string memory _symbol,
        address holdTime_,
        address admin_
    ) ERC20(_name, _symbol) {
        require(holdTime_ != address(0), "Every.finance: zero address");
        require(admin_ != address(0), "Every.finance: zero address");

        _setupRole(DEFAULT_ADMIN_ROLE, admin_);
        holdTime = HoldTime(holdTime_);
    }

    /**
     * @dev Update investment.
     * @param investment_.
     * Emits an {UpdateInvestment} event indicating the updated investment `investment_`.
     */
    function updateInvestment(
        address investment_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(investment_ != address(0), "Every.finance: zero address");
        require(investment_ != investment, "Every.finance: no change");
        _revokeRole(INVESTMENT, investment);
        _grantRole(INVESTMENT, investment_);
        whitelist[investment] = false;
        whitelist[investment_] = true;
        investment = investment_;
        emit UpdateInvestment(investment_);
    }

    /**
     * @dev Update holdTime.
     * @param holdTime_.
     * Emits an {UpdateHoldTime} event indicating the updated holdTime `holdTime_`.
     */
    function updateHoldTime(
        address holdTime_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(holdTime_ != address(0), "Every.finance: zero address");
        require(holdTime_ != address(holdTime), "Every.finance: no change");
        holdTime = HoldTime(holdTime_);
        emit UpdateHoldTime(holdTime_);
    }

    /**
     * @dev Add `account_` to `whitelist `.
     * @param account_ .
     * Emits an {AddToWhiteList} event indicating the addedd address `account_`.
     */
    function addToWhiteList(
        address account_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(account_ != address(0), "Every.finance: zero address");
        require(!whitelist[account_], "Every.finance: address exists");
        whitelist[account_] = true;
        emit AddToWhiteList(account_);
    }

    /**
     * @dev remove `account_` from `whitelist `.
     * @param account_ .
     * Emits an {RemoveFromWhiteList} event indicating the deleted address `account_`.
     */
    function removeFromWhiteList(
        address account_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(
            whitelist[account_],
            "Every.finance: address doesn't exist"
        );
        whitelist[account_] = false;
        emit RemoveFromWhiteList(account_);
    }

    /**
     * @dev mint `amount_`Token for `to_`
     * @param to_ receiver's address.
     * @param amount_  amount to mint.
     * Emits an {Mint} event with `to_`, and `amount_`.
     */
    function mint(address to_, uint256 amount_) external onlyRole(INVESTMENT) {
        _mint(to_, amount_);
        emit Mint(to_, amount_);
    }

    /**
     * @dev burn `amount_`Token for `from_`
     * @param from_ user's address.
     * @param amount_ amount to burn.
     * Emits an {Burn} event with `from_`, and `amount_`.
     */
    function burn(
        address from_,
        uint256 amount_
    ) external onlyRole(INVESTMENT) {
        require(amount_ != 0, "Every.finance: zero amount");
        _burn(from_, amount_);
        emit Burn(from_, amount_);
    }

    /**
     * @dev get the average token hold time of `account_`
     * @param account_  user's address.
     * @return time_ average token hold time.
     */
    function getHoldTime(address account_) public view returns (uint256 time_) {
        time_ = holdTime.getHoldTime(account_);
    }

    /**
     * @dev update the average token hold time for `account_`.
     * @param account_ user's address.
     * @param amount_  new received token amount.
     */

    function _updateHoldTime(address account_, uint256 amount_) internal {
        require(amount_ != 0, "Every.finance: zero amount");
        holdTime.updateHoldTime(account_, amount_);
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning. It permits to update the hold time of the receiver `to_` if :
     *  - the receiver's address `from_` is not zero nor whitelisted  and the sender is not whitelisted
     * @param from sender's address.
     * @param to receiver's address.
     * @param amount transferred amount.
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual override {
        if ((to != address(0)) && (!whitelist[from]) && (!whitelist[to])) {
            _updateHoldTime(to, amount);
        }
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

/**
 * @dev Implementation of the contract HoldTime.
 * It allows to update average hold time of the yield-bearing token.
 */

contract HoldTime is Ownable {
    address public token;
    mapping(address => uint256) private holdTimes;

    event UpdateToken(address indexed token_);
    event UpdateHoldTime(
        address indexed account_,
        uint256 oldHoldTime_,
        uint256 newHoldTime_
    );

    /**
     * @dev Update token.
     * @param token_ token's address
     * @notice Emits a {UpdateToken} event indicating the updated token `token_`.
     */
    function updateToken(address token_) external onlyOwner {
        require(token_ != address(0), "Every.finance: zero address");
        require(token_ != token, "Every.finance: no change");
        token = token_;
        emit UpdateToken(token_);
    }

    /**
     * @dev update HoldTimes.
     * @param account_ account's address.
     * @param amount_  token amount.
     * Emits a {UpdateHoldTime} event with `account_`, `oldHoldTime_` and `newHoldTime_`.
     */
    function updateHoldTime(address account_, uint256 amount_) external {
        require(msg.sender == token, "Every.finance: caller is not token");
        uint256 oldAmount_ = IERC20(token).balanceOf(account_);
        uint256 oldHoldTime_ = holdTimes[account_];
        uint256 newHoldTime_ = (oldAmount_ *
            oldHoldTime_ +
            block.timestamp *
            amount_) / (oldAmount_ + amount_);
        holdTimes[account_] = newHoldTime_;
        emit UpdateHoldTime(account_, oldHoldTime_, newHoldTime_);
    }

    /**
     * @dev get hold time.
     * @param account_ investor's address.
     * @return time_ hold time.
     */
    function getHoldTime(address account_) public view returns (uint256 time_) {
        time_ = holdTimes[account_];
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;
import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
import "../libraries/AssetTransfer.sol";

/**
 * @author Every.finance.
 * @notice Implementation of Treasury contract.
 */

contract Treasury is AccessControlEnumerable {
    bytes32 public constant WITHDRAWER = keccak256("WITHDRAWER");

    event SendTo(address indexed to_, uint256 amount_, address asset_);

    constructor(address admin_) payable {
        _setupRole(DEFAULT_ADMIN_ROLE, admin_);
    }

    receive() external payable {}

    /**
     * @dev Send asset `asset_` from the contract to address `to_`.
     * @param to_ receiver.
     * @param amount_ amount to send.
     * @param asset_ asset's address.
     * Emits an {SendTo} event with `to_`, `amount_` and `asset_`.
     */

    function sendTo(
        address to_,
        uint256 amount_,
        address asset_
    ) public onlyRole(WITHDRAWER) {
        require(to_ != address(0), "Every.finance: zero address");
        AssetTransfer.transfer(to_, amount_, asset_);
        emit SendTo(to_, amount_, asset_);
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
import "@chainlink/contracts/src/v0.8/interfaces/AggregatorV3Interface.sol";
import "@openzeppelin/contracts/security/Pausable.sol";
import "../libraries/FeeMinter.sol";
import "./Management.sol";
import "./Proof.sol";
import "./Token.sol";

/**
 * @dev Implementation of the contract Investment.
 * It allows the investor to depositProof/withdraw funds and the manager to validate
 * the depositProof/withdrawalProof investor requests.
 */

interface IParity {
    function setDepositData(
        uint256 amountMinted_,
        uint256 amountValidated_,
        uint256 id_
    ) external;

    function setWithdrawalData(
        uint256 amountMinted_,
        uint256 amountValidated_,
        uint256 id_
    ) external;
}

contract Investment is AccessControlEnumerable, Pausable {
    using Math for uint256;
    bytes32 public constant PROOF = keccak256("PROOF");
    bytes32 public constant MANAGER = keccak256("MANAGER");
    uint256 public constant MAX_PRICE = type(uint256).max;
    uint256 public immutable id;
    uint256 public currentEventId;
    uint256 public tokenPrice;
    uint256 public tokenPriceMean;
    uint256 public managementFeeLastTime;
    uint256 public depositProofTokenId;
    uint256 public withdrawalProofTokenId;
    uint256 public eventBatchSize;
    uint256 public lastPerformanceFee;
    uint256 public lastManagementFee;
    uint256 public totalPerformanceFee;
    uint256 public totalManagementFee;
    address public asset;
    address public assetOracle;
    Token public token;
    Management public management;
    Proof public depositProof;
    Proof public withdrawalProof;
    IParity public managementParity;
    event UpdateManagement(address indexed management_);
    event UpdateDepositProof(address indexed depositProof_);
    event UpdateWithdrawalProof(address indexed withdrawalProof_);
    event UpdateManagementParity(address indexed managementParity_);
    event UpdateToken(address indexed token_);
    event UpdateAsset(address indexed asset_);
    event UpdateAssetOracle(address indexed assetOracle_);
    event UpdateEventBatchSize(uint256 eventBatchSize_);
    event DepositRequest(address indexed account_, uint256 amount_);
    event CancelDepositRequest(address indexed account_, uint256 amount_);
    event WithdrawalRequest(address indexed account_, uint256 amount_);
    event CancelWithdrawalRequest(address indexed account_, uint256 amount_);
    event StartNextEvent(uint256 tokenPrice, uint256 currentEventId);

    event Validatedeposit(
        uint256 indexed tokenId_,
        uint256 validatedAmount_,
        uint256 mintedAmount_
    );
    event Validatewithdrawal(
        uint256 indexed tokenId_,
        uint256 validatedAmount_,
        uint256 SentAmount_
    );
    event MintPerformanceFee(uint256 performanceFee_);
    event MintManagementFee(uint256 managementFee_);
    event MintOrBurnInvestmentFee(
        uint256 amount_,
        bool isFee_,
        uint256 remainingAmount_
    );

    constructor(
        uint256 id_,
        address asset_,
        address token_,
        address management_,
        address depositProof_,
        address withdrawalProof_,
        address admin_,
        address assetOracle_
    ) payable {
        require(id_ <= 2, "Every.finance: out of range");
        require(token_ != address(0), "Every.finance: zero address");
        require(management_ != address(0), "Every.finance: zero address");
        require(depositProof_ != address(0), "Every.finance: zero address");
        require(
            withdrawalProof_ != address(0),
            "Every.finance: zero address"
        );
        require(admin_ != address(0), "Every.finance: zero address");
        require(assetOracle_ != address(0), "Every.finance: zero address");
        id = id_;
        token = Token(token_);
        management = Management(management_);
        depositProof = Proof(depositProof_);
        withdrawalProof = Proof(withdrawalProof_);
        if (asset_ != address(0)) {
            (bool success_, uint8 assetDecimals_) = AssetTransfer
                .tryGetAssetDecimals(IERC20(asset_));
            require(success_, "Every.finance: no decimal");
            require(
                assetDecimals_ <= uint8(18),
                "Every.finance: max decimal"
            );
            asset = asset_;
            assetOracle = assetOracle_;
        }
        _setupRole(DEFAULT_ADMIN_ROLE, admin_);
        _setupRole(PROOF, address(depositProof_));
        _setupRole(PROOF, address(withdrawalProof_));
    }

    receive() external payable {}

    /**
     * @dev Update management.
     * @param management_ management contract address
     * Emits an {UpdateManagement} event indicating the updated management contract.
     */
    function updateManagement(
        address management_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(management_ != address(0), "Every.finance: zero address");
        require(
            management_ != address(management),
            "Every.finance: no change"
        );
        management = Management(management_);
        emit UpdateManagement(management_);
    }

    /**
     * @dev Update depositProof.
     * @param depositProof_ depositProof contract address
     * Emits an {UpdateDepositProof} event indicating the updated depositProof contract.
     */
    function updateDepositProof(
        address depositProof_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(depositProof_ != address(0), "Every.finance: zero address");
        require(
            depositProof_ != address(depositProof),
            "Every.finance: no change"
        );
        _revokeRole(PROOF, address(depositProof));
        _grantRole(PROOF, depositProof_);
        depositProof = Proof(depositProof_);
        emit UpdateDepositProof(depositProof_);
    }

    /**
     * @dev Update withdrawalProof.
     * @param withdrawalProof_ withdrawalProof contract address
     * Emits an {UpdateWithdrawalProof} event indicating the updated withdrawalProof contract.
     */
    function updateWithdrawalProof(
        address withdrawalProof_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(
            withdrawalProof_ != address(0),
            "Every.finance: zero address"
        );
        require(
            withdrawalProof_ != address(withdrawalProof),
            "Every.finance: no change"
        );
        _revokeRole(PROOF, address(withdrawalProof));
        _grantRole(PROOF, withdrawalProof_);
        withdrawalProof = Proof(withdrawalProof_);
        emit UpdateWithdrawalProof(withdrawalProof_);
    }

    /**
     * @dev Update managementParity.
     * @param managementParity_ ManagementParity contract address
     * Emits an {UpdateManagementParity} event indicating the updated ManagementParity contract.
     */
    function updateManagementParity(
        address managementParity_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(
            managementParity_ != address(0),
            "Every.finance: zero address"
        );
        require(
            managementParity_ != address(managementParity),
            "Every.finance: no change"
        );
        managementParity = IParity(managementParity_);
        emit UpdateManagementParity(managementParity_);
    }

    /**
     * @dev Update the yield-bearing token address.
     * @param token_ token's address.
     * Emits an {UpdateToken} event indicating the updated token contract.
     */
    function updateToken(address token_) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(token_ != address(0), "Every.finance: zero address");
        require(token_ != address(token), "Every.finance: no change");
        token = Token(token_);
        emit UpdateToken(token_);
    }

     /**
     * @dev Update asset's price oracle.
     * @param assetOracle_ asset's price oracle.
     * Emits an {UpdateAssetOracle} event indicating the updated token contract.
     */

    function updateAssetOracle(address assetOracle_) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(assetOracle_ != address(0), "Every.finance: zero address");
        require(assetOracle_ != assetOracle, "Every.finance: no change");
        assetOracle = assetOracle_;
        emit UpdateAssetOracle(assetOracle_);
    }

    /**
     * @dev Update the underlying asset that investors can deposit.
     * asset's address cannot be updated if there are deposit/withdrawal requests on pending.
     * @param asset_ asset's address.
     * Emits an {UpdateAsset} event indicating the updated asset `asset_`.
     */
    function updateAsset(address asset_) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(asset != asset_, "Tansformative.Fi: no asset change");
        require(
            (depositProof.totalAmount() == 0) &&
                (withdrawalProof.totalAmount() == 0),
            "Every.finance: requests on pending"
        );
        if (asset_ != address(0)) {
            (bool success_, uint8 assetDecimals_) = AssetTransfer
                .tryGetAssetDecimals(IERC20(asset_));
            require(success_, "Every.finance: no decimal");
            require(
                assetDecimals_ <= uint8(18),
                "Every.finance: max decimal"
            );
        }
        asset = asset_;
        emit UpdateAsset(asset_);
    }

    /**
     * @dev Update eventBatchSize (maximum  number of investors to be validate by batch).
     * @param eventBatchSize_  new eventBatchSize number.
     * Emits an {UpdateEventBatchSize} event indicating the updated eventBatchSize `eventBatchSize_`.
     */
    function updateEventBatchSize(
        uint256 eventBatchSize_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(eventBatchSize_ != 0, "Every.finance: zero value");
        eventBatchSize = eventBatchSize_;
        emit UpdateEventBatchSize(eventBatchSize_);
    }

    /**
     * @dev Update ManagementFeeLastTime.
     */
    function updateManagementFeeLastTime(uint256 managementFeeLastTime_) external onlyRole(DEFAULT_ADMIN_ROLE) {
        managementFeeLastTime = managementFeeLastTime_;
    }

    /**
     * @dev Update TokenPriceMean.
     */
    function updateTokenPriceMean(uint256 tokenPriceMean_) external onlyRole(DEFAULT_ADMIN_ROLE) {
        tokenPriceMean = tokenPriceMean_;
    }


    /**
     * @dev get the last price of asset.
     */
    function getAssetPrice() public view returns (uint256, uint256) {
        AggregatorV3Interface priceFeed_ = AggregatorV3Interface(assetOracle);
            (
                ,
                /*uint80 roundID*/ int price_ /*uint startedAt*/ /*uint timeStamp*/ /*uint80 answeredInRound*/,
                ,
                ,

            ) = priceFeed_.latestRoundData();
            require(price_ > 0, "Every.finance: invalid price");
            uint8 decimals_ = priceFeed_.decimals();
            return (uint256(price_), decimals_);
    }



    /**
     * @dev start new event (manager cycle validation).
     * Emits an {UpdateStartNextEvent} event with token price `tokenPrice` and next event id `currentEventId`.
     *
     */
    function startNextEvent() external onlyRole(MANAGER) {
        (tokenPrice, ) = management.tokenPrice();
        currentEventId += 1;
        emit StartNextEvent(tokenPrice, currentEventId);
    }

    /**
     * @dev validate investor deposit requests by the manager.
     * The deposit request consists of minting the required amount of yield-bearing token for the investor, and
     * decreasing his pending request amount by an equivalent amount.
     * If the deposit request is fully validated (the pending request amount is zero), the corresponding proof is burned.
     * @param tokenIds_ array of Proof tokens ids.
     * @param maxdeposit_  max total amount of deposit asset to validate.
     * Emits an {Validatedeposit} event with token id `tokenId_`, validate deposit asset amount
     * `amountAsset_` and minted token amount `amountToken_`.
     */
    function validateDeposits(
        uint256[] calldata tokenIds_,
        uint256 maxdeposit_
    )
        external
        whenNotPaused
        onlyRole(MANAGER)
        returns (uint256 newMaxdeposit_)
    {
        uint256 amountAsset_;
        uint256 amountAssetTotal_;
        uint256 amountToken_;
        uint256 amountTokenTotal_;
        uint256 tokenId_;
        uint256 size_ = tokenIds_.length;
        uint256 totalSupplyToken_ = token.totalSupply();
        address owner_;
        require(size_ != 0, "Every.finance: size is zero");
        require(size_ <= eventBatchSize, "Every.finance: max size");
        (uint256 assetPrice_, uint256 decimal_) = getAssetPrice();
        for (uint256 i = 0; i < size_; ) {
            tokenId_ = tokenIds_[i];
            owner_ = depositProof.ownerOf(tokenId_);
            require(owner_ != address(0), "Every.finance: zero address");
            if (!isValidPrice(depositProof, tokenId_)) {
                depositProof.updateEventId(tokenId_, currentEventId);
            } else {
                if (maxdeposit_ <= amountAssetTotal_) {
                    break;
                }
                depositProof.preValidatePendingRequest(
                    tokenId_,
                    currentEventId
                );
                (amountAsset_, , , , ) = depositProof.pendingRequests(tokenId_);
                amountAsset_ = Math.min(
                    maxdeposit_ - amountAssetTotal_,
                    amountAsset_
                );
                amountToken_ = Math.mulDiv(
                    amountAsset_,
                    FeeMinter.SCALING_FACTOR * assetPrice_,
                    tokenPrice  * (10 ** decimal_)
                );
                if (
                    (owner_ == address(managementParity)) && (amountAsset_ != 0)
                ) {
                    managementParity.setDepositData(
                        amountToken_,
                        amountAsset_,
                        id
                    );
                }
                unchecked {
                    amountAssetTotal_ += amountAsset_;
                }
                if (amountToken_ != 0) {
                    token.mint(owner_, amountToken_);
                    amountTokenTotal_ += amountToken_;
                }
                depositProof.validatePendingRequest(
                    tokenId_,
                    amountAsset_,
                    currentEventId
                );

                emit Validatedeposit(tokenId_, amountAsset_, amountToken_);
            }
            unchecked {
                i++;
            }
        }
        unchecked {
            newMaxdeposit_ = maxdeposit_ - amountAssetTotal_;
        }
        if (amountTokenTotal_ != 0) {
            tokenPriceMean =
                ((totalSupplyToken_ * tokenPriceMean) +
                    (amountTokenTotal_ * tokenPrice)) /
                (totalSupplyToken_ + amountTokenTotal_);
        }
        if (managementFeeLastTime == 0) {
            managementFeeLastTime = block.timestamp;
        }
    }

    /**
     * @dev validate investor withdrawal requests by the manager.
     * The deposit request consists of sending the required amount of asset to the investor, and
     * burning the equivalent amount in yield-bearing token.
     * If the withdrawal request is fully validated (the pending request amount is zero), the corresponding proof is burned.
     * @param tokenIds_ array of Proof tokens ids.
     * @param maxwithdrawal_  max total amount of withdrawal to validate.
     * Emits an {ValidateWithdrawal} event with token id `tokenId_`, validate withdrawal asset amount
     * `amountAsset_` and burned token amount `amountToken_`.
     */
    function validateWithdrawals(
        uint256[] calldata tokenIds_,
        uint256 maxwithdrawal_
    )
        external
        whenNotPaused
        onlyRole(MANAGER)
        returns (uint256 _newMaxwithdrawal)
    {
        uint256 amountToken_;
        uint256 amountTokenTotal_;
        uint256 amountAsset_;
        uint256 size_ = tokenIds_.length;
        uint256 tokenId_;
        address owner_;
        require(size_ != 0, "Every.finance: size is zero");
        require(size_ <= eventBatchSize, "Every.finance: max size");
        uint256 amountTotal_ = withdrawalProof.totalAmount();
        (uint256 assetPrice_, uint256 decimal_) = getAssetPrice();
        for (uint256 i = 0; i < size_; ) {
            tokenId_ = tokenIds_[i];
            owner_ = withdrawalProof.ownerOf(tokenId_);
            require(owner_ != address(0), "Every.finance: zero address");
            if (!isValidPrice(withdrawalProof, tokenId_)) {
                withdrawalProof.updateEventId(tokenId_, currentEventId);
            } else {
                withdrawalProof.preValidatePendingRequest(
                    tokenId_,
                    currentEventId
                );
                (amountToken_, , , , ) = withdrawalProof.pendingRequests(
                    tokenId_
                );
                amountToken_ = Math.min(
                    Math.mulDiv(maxwithdrawal_, amountToken_, amountTotal_),
                    amountToken_
                );
                unchecked {
                    amountTokenTotal_ += amountToken_;
                }
                amountAsset_ = Math.mulDiv(
                    amountToken_,
                    tokenPrice * (10 ** decimal_),
                    FeeMinter.SCALING_FACTOR * assetPrice_
                );
                if (
                    (owner_ == address(managementParity)) && (amountToken_ != 0)
                ) {
                    managementParity.setWithdrawalData(
                        amountAsset_,
                        amountToken_,
                        id
                    );
                }
                withdrawalProof.validatePendingRequest(
                    tokenId_,
                    amountToken_,
                    currentEventId
                );
                if (amountAsset_ != 0) {
                    AssetTransfer.transfer(owner_, amountAsset_, asset);
                }

                emit Validatewithdrawal(tokenId_, amountToken_, amountAsset_);
            }
            unchecked {
                i++;
            }
        }
        unchecked {
            _newMaxwithdrawal = maxwithdrawal_ - amountTokenTotal_;
        }

        if ((amountTokenTotal_) != 0) {
            token.burn(address(this), amountTokenTotal_);
        }
    }

    /**
     * @dev make a deposit request by the investor.
     * the investor sends an amount of asset to the smart contracts and deposit fee to the treasury.
     * the investor receives or updates his deposit Proof {ERC721}.
     * @param account_ investor'address.
     * @param tokenId_ token id of the deposit Proof (if tokenId_ == 0, then a new token is minted).
     * @param amount_ amount of asset to deposit.
     * @param minPrice_ minimum price of yield-bearing token to be accepted.
     * @param maxPrice_ maximum price of yield-bearing token to be accepted.
     * @param maxFee_ maximum deposit fee to be accepted.
     * Emits an {DepositRequest} event with account `account_` and  amount `amount_`.
     */
    function depositRequest(
        address account_,
        uint256 tokenId_,
        uint256 amount_,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 maxFee_
    ) external payable whenNotPaused {
        uint256 fee_;
        require(amount_ != 0, "Transformative Fi: zero amount");
        if (account_ != address(managementParity)) {
            require(
                amount_ >= management.minDepositAmount(),
                "Every.finance: min depositProof Amount"
            );
            fee_ = getDepositFee(amount_);
            require(fee_ <= maxFee_, "Every.finance: max allowed fee");
            amount_ -= fee_;
        }
        require(
            (minPrice_ <= maxPrice_) && (maxPrice_ != 0),
            "Every.finance: wrong prices"
        );
        if (tokenId_ == 0) {
            depositProofTokenId += 1;
            depositProof.mint(
                account_,
                depositProofTokenId,
                amount_,
                minPrice_,
                maxPrice_,
                currentEventId
            );
        } else {
            require(
                depositProof.ownerOf(tokenId_) == account_,
                "Every.finance: account is not owner"
            );

            if (account_ != _msgSender()) {
                (
                    ,
                    ,
                    uint256 minPriceOld_,
                    uint256 maxPriceOld_,

                ) = depositProof.pendingRequests(tokenId_);
                require(
                    (minPrice_ == minPriceOld_) && (maxPrice_ == maxPriceOld_),
                    "Every.finance: prices don't match"
                );
            }
            depositProof.increasePendingRequest(
                tokenId_,
                amount_,
                minPrice_,
                maxPrice_,
                currentEventId
            );
        }
        if (asset != address(0)) {
            AssetTransfer.transferFrom(
                _msgSender(),
                address(this),
                amount_ + fee_,
                IERC20(asset)
            );
        } else {
            require(
                (msg.value == amount_ + fee_),
                "Every.finance: no required amount"
            );
        }
        if (fee_ > 0) {
            AssetTransfer.transfer(management.treasury(), fee_, asset);
        }
        emit DepositRequest(account_, amount_);
    }

    /**
     * @dev cancel a deposit request by the investor.
     * the investor can cancel a full or partial amount of his deposit.
     * the investor burns or updates his deposit Proof {ERC721}.
     * @param tokenId_ token id of the deposit Proof (if tokenId_ == 0, then a new token is minted).
     * @param amount_ amount of asset to cancel.
     * Emits an {CancelDepositRequest} event with the caller and  amount `amount_`.
     */
    function cancelDepositRequest(
        uint256 tokenId_,
        uint256 amount_
    ) external whenNotPaused {
        require(
            management.isCancelDeposit(),
            "Every.finance: no deposit cancel"
        );
        require(amount_ != 0, "Transformative Fi: zero amount");
        require(
            depositProof.ownerOf(tokenId_) == _msgSender(),
            "Every.finance: caller is not owner"
        );
        depositProof.decreasePendingRequest(tokenId_, amount_, currentEventId);
        AssetTransfer.transfer(_msgSender(), amount_, asset);
        emit CancelDepositRequest(_msgSender(), amount_);
    }

    /**
     * @dev make a withdrawal request by the investor.
     * the investor sends an amount of yield-bearing token to the smart contracts and withdrawal fee to the treasury.
     * the investor receives or updates his withdrawal Proof {ERC721}.
     * @param tokenId_ token id of the withdrawal Proof (if tokenId_ == 0, then a new token is minted).
     * @param amount_ amount of yield-bearing token to withdraw.
     * @param minPrice_ minimum price of yield-bearing token to be accepted.
     * @param maxPrice_ maximum price of yield-bearing token to be accepted.
     * @param maxFee_ maximum withdrawal fee to be accepted.
     * Emits an {WithdrawalRequest} event with account `account_` and  amount `amount_`.
     */
    function withdrawalRequest(
        uint256 tokenId_,
        uint256 amount_,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 maxFee_
    ) external whenNotPaused {
        require(amount_ != 0, "Transformative Fi: zero amount");
        uint256 fee_;
        require(
            token.balanceOf(_msgSender()) >= amount_,
            "Transformative Fi: amount exceeds balance"
        );
        if (_msgSender() != address(managementParity)) {
            uint256 holdTime_ = token.getHoldTime(_msgSender());
            fee_ =
                (management.getWithdrawalFeeRate(holdTime_) * amount_) /
                FeeMinter.SCALING_FACTOR;

            require(fee_ <= maxFee_, "Every.finance: max allowed fee");
            amount_ = amount_ - fee_;
        }
        require(
            (minPrice_ <= maxPrice_) && (maxPrice_ != 0),
            "Every.finance: wrong prices"
        );
        if (tokenId_ == 0) {
            withdrawalProofTokenId += 1;
            withdrawalProof.mint(
                _msgSender(),
                withdrawalProofTokenId,
                amount_,
                minPrice_,
                maxPrice_,
                currentEventId
            );
        } else {
            require(
                withdrawalProof.ownerOf(tokenId_) == _msgSender(),
                "Every.finance: caller is not owner"
            );

            withdrawalProof.increasePendingRequest(
                tokenId_,
                amount_,
                minPrice_,
                maxPrice_,
                currentEventId
            );
        }
        token.transferFrom(_msgSender(), address(this), amount_);
        if (fee_ != 0) {
            token.transferFrom(_msgSender(), management.treasury(), fee_);
        }
        emit WithdrawalRequest(_msgSender(), amount_);
    }

    /**
     * @dev cancel a withdrawal request by the investor.
     * the investor can cancel a full or partial amount of his withdrawal.
     * the investor burns or updates his withdrawal Proof {ERC721}.
     * @param tokenId_ token id of the withdrawal Proof (if tokenId_ == 0, then a new token is minted).
     * @param amount_ amount of yield-bearing token to cancel.
     * Emits an {CancelWithdrawalRequest} event with the caller and  amount `amount_`.
     */
    function cancelWithdrawalRequest(
        uint256 tokenId_,
        uint256 amount_
    ) external whenNotPaused {
        require(
            management.isCancelWithdrawal(),
            "Every.finance: no withdrawal cancel"
        );
        require(amount_ != 0, "Transformative Fi: zero amount");
        require(
            withdrawalProof.ownerOf(tokenId_) == _msgSender(),
            "Every.finance: caller is not owner"
        );
        withdrawalProof.decreasePendingRequest(
            tokenId_,
            amount_,
            currentEventId
        );
        token.transfer(_msgSender(), amount_);
        emit CancelWithdrawalRequest(_msgSender(), amount_);
    }

    /**
     * @dev Send asset to the SafeHouse by the manager.
     * @param amount_ amount to send.
     */
    function sendToSafeHouse(
        uint256 amount_
    ) external whenNotPaused onlyRole(MANAGER) {
        require(amount_ != 0, "Every.finance: zero amount");
        address safeHouse_ = management.safeHouse();
        require(safeHouse_ != address(0), "Every.finance: zero address");
        AssetTransfer.transfer(safeHouse_, amount_, asset);
    }

    /**
     * @dev mint Performance fee by the manager
     * performance fee are minted in yield-bearing token.
     */
    function mintPerformanceFee() external onlyRole(MANAGER) {
        (uint256 tokenPrice_, ) = management.tokenPrice();
        uint256 performanceFeeRate_ = management.performanceFeeRate();
        address treasury_ = management.treasury();
        uint256 performanceFee_;
        (tokenPriceMean, performanceFee_) = FeeMinter.mintPerformanceFee(
            tokenPrice_,
            tokenPriceMean,
            performanceFeeRate_,
            treasury_,
            address(token)
        );
        lastPerformanceFee = performanceFee_;
        totalPerformanceFee += performanceFee_;
        emit MintPerformanceFee(performanceFee_);
    }

    /**
     * @dev mint management fee by the manager
     * management fee are minted in yield-bearing token.
     */
    function mintManagementFee() external onlyRole(MANAGER) {
        uint256 managementFeeRate_ = management.managementFeeRate();
        address treasury_ = management.treasury();
        uint256 managementFee_;
        (managementFeeLastTime, managementFee_) = FeeMinter.mintManagementFee(
            managementFeeLastTime,
            managementFeeRate_,
            treasury_,
            address(token)
        );
        lastManagementFee = managementFee_;
        totalManagementFee += managementFee_;
        emit MintManagementFee(managementFee_);
    }

    /**
     * @dev mint or burn Investment fee by the manager
     * Investment fee are minted (negative fee) Or bunred (positive fee) in yield-bearing token.
     * @param amount_ amount of negative/positive fee.
     * @param isFee_ true if negative fee, false otherwise.
     */
    function mintOrBurnInvestmentFee(
        uint256 amount_,
        bool isFee_
    ) external payable onlyRole(MANAGER) returns (uint256 remainingAmount_) {
        (uint256 tokenPrice_, ) = management.tokenPrice();
        address treasury_ = management.treasury();
        remainingAmount_ = FeeMinter.MintInvestmentFee(
            amount_,
            tokenPrice_,
            isFee_,
            payable(treasury_),
            address(token),
            asset
        );

        emit MintOrBurnInvestmentFee(amount_, isFee_, remainingAmount_);
    }

    /**
     * @dev get deposit fee for a deposit amount `amount_`
     * @param amount_ amount in asset to deposit by the investor.
     */
    function getDepositFee(uint256 amount_) public view returns (uint256) {
        return management.getDepositFee(amount_);
    }

    /**
     * @dev get  yield-bearing token price.
     */
    function getTokenPrice() public view returns (uint256 price_) {
        (price_, ) = management.tokenPrice();
    }

    /**
     * @dev verify if the price bounds of deposit/withdrawal pending request are valid.
     * @param proof_ Proof contract'address.
     * @param tokenId_  token id of the pending request.
     * @return isValid_ true if price bounds are valid , fase otherwise.
     */
    function isValidPrice(
        Proof proof_,
        uint256 tokenId_
    ) public view returns (bool isValid_) {
        (, , uint256 minPrice_, uint256 maxPrice_, ) = proof_.pendingRequests(
            tokenId_
        );
        isValid_ = (minPrice_ <= tokenPrice) && (maxPrice_ >= tokenPrice);
    }

    function pause() public onlyRole(DEFAULT_ADMIN_ROLE) {
        _pause();
    }

    function unpause() public onlyRole(DEFAULT_ADMIN_ROLE) {
        _unpause();
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/access/AccessControlEnumerable.sol";
import "@openzeppelin/contracts/utils/math/Math.sol";

/**
 * @dev Implementation of the contract Management.
 * It allows the manager to set the different parameters of the product.
 */
contract Management is AccessControlEnumerable {
    bytes32 public constant MANAGER = keccak256("MANAGER");
    bytes32 public constant ORACLE = keccak256("ORACLE");
    uint256 public constant SCALING_FACTOR = 1e8;

    struct Fee {
        uint256 rate;
        uint256 time;
    }

    struct Price {
        uint256 value;
        uint256 time;
    }

    struct DepositFee {
        uint256 rate;
        uint256 minValue;
        uint256 maxValue;
    }

    uint256 public managementFeeRate;
    uint256 public performanceFeeRate;
    uint256 public minDepositAmount;
    Price public tokenPrice;
    DepositFee public depositFee;
    Fee[] public withdrawalFee;
    bool public isCancelDeposit;
    bool public isCancelWithdrawal;
    address public treasury;
    address public safeHouse;

    event UpdateTreasury(address indexed treasury_);
    event UpdateSafeHouse(address indexed safeHouse_);
    event UpdateIsCancelDeposit(bool iscancelDeposit_);
    event UpdateIsCancelWithdrawal(bool isWithdrawalCancel_);
    event UpdateDepositFee(uint256 rate_, uint256 minValue_, uint256 maxValue_);
    event UpdateManagementFeeRate(uint256 managementFeeRate_);
    event UpdatePerformanceFeeRate(uint256 performanceFeeRate_);
    event UpdateMinDepositAmount(uint256 minDepositAmount_);
    event UpdateTokenPrice(Price price_);
    event AddWithdrawalFee(uint256 rate_, uint256 time_);
    event UpdateWithdrawalFee(uint256 index_, uint256 rate_, uint256 time_);
    event DeleteLastWithdrawalFee(uint256 rate_, uint256 time_);

    constructor(address admin_, address manager_, address treasury_) {
        require(admin_ != address(0), "Every.finance: zero address");
        require(manager_ != address(0), "Every.finance: zero address");
        require(treasury_ != address(0), "Every.finance: zero address");
        treasury = treasury_;
        _setupRole(DEFAULT_ADMIN_ROLE, admin_);
        _setupRole(MANAGER, manager_);
    }

    /**
     * @dev Update treasury.
     * @param treasury_.
     * Emits an {UpdateTreasury} event indicating the updated treasury `treasury_`.
     */
    function updateTreasury(
        address treasury_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(treasury_ != address(0), "Every.finance: zero address");
        require(treasury != treasury_, "Every.finance: no change");
        treasury = treasury_;
        emit UpdateTreasury(treasury_);
    }

    /**
     * @dev Update safeHouse.
     * @param safeHouse_.
     * Emits an {UpdateSafeHouse} event indicating the updated safeHouse `safeHouse_`.
     */
    function updateSafeHouse(
        address safeHouse_
    ) external onlyRole(DEFAULT_ADMIN_ROLE) {
        require(safeHouse_ != address(0), "Every.finance: zero address");
        require(safeHouse != safeHouse_, "Every.finance: no change");
        safeHouse = safeHouse_;
        emit UpdateSafeHouse(safeHouse_);
    }

    /**
     * @dev Update isCancelDeposit.
     * @param  isCancelDeposit_.
     * Emits an {UpdateIsCancelDeposit} event indicating the updated  isCancelDeposit ` isCancelDeposit_`.
     */
    function updateIsCancelDeposit(
        bool isCancelDeposit_
    ) external onlyRole(MANAGER) {
        require(
            isCancelDeposit_ != isCancelDeposit,
            "Every.finance: no change"
        );
        isCancelDeposit = isCancelDeposit_;
        emit UpdateIsCancelDeposit(isCancelDeposit_);
    }

    /**
     * @dev Update isCancelWithdrawal.
     * @param  isCancelWithdrawal_.
     * Emits an {UpdateIsCancelWithdrawal} event indicating the updated  isCancelWithdrawal ` isCancelWithdrawal_`.
     */
    function updateIsCancelWithdrawal(
        bool isCancelWithdrawal_
    ) external onlyRole(MANAGER) {
        require(
            isCancelWithdrawal_ != isCancelWithdrawal,
            "Every.finance: no change"
        );
        isCancelWithdrawal = isCancelWithdrawal_;
        emit UpdateIsCancelWithdrawal(isCancelWithdrawal_);
    }

    /**
     * @dev Update depositFee.
     * @param  rate_.
     * @param  minValue_.
     * @param  maxValue_.
     * Emits an {UpdateDepositFee} event indicating the updated rate `rate_`, min value `minValue_`
     * and max value `maxValue_`
     */
    function updateDepositFee(
        uint256 rate_,
        uint256 minValue_,
        uint256 maxValue_
    ) external onlyRole(MANAGER) {
        require(rate_ <= SCALING_FACTOR, "Every.finance: out of range");
        require(
            minValue_ <= maxValue_,
            "Every.finance: wrong min max values"
        );
        depositFee = DepositFee(rate_, minValue_, maxValue_);
        emit UpdateDepositFee(rate_, minValue_, maxValue_);
    }

    /**
     * @dev Update managementFeeRate.
     * @param managementFeeRate_.
     * Emits an {UpdateManagementFeeRate} event indicating the updated managementFeeRate `managementFeeRate_`.
     */

    function updateManagementFeeRate(
        uint256 managementFeeRate_
    ) external onlyRole(MANAGER) {
        require(
            managementFeeRate_ <= SCALING_FACTOR,
            "Every.finance: out of range"
        );
        managementFeeRate = managementFeeRate_;
        emit UpdateManagementFeeRate(managementFeeRate_);
    }

    /**
     * @dev Update performanceFeeRate.
     * @param performanceFeeRate_.
     * Emits an {UpdatePerformanceFeeRate} event indicating the updated performanceFeeRate `performanceFeeRate_`.
     */

    function updatePerformanceFeeRate(
        uint256 performanceFeeRate_
    ) external onlyRole(MANAGER) {
        require(
            performanceFeeRate_ <= SCALING_FACTOR,
            "Every.finance: out of range"
        );
        performanceFeeRate = performanceFeeRate_;
        emit UpdatePerformanceFeeRate(performanceFeeRate_);
    }

    /**
     * @dev Update MinDepositAmount.
     * @param minDepositAmount_.
     * Emits an {UpdateMinDepositAmount} event indicating the updated minDepositAmount `minDepositAmount_`.
     */

    function updateMinDepositAmount(
        uint256 minDepositAmount_
    ) external onlyRole(MANAGER) {
        require(
            depositFee.minValue <= minDepositAmount_,
            "Every.finance: lower than min deposit fee"
        );
        minDepositAmount = minDepositAmount_;
        emit UpdateMinDepositAmount(minDepositAmount_);
    }

    /**
     * @dev Update tokenPrice.
     * @param price_.
     * Emits an {UpdateTokenPrice} event indicating the updated tokenPrice.
     */
    function updateTokenPrice(uint256 price_) external onlyRole(ORACLE) {
        require(price_ != 0, "Every.finance: zero price");
        tokenPrice = Price(price_, block.timestamp);
        emit UpdateTokenPrice(tokenPrice);
    }

    /**
     * @dev add a new withdrawal fee.
     * @param rate_.
     * @param time_.
     * Emits an {AddWithdrawalFee} event with feeRate `rate_` and feePeriod `time_`.
     */

    function addWithdrawalFee(
        uint256 rate_,
        uint256 time_
    ) external onlyRole(MANAGER) {
        require(rate_ <= SCALING_FACTOR, "Every.finance: out of range");
        uint256 size_ = withdrawalFee.length;
        if (size_ != 0) {
            require(
                withdrawalFee[size_ - 1].time < time_,
                "Every.finance: times don't match"
            );
            require(
                withdrawalFee[size_ - 1].rate > rate_,
                "Every.finance: fee rates don't match"
            );
        }
        withdrawalFee.push(Fee(rate_, time_));
        emit AddWithdrawalFee(rate_, time_);
    }

    /**
     * @dev Update withdrawal fee.
     * @param index_ index of array withdrawalFee to be updated.
     * @param rate_ new fee.
     * @param time_ new period.
     * Emits an {UpdateWithdrawalFee} event with `index_`, `rate_`, and 'time_'.
     */

    function updateWithdrawalFee(
        uint256 index_,
        uint256 rate_,
        uint256 time_
    ) external onlyRole(MANAGER) {
        require(rate_ <= SCALING_FACTOR, "Every.finance: out of range");
        uint256 size_ = withdrawalFee.length;
        require(index_ < size_, "Every.finance: out of size");
        if (index_ != 0) {
            require(
                withdrawalFee[index_ - 1].time < time_,
                "Every.finance: times don't match"
            );
            require(
                withdrawalFee[index_ - 1].rate > rate_,
                "Every.finance: fee rates don't match"
            );
        }
        if (index_ < size_ - 1) {
            require(
                withdrawalFee[index_ + 1].time > time_,
                "Every.finance: times don't match"
            );
            require(
                withdrawalFee[index_ + 1].rate < rate_,
                "Every.finance: fee rates don't match"
            );
        }
        withdrawalFee[index_] = Fee(rate_, time_);
        emit UpdateWithdrawalFee(index_, rate_, time_);
    }

    /**
     * @dev delete last fee from  withdrawalFee.
     * Emits an {DeleteLastWithdrawalFee} event with the removed fee.
     */

    function deleteLastWithdrawalFee() external onlyRole(MANAGER) {
        uint256 size_ = withdrawalFee.length;
        require(size_ != 0, "Every.finance. array is empty");
        Fee memory fee_ = withdrawalFee[size_ - 1];
        withdrawalFee.pop();
        emit DeleteLastWithdrawalFee(fee_.rate, fee_.time);
    }

    /**
     * @dev calculate withdrawal fee rate.
     * @param holdTime_ hold time of the yield-bearing tokens.
     */

    function calculateWithdrawalFeeRate(
        uint256 holdTime_
    ) public view returns (uint256) {
        uint256 size_ = withdrawalFee.length;
        require(block.timestamp >= holdTime_, "Every.finance: max time");
        uint256 deltaTime_;
        unchecked {
            deltaTime_ = block.timestamp - holdTime_;
        }
        if (size_ == 0) {
            return 0;
        } else if (deltaTime_ <= withdrawalFee[0].time) {
            return withdrawalFee[0].rate;
        } else if (deltaTime_ > withdrawalFee[size_ - 1].time) {
            return 0;
        } else {
            uint256 time_;
            Fee memory fee_;
            for (uint256 i = 0; i < size_ - 1; ) {
                time_ = withdrawalFee[i].time;
                fee_ = withdrawalFee[i + 1];
                if ((deltaTime_ > time_) && (deltaTime_ <= fee_.time)) {
                    return fee_.rate;
                }
                unchecked {
                    i++;
                }
            }
            return 0;
        }
    }

    /**
     * @dev get deposit fee.
     * @param amount_ deposit amount.
     * @return fee_ deposit fee.
     */
    function getDepositFee(uint256 amount_) public view returns (uint256 fee_) {
        DepositFee memory depositFee_ = depositFee;
        fee_ = Math.max(
            Math.mulDiv(depositFee_.rate, amount_, SCALING_FACTOR),
            depositFee_.minValue
        );
        fee_ = Math.min(fee_, depositFee_.maxValue);
    }

    /**
     * @dev get token price.
     */
    function getTokenPrice() public view returns (Price memory) {
        return tokenPrice;
    }

    /**
     * @dev get withdrawal fee rate.
     * @param holdTime_ hold time of the yield-bearing tokens.
     * @return feeRate_ withdrawal fee rate.
     */
    function getWithdrawalFeeRate(
        uint256 holdTime_
    ) public view returns (uint256 feeRate_) {
        feeRate_ = calculateWithdrawalFeeRate(holdTime_);
    }

    /**
     * @dev get withdrawal fee.
     * @param index_ index of array withdrawal fee.
     * @return fee_ withdrawal fee.
     */
    function getWithdrawalFee(
        uint256 index_
    ) public view returns (Fee memory fee_) {
        require(
            index_ < withdrawalFee.length,
            "Every.finance. out of size"
        );
        fee_ = withdrawalFee[index_];
    }

    /**
     * @dev get withdrawalFee size.
     */

    function getWithdrawalFeeSize() public view returns (uint256) {
        return withdrawalFee.length;
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/utils/math/Math.sol";
import "./AssetTransfer.sol";
import "../common/Treasury.sol";
import "../common/Token.sol";

/**
 * @dev Implementation of the library FeeMinter that proposes functions to calculate and mint different fee.
 */

library FeeMinter {
    uint256 public constant SCALING_FACTOR = 1e8;
    uint256 public constant SECONDES_PER_YEAR = 365 days;

    /**
     * @dev calculate and mint performance fee.
     * performance fee is generated when the current price is above the average price.
     * Performance fee is minted in yield-bearing token for the treasury.
     * @param tokenPrice_ current price of the yield-bearing token.
     * @param tokenPriceMean_ average price of the yield-bearing token.
     * @param performanceFeeRate_ performance fee rate. Its precision factor is SCALING_FACTOR.
     * @param treasury_ treasury
     * @param token_  yield-bearing token's address.
     */
    function mintPerformanceFee(
        uint256 tokenPrice_,
        uint256 tokenPriceMean_,
        uint256 performanceFeeRate_,
        address treasury_,
        address token_
    ) internal returns (uint256, uint256) {
        Token tokenERC20_ = Token(token_);
        uint256 performanceFee_;
        if (tokenPrice_ > tokenPriceMean_) {
            uint256 deltaPrice_;
            unchecked {
                deltaPrice_ = tokenPrice_ - tokenPriceMean_;
                tokenPriceMean_ = tokenPrice_;
            }
            performanceFee_ = Math.mulDiv(
                tokenERC20_.totalSupply(),
                (deltaPrice_ * performanceFeeRate_),
                (tokenPrice_ * SCALING_FACTOR)
            );

            tokenERC20_.mint(treasury_, performanceFee_);
        }
        return (tokenPriceMean_, performanceFee_);
    }

    /**
     * @dev calculate and mint management fee.
     * management fee is minted in yield-bearing token for the treasury.
     * @param managementFeeLastTime_  last time at wich the management fee is calculated.
     * @param managementFeeRate_ management fee rate. Its precision factor is SCALING_FACTOR.
     * @param treasury_ treasury
     * @param token_  yield-bearing token's address.
     */
    function mintManagementFee(
        uint256 managementFeeLastTime_,
        uint256 managementFeeRate_,
        address treasury_,
        address token_
    ) internal returns (uint256, uint256) {
        uint256 managementFee_;
        if (managementFeeLastTime_ != 0) {
            Token tokenERC20_ = Token(token_);
            uint256 deltaTime_ = block.timestamp - managementFeeLastTime_;
            managementFee_ = Math.mulDiv(
                tokenERC20_.totalSupply(),
                (managementFeeRate_ * deltaTime_),
                (SCALING_FACTOR * SECONDES_PER_YEAR)
            );
            managementFeeLastTime_ = block.timestamp;
            tokenERC20_.mint(treasury_, managementFee_);
        }
        return (managementFeeLastTime_, managementFee_);
    }

    /**
     * @dev calculate and mint investment fee (ie. slippage fee)
     * investment fee is minted in yield-bearing token for the treasury.
     * investment fee can be negative (cost: isFee == true) or positive (profit: isFee == false).
     * if investment fee is negative, the manager can verify if he can get from the treasury the underlying  asset ,
     * and mint for it the equivalent amount in yield-bearing token.
     * if investment fee is positive, the manager can verify if he can send to the treasury the underlying  asset ,
     * and burn form it the equivalent amount in yield-bearing token.
     * @param amount_ amount of fee in yield-bearing token.
     * @param tokenPrice_ current token price.
     * @param isFee_ true if positive fee, false otherwise.
     * @param treasury_ treasury
     * @param token_  yield-bearing token's address.
     * @param asset_  asset's address.
     */
    function MintInvestmentFee(
        uint256 amount_,
        uint256 tokenPrice_,
        bool isFee_,
        address payable treasury_,
        address token_,
        address asset_
    ) internal returns (uint256) {
        require(amount_ != 0, "Every.finance: zero amount");

        uint256 assetBalanceTreasury_ = _getBalance(asset_, treasury_);
        uint256 tokenBalanceTreasury_ = IERC20(token_).balanceOf(treasury_);

        if (isFee_) {
            return
                _mintNegativeInvestmentFee(
                    amount_,
                    assetBalanceTreasury_,
                    tokenPrice_,
                    treasury_,
                    address(token_),
                    asset_
                );
        } else {
            return
                _burnPositiveInvestmentFee(
                    amount_,
                    tokenBalanceTreasury_,
                    tokenPrice_,
                    treasury_,
                    address(token_),
                    asset_
                );
        }
    }

    /**
     * @dev get asset's balance of the treasury.
     * @param asset_  asset's addres.
     * @param treasury_ treasury
     */
    function _getBalance(
        address asset_,
        address treasury_
    ) internal view returns (uint256 balance_) {
        if (asset_ == address(0)) {
            balance_ = treasury_.balance;
        } else {
            balance_ = IERC20(asset_).balanceOf(treasury_);

            (bool success_, uint8 assetDecimals_) = AssetTransfer
                .tryGetAssetDecimals(IERC20(asset_));
            require(success_, "Every.finance: no decimal");
            require(
                assetDecimals_ <= uint8(18),
                "Every.finance: max decimal"
            );
            unchecked {
                assetDecimals_ = uint8(18) - assetDecimals_;
            }
            balance_ = balance_ * 10 ** assetDecimals_;
        }
    }

    /**
     * @dev calculate and mint negative investment fee (ie. slippage fee)
     * investment fee is minted in yield-bearing token for the treasury.
     * the function verifies if it's possible to get from the treasury the underlying  asset ,
     * and mint for it the equivalent amount in yield-bearing token.
     * @param amount_ amount of fee in yield-bearing token.
     * @param assetBalanceTreasury_ asset's balance of the treasury.
     * @param tokenPrice_ current token price.
     * @param treasury_ treasury
     * @param token_ yield-bearing token's address.
     * @param asset_ asset's address.
     */
    function _mintNegativeInvestmentFee(
        uint256 amount_,
        uint256 assetBalanceTreasury_,
        uint256 tokenPrice_,
        address payable treasury_,
        address token_,
        address asset_
    ) internal returns (uint256 remainingAmount_) {
        uint256 deltaAmount_ = Math.min(amount_, assetBalanceTreasury_);
        if (deltaAmount_ != 0) {
            Token tokenERC20_ = Token(token_);
            Treasury(treasury_).sendTo(address(this), deltaAmount_, asset_);
            uint256 tokenAmount_ = Math.mulDiv(
                deltaAmount_,
                SCALING_FACTOR,
                tokenPrice_
            );
            tokenERC20_.mint(treasury_, tokenAmount_);
            unchecked {
                remainingAmount_ = amount_ - deltaAmount_;
            }
        } else {
            remainingAmount_ = amount_;
        }
    }

    /**
     * @dev calculate and burn positive investment fee (ie. slippage fee)
     * investment fee is burned in yield-bearing token from the treasury.
     * the function verifies if it's possible to send to the treasury the underlying  asset ,
     * and burn  from it the equivalent amount in yield-bearing token.
     * @param amount_ amount of fee in yield-bearing token.
     * @param tokenBalanceTreasury_ yield-bearing token's balance of the treasury.
     * @param tokenPrice_ current token price.
     * @param treasury_ treasury
     * @param token_ yield-bearing token's address.
     * @param asset_ asset's address.
     */
    function _burnPositiveInvestmentFee(
        uint256 amount_,
        uint256 tokenBalanceTreasury_,
        uint256 tokenPrice_,
        address treasury_,
        address token_,
        address asset_
    ) internal returns (uint256 remainingAmount_) {
        uint256 tokenAmount_ = Math.mulDiv(
            amount_,
            SCALING_FACTOR,
            tokenPrice_
        );
        tokenAmount_ = Math.min(tokenAmount_, tokenBalanceTreasury_);
        uint256 deltaAmount_;
        if (tokenAmount_ != 0) {
            Token tokenERC20_ = Token(token_);
            deltaAmount_ = Math.mulDiv(
                tokenAmount_,
                tokenPrice_,
                SCALING_FACTOR
            );
            AssetTransfer.transfer(treasury_, deltaAmount_, asset_);
            tokenERC20_.burn(treasury_, tokenAmount_);
        }
        unchecked {
            remainingAmount_ = amount_ - deltaAmount_;
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

interface IMetadata {
    function render(uint256 _tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;
import "../common/Investment.sol";

/**
 * @author Every.finance.
 * @notice Implementation of the contract InvestmentAlpha.
 */

contract InvestmentAlpha is Investment {
    constructor(
        address asset_,
        address token_,
        address management_,
        address deposit_,
        address withdrawal_,
        address admin_, 
        address assetOracle_
    ) Investment(0, asset_, token_, management_, deposit_, withdrawal_, admin_, assetOracle_) {}
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

/**
 * @dev Implementation of the library AssetTransfer that proposes functions to transfer Ether/ERC20 asset.
 */
library AssetTransfer {
    using SafeERC20 for IERC20;

    /**
     * @dev transfer `amount_` of asset `asset_` from `from_` to `to_`.
     * @param from_ sender'address.
     * @param to_ receiver'address.
     * @param amount_ amount to send.
     * @param asset_ asset's IERC20 interface to send.Its decimal has to be lower than 18,
     * if it is ERC20.
     */
    function transferFrom(
        address from_,
        address to_,
        uint256 amount_,
        IERC20 asset_
    ) internal {
        (bool success_, uint8 assetDecimals_) = tryGetAssetDecimals(asset_);
        require(success_, "Every.finance: no decimal");
        require(assetDecimals_ <= uint8(18), "Every.finance: max decimal");
        unchecked {
            assetDecimals_ = uint8(18) - assetDecimals_;
        }
        amount_ = amount_ / 10 ** assetDecimals_;
        require(amount_ != 0, "Every.finance: zero amount");
        asset_.safeTransferFrom(from_, to_, amount_);
    }

    /**
     * @dev transfer `amount_` of asset `asset_` to `to_`.
     * @param to_ receiver'address.
     * @param amount_ amount to send.
     * @param asset_ asset's address to send. Its decimal has to be lower than 18,
     * if it is ERC20.
     */
    function transfer(address to_, uint256 amount_, address asset_) internal {
        if (asset_ != address(0)) {
            (bool success_, uint8 assetDecimals_) = tryGetAssetDecimals(
                IERC20(asset_)
            );
            require(success_, "Every.finance: no decimal");
            assetDecimals_ = uint8(18) - assetDecimals_;
            amount_ = amount_ / 10 ** assetDecimals_;
            require(amount_ != 0, "Every.finance: zero amount");
            IERC20(asset_).safeTransfer(to_, amount_);
        } else {
            require(
                address(this).balance >= amount_,
                "Every.finance: amount exceeds balance"
            );
            payable(to_).transfer(amount_);
        }
    }

    /**
     * @dev get asset's decimal.
     * @param asset_ asset's IERC20 interface.
     */
    function tryGetAssetDecimals(
        IERC20 asset_
    ) internal view returns (bool, uint8) {
        (bool success, bytes memory encodedDecimals) = address(asset_)
            .staticcall(
                abi.encodeWithSelector(IERC20Metadata.decimals.selector)
            );
        if (success && encodedDecimals.length >= 32) {
            uint256 returnedDecimals = abi.decode(encodedDecimals, (uint256));
            if (returnedDecimals <= type(uint8).max) {
                return (true, uint8(returnedDecimals));
            }
        }
        return (false, 0);
    }
}

// SPDX-License-Identifier: MIT
// Every.finance Contracts
pragma solidity ^0.8.4;

struct PendingRequestData {
    uint256 lockedAmount;
    uint256 availableAmount;
    uint256 minPrice;
    uint256 maxPrice;
    uint256 eventId;
}

/**
 * @dev Implementation of the library PendingRequest that proposes functions to update for an investor a struct PendingRequestData.
 */
library PendingRequest {
    /**
     * @dev Modifier that checks if the new price bounds are valid.
     * It reverts when introducing new price bounds during a manager event validation.
     * It prevents the investor to modify the price bounds of his deposit/withdrawal request
     * during a manager event validation.
     */
    modifier CheckPrice(
        PendingRequestData storage request,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 currentEventId_
    ) {
        if ((request.minPrice != 0) || (request.maxPrice != 0)) {
            if (currentEventId_ > request.eventId) {
                require(
                    (minPrice_ == request.minPrice) &&
                        (maxPrice_ == request.maxPrice),
                    "Every.finance: price don't match"
                );
            }
        }
        _;
    }

    /**
     * @dev Modifier that update for an investor his pending request data
     * to be synchronized with the current event id.
     */
    modifier syncWithEventId(
        PendingRequestData storage request,
        uint256 currentEventId_
    ) {
        if (currentEventId_ > request.eventId) {
            request.lockedAmount += request.availableAmount;
            request.availableAmount = 0;
            request.eventId = currentEventId_;
        }
        _;
    }

    /**
     * @dev increase a pending request `request` by `amount`.
     * This function is called when an investor makes a deposit/withdrawal request.
     * @param request  pending request.
     * @param amount_ amount to add.
     * @param minPrice_ minimum price of the yield-bearing token.
     * @param maxPrice_ maximum price  of the yield-bearing token
     * @param currentEventId_  id of the next manager event (process).
     */
    function increase(
        PendingRequestData storage request,
        uint256 amount_,
        uint256 minPrice_,
        uint256 maxPrice_,
        uint256 currentEventId_
    )
        internal
        CheckPrice(request, minPrice_, maxPrice_, currentEventId_)
        syncWithEventId(request, currentEventId_)
    {
        request.availableAmount += amount_;
        request.minPrice = minPrice_;
        request.maxPrice = maxPrice_;
    }

    /**
     * @dev decrease a pending request `request` by `amount`.
     * This function is called when an investor cancels a deposit/withdrawal request.
     * @param request  pending request.
     * @param amount_ amount to remove.
     * @param currentEventId_  id of the next manager event (process).
     */
    function decrease(
        PendingRequestData storage request,
        uint256 amount_,
        uint256 currentEventId_
    ) internal syncWithEventId(request, currentEventId_) {
        require(
            request.availableAmount >= amount_,
            "Every.finance: max amount"
        );
        unchecked {
            request.availableAmount -= amount_;
        }
    }

    /**
     * @dev update event Id
     *
     * @param request pending request.
     * @param currentEventId_  id of the next manager event (process).
     */
    function updateEventId(
        PendingRequestData storage request,
        uint256 currentEventId_
    ) internal {
        request.eventId = currentEventId_;
    }

    /**
     * @dev update the locked and available pending balances of `request` before the manager validation.
     * @param request pending request.
     * @param currentEventId_  id of the next manager event (process).
     */
    function preValidate(
        PendingRequestData storage request,
        uint256 currentEventId_
    ) internal syncWithEventId(request, currentEventId_) {}

    /**
     * @dev decrease the locked pending balance of `request` after the manager validation by `amount`.
     * @param request pending request.
     * @param currentEventId_  id of the next manager event (process).
     */
    function validate(
        PendingRequestData storage request,
        uint256 amount_,
        uint256 currentEventId_
    ) internal syncWithEventId(request, currentEventId_) {
        require(
            request.lockedAmount >= amount_,
            "Every.finance: max amount"
        );
        unchecked {
            request.lockedAmount -= amount_;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator
    ) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1);

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(
        uint256 x,
        uint256 y,
        uint256 denominator,
        Rounding rounding
    ) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10**64) {
                value /= 10**64;
                result += 64;
            }
            if (value >= 10**32) {
                value /= 10**32;
                result += 32;
            }
            if (value >= 10**16) {
                value /= 10**16;
                result += 16;
            }
            if (value >= 10**8) {
                value /= 10**8;
                result += 8;
            }
            if (value >= 10**4) {
                value /= 10**4;
                result += 4;
            }
            if (value >= 10**2) {
                value /= 10**2;
                result += 2;
            }
            if (value >= 10**1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10**result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result * 8) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.0;

import "./IERC20.sol";
import "./extensions/IERC20Metadata.sol";
import "../../utils/Context.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 * For a generic mechanism see {ERC20PresetMinterPauser}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC20
 * applications.
 *
 * Additionally, an {Approval} event is emitted on calls to {transferFrom}.
 * This allows applications to reconstruct the allowance for all accounts just
 * by listening to said events. Other implementations of the EIP may not emit
 * these events, as it isn't required by the specification.
 *
 * Finally, the non-standard {decreaseAllowance} and {increaseAllowance}
 * functions have been added to mitigate the well-known issues around setting
 * allowances. See {IERC20-approve}.
 */
contract ERC20 is Context, IERC20, IERC20Metadata {
    mapping(address => uint256) private _balances;

    mapping(address => mapping(address => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * The default value of {decimals} is 18. To select a different value for
     * {decimals} you should overload it.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the value {ERC20} uses, unless this function is
     * overridden;
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual override returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual override returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `amount`.
     */
    function transfer(address to, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, amount);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual override returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `amount` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 amount) public virtual override returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, amount);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Emits an {Approval} event indicating the updated allowance. This is not
     * required by the EIP. See the note at the beginning of {ERC20}.
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `amount`.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) public virtual override returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, amount);
        _transfer(from, to, amount);
        return true;
    }

    /**
     * @dev Atomically increases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, allowance(owner, spender) + addedValue);
        return true;
    }

    /**
     * @dev Atomically decreases the allowance granted to `spender` by the caller.
     *
     * This is an alternative to {approve} that can be used as a mitigation for
     * problems described in {IERC20-approve}.
     *
     * Emits an {Approval} event indicating the updated allowance.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `spender` must have allowance for the caller of at least
     * `subtractedValue`.
     */
    function decreaseAllowance(address spender, uint256 subtractedValue) public virtual returns (bool) {
        address owner = _msgSender();
        uint256 currentAllowance = allowance(owner, spender);
        require(currentAllowance >= subtractedValue, "ERC20: decreased allowance below zero");
        unchecked {
            _approve(owner, spender, currentAllowance - subtractedValue);
        }

        return true;
    }

    /**
     * @dev Moves `amount` of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `from` must have a balance of at least `amount`.
     */
    function _transfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {
        require(from != address(0), "ERC20: transfer from the zero address");
        require(to != address(0), "ERC20: transfer to the zero address");

        _beforeTokenTransfer(from, to, amount);

        uint256 fromBalance = _balances[from];
        require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
        unchecked {
            _balances[from] = fromBalance - amount;
            // Overflow not possible: the sum of all balances is capped by totalSupply, and the sum is preserved by
            // decrementing then incrementing.
            _balances[to] += amount;
        }

        emit Transfer(from, to, amount);

        _afterTokenTransfer(from, to, amount);
    }

    /** @dev Creates `amount` tokens and assigns them to `account`, increasing
     * the total supply.
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function _mint(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: mint to the zero address");

        _beforeTokenTransfer(address(0), account, amount);

        _totalSupply += amount;
        unchecked {
            // Overflow not possible: balance + amount is at most totalSupply + amount, which is checked above.
            _balances[account] += amount;
        }
        emit Transfer(address(0), account, amount);

        _afterTokenTransfer(address(0), account, amount);
    }

    /**
     * @dev Destroys `amount` tokens from `account`, reducing the
     * total supply.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     * - `account` must have at least `amount` tokens.
     */
    function _burn(address account, uint256 amount) internal virtual {
        require(account != address(0), "ERC20: burn from the zero address");

        _beforeTokenTransfer(account, address(0), amount);

        uint256 accountBalance = _balances[account];
        require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
        unchecked {
            _balances[account] = accountBalance - amount;
            // Overflow not possible: amount <= accountBalance <= totalSupply.
            _totalSupply -= amount;
        }

        emit Transfer(account, address(0), amount);

        _afterTokenTransfer(account, address(0), amount);
    }

    /**
     * @dev Sets `amount` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     */
    function _approve(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        require(owner != address(0), "ERC20: approve from the zero address");
        require(spender != address(0), "ERC20: approve to the zero address");

        _allowances[owner][spender] = amount;
        emit Approval(owner, spender, amount);
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `amount`.
     *
     * Does not update the allowance amount in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Might emit an {Approval} event.
     */
    function _spendAllowance(
        address owner,
        address spender,
        uint256 amount
    ) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance != type(uint256).max) {
            require(currentAllowance >= amount, "ERC20: insufficient allowance");
            unchecked {
                _approve(owner, spender, currentAllowance - amount);
            }
        }
    }

    /**
     * @dev Hook that is called before any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * will be transferred to `to`.
     * - when `from` is zero, `amount` tokens will be minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero, `amount` of ``from``'s tokens
     * has been transferred to `to`.
     * - when `from` is zero, `amount` tokens have been minted for `to`.
     * - when `to` is zero, `amount` of ``from``'s tokens have been burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 amount
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.2) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: address zero is not a valid owner");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _ownerOf(tokenId);
        require(owner != address(0), "ERC721: invalid token ID");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        _requireMinted(tokenId);

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overridden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not token owner or approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        _requireMinted(tokenId);

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: caller is not token owner or approved");
        _safeTransfer(from, to, tokenId, data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns the owner of the `tokenId`. Does NOT revert if token doesn't exist
     */
    function _ownerOf(uint256 tokenId) internal view virtual returns (address) {
        return _owners[tokenId];
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _ownerOf(tokenId) != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || isApprovedForAll(owner, spender) || getApproved(tokenId) == spender);
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId, 1);

        // Check that tokenId was not minted by `_beforeTokenTransfer` hook
        require(!_exists(tokenId), "ERC721: token already minted");

        unchecked {
            // Will not overflow unless all 2**256 token ids are minted to the same owner.
            // Given that tokens are minted one by one, it is impossible in practice that
            // this ever happens. Might change if we allow batch minting.
            // The ERC fails to describe this case.
            _balances[to] += 1;
        }

        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId, 1);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     * This is an internal function that does not check if the sender is authorized to operate on the token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId, 1);

        // Update ownership in case tokenId was transferred by `_beforeTokenTransfer` hook
        owner = ERC721.ownerOf(tokenId);

        // Clear approvals
        delete _tokenApprovals[tokenId];

        unchecked {
            // Cannot overflow, as that would require more tokens to be burned/transferred
            // out than the owner initially received through minting and transferring in.
            _balances[owner] -= 1;
        }
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId, 1);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId, 1);

        // Check that tokenId was not transferred by `_beforeTokenTransfer` hook
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");

        // Clear approvals from the previous owner
        delete _tokenApprovals[tokenId];

        unchecked {
            // `_balances[from]` cannot overflow for the same reason as described in `_burn`:
            // `from`'s balance is the number of token held, which is at least one before the current
            // transfer.
            // `_balances[to]` could overflow in the conditions described in `_mint`. That would require
            // all 2**256 token ids to be minted, which in practice is impossible.
            _balances[from] -= 1;
            _balances[to] += 1;
        }
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId, 1);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits an {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits an {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Reverts if the `tokenId` has not been minted yet.
     */
    function _requireMinted(uint256 tokenId) internal view virtual {
        require(_exists(tokenId), "ERC721: invalid token ID");
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    /// @solidity memory-safe-assembly
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting and burning. If {ERC721Consecutive} is
     * used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s tokens will be transferred to `to`.
     * - When `from` is zero, the tokens will be minted for `to`.
     * - When `to` is zero, ``from``'s tokens will be burned.
     * - `from` and `to` are never both zero.
     * - `batchSize` is non-zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 firstTokenId,
        uint256 batchSize
    ) internal virtual {}

    /**
     * @dev Hook that is called after any token transfer. This includes minting and burning. If {ERC721Consecutive} is
     * used, the hook may be called as part of a consecutive (batch) mint, as indicated by `batchSize` greater than 1.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s tokens were transferred to `to`.
     * - When `from` is zero, the tokens were minted for `to`.
     * - When `to` is zero, ``from``'s tokens were burned.
     * - `from` and `to` are never both zero.
     * - `batchSize` is non-zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 firstTokenId,
        uint256 batchSize
    ) internal virtual {}

    /**
     * @dev Unsafe write access to the balances, used by extensions that "mint" tokens using an {ownerOf} override.
     *
     * WARNING: Anyone calling this MUST ensure that the balances remain consistent with the ownership. The invariant
     * being that for any address `a` the value returned by `balanceOf(a)` must be equal to the number of tokens such
     * that `ownerOf(tokenId)` is `a`.
     */
    // solhint-disable-next-line func-name-mixedcase
    function __unsafe_increaseBalance(address account, uint256 amount) internal {
        _balances[account] += amount;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (access/AccessControl.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";
import "../utils/Context.sol";
import "../utils/Strings.sol";
import "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address => bool) members;
        bytes32 adminRole;
    }

    mapping(bytes32 => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with a standardized message including the required role.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     *
     * _Available since v4.1._
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual override returns (bool) {
        return _roles[role].members[account];
    }

    /**
     * @dev Revert with a standard message if `_msgSender()` is missing `role`.
     * Overriding this function changes the behavior of the {onlyRole} modifier.
     *
     * Format of the revert message is described in {_checkRole}.
     *
     * _Available since v4.6._
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Revert with a standard message if `account` is missing `role`.
     *
     * The format of the revert reason is given by the following regular expression:
     *
     *  /^AccessControl: account (0x[0-9a-f]{40}) is missing role (0x[0-9a-f]{64})$/
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert(
                string(
                    abi.encodePacked(
                        "AccessControl: account ",
                        Strings.toHexString(account),
                        " is missing role ",
                        Strings.toHexString(uint256(role), 32)
                    )
                )
            );
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual override returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual override onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address account) public virtual override {
        require(account == _msgSender(), "AccessControl: can only renounce roles for self");

        _revokeRole(role, account);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event. Note that unlike {grantRole}, this function doesn't perform any
     * checks on the calling account.
     *
     * May emit a {RoleGranted} event.
     *
     * [WARNING]
     * ====
     * This function should only be called from the constructor when setting
     * up the initial roles for the system.
     *
     * Using this function in any other way is effectively circumventing the admin
     * system imposed by {AccessControl}.
     * ====
     *
     * NOTE: This function is deprecated in favor of {_grantRole}.
     */
    function _setupRole(bytes32 role, address account) internal virtual {
        _grantRole(role, account);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual {
        if (!hasRole(role, account)) {
            _roles[role].members[account] = true;
            emit RoleGranted(role, account, _msgSender());
        }
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual {
        if (hasRole(role, account)) {
            _roles[role].members[account] = false;
            emit RoleRevoked(role, account, _msgSender());
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControl.sol)

pragma solidity ^0.8.0;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     *
     * _Available since v3.1._
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `account`.
     */
    function renounceRole(bytes32 role, address account) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/draft-IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(
        IERC20 token,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, newAllowance));
        }
    }

    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        if (returndata.length > 0) {
            // Return data is optional
            require(abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position of the value in the `values` array, plus 1 because index 0
        // means a value is not in the set.
        mapping(bytes32 => uint256) _indexes;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._indexes[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We read and store the value's index to prevent multiple reads from the same storage slot
        uint256 valueIndex = set._indexes[value];

        if (valueIndex != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 toDeleteIndex = valueIndex - 1;
            uint256 lastIndex = set._values.length - 1;

            if (lastIndex != toDeleteIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the last value to the index where the value to delete is
                set._values[toDeleteIndex] = lastValue;
                // Update the index for the moved value
                set._indexes[lastValue] = valueIndex; // Replace lastValue's index to valueIndex
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the index for the deleted slot
            delete set._indexes[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._indexes[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (access/AccessControlEnumerable.sol)

pragma solidity ^0.8.0;

import "./IAccessControlEnumerable.sol";
import "./AccessControl.sol";
import "../utils/structs/EnumerableSet.sol";

/**
 * @dev Extension of {AccessControl} that allows enumerating the members of each role.
 */
abstract contract AccessControlEnumerable is IAccessControlEnumerable, AccessControl {
    using EnumerableSet for EnumerableSet.AddressSet;

    mapping(bytes32 => EnumerableSet.AddressSet) private _roleMembers;

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControlEnumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns one of the accounts that have `role`. `index` must be a
     * value between 0 and {getRoleMemberCount}, non-inclusive.
     *
     * Role bearers are not sorted in any particular way, and their ordering may
     * change at any point.
     *
     * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
     * you perform all queries on the same block. See the following
     * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
     * for more information.
     */
    function getRoleMember(bytes32 role, uint256 index) public view virtual override returns (address) {
        return _roleMembers[role].at(index);
    }

    /**
     * @dev Returns the number of accounts that have `role`. Can be used
     * together with {getRoleMember} to enumerate all bearers of a role.
     */
    function getRoleMemberCount(bytes32 role) public view virtual override returns (uint256) {
        return _roleMembers[role].length();
    }

    /**
     * @dev Overload {_grantRole} to track enumerable memberships
     */
    function _grantRole(bytes32 role, address account) internal virtual override {
        super._grantRole(role, account);
        _roleMembers[role].add(account);
    }

    /**
     * @dev Overload {_revokeRole} to track enumerable memberships
     */
    function _revokeRole(bytes32 role, address account) internal virtual override {
        super._revokeRole(role, account);
        _roleMembers[role].remove(account);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/IAccessControlEnumerable.sol)

pragma solidity ^0.8.0;

import "./IAccessControl.sol";

/**
 * @dev External interface of AccessControlEnumerable declared to support ERC165 detection.
 */
interface IAccessControlEnumerable is IAccessControl {
    /**
     * @dev Returns one of the accounts that have `role`. `index` must be a
     * value between 0 and {getRoleMemberCount}, non-inclusive.
     *
     * Role bearers are not sorted in any particular way, and their ordering may
     * change at any point.
     *
     * WARNING: When using {getRoleMember} and {getRoleMemberCount}, make sure
     * you perform all queries on the same block. See the following
     * https://forum.openzeppelin.com/t/iterating-over-elements-on-enumerableset-in-openzeppelin-contracts/2296[forum post]
     * for more information.
     */
    function getRoleMember(bytes32 role, uint256 index) external view returns (address);

    /**
     * @dev Returns the number of accounts that have `role`. Can be used
     * together with {getRoleMember} to enumerate all bearers of a role.
     */
    function getRoleMemberCount(bytes32 role) external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface AggregatorV3Interface {
  function decimals() external view returns (uint8);

  function description() external view returns (string memory);

  function version() external view returns (uint256);

  function getRoundData(uint80 _roundId)
    external
    view
    returns (
      uint80 roundId,
      int256 answer,
      uint256 startedAt,
      uint256 updatedAt,
      uint80 answeredInRound
    );

  function latestRoundData()
    external
    view
    returns (
      uint80 roundId,
      int256 answer,
      uint256 startedAt,
      uint256 updatedAt,
      uint80 answeredInRound
    );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (token/ERC721/extensions/ERC721Enumerable.sol)

pragma solidity ^0.8.0;

import "../ERC721.sol";
import "./IERC721Enumerable.sol";

/**
 * @dev This implements an optional extension of {ERC721} defined in the EIP that adds
 * enumerability of all the token ids in the contract as well as all token ids owned by each
 * account.
 */
abstract contract ERC721Enumerable is ERC721, IERC721Enumerable {
    // Mapping from owner to list of owned token IDs
    mapping(address => mapping(uint256 => uint256)) private _ownedTokens;

    // Mapping from token ID to index of the owner tokens list
    mapping(uint256 => uint256) private _ownedTokensIndex;

    // Array with all token ids, used for enumeration
    uint256[] private _allTokens;

    // Mapping from token id to position in the allTokens array
    mapping(uint256 => uint256) private _allTokensIndex;

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC721) returns (bool) {
        return interfaceId == type(IERC721Enumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) public view virtual override returns (uint256) {
        require(index < ERC721.balanceOf(owner), "ERC721Enumerable: owner index out of bounds");
        return _ownedTokens[owner][index];
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _allTokens.length;
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index) public view virtual override returns (uint256) {
        require(index < ERC721Enumerable.totalSupply(), "ERC721Enumerable: global index out of bounds");
        return _allTokens[index];
    }

    /**
     * @dev See {ERC721-_beforeTokenTransfer}.
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 firstTokenId,
        uint256 batchSize
    ) internal virtual override {
        super._beforeTokenTransfer(from, to, firstTokenId, batchSize);

        if (batchSize > 1) {
            // Will only trigger during construction. Batch transferring (minting) is not available afterwards.
            revert("ERC721Enumerable: consecutive transfers not supported");
        }

        uint256 tokenId = firstTokenId;

        if (from == address(0)) {
            _addTokenToAllTokensEnumeration(tokenId);
        } else if (from != to) {
            _removeTokenFromOwnerEnumeration(from, tokenId);
        }
        if (to == address(0)) {
            _removeTokenFromAllTokensEnumeration(tokenId);
        } else if (to != from) {
            _addTokenToOwnerEnumeration(to, tokenId);
        }
    }

    /**
     * @dev Private function to add a token to this extension's ownership-tracking data structures.
     * @param to address representing the new owner of the given token ID
     * @param tokenId uint256 ID of the token to be added to the tokens list of the given address
     */
    function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private {
        uint256 length = ERC721.balanceOf(to);
        _ownedTokens[to][length] = tokenId;
        _ownedTokensIndex[tokenId] = length;
    }

    /**
     * @dev Private function to add a token to this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be added to the tokens list
     */
    function _addTokenToAllTokensEnumeration(uint256 tokenId) private {
        _allTokensIndex[tokenId] = _allTokens.length;
        _allTokens.push(tokenId);
    }

    /**
     * @dev Private function to remove a token from this extension's ownership-tracking data structures. Note that
     * while the token is not assigned a new owner, the `_ownedTokensIndex` mapping is _not_ updated: this allows for
     * gas optimizations e.g. when performing a transfer operation (avoiding double writes).
     * This has O(1) time complexity, but alters the order of the _ownedTokens array.
     * @param from address representing the previous owner of the given token ID
     * @param tokenId uint256 ID of the token to be removed from the tokens list of the given address
     */
    function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId) private {
        // To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = ERC721.balanceOf(from) - 1;
        uint256 tokenIndex = _ownedTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = _ownedTokens[from][lastTokenIndex];

            _ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
            _ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index
        }

        // This also deletes the contents at the last position of the array
        delete _ownedTokensIndex[tokenId];
        delete _ownedTokens[from][lastTokenIndex];
    }

    /**
     * @dev Private function to remove a token from this extension's token tracking data structures.
     * This has O(1) time complexity, but alters the order of the _allTokens array.
     * @param tokenId uint256 ID of the token to be removed from the tokens list
     */
    function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private {
        // To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = _allTokens.length - 1;
        uint256 tokenIndex = _allTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so
        // rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding
        // an 'if' statement (like in _removeTokenFromOwnerEnumeration)
        uint256 lastTokenId = _allTokens[lastTokenIndex];

        _allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
        _allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index

        // This also deletes the contents at the last position of the array
        delete _allTokensIndex[tokenId];
        _allTokens.pop();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/draft-IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/extensions/IERC721Enumerable.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {
    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}