Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 *
 * Alternatively, {ERC165Storage} provides an easier to use but more expensive implementation.
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "IERC721.sol";
import "IERC721Receiver.sol";
import "IERC721Metadata.sol";
import "Address.sol";
import "Context.sol";
import "Strings.sol";
import "ERC165.sol";

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension, but not including the Enumerable extension, which is available separately as
 * {ERC721Enumerable}.
 */
contract ERC721 is Context, ERC165, IERC721, IERC721Metadata {
    using Address for address;
    using Strings for uint256;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to owner address
    mapping(uint256 => address) private _owners;

    // Mapping owner address to token count
    mapping(address => uint256) private _balances;

    // Mapping from token ID to approved address
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    /**
     * @dev Initializes the contract by setting a `name` and a `symbol` to the token collection.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC165, IERC165) returns (bool) {
        return
            interfaceId == type(IERC721).interfaceId ||
            interfaceId == type(IERC721Metadata).interfaceId ||
            super.supportsInterface(interfaceId);
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view virtual override returns (uint256) {
        require(owner != address(0), "ERC721: balance query for the zero address");
        return _balances[owner];
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view virtual override returns (address) {
        address owner = _owners[tokenId];
        require(owner != address(0), "ERC721: owner query for nonexistent token");
        return owner;
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        require(_exists(tokenId), "ERC721Metadata: URI query for nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return "";
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public virtual override {
        address owner = ERC721.ownerOf(tokenId);
        require(to != owner, "ERC721: approval to current owner");

        require(
            _msgSender() == owner || isApprovedForAll(owner, _msgSender()),
            "ERC721: approve caller is not owner nor approved for all"
        );

        _approve(to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view virtual override returns (address) {
        require(_exists(tokenId), "ERC721: approved query for nonexistent token");

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        require(operator != _msgSender(), "ERC721: approve to caller");

        _operatorApprovals[_msgSender()][operator] = approved;
        emit ApprovalForAll(_msgSender(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        //solhint-disable-next-line max-line-length
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");

        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, "");
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        require(_isApprovedOrOwner(_msgSender(), tokenId), "ERC721: transfer caller is not owner nor approved");
        _safeTransfer(from, to, tokenId, _data);
    }

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * `_data` is additional data, it has no specified format and it is sent in call to `to`.
     *
     * This internal function is equivalent to {safeTransferFrom}, and can be used to e.g.
     * implement alternative mechanisms to perform token transfer, such as signature-based.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeTransfer(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _transfer(from, to, tokenId);
        require(_checkOnERC721Received(from, to, tokenId, _data), "ERC721: transfer to non ERC721Receiver implementer");
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     * and stop existing when they are burned (`_burn`).
     */
    function _exists(uint256 tokenId) internal view virtual returns (bool) {
        return _owners[tokenId] != address(0);
    }

    /**
     * @dev Returns whether `spender` is allowed to manage `tokenId`.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function _isApprovedOrOwner(address spender, uint256 tokenId) internal view virtual returns (bool) {
        require(_exists(tokenId), "ERC721: operator query for nonexistent token");
        address owner = ERC721.ownerOf(tokenId);
        return (spender == owner || getApproved(tokenId) == spender || isApprovedForAll(owner, spender));
    }

    /**
     * @dev Safely mints `tokenId` and transfers it to `to`.
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(address to, uint256 tokenId) internal virtual {
        _safeMint(to, tokenId, "");
    }

    /**
     * @dev Same as {xref-ERC721-_safeMint-address-uint256-}[`_safeMint`], with an additional `data` parameter which is
     * forwarded in {IERC721Receiver-onERC721Received} to contract recipients.
     */
    function _safeMint(
        address to,
        uint256 tokenId,
        bytes memory _data
    ) internal virtual {
        _mint(to, tokenId);
        require(
            _checkOnERC721Received(address(0), to, tokenId, _data),
            "ERC721: transfer to non ERC721Receiver implementer"
        );
    }

    /**
     * @dev Mints `tokenId` and transfers it to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {_safeMint} whenever possible
     *
     * Requirements:
     *
     * - `tokenId` must not exist.
     * - `to` cannot be the zero address.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 tokenId) internal virtual {
        require(to != address(0), "ERC721: mint to the zero address");
        require(!_exists(tokenId), "ERC721: token already minted");

        _beforeTokenTransfer(address(0), to, tokenId);

        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(address(0), to, tokenId);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId) internal virtual {
        address owner = ERC721.ownerOf(tokenId);

        _beforeTokenTransfer(owner, address(0), tokenId);

        // Clear approvals
        _approve(address(0), tokenId);

        _balances[owner] -= 1;
        delete _owners[tokenId];

        emit Transfer(owner, address(0), tokenId);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *  As opposed to {transferFrom}, this imposes no restrictions on msg.sender.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {
        require(ERC721.ownerOf(tokenId) == from, "ERC721: transfer of token that is not own");
        require(to != address(0), "ERC721: transfer to the zero address");

        _beforeTokenTransfer(from, to, tokenId);

        // Clear approvals from the previous owner
        _approve(address(0), tokenId);

        _balances[from] -= 1;
        _balances[to] += 1;
        _owners[tokenId] = to;

        emit Transfer(from, to, tokenId);
    }

    /**
     * @dev Approve `to` to operate on `tokenId`
     *
     * Emits a {Approval} event.
     */
    function _approve(address to, uint256 tokenId) internal virtual {
        _tokenApprovals[tokenId] = to;
        emit Approval(ERC721.ownerOf(tokenId), to, tokenId);
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target address.
     * The call is not executed if the target address is not a contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        if (to.isContract()) {
            try IERC721Receiver(to).onERC721Received(_msgSender(), from, tokenId, _data) returns (bytes4 retval) {
                return retval == IERC721Receiver.onERC721Received.selector;
            } catch (bytes memory reason) {
                if (reason.length == 0) {
                    revert("ERC721: transfer to non ERC721Receiver implementer");
                } else {
                    assembly {
                        revert(add(32, reason), mload(reason))
                    }
                }
            }
        } else {
            return true;
        }
    }

    /**
     * @dev Hook that is called before any token transfer. This includes minting
     * and burning.
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, ``from``'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, ``from``'s `tokenId` will be burned.
     * - `from` and `to` are never both zero.
     *
     * To learn more about hooks, head to xref:ROOT:extending-contracts.adoc#using-hooks[Using Hooks].
     */
    function _beforeTokenTransfer(
        address from,
        address to,
        uint256 tokenId
    ) internal virtual {}
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize, which returns 0 for contracts in
        // construction, since the code is only stored at the end of the
        // constructor execution.

        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _setOwner(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _setOwner(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _setOwner(newOwner);
    }

    function _setOwner(address newOwner) private {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _HEX_SYMBOLS = "0123456789abcdef";

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT licence
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        if (value == 0) {
            return "0x00";
        }
        uint256 temp = value;
        uint256 length = 0;
        while (temp != 0) {
            length++;
            temp >>= 8;
        }
        return toHexString(value, length);
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _HEX_SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IOpenDAO {
    function balanceOf(address owner) external view returns(uint256);
    function transferFrom(address, address, uint256) external;
    function allowance(address owner, address spender) external view returns(uint256);
    function approve(address spender, uint256 amount) external returns(bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;


import "ThreePerWallet.sol";
import "Ownable.sol";
import "ERC721.sol";
import "IERC721.sol";

import "IOpenDAO.sol";
/***************************************************************************************************
oooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo
ooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo+/::://+ooooooooooooo
oooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo/-`       `./ooooooooooo
oooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo/.             .+ooooooooo
ooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooooo/`               `+oooooooo
ooooooooooooooooooooooooooooooooooooooossyyhhddddmmmmmddddhhyyssoooooooo+`                 ./++ooooo
ooooooooooooooooooooooooooooooooosyhdmNNNNNmmmmmddddddddmmmmNNNNNmdhyso/-                   ```-/ooo
ooooooooooooooooooooooooooooosydNNNmmddhhdddmddddddddddddddhhysyhhdmNNmo`                       `:oo
ooooooooooooo++:-....-:++oosdNMMd+/:yNMMMMNmdhhyyyyyyyyyyhhdmMMNmo-:/oNMh                         /o
oooooooooooo/.          ./oNMNMMdyo/ossyyyhddmmNmmmmmmmmmmmmNmhs+:::/sNMh                         `:
ooooooooooo-              +MMoshdNNMMNmdhysoo+/////++++oooooosyhhdmNMNd+`                           
oooooooooo/               /MMo::::/+oshNMMMMMMMMMMMMMMMMMMMMMMMMmdhyo.                              
oooo+/:::/-             `.-NMm::::::/yNMNhs+++oooossssoooo++sdMMmyooo+:.``                      ``..
o/.`                  omMMMMMMy::::sNMNy+/////////////////////+hMMmsooooooo+++/////////////+++oooooo
.                    hMNs++ohMMs:+mMNy+/////////////////////////odMMhooooooooooooooooooooooooooooooo
                    -MMs:::::yMMhNMmo////////////////////////////+yMMdoooooooooooooooooooooooooooooo
                    -MMs::::::smMMd+/////////////////////////////++yMMdooooooooooooooooooooooooooooo
                     dMm/:::::+NMd+//////////osys+//////////////smNNMMMhoooooooooooooooooooooooooooo
                     -mMd/::::mMN+/////////+hNNMMmo////////////sMMyyMMMMsooooooooooooooooooooooooooo
                      -dMNs/:sMMs//////////yMM/-hMNo///////////NMd .MMMMdooooooooooooooooooooooooooo
`                     `hMMMmomMm///////////NMd  `MMh///////////mMm`.MMMMNooooooooooooooooooooooooooo
+/:-----------------..oMMshNMMMy///////////mMm` .MMh///////////oNMmmMNdMMsoooooooooooooooooooooooooo
oooooooooooooooooooooohMM+:/hMMs///////////sNMmymMNo///+++syyhhhdNMNhoyMMsoooooooooooooooooooooooooo
oooooooooooooooooooooosMMh::sMMo////////////+ydddy+/+oydNMMNNNmmmNNMMNNMMooooooooooooooooooooooooooo
oooooooooooooooooooooooyMMh:sMMo//////////////////+smMMmhyo+//////+yyymMMdoooooooooooooooooooooooooo
ooooooydmNMMMNNNmmdhysooyNMmhMMs/////////////////omMMho/oNNo//////yMM+/sNMmooooooooooosssyyssooooooo
ooooohMMy+///++oshdNMMNdoohMMMMh/////////////////smd+///oMMo//////omd+//hMMoooooyhmNMMMMMMMMMNdooooo
ooooohMMs-`         ./mMNooodNMN//////////////////+//////++////////+////hMMooymMMmhs+:-..``./NMdoooo
ooooooyMMMNmhysso.    :MMyoooyMMs/////////////+s+//////////////////////+NMmodMMs-`   `.-:/+ydMMhoooo
oooooooMMmosyhhdd:    .MMhooooNMm+////////////hMN+/////////+oyhmmmdysoodMMsoMMs    `mNNNNNmhmMMooooo
ooooooohNMdsosymNd     hMNsoooyMMy////////////oNMmso++++oshNNNmdhdmNMNNMmyohMM-    /hs+/::/+mMmooooo
oooooooosNMMddhyo/     `yNNmddNMMNy+///////////ohNMNNmNNNNmdyo+///+yMMNyosyNMh     hNNmmmNNMNhoooooo
ooooooooodMM+--+dm+  ..  -ohNMMNymMmy+///////////+oyyhyyso+//////+omMNMNmNMmo`   .-..://+dMMoooooooo
oooooooooohNNNMMms--ymm. ``+NMM: .omMmy+////////////oso++/+++ooshmMNdohMMm/. --``dNmhsosdMNyoooooooo
oooooooooooosmMMdhdMMh:`/dmMMMMy   .oNMNhs+////////+mMNmmdmmNNMNNdyo///yNMy``mMh::omMMNNmhsooooooooo
oooooooooooooohmNMMMMhydMMMMyyMMo `+dMNNNMNho///////+syhdddhysso+///////sNMdssNMMNNMNhoooooooooooooo
oooooooooooosmMMMMMMMMmhhMMh//yMMohMNyssyymMNs///////////////////////////oNMMMNNdyysoooooooooooooooo
oooooooooooomMm++oshNMNyNMm+///yMMMM+dMmmMmdMMs+//////////////////////////oNMmoooooooooooooooooooooo
ooooooooooooNMd::::::omMMMo/////oNMN:NMsoNMsMMMms/////+++++////////////////sMMhooooooooooooooooooooo
oooo+/:--::/mMm:::::::+MMh///////yMMy+dmmdohMMyMMmhdNMMMNMMMMNNmdys+////////hMMyoooooooooooooooooooo
o+:`        yMM:::::::dMN+////////yNMmysshmMMm..omMMmo:::::://+oydNNdo//////+mMNoooooooooooooooooooo
/`          :MMs:::::/MMh//////////+yNMMNMMo/NN: `/hNMmy+:::::::::/omMh//////oMMdo+/:::/+ooooooooooo
             dMm:::::yMM+////////////oNMdoMd`.dd    .+hNMmho/:::::::/dMy//////dMM/`     `-+ooooooooo
             +MMy::::NMm//////////////sMMy+Nd.``      `./ymMNdyo/::::/MN++mms/oMMo        `+oooooooo
            sNMMMs::+MMy///////////////yMM//Nm:           `-ohmNNmyo+/mMo/mMm//mMm         /oooooooo
           :MMshMNs:sMMo////////////ymh+mMm -hNs`             .-+ymNNmNMhohMMo/yMM-        -/+oooooo
           +MM+:hMMohMM/////////////dMN/yMM: `oNd/`               `-/shmNNNMMh/oMM+          `/ooooo
           -MMs::os/mMm/////////////dMM/+MMo   -yNy                    `-/sNMm//MMy           `+oooo
            dMm:::::NMm/////////////hMM++MMs     -.                        yMM+/NMd            /oooo
            :MMy::::NMd/////////////hMM+oMM+                               +MMo/mMm`          .+oooo
             sMMo:::NMd/////////////hMModMN`                               /MMs/mMNo+++++////+oooooo
              yMMs::mMm/////////////yMMdMM/                                :MMs/NMmooooooooooooooooo
 ***************************************************************************************************/

contract KaijuDAO is ERC721, ThreePerWallet, Ownable{
    using Address for address;
    using Strings for uint256;

    address private signer;
    address payable public treasury;
    bool private publicGen0Sale;
    bool private publicGen1Sale;
    bool private preGen0Sale;
    
    uint16 public minted;
    //uint256 public constant MINT_PRICE_SOS_GEN0 = 50000000000000000000000000;
    uint256 public  MINT_PRICE_ETH_GEN0_PRESALE = 0.03 ether;
    uint256 public  MINT_PRICE_ETH_GEN0 = 0.04 ether;
    uint256 public  MINT_PRICE_ETH_GEN1 = 0.04 ether;
    uint256 public  MINT_PRICE_SOS_GEN0_PRESALE = 23000000000000000000000000;
    uint256 public  MINT_PRICE_SOS_GEN0 = 31000000000000000000000000;
    uint256 public  MINT_PRICE_SOS_GEN1 = 31000000000000000000000000;
    uint256 public MAX_TOKENS_GEN0 = 10000;
    uint256 public MAX_TOKENS_GEN1 = 10000;
    uint256 public MAX_AIRDROPS_GEN0 = 100;
    uint256 public MAX_AIRDROPS_GEN1 = 100;
    uint256 public remain_airdrops_gen0 = 100;
    uint256 public remain_airdrops_gen1 = 100;

    uint16 public round_gen0;
    uint16 public round_gen1;

    address[] public power_leaders;
    address[] public money_leaders;
    address[] public music_leaders;
    address[] public alien_leaders;
    address[] public zombie_leaders;

    mapping(uint256 => uint16) public traits;
    uint256[] public power_list;
    uint256[] public money_list;
    uint256[] public music_list;
    uint256[] public alien_list;
    uint256[] public zombie_list;

    IOpenDAO private openDAO;

    uint256 private accum_eth_gen0 = 0 ether;
    uint256 private accum_eth_gen1 = 0 ether;

    uint256 private accum_sos_gen0 = 0;
    uint256 private accum_sos_gen1 = 0;

    constructor(address _openDAOAddress) ERC721("ChubbyKaijuDAO", "CKAIJU"){
        openDAO = IOpenDAO(_openDAOAddress);
    }

    function initialize(uint256 supply0, uint256 supply1, uint256 airdrop0, uint256 airdrop1, address _signer, address payable _treasury) public onlyOwner {
        openDAO.approve(address(this), 1000000000000000000000000000000);
        MAX_TOKENS_GEN0=supply0;
        MAX_TOKENS_GEN1=supply1;
        MAX_AIRDROPS_GEN0 = airdrop0;
        remain_airdrops_gen0 = MAX_AIRDROPS_GEN0;
        MAX_AIRDROPS_GEN1 = airdrop1;
        remain_airdrops_gen1 = MAX_AIRDROPS_GEN1;
        signer = _signer;
        treasury = _treasury;
    }

    function _setTrait(uint256 tokenId) internal {
        uint256 seed = uint256(keccak256(abi.encodePacked(block.timestamp, tokenId)));
        if(tokenId<MAX_TOKENS_GEN0+1){
            uint16 mod = uint16(seed % 3);
            traits[tokenId] = mod;
            if(mod == 0 && power_list.length<uint256(MAX_TOKENS_GEN0/3)){
                power_list.push(tokenId);
            }else if(mod == 1 && money_list.length<uint256(MAX_TOKENS_GEN0/3)){
                money_list.push(tokenId);
            }else{
                music_list.push(tokenId);
            }
        }else{
            uint16 mod = uint16(seed % 2)+3;
            traits[tokenId] = mod;
            if(mod==3 && alien_list.length < MAX_TOKENS_GEN1/2) alien_list.push(tokenId);
            else zombie_list.push(tokenId);
        }
    }

    function airdropGEN0(address[] calldata airdropAddresses) public onlyOwner {
        require(remain_airdrops_gen0-airdropAddresses.length>=0, "Too many airdrops");
        for(uint256 i = 0; i < airdropAddresses.length; i++) {
            minted++;
            _setTrait(minted);
            _mint(airdropAddresses[i], minted);
            _autoTransfer();
        }
        remain_airdrops_gen0 -= airdropAddresses.length;
    }

    function airdropGEN1(address[] calldata airdropAddresses) public onlyOwner {
        require(remain_airdrops_gen1-airdropAddresses.length>=0, "Too many airdrops");
        for(uint256 i = 0; i < airdropAddresses.length; i++) {
            minted++;
            _setTrait(minted);
            _mint(airdropAddresses[i], minted);
            _autoTransfer();
        }
        remain_airdrops_gen1 -= airdropAddresses.length;
    }

    function preSaleETH(bytes memory signature, uint16 amount) external payable threePerWallet(msg.sender, minted+1){
        require(preGen0Sale, "preSale closed");
        require(isWhitelisted(msg.sender, signature), "Not Whitelisted");
        require(MINT_PRICE_ETH_GEN0_PRESALE * amount == msg.value, "Invalid payment amount");
        require(amount < 4, "Too many amount");
        require(minted + amount <= MAX_TOKENS_GEN0-remain_airdrops_gen0, "minted out");
        for(uint i=0; i<amount; i++){
            minted++;
            accum_eth_gen0 += MINT_PRICE_ETH_GEN0_PRESALE;
            _setTrait(minted);
            _mint(msg.sender, minted);
            _autoTransfer();
        }
    }
    function publicETH(uint16 amount) external payable threePerWallet(msg.sender, minted+1){
        if(minted<MAX_TOKENS_GEN0){
            require(publicGen0Sale, "publicGen0Sale not open");
            require(MINT_PRICE_ETH_GEN0 * amount == msg.value, "Invalid payment amount");
            require(minted + amount <= MAX_TOKENS_GEN0-remain_airdrops_gen0, "minted out");
        }else{
            require(publicGen1Sale, "publicGen1Sale not open");
            require(MINT_PRICE_ETH_GEN1 * amount == msg.value, "Invalid payment amount");
            require(minted + amount <= MAX_TOKENS_GEN0+MAX_TOKENS_GEN1-remain_airdrops_gen1, "minted out");
        } 
        require(amount < 4, "Too many amount");
        
        for(uint i=0; i<amount; i++){
            minted++;
            if(minted < MAX_TOKENS_GEN0+1) accum_eth_gen0 += MINT_PRICE_ETH_GEN0;
            else accum_eth_gen1 += MINT_PRICE_ETH_GEN1;
            _setTrait(minted);
            _mint(msg.sender, minted);
            _autoTransfer();
        }
    }
    function preSaleSOS(bytes memory signature, uint16 amount) external threePerWallet(msg.sender, minted+1){
        require(preGen0Sale, "preSale closed");
        require(isWhitelisted(msg.sender, signature), "Not Whitelisted");
        require(amount < 4, "Too many amount");
        require(minted + amount <= MAX_TOKENS_GEN0-remain_airdrops_gen0, "minted out");
        require(MINT_PRICE_SOS_GEN0_PRESALE * amount <= openDAO.balanceOf(msg.sender), "not enough balance");
        require(MINT_PRICE_SOS_GEN0_PRESALE * amount <= openDAO.allowance(msg.sender, address(this)), "low allowance");
        openDAO.transferFrom(msg.sender, address(this), MINT_PRICE_SOS_GEN0_PRESALE * amount);
        for(uint i=0; i<amount; i++){
            minted++;
            accum_sos_gen0 += MINT_PRICE_SOS_GEN0_PRESALE;
            _setTrait(minted);
            _mint(msg.sender, minted);
            _autoTransfer();
        }
    }
    function publicSOS(uint16 amount) external threePerWallet(msg.sender, minted+1){
        if(minted<MAX_TOKENS_GEN0){
            require(publicGen0Sale, "publicGen0Sale not open");
            require(minted + amount <= MAX_TOKENS_GEN0-remain_airdrops_gen0, "minted out");
            require(MINT_PRICE_SOS_GEN0 * amount <= openDAO.balanceOf(msg.sender), "not enough balance");
            require(MINT_PRICE_SOS_GEN0 * amount <= openDAO.allowance(msg.sender, address(this)), "low allowance");
        }else{
            require(publicGen1Sale, "publicGen1Sale not open");
            require(minted + amount <= MAX_TOKENS_GEN0+MAX_TOKENS_GEN1-remain_airdrops_gen1, "minted out");
            require(MINT_PRICE_SOS_GEN1 * amount <= openDAO.balanceOf(msg.sender), "not enough balance");
            require(MINT_PRICE_SOS_GEN1 * amount <= openDAO.allowance(msg.sender, address(this)), "low allowance");
        } 
        require(amount < 4, "Too many amount");
        
        openDAO.transferFrom(msg.sender, address(this), MINT_PRICE_SOS_GEN0_PRESALE * amount);
        for(uint i=0; i<amount; i++){
            minted++;
            if(minted < MAX_TOKENS_GEN0+1) accum_sos_gen0 += MINT_PRICE_SOS_GEN0;
            else accum_sos_gen1 += MINT_PRICE_SOS_GEN1;
            _setTrait(minted);
            _mint(msg.sender, minted);
            _autoTransfer();
        }
    }

    function ownerOf(uint256 tokenId) public view override(ERC721) returns (address) {
        return super.ownerOf(tokenId);
    }

    function contractURI() public pure returns (string memory) {
        //TODO change contractURI
        return "https://raw.githubusercontent.com/KaijuDAO/kaijudao/main/contracturi";
    }

    function tokenURI(uint256 tokenId) public view override returns (string memory) {
        require(_exists(tokenId), "nonexistent token");

        string memory baseURI = _baseURI();
        return bytes(baseURI).length > 0 ? string(abi.encodePacked(baseURI, tokenId.toString())) : "";
    }

    function _baseURI() override internal pure returns (string memory) {
        //TODO change baseURI
        return "https://raw.githubusercontent.com/KaijuDAO/kaijudao/main/tokenuri/";
    }

    function _mint(address to, uint256 tokenId) internal override(ERC721, ThreePerWallet) {
        ThreePerWallet._mint(to, tokenId);
    }

    function setLeadersGen0(address power, address money, address music) external onlyOwner {
        power_leaders.push(power);
        money_leaders.push(money);
        music_leaders.push(music);
        round_gen0++;
    }

    function setLeadersGen1(address alien, address zombie) external onlyOwner {
        alien_leaders.push(alien);
        zombie_leaders.push(zombie);
        round_gen1++;
    }

    function getEthSignedMessageHash(bytes32 _messageHash) public pure returns (bytes32) {
        /*
        Signature is produced by signing a keccak256 hash with the following format:
        "\x19Ethereum Signed Message\n" + len(msg) + msg
        */
        return
        keccak256(
            abi.encodePacked("\x19Ethereum Signed Message:\n32", _messageHash)
        );
    }

    function isWhitelisted(address user, bytes memory signature) public view returns (bool) {
        bytes32 messageHash = keccak256(abi.encode(user));
        bytes32 ethSignedMessageHash = getEthSignedMessageHash(messageHash);

        return recoverSigner(ethSignedMessageHash, signature) == signer;
    }

    function recoverSigner(bytes32 _ethSignedMessageHash, bytes memory _signature) private pure returns (address) {
        (bytes32 r, bytes32 s, uint8 v) = splitSignature(_signature);
        return ecrecover(_ethSignedMessageHash, v, r, s);
    }

    function splitSignature(bytes memory sig) private pure returns (bytes32 r, bytes32 s, uint8 v) {
        require(sig.length == 65, "sig invalid");

        assembly {
        /*
        First 32 bytes stores the length of the signature

        add(sig, 32) = pointer of sig + 32
        effectively, skips first 32 bytes of signature

        mload(p) loads next 32 bytes starting at the memory address p into memory
        */

        // first 32 bytes, after the length prefix
            r := mload(add(sig, 32))
        // second 32 bytes
            s := mload(add(sig, 64))
        // final byte (first byte of the next 32 bytes)
            v := byte(0, mload(add(sig, 96)))
        }

        // implicitly return (r, s, v)
    }
    function setPreGen0Sale(bool isPre) public onlyOwner {
        preGen0Sale = isPre;
    }
    function setpublicGen0Sale(bool isPublic) public onlyOwner {
        publicGen0Sale = isPublic;
    }
    
    function setpublicGen1Sale(bool isPublic) public onlyOwner {
        publicGen1Sale = isPublic;
    }

    function setSupplyGen0(uint256 supply) public onlyOwner {
        MAX_TOKENS_GEN0=supply;
    }

    function setSupplyGen1(uint256 supply) public onlyOwner {
        MAX_TOKENS_GEN1=supply;
    }

    function setSigner(address _signer) public onlyOwner {
        signer = _signer;
    }

    function setTreasury(address payable _treasury) public onlyOwner {
        treasury = _treasury;
    }

    function setAirdropGen0(uint256 airdrop) public onlyOwner{
        MAX_AIRDROPS_GEN0 = airdrop;
    }

    function setAirdropGen1(uint256 airdrop) public onlyOwner{
        MAX_AIRDROPS_GEN1 = airdrop;
    }

    function setGen0SOSPrice(uint256 price) public onlyOwner{
        MINT_PRICE_SOS_GEN0 = price;
    }

    function setGen1SOSPrice(uint256 price) public onlyOwner{
        MINT_PRICE_SOS_GEN1 = price;
    }

    function _autoTransfer() internal {
        if(minted < MAX_TOKENS_GEN0+1){
            if(minted%1000 == 0){
                require(address(this).balance>=accum_eth_gen0);
                treasury.transfer(accum_eth_gen0/4);
                openDAO.transferFrom(address(this), treasury, uint256(accum_sos_gen0/4));
                accum_eth_gen0=0 ether;
                accum_sos_gen0=0 ;
                
            }
        }else{
            // TODO: Gen1 treasury autotransfer
            if(minted%1000 == 0){
                require(address(this).balance>=accum_eth_gen1);
                treasury.transfer(accum_eth_gen1/4);
                openDAO.transferFrom(address(this), treasury, uint256(accum_sos_gen1/4));
                accum_eth_gen1=0 ether;
                accum_sos_gen1=0 ;
            }
        }
    }

    function withdraw() public onlyOwner{
        payable(owner()).transfer(address(this).balance);
        openDAO.transferFrom(address(this), owner(), openDAO.balanceOf(address(this)));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import "ERC721.sol";

/// @author 1001.digital
/// @title An extension that enables checking that an address only holds one token.
abstract contract ThreePerWallet is ERC721 {
    // Mapping owner address to token
    mapping (address => uint256) private _ownedGen0;
    mapping (address => uint256) private _ownedGen1;

    /// Require an externally owned account to only hold one token.
    /// @param wallet the address of
    /// @dev Only allow one token per wallet
    modifier threePerWallet(address wallet, uint256 tokenId) {
        if (_isExternal(wallet)) {
            if(tokenId<10001){
                require(_ownedGen0[wallet] < 3, "Can only hold three tokens per wallet");
            }else{
                require(_ownedGen1[wallet] < 3, "Can only hold three tokens per wallet");
            }
            
        }

        _;
    }


    /// Store `_ownedGen0` instead of `_balances`.
    /// @param to the address to which to mint the token
    /// @param tokenId the tokenId that should be minted
    /// @dev overrides the OpenZeppelin `_mint` method to accomodate for our own balance tracker
    function _mint(address to, uint256 tokenId) internal virtual override threePerWallet(to, tokenId) {
        super._mint(to, tokenId);

        // We add one to account for 0-index based collections
        if(msg.sender==to){
            if(tokenId<10001){
                _ownedGen0[to] += 1;
            }else{
                _ownedGen1[to] += 1;
            }
        }
        
    }
    /*
    /// Track transfers in `_ownedGen0` instead of `_balances`
    /// @param from the address from which to transfer the token
    /// @param to the address to which to transfer the token
    /// @param tokenId the tokenId that is being transferred
    /// @dev overrides the OpenZeppelin `_transfer` method to accomodate for our own balance tracker
    function _transfer(address from, address to, uint256 tokenId) internal virtual override threePerWallet(to, tokenId) {
        super._transfer(from, to, tokenId);
        if(tokenId<10001){
            _ownedGen0[from] -= 1;
            // We add one to account for 0-index based collections
            _ownedGen0[to] += 1;
        }else{
            _ownedGen1[from] -= 1;
            // We add one to account for 0-index based collections
            _ownedGen1[to] += 1;
        }
        
    }
    */
    function _isContract(address account) internal view returns (bool) {
        return _getSize(account) > 0;
    }

    /// Check whether an address is an external wallet.
    /// @param account the address to check
    /// @dev checks if the `extcodesize` of `address` is zero
    /// @return true for external wallets
    function _isExternal(address account) internal view returns (bool) {
        return _getSize(account) == 0;
    }

    /// Get the size of the code of an address
    /// @param account the address to check
    /// @dev gets the `extcodesize` of `address`
    /// @return the size of the address
    function _getSize(address account) internal view returns (uint256) {
        uint256 size;
        assembly {
            size := extcodesize(account)
        }
        return size;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @title ERC721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be reverted.
     *
     * The selector can be obtained in Solidity with `IERC721.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}