Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "./IERC20.sol";

interface IAccelerationProgram is IERC20 {

    function mint(address to, uint256 amount) external;
    function burn(address from, uint256 amount) external;
    function updateMintPermission(address from, bool state) external;
    function updateBurnPermission(address from, bool state) external;

    function transferOwnership(address newOwner) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface IBarkDao {

    struct Member {
        address parent;
        uint256 lastActionBlock;
        bool hasTeam;
    }

    function highestParentAddress() external view returns (address);
    function getLevel(address addr) external view returns (uint256);
    function members(address addr) external view returns (Member memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface ILiquidityTreasury {

    struct TokenInfo {
        string name;
        uint8 decimals;
        uint256 internalPrice;
    }

    enum Operation { ADD, UPDATE }

    function emergencyWithdrawal(address token, address to, uint256 amount) external;
    function manageTokenPair(
        uint256 pairId,
        address tokenA,
        address tokenB,
        uint256 minAmount,
        Operation op
    ) external;
    function manageBondLife(uint256 durationInDays) external;
    function manageBondType(
        uint256 bondTypeId,
        uint256 pairId,
        uint256 lifeId,
        bool offerActive,
        bool settlementActive,
        Operation op
    ) external;
    function setBasicReturns(
        address[] calldata tokens,
        uint256[] calldata lifeIds,
        uint256[] calldata returnRates
    ) external;
    function setBatchUserRates(
        address[] calldata users,
        uint256[] calldata lifeIds,
        uint256[] calldata points
    ) external;
    function setReceiver(address to) external;
    function setUniversalOfferLoanDisable(bool state) external;
    function setUniversalSettlementDisable(bool state) external;
    function setUniversalDropOut(bool state) external;
    function setUserOfferLoanDisable(address from, bool state) external;
    function setUserGetIncentiveDisable(address from, bool state) external;
    function setUserSettlementDisable(address from, bool state) external;
    function setSingleBondSettlementDisable(uint256 tokenId, bool state) external;
    function transferOwnership(address newOwner) external;
    function setIncentiveRate(uint256 rate) external;
    function setInternalPrice(address token, uint256 price) external;
    function setPointConfig(
        uint256 lifeId,
        uint256 activeUpperLevel,
        uint256[] calldata weightFactors
    ) external;
    function updatePoint(address from, uint256 lifeId, uint256 amount) external;
    function setPointAirdrop(address to) external;

    function setInFlowMode(uint256 mode, bool enabled) external;
    function setOutFlowMode(uint256 mode) external;
    function setFromPermission(address addr, bool enabled) external;
    function setToPermission(address addr, bool enabled) external;

    function getTokenInfo(address token) external view returns (TokenInfo memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "./Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

import "./Ownable.sol";
import "./ReentrancyGuard.sol";
import "./IBarkDao.sol";
import "./ILiquidityTreasury.sol";
import "./IAccelerationProgram.sol";

contract PointAirdrop is Ownable, ReentrancyGuard {

    struct AirdropConfig {
        uint256 totalCap;
        uint256 totalMinted;
        uint256 claimAmount;
        address pointToken;
    }

    IBarkDao public barkDao;
    ILiquidityTreasury public liquidityTreasury;

    mapping(uint256 => AirdropConfig) public airdropConfigs;
    mapping(address => mapping(uint256 => bool)) public hasClaimed;

    error BarkDaoUnregistered();
    error AirdropNotActive();
    error AbnormalParameter();
    error AlreadyClaimed();
    error ExceedsTotalAirdrop();
    error InvalidTotalCap();
    error InvalidClaimAmount();

    event AirdropClaimed(address indexed user, uint256 indexed pointType, uint256 amount);
    event CapUpdated(uint256 indexed pointType, uint256 newCap);
    event ClaimAmountUpdated(uint256 indexed pointType, uint256 amount);

    modifier onlyRegistered() {
        IBarkDao.Member memory member = barkDao.members(msg.sender);
        if (member.parent == address(0)) revert BarkDaoUnregistered();
        _;
    }

    modifier onlyPointType(uint256 pointType) {
        if (pointType == 0 || pointType > 3) revert AbnormalParameter();
        _;
    }

    constructor(
        address _barkDAO,
        address _liquidityTreasury,
        AirdropConfig[] memory configs,
        address _owner
    ) {
        barkDao = IBarkDao(_barkDAO);
        liquidityTreasury = ILiquidityTreasury(_liquidityTreasury);
        for (uint256 x = 0; x < configs.length; x++) {
            airdropConfigs[x + 1] = configs[x];
        }

        transferOwnership(_owner);
    }

    function claim(uint256 pointType) external nonReentrant onlyRegistered onlyPointType(pointType)  {
        _claim(pointType);
    }

    function setTotalCap(uint256 pointType, uint256 newCap) external onlyOwner onlyPointType(pointType) {
        AirdropConfig storage config = airdropConfigs[pointType];
        if (newCap < config.totalMinted) revert InvalidTotalCap();

        config.totalCap = newCap;

        emit CapUpdated(pointType, newCap);
    }

    function setClaimAmount(uint256 pointType, uint256 amount) external onlyOwner onlyPointType(pointType) {
        if (amount > 500 ether) revert InvalidClaimAmount();

        AirdropConfig storage config = airdropConfigs[pointType];
        config.claimAmount = amount;

        emit ClaimAmountUpdated(pointType, amount);
    }

    function getUserClaimStatus(address user) external view returns (bool[3] memory claimed) {
        claimed[0] = hasClaimed[user][1];
        claimed[1] = hasClaimed[user][2];
        claimed[2] = hasClaimed[user][3];
    }

    function getAllConfigs() external view returns (AirdropConfig[3] memory configs) {
        configs[0] = airdropConfigs[1];
        configs[1] = airdropConfigs[2];
        configs[2] = airdropConfigs[3];
    }

    function _claim(uint256 pointType) internal {
        AirdropConfig storage config = airdropConfigs[pointType];

        if (config.claimAmount == 0) revert AirdropNotActive();
        if (hasClaimed[msg.sender][pointType]) revert AlreadyClaimed();

        uint256 newTotal = config.totalMinted + config.claimAmount;
        if (newTotal > config.totalCap) revert ExceedsTotalAirdrop();

        hasClaimed[msg.sender][pointType] = true;
        config.totalMinted = newTotal;

        // update lt v0 point
        liquidityTreasury.updatePoint(msg.sender, pointType, config.claimAmount);
        // mint point token
        IAccelerationProgram(config.pointToken).mint(msg.sender, config.claimAmount);

        emit AirdropClaimed(msg.sender, pointType, config.claimAmount);
    }

}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}