Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides a set of functions to operate with Base64 strings.
 */
library Base64 {
    /**
     * @dev Base64 Encoding/Decoding Table
     */
    string internal constant _TABLE = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/";

    /**
     * @dev Converts a `bytes` to its Bytes64 `string` representation.
     */
    function encode(bytes memory data) internal pure returns (string memory) {
        /**
         * Inspired by Brecht Devos (Brechtpd) implementation - MIT licence
         * https://github.com/Brechtpd/base64/blob/e78d9fd951e7b0977ddca77d92dc85183770daf4/base64.sol
         */
        if (data.length == 0) return "";

        // Loads the table into memory
        string memory table = _TABLE;

        // Encoding takes 3 bytes chunks of binary data from `bytes` data parameter
        // and split into 4 numbers of 6 bits.
        // The final Base64 length should be `bytes` data length multiplied by 4/3 rounded up
        // - `data.length + 2`  -> Round up
        // - `/ 3`              -> Number of 3-bytes chunks
        // - `4 *`              -> 4 characters for each chunk
        string memory result = new string(4 * ((data.length + 2) / 3));

        assembly {
            // Prepare the lookup table (skip the first "length" byte)
            let tablePtr := add(table, 1)

            // Prepare result pointer, jump over length
            let resultPtr := add(result, 32)

            // Run over the input, 3 bytes at a time
            for {
                let dataPtr := data
                let endPtr := add(data, mload(data))
            } lt(dataPtr, endPtr) {

            } {
                // Advance 3 bytes
                dataPtr := add(dataPtr, 3)
                let input := mload(dataPtr)

                // To write each character, shift the 3 bytes (18 bits) chunk
                // 4 times in blocks of 6 bits for each character (18, 12, 6, 0)
                // and apply logical AND with 0x3F which is the number of
                // the previous character in the ASCII table prior to the Base64 Table
                // The result is then added to the table to get the character to write,
                // and finally write it in the result pointer but with a left shift
                // of 256 (1 byte) - 8 (1 ASCII char) = 248 bits

                mstore8(resultPtr, mload(add(tablePtr, and(shr(18, input), 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance

                mstore8(resultPtr, mload(add(tablePtr, and(shr(12, input), 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance

                mstore8(resultPtr, mload(add(tablePtr, and(shr(6, input), 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance

                mstore8(resultPtr, mload(add(tablePtr, and(input, 0x3F))))
                resultPtr := add(resultPtr, 1) // Advance
            }

            // When data `bytes` is not exactly 3 bytes long
            // it is padded with `=` characters at the end
            switch mod(mload(data), 3)
            case 1 {
                mstore8(sub(resultPtr, 1), 0x3d)
                mstore8(sub(resultPtr, 2), 0x3d)
            }
            case 2 {
                mstore8(sub(resultPtr, 1), 0x3d)
            }
        }

        return result;
    }
}

 

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721.sol)

pragma solidity ^0.8.0;

import "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/IERC721Receiver.sol)

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Strings.sol)

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/IERC165.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/ERC721Enumerable.sol)

pragma solidity ^0.8.0;

import "../ERC721.sol";
import "./IERC721Enumerable.sol";

/**
 * @dev This implements an optional extension of {ERC721} defined in the EIP that adds
 * enumerability of all the token ids in the contract as well as all token ids owned by each
 * account.
 */
abstract contract ERC721Enumerable is ERC721, IERC721Enumerable {
    // Mapping from owner to list of owned token IDs
    mapping(address => mapping(uint256 => uint256)) private _ownedTokens;

    // Mapping from token ID to index of the owner tokens list
    mapping(uint256 => uint256) private _ownedTokensIndex;

    // Array with all token ids, used for enumeration
    uint256[] private _allTokens;

    // Mapping from token id to position in the allTokens array
    mapping(uint256 => uint256) private _allTokensIndex;

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(IERC165, ERC721) returns (bool) {
        return interfaceId == type(IERC721Enumerable).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721Enumerable-tokenOfOwnerByIndex}.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) public view virtual override returns (uint256) {
        require(index < ERC721.balanceOf(owner), "ERC721Enumerable: owner index out of bounds");
        return _ownedTokens[owner][index];
    }

    /**
     * @dev See {IERC721Enumerable-totalSupply}.
     */
    function totalSupply() public view virtual override returns (uint256) {
        return _allTokens.length;
    }

    /**
     * @dev See {IERC721Enumerable-tokenByIndex}.
     */
    function tokenByIndex(uint256 index) public view virtual override returns (uint256) {
        require(index < ERC721Enumerable.totalSupply(), "ERC721Enumerable: global index out of bounds");
        return _allTokens[index];
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual override {
        super._beforeTokenTransfer(from, to, tokenId);

        if (from == address(0)) {
            _addTokenToAllTokensEnumeration(tokenId);
        } else if (from != to) {
            _removeTokenFromOwnerEnumeration(from, tokenId);
        }
        if (to == address(0)) {
            _removeTokenFromAllTokensEnumeration(tokenId);
        } else if (to != from) {
            _addTokenToOwnerEnumeration(to, tokenId);
        }
    }

    /**
     * @dev Private function to add a token to this extension's ownership-tracking data structures.
     * @param to address representing the new owner of the given token ID
     * @param tokenId uint256 ID of the token to be added to the tokens list of the given address
     */
    function _addTokenToOwnerEnumeration(address to, uint256 tokenId) private {
        uint256 length = ERC721.balanceOf(to);
        _ownedTokens[to][length] = tokenId;
        _ownedTokensIndex[tokenId] = length;
    }

    /**
     * @dev Private function to add a token to this extension's token tracking data structures.
     * @param tokenId uint256 ID of the token to be added to the tokens list
     */
    function _addTokenToAllTokensEnumeration(uint256 tokenId) private {
        _allTokensIndex[tokenId] = _allTokens.length;
        _allTokens.push(tokenId);
    }

    /**
     * @dev Private function to remove a token from this extension's ownership-tracking data structures. Note that
     * while the token is not assigned a new owner, the `_ownedTokensIndex` mapping is _not_ updated: this allows for
     * gas optimizations e.g. when performing a transfer operation (avoiding double writes).
     * This has O(1) time complexity, but alters the order of the _ownedTokens array.
     * @param from address representing the previous owner of the given token ID
     * @param tokenId uint256 ID of the token to be removed from the tokens list of the given address
     */
    function _removeTokenFromOwnerEnumeration(address from, uint256 tokenId) private {
        // To prevent a gap in from's tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = ERC721.balanceOf(from) - 1;
        uint256 tokenIndex = _ownedTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary
        if (tokenIndex != lastTokenIndex) {
            uint256 lastTokenId = _ownedTokens[from][lastTokenIndex];

            _ownedTokens[from][tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
            _ownedTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index
        }

        // This also deletes the contents at the last position of the array
        delete _ownedTokensIndex[tokenId];
        delete _ownedTokens[from][lastTokenIndex];
    }

    /**
     * @dev Private function to remove a token from this extension's token tracking data structures.
     * This has O(1) time complexity, but alters the order of the _allTokens array.
     * @param tokenId uint256 ID of the token to be removed from the tokens list
     */
    function _removeTokenFromAllTokensEnumeration(uint256 tokenId) private {
        // To prevent a gap in the tokens array, we store the last token in the index of the token to delete, and
        // then delete the last slot (swap and pop).

        uint256 lastTokenIndex = _allTokens.length - 1;
        uint256 tokenIndex = _allTokensIndex[tokenId];

        // When the token to delete is the last token, the swap operation is unnecessary. However, since this occurs so
        // rarely (when the last minted token is burnt) that we still do the swap here to avoid the gas cost of adding
        // an 'if' statement (like in _removeTokenFromOwnerEnumeration)
        uint256 lastTokenId = _allTokens[lastTokenIndex];

        _allTokens[tokenIndex] = lastTokenId; // Move the last token to the slot of the to-delete token
        _allTokensIndex[lastTokenId] = tokenIndex; // Update the moved token's index

        // This also deletes the contents at the last position of the array
        delete _allTokensIndex[tokenId];
        _allTokens.pop();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/ERC721.sol)

pragma solidity ^0.8.0;

import "./IERC721.sol";
import "./IERC721Receiver.sol";
import "./extensions/IERC721Metadata.sol";
import "../../utils/Address.sol";
import "../../utils/Context.sol";
import "../../utils/Strings.sol";
import "../../utils/introspection/ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        _setApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);

        _afterTokenTransfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);

        _afterTokenTransfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer from incorrect owner");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);

        _afterTokenTransfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Approve `operator` to operate on all of `owner` tokens
     *
     * Emits a {ApprovalForAll} event.
     */
    function _setApprovalForAll(
        address owner,
        address operator,
        bool approved
    ) internal virtual {
        require(owner != operator, "ERC721: approve to caller");
        _operatorApprovals[owner][operator] = approved;
        emit ApprovalForAll(owner, operator, approved);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}

    /**
     * @dev Hook that is called after any transfer of tokens. This includes
     * minting and burning.
     *
     * Calling conditions:
     *
     * - when `from` and `to` are both non-zero.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _afterTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: GPL-3.0


//  ███████╗██╗     ███████╗███╗   ███╗███████╗███╗   ██╗████████╗███████╗
//  ██╔════╝██║     ██╔════╝████╗ ████║██╔════╝████╗  ██║╚══██╔══╝██╔════╝
//  █████╗  ██║     █████╗  ██╔████╔██║█████╗  ██╔██╗ ██║   ██║   ███████╗
//  ██╔══╝  ██║     ██╔══╝  ██║╚██╔╝██║██╔══╝  ██║╚██╗██║   ██║   ╚════██║
//  ███████╗███████╗███████╗██║ ╚═╝ ██║███████╗██║ ╚████║   ██║   ███████║
//  ╚══════╝╚══════╝╚══════╝╚═╝     ╚═╝╚══════╝╚═╝  ╚═══╝   ╚═╝   ╚══════╝

// Created By: https://elements.blue

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/token/ERC721/extensions/ERC721Enumerable.sol";
import "@openzeppelin/contracts/access/Ownable.sol";



import {NFTDetails,Element,Meta} from "./meta.sol";


contract Elements is ERC721Enumerable, Ownable {
    using Strings for uint256;
    event Mint(address indexed owner, uint256 indexed tokenId);

    receive() external payable {}

    mapping(bytes1 => Element) public elements;
    bytes1[] elementIds=[bytes1('1'),bytes1('2'),bytes1('3'),bytes1('4') ];

    uint randNonce = 1;
    uint32[] raritykeys=[1,1,1,1,1,1,1,1,1,1,1,1,1,1,2,2,2,2,2,2,2,2,3,3,3,3,4,4,5];
    uint32 basicElementSupplyCap = 37500;
    uint32 basicElementPreMintCap = 24;
    uint32 artLevelWeight = 4;
    uint32 maxLevelWeight = 20;
    mapping(bytes1 => uint32) public basicElementMintedCount;

    // ----- Minting -----
    uint256 public mintPrice = 0.003 ether;
    uint256 private lastTokenId=1000;
    // Minting Stage:
    // 0 - Not open
    // 1 - freeMint
    // 2 - preMint
    // 3 - publicMint
    uint8 public mintingStage=0; 
    mapping(address => uint256) public preMintAddresses;


    mapping(uint256 => NFTDetails) public tokenInfo;
    string public baseURI = "";
    string public externalURI = "https://elements.blue";

    constructor() ERC721("Elements", "Elements") {
         // Adding basic Elements
         bytes1[] memory _parents;
         elements["1"] = Element({name: "Fire", parents:  _parents,supply: 0,supplyMass:0, tier:0 });
         elements["2"] = Element({name: "Water", parents:  _parents,supply: 0, supplyMass:0, tier:0 });
         elements["3"] = Element({name: "Air", parents:  _parents,supply: 0,supplyMass:0, tier:0 });
         elements["4"] = Element({name: "Earth", parents:  _parents,supply: 0,supplyMass:0, tier:0 });
          
 
        // Initial Creatures before mint
        bytes1[] memory _parents2=new bytes1[](2);
        _parents2[0]=bytes1('1');
        _parents2[1]=bytes1('4');
        elements["M"] = Element({name: "Roc", parents: _parents2,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('M'));

        bytes1[] memory _parents3=new bytes1[](2);
        _parents3[0]=bytes1('2');
        _parents3[1]=bytes1('3');
        elements["L"] = Element({name: "Erawan", parents: _parents3,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('l'));

        bytes1[] memory _parents4=new bytes1[](2);
        _parents4[0]=bytes1('2');
        _parents4[1]=bytes1('4');
        elements["E"] = Element({name: "Mandrake", parents: _parents4,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('E'));


        bytes1[] memory _parents5=new bytes1[](2);
        _parents5[0]=bytes1('1');
        _parents5[1]=bytes1('3');
        elements["D"] = Element({name: "Vethal", parents: _parents5,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('D'));


        bytes1[] memory _parents7=new bytes1[](2);
        _parents7[0]=bytes1('M');
        _parents7[1]=bytes1('3');
        elements["F"] = Element({name: "Anga", parents: _parents7,supply: 0,supplyMass:0, tier:2});
        elementIds.push(bytes1('F'));


        bytes1[] memory _parents8=new bytes1[](2);
        _parents8[0]=bytes1('L');
        _parents8[1]=bytes1('4');
        elements["O"] = Element({name: "Titan", parents: _parents8,supply: 0,supplyMass:0, tier:2});
        elementIds.push(bytes1('O'));

        bytes1[] memory _parents9=new bytes1[](2);
        _parents9[0]=bytes1('D');
        _parents9[1]=bytes1('2');
        elements["J"] = Element({name: "Wukong", parents: _parents9,supply: 0,supplyMass:0, tier:2});
        elementIds.push(bytes1('J'));

        bytes1[] memory _parents10=new bytes1[](2);
        _parents10[0]=bytes1('E');
        _parents10[1]=bytes1('1');
        elements["H"] = Element({name: "Herbant", parents: _parents10,supply: 0,supplyMass:0, tier:2});
        elementIds.push(bytes1('H'));

        bytes1[] memory _parents11=new bytes1[](2);
        _parents11[0]=bytes1('E');
        _parents11[1]=bytes1('D');
        elements["C"] = Element({name: "Flus", parents: _parents11,supply: 0,supplyMass:0, tier:2});
        elementIds.push(bytes1('C'));

        bytes1[] memory _parents12=new bytes1[](2);
        _parents12[0]=bytes1('M');
        _parents12[1]=bytes1('L');
        elements["G"] = Element({name: "Lado", parents: _parents12,supply: 0,supplyMass:0, tier:2});
        elementIds.push(bytes1('G'));

        bytes1[] memory _parents13=new bytes1[](2);
        _parents13[0]=bytes1('C');
        _parents13[1]=bytes1('G');
        elements["N"] = Element({name: "Demon", parents: _parents13,supply: 0,supplyMass:0, tier:3});
        elementIds.push(bytes1('N'));

        bytes1[] memory _parents14=new bytes1[](2);
        _parents14[0]=bytes1('O');
        _parents14[1]=bytes1('H');
        elements["K"] = Element({name: "Deacon", parents: _parents14,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('K'));

        bytes1[] memory _parents15=new bytes1[](2);
        _parents15[0]=bytes1('F');
        _parents15[1]=bytes1('J');
        elements["I"] = Element({name: "Makara", parents: _parents15,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('I'));

        bytes1[] memory _parents16=new bytes1[](2);
        _parents16[0]=bytes1('N');
        _parents16[1]=bytes1('K');
        elements["A"] = Element({name: "Vamp", parents: _parents16,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('A'));

        bytes1[] memory _parents17=new bytes1[](2);
        _parents17[0]=bytes1('N');
        _parents17[1]=bytes1('I');
        elements["B"] = Element({name: "Dragon", parents: _parents17,supply: 0,supplyMass:0, tier:1});
        elementIds.push(bytes1('B')); 
    }

    function addToWhitelist(address[] memory toAdd) external onlyOwner {
        for (uint256 i = 0; i < toAdd.length; i++) {
            preMintAddresses[toAdd[i]] = basicElementPreMintCap;
            
        }
    }
   
    
    // Spit higher mass to one mass
    function split (uint256    _tokenId) external payable {
        require( _exists(_tokenId), "nonexistent token" );
        require(ownerOf(_tokenId)==msg.sender,"  token not owned");
        NFTDetails memory tokenDetails= tokenInfo[_tokenId];
        require(  tokenDetails.mass>= 2 , "low mass" );
        uint32 newImmunity=tokenDetails.immunity+1;  
        tokenInfo[_tokenId]=NFTDetails({elementId:tokenDetails.elementId, mass: 1, power:tokenDetails.power, immunity:newImmunity, experience:tokenDetails.experience});
        for (uint256 i = 1; i < tokenDetails.mass; i++) {
            _mintWithoutValidation(msg.sender, tokenDetails.elementId, 1,tokenDetails.power,newImmunity,tokenDetails.experience);
        }  
        addElementSupply(tokenDetails.elementId,(tokenDetails.mass-1),0,false,false);
        // No Change in Supply Mass
    }
    // Split NFT into parent NFTs
    function fision (uint256 _tokenId ) external payable {
        require( _exists(_tokenId), "nonexistent token" );
        require(ownerOf(_tokenId)==msg.sender,"  token not owned");
        NFTDetails memory tokenDetails= tokenInfo[_tokenId];
        require( elements[tokenDetails.elementId].parents.length>0, "should not be a base element" );
        //Adjust Mass
        addElementSupply(tokenDetails.elementId,1, tokenDetails.mass,true,true );
        addElementSupply(elements[tokenDetails.elementId].parents[0],1, tokenDetails.mass,false,false);
        tokenInfo[_tokenId]=NFTDetails({elementId:elements[tokenDetails.elementId].parents[0], mass: tokenDetails.mass, power:tokenDetails.power, immunity:tokenDetails.immunity+1, experience:tokenDetails.experience});
        for (uint256 i = 1; i < elements[tokenDetails.elementId].parents.length; i++) {
            addElementSupply(elements[tokenDetails.elementId].parents[i],1, tokenDetails.mass,false,false);
            _mintWithoutValidation(msg.sender, elements[tokenDetails.elementId].parents[i] , tokenDetails.mass,tokenDetails.power, tokenDetails.immunity+1, tokenDetails.experience);
        }
    }
    // Adjust Supply on every action
    function addElementSupply(bytes1 elementId, uint32 supply, uint32 supplyMass ,bool subSupply, bool subMass ) private {
        if(supply!=0){
            if(subSupply){
                require(elements[elementId].supply>=supply,"wrong supply");
                elements[elementId].supply-=supply;
            }else{
                elements[elementId].supply+=supply;
            }
        }
         if(supplyMass!=0){
            if(subMass){
                require(elements[elementId].supplyMass>=supplyMass,"wrong supplyMass");
                elements[elementId].supplyMass-=supplyMass;
            }else{
                elements[elementId].supplyMass+=supplyMass;
            } 
        }
    }
    // Combine Same Elements to increase mass
    function combine (uint256[]  memory  _tokenIds, uint256    _burnTokenId) external payable {
        require(_tokenIds.length>1,"atleast 2 elements required");
        require(_tokenIds.length<=10,"can't combine more than 10 elements");
        require(!hasDuplicates(_tokenIds,_burnTokenId),"duplicates tokens");
        if(_burnTokenId>0){
            require(_exists(_burnTokenId),"burn token not exist");
            require(ownerOf(_burnTokenId)==msg.sender,"burn token not owned");
        }
        bytes1 _resultElementId=tokenInfo[_tokenIds[0]].elementId;
        uint32 newMass=0;
        uint32 newPower=0;  
        uint32 newImmunity=0;  
        uint32 newExperience=0;
        for (uint256 i = 0; i < _tokenIds.length; i++) {
            require(_exists(_tokenIds[i]),"token not exist");
            require(ownerOf(_tokenIds[i])==msg.sender,"token not owned");
            NFTDetails memory tokenDetails= tokenInfo[_tokenIds[i]];
            require(tokenDetails.elementId==_resultElementId,"all should be same element"); 
            newMass+=tokenDetails.mass;
            newPower+=(tokenDetails.power*tokenDetails.mass);
            newImmunity+=(tokenDetails.immunity*tokenDetails.mass);
            newExperience+=(tokenDetails.experience*tokenDetails.mass);
        }
        newPower=(newPower/newMass)+1;  
        newImmunity=newImmunity/newMass;  
        newExperience=newExperience/newMass;
        // Burn all tokens
        if(_burnTokenId>0){
            //mass of burn id is greater than one
            if(tokenInfo[_burnTokenId].mass>1){
                tokenInfo[_burnTokenId].mass-=1;
                addElementSupply(tokenInfo[_burnTokenId].elementId,0,1,false,true);
            }else{ // burn token id mass is one
                addElementSupply(tokenInfo[_burnTokenId].elementId,1,1, true, true);
                _burnToken(_burnTokenId);
            }
            addElementSupply(_resultElementId,uint32(_tokenIds.length-1),0, true, false);
        }else{
            newMass-=1;
            require(newMass<=1,"add more elements to combine");
            addElementSupply(_resultElementId,uint32(_tokenIds.length-1),1, true, true);
        }
        for (uint256 i = 1; i < _tokenIds.length; i++) {
             _burnToken(_tokenIds[i]);
        }
        tokenInfo[_tokenIds[0]]=NFTDetails({elementId:_resultElementId, mass: newMass, power:newPower, immunity:newImmunity, experience:newExperience});
    }

 
    // Check duplicates
     function hasDuplicates(uint256[] memory _tokenIds,uint256 _burnTokenId) internal pure returns (bool) {
          for (uint256 i = 0; i < _tokenIds.length; i++) {
              for (uint256 j = i+1; j < _tokenIds.length; j++) {
                  if(_tokenIds[i]==_tokenIds[j]){
                      return true;
                  }
              }
              if(_burnTokenId>0 && _tokenIds[i]==_burnTokenId){
                      return true;
              }
          }
          return false;
     }
    
    
    // Combine nfts to create higher tier NFts
    function fusion (uint256[] memory _tokenIds, string memory __resultId, uint32 _resultMass, uint256 _burnTokenId) external payable {
        require(_tokenIds.length>1 
                && bytes(__resultId).length==1
                && _resultMass>0
                && _burnTokenId>0 , "tokens requiremnt not met" );
        bytes1 _resultId= bytes1( bytes(__resultId) );
        require(elements[_resultId].parents.length>1,"result token should not be a base element");
        require(ownerOf(_burnTokenId)==msg.sender,"burn token not owned");
        require(!hasDuplicates(_tokenIds,_burnTokenId),"duplicate tokens");
        uint32[] memory massToBurn  =new uint32[](_tokenIds.length) ; // Mass to burn for each token
        uint32[] memory massRequired =new uint32[](elements[_resultId].parents.length) ; // To Check enough elements added
        
        for (uint256 i = 0; i < _tokenIds.length; i++) {
             require(_exists(_tokenIds[i]),"token not exist");
             require(ownerOf(_tokenIds[i])==msg.sender,"token not owned");
             NFTDetails memory tokenDetails= tokenInfo[_tokenIds[i]];
            for (uint256 j = 0; j < elements[_resultId].parents.length; j++) {
                 
                if(elements[_resultId].parents[j]==tokenDetails.elementId  // incoming token contains required element 
                    && massRequired[j]<_resultMass){ // required mass not meet
                       
                        uint32 newMassRequirement=_resultMass-massRequired[j];
                        
                        if(tokenDetails.mass<=newMassRequirement){ // dont have enough mass or equal
                            massRequired[j]+=tokenDetails.mass;
                            massToBurn[i]+=tokenDetails.mass;
                        }else{
                            massRequired[j]+=newMassRequirement;
                            massToBurn[i]+=newMassRequirement;
                        }
                    }
             }
        }
         
        //Check input tokens have enough mass
        for (uint256 j = 0; j < elements[_resultId].parents.length; j++) {
             require(massRequired[j]==_resultMass, "mass requirement not met"); 
        }
        
        uint32 massBurned=0; 
        uint32 powerBurned=0;  
        uint32 immunityBurned=0;  
        uint32 experienceBurned=0;
        // Burn Parents and Mint if there is additional mass
         for (uint256 i = 0; i < _tokenIds.length; i++) {
             NFTDetails memory tokenDetails= tokenInfo[_tokenIds[i]];
             if(massToBurn[i]>0 ){
                 if(tokenDetails.mass>massToBurn[i]){
                     
                     tokenInfo[_tokenIds[i]].mass=tokenDetails.mass-massToBurn[i];
                     addElementSupply(tokenDetails.elementId,0,  massToBurn[i], false, true);
                      
                 }else{
                     addElementSupply(tokenDetails.elementId, 1,  massToBurn[i], true, true);
                     _burnToken(_tokenIds[i]);
                 }
                 massBurned+=massToBurn[i];
                 powerBurned+=(tokenDetails.power*massToBurn[i]);
                 immunityBurned+=(tokenDetails.immunity*massToBurn[i]);
                 experienceBurned+=(tokenDetails.experience*massToBurn[i]);

             }
         }
         // Burn Burn Element
          NFTDetails memory burnTokenDetails= tokenInfo[_burnTokenId];
          if(burnTokenDetails.mass>1){
                tokenInfo[_burnTokenId].mass-=1;
                addElementSupply(burnTokenDetails.elementId,0, 1, false, true);
          }else{
                addElementSupply(burnTokenDetails.elementId, 1, 1, true, true);
                _burnToken(_burnTokenId);
                
          }

          powerBurned =(powerBurned/massBurned)+1;
          immunityBurned=immunityBurned/massBurned;
          experienceBurned=experienceBurned/massBurned;

          // Mint result NFT
          _mintWithoutValidation(msg.sender, _resultId, _resultMass,powerBurned, immunityBurned, experienceBurned);
          addElementSupply(_resultId,1,_resultMass, false, false);
    }  
    
    function stringToBytes1(string memory source) public pure returns (bytes1  result) {
    bytes memory tempEmptyStringTest = bytes(source);
    if (tempEmptyStringTest.length == 0) {
        return 0x0;
    }

    assembly {
        result := mload(add(source, 1))
    }
}

    function mint (string[] memory _elements, uint8[] memory _mass) external payable {
        require(mintingStage>0, "premint/public mint not active" );
        require(_elements.length == _mass.length, "wrong elements/mass" );
        uint32 totalWeight=0;
        // Additional Validation
        for (uint256 i = 0; i < _elements.length; i++) {
             bytes1   elementId= bytes1( bytes(_elements[i]) );
            // Can Mint only Basic Elements
            require(elements[elementId].parents.length==0,   " Not a basic Element" );
            // Check Basic Elements Supply Cap : [ if parents is null, its a basic element]
             require(basicElementMintedCount[elementId]  + _mass[i] <= basicElementSupplyCap, "supply cap" );
            //changed to 
           // require(basicElementMintedCount[elementId]  + _mass[i] <= elements[elementId].totalSupply, "supply cap" );
            totalWeight+=_mass[i];
        }
        require( totalWeight >0, "No elements selected" );
        if(mintingStage==1){ // Is freemint
            //Check Whitelist
            require( totalWeight <= preMintAddresses[msg.sender], "WL Alloc Cap" );
        }else {
            if(mintingStage==2){ //Is Pre Mint
                
                require( totalWeight <= preMintAddresses[msg.sender], "WL Alloc Cap" );
            
            }else if(mintingStage==3){ //Is public Mint
                // do nothing
            }
            // Check payable amount
            require( totalWeight * mintPrice <= msg.value, "amount low" );
        }

        // Check max mint per transaction
        require(totalWeight<=basicElementPreMintCap, "user mint cap" );

        // --------- START MINTING -------------------
        if(mintingStage<=2){ // Is premint
            preMintAddresses[msg.sender] -= totalWeight;
        }else if(mintingStage==3){ // Is public Mint
            
        }
        for (uint256 i = 0; i < _elements.length; i++) {
            bytes1   elementId= bytes1( bytes(_elements[i]) );
            // For basic element mint Count
            basicElementMintedCount[elementId]+=_mass[i];
             addElementSupply(elementId,1,_mass[i], false, false);
            _mintWithoutValidation(msg.sender,elementId,_mass[i],_randomRarity(uint(_mass[i])),_randomRarity(uint(_mass[i])),0);
        }
       
     }

    
    function _randomRarity(uint checks) private returns (uint32){
        uint totalR=0;
        for(uint i=0;i<checks;i++){
            totalR+=uint(keccak256(abi.encodePacked(block.timestamp, msg.sender, randNonce++))) %  (raritykeys.length);
        }
        if(checks>1){
            totalR=totalR/checks;
        }
        return raritykeys[totalR]  ;
    }
    
    function _getArtWeight(  uint32 mass, uint32 power,  uint32 immunity) private view  returns (uint256){
       uint256 totalWeight= (mass+power+immunity)/artLevelWeight;
       if(totalWeight<maxLevelWeight){
           return totalWeight;
       }else{
           return maxLevelWeight;
       }
    }

    function _burnToken(uint256 tokenId  ) internal {
        delete tokenInfo[tokenId] ;
        _burn(tokenId );
    }

    function _mintWithoutValidation(address to, bytes1 elementId, uint32 mass, uint32 power,  uint32 immunity,  uint32 experience) internal {
        // Element Should Exist
        require(elementExists(elementId), "Element Not Exists");
        // Add token Count
        lastTokenId++;
        // Add token metadata
        tokenInfo[lastTokenId]=NFTDetails({elementId:elementId, mass: mass, power:power, immunity:immunity, experience:experience});
        // Mint
        _safeMint(to, lastTokenId);
        emit Mint(to, lastTokenId);
    }
 

    function tokenURI(uint256 tokenId) public view  virtual  override  returns (string memory)
    {
        require( _exists(tokenId), "nonexistent token" );
        require( bytes(baseURI).length >0,"baseuri error");
        return  Meta.getMeta(tokenId,_getArtWeight( tokenInfo[tokenId].mass, tokenInfo[tokenId].power, tokenInfo[tokenId].immunity) , tokenInfo[tokenId],elements[tokenInfo[tokenId].elementId],externalURI,baseURI);
    }


  

    // Update Elements Master error
    function addNftElement(
        string memory _elementId,
        string memory _elementName,
        string[] memory _parents,
        uint8 tier
    ) external onlyOwner {
        bytes1   elementId= bytes1( bytes(_elementId) );
        require( !elementExists(elementId), "Exist" );
        bytes1[]  memory parents =new  bytes1[](_parents.length);
        for(uint i=0;i<_parents.length;i++){
            parents[0]= (bytes1( bytes(_parents[i]) ));
        }
        elements[elementId] = Element({name: bytes(_elementName), parents: parents, supply:0, supplyMass:0, tier:tier});
        elementIds.push(elementId);
    }
    function updateNftElement(
        string memory _elementId,
        string memory _elementName,
        string[] memory _parents,
        uint8 tier
    ) external onlyOwner {
         bytes1   elementId= bytes1( bytes(_elementId) );
        require( elementExists(elementId), "Not Exist" );
        bytes1[] memory parents=new  bytes1[](_parents.length);
        for(uint i=0;i<_parents.length;i++){
            bytes1   parentId=bytes1( bytes(_parents[i]) );
            require( elementExists(parentId), "Not Exist" );
            parents[i]=parentId;
        }
        elements[elementId].name =bytes(_elementName);
        elements[elementId].parents =parents; 
        elements[elementId].tier =tier; 
    }
    // Other basic Utilities
    function walletOfOwner(address _owner) public view returns (uint256[] memory) {
        uint256 ownerTokenCount = balanceOf(_owner);
        uint256[] memory tokenIds = new uint256[](ownerTokenCount);
        for (uint256 i; i < ownerTokenCount; i++) {
            tokenIds[i] = tokenOfOwnerByIndex(_owner, i);
        }
        return tokenIds;
    }
    function setBaseURI(string memory _newURI,bool  isExternal) public onlyOwner {
        if(isExternal){
            externalURI=_newURI;
        }else{
            baseURI = _newURI;
        }
        
    }
    function setCost(uint256   _newCost) public onlyOwner {
        mintPrice = _newCost;
    }
    function setLevelWeight( uint32 _artLevelWeight,uint32 _maxLevelWeight) public onlyOwner {
        if(_artLevelWeight>0){
            artLevelWeight = _artLevelWeight;
        }
        if(_maxLevelWeight>0){
            maxLevelWeight = _maxLevelWeight;
        }
    }
    function setSupplyCap(uint32 _basicElementSupplyCap ) public onlyOwner {
          basicElementSupplyCap =_basicElementSupplyCap;
    }
    function setMintCap(  uint32 _basicElementPreMintCap) public onlyOwner {  
      basicElementPreMintCap = _basicElementPreMintCap;
    }
    function setMintingStage(uint8   _stage) public onlyOwner {
        mintingStage = _stage;
    }
    function elementExists(bytes1  _elementId) internal view returns (bool ){
        bool doesListContainElement = false;
        for (uint i=0; i < elementIds.length; i++) {
            if (_elementId == elementIds[i]) {
                doesListContainElement = true;
            }
        }
        return doesListContainElement;
    }

 

    function withdraw() public payable onlyOwner {
        require(payable(msg.sender).send(address(this).balance));
    }

    function _beforeTokenTransfer(address from, address to, uint256 tokenId) internal virtual override{
        super._beforeTokenTransfer(from, to, tokenId);
        if(to!=address(0) && from!=address(0)){
             tokenInfo[tokenId].experience+=1;
        }
    }
 
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC721/extensions/IERC721Enumerable.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional enumeration extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Enumerable is IERC721 {
    /**
     * @dev Returns the total amount of tokens stored by the contract.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns a token ID owned by `owner` at a given `index` of its token list.
     * Use along with {balanceOf} to enumerate all of ``owner``'s tokens.
     */
    function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256);

    /**
     * @dev Returns a token ID at a given `index` of all the tokens stored by the contract.
     * Use along with {totalSupply} to enumerate all tokens.
     */
    function tokenByIndex(uint256 index) external view returns (uint256);
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.0;

import {Base64} from "./base64.sol";
struct NFTDetails {
        bytes1 elementId;
        uint32 mass;
        uint32 immunity;
        uint32 power;
        uint32 experience;
    }

struct Element {
        bytes name;
     
        bytes1[] parents;
        uint32 supply;
        uint32 supplyMass;
        uint8 tier;
    }

library Meta {

    string public constant description= "The Game of Building, Fighting and Owning Powerful Creatures on 'Planet EO'.";

    function getMeta(uint256 tokenId,uint256 artWeight, NFTDetails memory metadata, Element memory element, string memory external_url, string memory meta_url) public pure returns (string memory) {
        bytes memory byteString  = abi.encodePacked("{");
        
        byteString = abi.encodePacked(
          byteString,
          _pushJsonStringAttribute("name", string(abi.encodePacked(string(element.name),' [',toString(metadata.mass),'] #', toString(tokenId)))  , true));
        byteString = abi.encodePacked(
          byteString,
          _pushJsonStringAttribute("description",string( description)  , true));
        byteString = abi.encodePacked(
          byteString,
          _pushJsonStringAttribute("external_url",string(external_url)  , true));

        // Image URls
        bytes memory elementFileName=isLowerCase(metadata.elementId)?abi.encodePacked("_",metadata.elementId):abi.encodePacked(metadata.elementId);
        string memory parameters=string(abi.encodePacked(
                "element=",elementFileName,
                "&experience=",toString(metadata.experience),
                "&mass=",toString(metadata.mass),
                "&immunity=",toString(metadata.immunity),
                "&power=",toString(metadata.power),
                "&level=",toString(artWeight),
                "&tier=",toString(element.tier)));
          byteString = abi.encodePacked(
          byteString,
          _pushJsonStringAttribute("animation_url",string(abi.encodePacked(meta_url,"html/",elementFileName,".html?",  parameters))  , true));

         
       // elementFileName=abi.encodePacked( elementFileName,"-", toString(artWeight));
         
        byteString = abi.encodePacked(
          byteString,
          _pushJsonStringAttribute("image",string(abi.encodePacked(meta_url,"images/",elementFileName,"-", toString(artWeight),".png"))  , true));
              
        // Attributes
        byteString = abi.encodePacked(byteString,'"attributes": [' );
        byteString = abi.encodePacked(
            byteString,
            _pushJsonTraitNumber("Mass", toString(metadata.mass) , true));
        byteString = abi.encodePacked(
            byteString,
            _pushJsonTraitNumber("Immunity", toString(metadata.immunity) , true));
        byteString = abi.encodePacked(
            byteString,
            _pushJsonTraitNumber("Power", toString(metadata.power) , true));
        byteString = abi.encodePacked(
            byteString,
            _pushJsonTraitNumber("Experience", toString(metadata.experience) , true));
        byteString = abi.encodePacked(
            byteString,
            '{"trait_type":"Tier", "value":', toString(element.tier),  ', "display_type":"number"},');
        byteString = abi.encodePacked(
            byteString,
            _pushJsonTraitString("Tier Name",string( abi.encodePacked("Tier ",toString(element.tier)) ), false));
         byteString = abi.encodePacked(byteString,']}' );

         string memory base64Json = Base64.encode(byteString);
        return string(abi.encodePacked('data:application/json;base64,', base64Json));
        // return string(byteString);
    }

     

    function _getString(string memory _str) private pure returns (string memory){
        return string(abi.encodePacked(_str));
    }
    function _getField(string memory _str) private pure returns (string memory){
        return string(abi.encodePacked(_str));
    }
    function _pushJsonStringAttribute(string memory key, string memory value, bool insertComma) private pure returns (string memory) {
        return string(abi.encodePacked('"', key, '": "', value, '"', insertComma ? ',' : ''));
    }
    function _pushJsonTraitNumber(string memory trait_type, string memory trait_value, bool insertComma) private pure returns (string memory) {
        return string(abi.encodePacked(
            '{"trait_type":"', trait_type, '", "value":', trait_value,   insertComma ? '},' : '}'
            ));
    }
    function _pushJsonTraitString(string memory trait_type, string memory trait_value, bool insertComma) private pure returns (string memory) {
        return string(abi.encodePacked(
            '{"trait_type":"', trait_type, '", "value":"', trait_value, '"' , insertComma ? '},' : '}'
            ));
    }

    function isLowerCase(bytes1 _id) public pure returns(bool){
        bytes memory allowed = bytes("abcdefghijklmnopqrstuvwxyz"); 
        for(uint j=0; j<allowed.length; j++){
            if(_id==allowed[j] ){
                return true;
            }
        }
        return false;
    }

    function toString(uint256 value) internal pure returns (string memory) {

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

 

}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/introspection/ERC165.sol)

pragma solidity ^0.8.0;

import "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}