Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (interfaces/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../token/ERC20/extensions/IERC20Metadata.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 *
 * _Available since v4.1._
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../Strings.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, "\x19Ethereum Signed Message:\n32")
            mstore(0x1c, hash)
            message := keccak256(0x00, 0x3c)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, "\x19\x01")
            mstore(add(ptr, 0x02), domainSeparator)
            mstore(add(ptr, 0x22), structHash)
            data := keccak256(ptr, 0x42)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Data with intended validator, created from a
     * `validator` and `data` according to the version 0 of EIP-191.
     *
     * See {recover}.
     */
    function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x00", validator, data));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

pragma solidity >=0.5.0;

interface IUniswapV2Pair {
    event Approval(address indexed owner, address indexed spender, uint value);
    event Transfer(address indexed from, address indexed to, uint value);

    function name() external pure returns (string memory);
    function symbol() external pure returns (string memory);
    function decimals() external pure returns (uint8);
    function totalSupply() external view returns (uint);
    function balanceOf(address owner) external view returns (uint);
    function allowance(address owner, address spender) external view returns (uint);

    function approve(address spender, uint value) external returns (bool);
    function transfer(address to, uint value) external returns (bool);
    function transferFrom(address from, address to, uint value) external returns (bool);

    function DOMAIN_SEPARATOR() external view returns (bytes32);
    function PERMIT_TYPEHASH() external pure returns (bytes32);
    function nonces(address owner) external view returns (uint);

    function permit(address owner, address spender, uint value, uint deadline, uint8 v, bytes32 r, bytes32 s) external;

    event Mint(address indexed sender, uint amount0, uint amount1);
    event Burn(address indexed sender, uint amount0, uint amount1, address indexed to);
    event Swap(
        address indexed sender,
        uint amount0In,
        uint amount1In,
        uint amount0Out,
        uint amount1Out,
        address indexed to
    );
    event Sync(uint112 reserve0, uint112 reserve1);

    function MINIMUM_LIQUIDITY() external pure returns (uint);
    function factory() external view returns (address);
    function token0() external view returns (address);
    function token1() external view returns (address);
    function getReserves() external view returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
    function price0CumulativeLast() external view returns (uint);
    function price1CumulativeLast() external view returns (uint);
    function kLast() external view returns (uint);

    function mint(address to) external returns (uint liquidity);
    function burn(address to) external returns (uint amount0, uint amount1);
    function swap(uint amount0Out, uint amount1Out, address to, bytes calldata data) external;
    function skim(address to) external;
    function sync() external;

    function initialize(address, address) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

import {IVotiumMultiMerkleStash} from "./interfaces/IVotiumMultiMerkleStash.sol";
import {ICvxDelegateRegistry} from "./interfaces/ICvxDelegateRegistry.sol";
import {ICvxLocker} from "./interfaces/ICvxLocker.sol";

import '@openzeppelin/contracts/security/ReentrancyGuard.sol';
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "./interfaces/IRegistryDelegate.sol";
import "./interfaces/IFeeSplitter.sol";
import "./libraries/ERC20Helpers.sol";
import "./interfaces/IVoteMarket.sol";
import "./interfaces/IDeposit.sol";
import "./SignatureVerifier.sol";
import "./interfaces/IWETH.sol";

/**
 * @title Manager
 * @notice Contract that manages locked cvx
 */
contract Manager is ReentrancyGuard, Ownable {

  event SetVotium(address votium);
  event SetVoteMarket(address voteMarket);
  event SetFeeSplitter(address feeSplitter);

  event SetCvxLocker(address locker);
  event SetCvxDelegate(address delegate);

  event SetDelegationSpace(string _delegationSpace, bool shouldClear);
  event SetVoteDelegate(address voteDelegate);
  event ClearVoteDelegate();

  event ClaimVoteMarketRewards(uint256 timestamp, address reward, uint256 amount);
  event ClaimConvexRewards(uint256 timestamp, address reward, uint256 amount);
  event ClaimVotiumReward(address token, uint256 index, uint256 amount);

  event SetRegistryDelegate(address _registryDelegate);
  event SetRegistry(address registryDelegate);
  event RegistryCleared();

  bytes32 public delegationSpace = bytes32("cvx.eth");
  IDeposit public immutable scrvUSD;
  address public emergencyMigrator;
  IERC20 public immutable crvUSD;
  IERC20 public immutable CVX;
  bool public relockPaused;
  bool public paused;

  IVoteMarket public voteMarket;
  ICvxLocker public cvxLocker;
  IFeeSplitter public feeSplitter;
  IVotiumMultiMerkleStash public votium;
  ICvxDelegateRegistry public cvxDelegate;
  IRegistryDelegate public registryDelegate;

  SignatureVerifier public verifier;

  mapping(address => bool) public whitelisted;

  IWETH weth = IWETH(0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2);

  /**
    @notice Convex reward details
    @param  token    address  Token
    @param  amount   uint256  Amount
    @param  balance  uint256  Balance (used for calculating the actual received amount)
   */
  struct ConvexReward {
    address token;
    uint256 amount;
    uint256 balance;
  }

  /**
    @param  _CVX          address  CVX address
    @param  _feeSplitter  address  FeeSplitter address
    @param  _cvxLocker    address  CvxLocker address
    @param  _cvxDelegate  address  CvxDelegateRegistry address
    @param  _votium       address  VotiumMultiMerkleStash address
    @param  _voteMarket     address  VoteMarket address
   */
  constructor(
    address _CVX,
    address _crvUSD,
    address _scrvUSD,
    address _feeSplitter,
    address _cvxLocker,
    address _cvxDelegate,
    address _votium,
    address _voteMarket,
    address _verifier
  ) {
    cvxDelegate = ICvxDelegateRegistry(_cvxDelegate);
    votium = IVotiumMultiMerkleStash(_votium);
    feeSplitter = IFeeSplitter(_feeSplitter);
    verifier = SignatureVerifier(_verifier);
    voteMarket = IVoteMarket(_voteMarket);
    cvxLocker = ICvxLocker(_cvxLocker);
    scrvUSD = IDeposit(_scrvUSD);
    crvUSD = IERC20(_crvUSD);
    CVX = IERC20(_CVX);

    crvUSD.approve(_scrvUSD, type(uint256).max);
    CVX.approve(_cvxLocker, type(uint256).max);
  }

  /**
   * @notice Sets whitelisted status of an address
   * @param user address user to set
   * @param _whitelisted bool whether or not the user should become whitelisted
   */
  function setWhitelisted(address user, bool _whitelisted) external onlyOwner {
    whitelisted[user] = _whitelisted;
  }

  /**
   * @notice withdraws the specified token to the msg sender. Can only do when paused
   * @param _token address The token to withdraw
   */
  function withdrawToken(address _token) external nonReentrant whenPaused onlyOwner {
    IERC20 token = IERC20(_token);
    uint256 amount = token.balanceOf(address(this));
    ERC20Helpers.safeTransfer(_token, msg.sender, amount);
  }

  /**
   * @notice sweeps the specified token to the fee distributor
   * @param _token address The token to sweep
   */
  function sweepToken(address _token) public whenNotPaused isWhitelisted {
    require(_token != address(CVX), "Can not sweep all CVX");
    if (_token == address(weth)) wrapEth();

    IERC20 token = IERC20(_token);
    uint256 amount = token.balanceOf(address(this));
    _sweepToken(address(token), amount);
  }

  /**
   * @notice Internal function that wraps eth into WETH
   */
  function wrapEth() internal {
    uint256 balance = address(this).balance;
    if (balance > 0) weth.deposit{ value: balance }();
  }

  /**
   * @notice Internal function that sweeps specific amounts of tokens
   */
  function _sweepToken(address _token, uint256 amount) internal {
    if (_token == address(crvUSD)) return _wrapAndSweepCrvUsd();
    ERC20Helpers.safeApprove(_token, address(feeSplitter), amount);
    feeSplitter.distribute(_token, amount);
  }

  /**
   * @notice wraps crvUSD in scrvUSD and sweeps to the fee distributor
   */
  function _wrapAndSweepCrvUsd() internal {
    scrvUSD.deposit(type(uint256).max, address(this));
    sweepToken(address(scrvUSD));
  }

  /**
   * @notice Get claimable rewards and balances
   * @return rewards  ConvexReward[]  Claimable rewards and balances
   */
  function _claimableConvexRewards() internal view
  returns (ConvexReward[] memory rewards) {
    // Get claimable rewards
    ICvxLocker.EarnedData[] memory earnings = cvxLocker.claimableRewards(address(this));
    rewards = new ConvexReward[](earnings.length);

    // Get the current balances for each token to calculate the amount received
    for (uint256 i; i < earnings.length; ++i)
      rewards[i] = ConvexReward({
        token: earnings[i].token,
        amount: earnings[i].amount,
        balance: IERC20(earnings[i].token).balanceOf(address(this))
      });
  }

  /**
   * @notice Claim rewards from convex (e.g. emissions) and distribute
   */
  function claimConvexRewards() external nonReentrant isWhitelisted {
    ConvexReward[] memory rewards = _claimableConvexRewards();

    // claim rewards
    cvxLocker.getReward(address(this), false);

    // Iterate over rewards and distribute
    for (uint256 i; i < rewards.length; ++i) {
      emit ClaimConvexRewards(block.timestamp, rewards[i].token, rewards[i].amount);
      if (rewards[i].amount > 0) _sweepToken(rewards[i].token, rewards[i].amount);
    } sweepToken(address(crvUSD));
  }

  /**
   * @notice Claim multiple VoteMarket rewards
   * @param  account  address account for which to claim
   * @param  reward  address token address of reward to claim
   * @param  claimable  uint256 amount of token to claim
   * @param  proof  bytes32[] claim merkle proof
   */
  function claimVoteMarketRewards(
    address account, address reward, uint256 claimable, bytes32[] calldata proof
  ) external whenNotPaused nonReentrant isWhitelisted {
    uint256 balanceWas = IERC20(reward).balanceOf(address(this));

    voteMarket.claim(account, reward, claimable, proof);
    claimable = IERC20(reward).balanceOf(address(this)) - balanceWas;

    emit ClaimVoteMarketRewards(block.timestamp, reward, claimable);

    if (claimable > 0) _sweepToken(reward, claimable);
    sweepToken(address(crvUSD));
  }

  /**
   * @notice Claim multiple Votium rewards
   * @param  votiumRewards  VotiumRewards[]  Votium rewards metadata
  */
  function claimVotiumRewards(
    IVotiumMultiMerkleStash.claimParam[] calldata votiumRewards
  ) external whenNotPaused nonReentrant isWhitelisted {
    for (uint256 i; i < votiumRewards.length; ++i) {
      address token = votiumRewards[i].token;
      uint256 index = votiumRewards[i].index;
      uint256 amount = votiumRewards[i].amount;
      bytes32[] memory merkleProof = votiumRewards[i].merkleProof;

      require(token != address(0), "reward must not be zero address");

      // Validates `token`, `index`, `amount`, and `merkleProof`
      votium.claim(
        token, index, address(this),
        amount, merkleProof
      );
      emit ClaimVotiumReward(token, index, amount);
      if (amount > 0) _sweepToken(token, amount);
    } sweepToken(address(crvUSD));
  }

  /**
   * @notice Set delegationSpace
   * @param  _delegationSpace  string  Convex Snapshot delegation space
   * @param  shouldClear       bool    Whether to clear the vote delegate for current delegation space
   */
  function setDelegationSpace(
    string memory _delegationSpace,
    bool shouldClear
  ) external onlyOwner {
    if (shouldClear) clearVoteDelegate();

    bytes memory space = bytes(_delegationSpace);
    require(space.length != 0, "must not be empty string");

    delegationSpace = bytes32(space);
    emit SetDelegationSpace(_delegationSpace, shouldClear);
  }

  /**
   * @notice Set vote delegate
   * @param  voteDelegate  address  Account to delegate votes to
   */
  function setVoteDelegate(address voteDelegate) external onlyOwner {
    require(voteDelegate != address(0), "must not be zero address");

    emit SetVoteDelegate(voteDelegate);

    cvxDelegate.setDelegate(delegationSpace, voteDelegate);
  }

  /**
   * @notice sets registry delegate
   * @param _registryDelegate address of delegate
   */
  function setRegistryDelegate(address _registryDelegate) external onlyOwner {
    require(_registryDelegate != address(0), "must not be zero address");

    emit SetRegistryDelegate(_registryDelegate);
    registryDelegate = IRegistryDelegate(_registryDelegate);
  }

  /**
   * @notice clears registry
   */
  function clearRegistry() external onlyOwner {
    require(address(registryDelegate) != address(0), "must not be zero address");

    emit RegistryCleared();
    registryDelegate.setToExpire();
  }

  /**
   * @notice Sets registry
   * @param  registry  address  Account to receive rewards from votium
   */
  function setRegistry(address registry) external onlyOwner {
    require(registry != address(0), "must not be zero address");

    registryDelegate.setRegistry(registry);
    emit SetRegistry(registry);
  }

  /**
   * @notice Remove vote delegate
   */
  function clearVoteDelegate() public onlyOwner {
    emit ClearVoteDelegate();

    cvxDelegate.clearDelegate(delegationSpace);
  }

  /**
   * @notice Set feeSplitter address
   * @param  _feeSplitter address _feeSplitter address
   */
  function setFeeSplitter(address _feeSplitter) external onlyOwner {
    require(_feeSplitter != address(0), "must not be zero address");

    feeSplitter = IFeeSplitter(_feeSplitter);
    emit SetFeeSplitter(_feeSplitter);
  }

  /**
   * @notice Set cvx locker address
   * @param  locker  address  Locker address
   */
  function setCvxLocker(address locker) external onlyOwner {
    require(locker != address(0), "must not be zero address");
    require(locker != address(cvxLocker), "Already set");

    ERC20Helpers.safeApprove(address(CVX), address(locker), type(uint256).max);
    ERC20Helpers.safeApprove(address(CVX), address(cvxLocker), 0);
    cvxLocker = ICvxLocker(locker);
    emit SetCvxLocker(locker);
  }

  /**
   * @notice Set votium
   * @param  _votium  address  votium address
   */
  function setVotium(address _votium) external onlyOwner {
    require(_votium != address(0), "must not be zero address");

    votium = IVotiumMultiMerkleStash(_votium);
    emit SetVotium(_votium);
  }

  /**
   * @notice Set voteMarket
   * @param  _voteMarket  address  voteMarket address
   */
  function setVoteMarket(address _voteMarket) external onlyOwner {
    require(_voteMarket != address(0), "must not be zero address");

    voteMarket = IVoteMarket(_voteMarket);
    emit SetVoteMarket(_voteMarket);
  }

  /// @notice Sets the Convex delegate registry address for managing vote delegation.
  /// @param delegate The address of the `ICvxDelegateRegistry` to use for delegations.
  function setCvxDelegate(address delegate) external onlyOwner {
    require(delegate != address(0), "must not be zero address");
    cvxDelegate = ICvxDelegateRegistry(delegate);
    emit SetCvxDelegate(delegate);
  }

  /**
   * @notice Relocks cvx in cvxLocker,
   *   or cvx that has been kicked to this contract
   */
  function relock() public whenNotPaused isWhitelisted {
    if (!relockPaused) {
      (uint256 unlockable) = _fetchUnlockable();
      if (unlockable > 0) cvxLocker.processExpiredLocks(true);

      uint256 cvxBalance = CVX.balanceOf(address(this));
      if (cvxBalance > 0) cvxLocker.lock(address(this), cvxBalance, 0);
    }
  }

  // Due to a strange bug involving unbounded arrays,
  // we use this safe version of accessing unlockable
  // amounts from the cvxLocker.
  function _fetchUnlockable() public view returns (uint256 unlockable) {
    // build the calldata for lockedBalances(address)
    bytes memory data = abi.encodeWithSelector(
      ICvxLocker.lockedBalances.selector,
      address(this)
    );

    // staticcall so any internal revert just gives ok=false
    (bool ok, bytes memory ret) = address(cvxLocker).staticcall(data);

    // if the call reverted or returned < 2 words, bail with 0
    if (!ok || ret.length < 64) return 0;

    // otherwise the 2nd returned word is at offset 32 (length) + 32 (total) = 64
    assembly {
      unlockable := mload(add(ret, 64))
    }
  }

  modifier isWhitelisted() {
    require(msg.sender == owner() || whitelisted[msg.sender], "sender not whitelisted");
    _;
  }

  /*//////////////////////////////////////////////////////////////
    EMERGENCY/MIGRATION LOGIC
  //////////////////////////////////////////////////////////////*/

  modifier whenPaused() {
    require(paused, "Contract is not paused");
    _;
  }

  modifier whenNotPaused() {
    require(!paused, "Contract is paused");
    _;
  }

  /**
   * @notice Set the contract's relockPaused state
   * @param state relockPaused state
   */
  function setRelockPaused(bool state) external onlyOwner {
    relockPaused = state;
  }

  /**
   * @notice Set the contract's pause state
   * @param state Pause state
   */
  function setPaused(bool state) external onlyOwner {
    paused = state;
  }

  /**
   * @notice Sets the emergency migrator, but only when paused
   */
  function setEmergencyMigrator(address _migrator) external whenPaused onlyOwner {
    emergencyMigrator = _migrator;
  }

  /**
   * @notice Emergency withdraw to the emergency Migrator
   */
  function triggerEmergencyMigration() external whenPaused onlyOwner {
    require(emergencyMigrator != address(0), "emergency migrator not set");
    cvxLocker.withdrawExpiredLocksTo(emergencyMigrator);
  }

  /// @notice Updates the on-chain signature verifier contract.
  /// @param _auctioneer The address of the new `SignatureVerifier` instance.
  function updateVerifier(address _auctioneer) public onlyOwner {
    verifier = SignatureVerifier(_auctioneer);
  }

  /// @notice Implements ERC-1271: validates a signature against the approved team.
  /// @param _hash      The hash of the data signed.
  /// @param _signature The signature to validate.
  /// @return magicValue Returns `0x1626ba7e` if valid, else `0xffffffff` as per ERC-1271.
  function isValidSignature(bytes32 _hash, bytes calldata _signature) external view returns (bytes4) {
    if (verifier.verifySignature(_hash, _signature))
      return 0x1626ba7e;
    else return 0xffffffff;
  }

  /// @notice Receive native ETH
  receive() external payable { }

  /// @notice Fallback to receive native ETH
  fallback() external payable { }

}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";

contract SignatureVerifier is Ownable {
  mapping(address => bool) public approvedTeam;

  constructor() {
    approvedTeam[msg.sender] = true;
  }

  /// @notice Approve or revoke a team member for signature verification.
  /// @param _member The address of the team member to update.
  /// @param _approval True to approve the member; false to revoke approval.
  function modifyTeam(address _member, bool _approval) public onlyOwner {
    approvedTeam[_member] = _approval;
  }

  /// @notice Checks whether a signature over a given hash was made by an approved team member.
  /// @param _hash   The hash of the signed message.
  /// @param _signature The signature bytes.
  /// @return True if the recovered signer is in the approved team; otherwise false.
  function verifySignature(bytes32 _hash, bytes memory _signature) public view returns (bool) {
    address signer = ECDSA.recover(_hash, _signature);
    return approvedTeam[signer];
  }
}

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity 0.8.25;

interface ICvxDelegateRegistry {
  function setDelegate(bytes32 id, address delegate) external;

  function clearDelegate(bytes32 id) external;

  function delegation(address account, bytes32 id) external view returns (address);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

interface ICvxLocker {
  struct LockedBalance {
    uint112 amount;
    uint112 boosted;
    uint32 unlockTime;
  }
  struct EarnedData {
    address token;
    uint256 amount;
  }

  struct Balances {
    uint112 locked;
    uint112 boosted;
    uint32 nextUnlockIndex;
  }

  function lock(
    address _account,
    uint256 _amount,
    uint256 _spendRatio
  ) external;

  function userLocks(address _user, uint256 index) external view returns (LockedBalance memory);
  function balances(address _user) external view returns (Balances memory);

  function lockedBalances(address _user)
  external
  view
  returns (
    uint256 total,
    uint256 unlockable,
    uint256 locked,
    LockedBalance[] memory lockData
  );

  function withdrawExpiredLocksTo(address recipient) external;
  function processExpiredLocks(bool _relock) external;

  function claimableRewards(address _account)
  external
  view
  returns (EarnedData[] memory userRewards);

  function getReward(address _account, bool _stake) external;

  function lockedBalanceOf(address _user) external view returns (uint256 amount);
  function balanceOf(address _user) external view returns (uint256 amount);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

interface IDeposit {
  function balanceOf(address account) external view returns (uint256);
  function previewRedeem(uint256 amount) external view returns (uint256);
  function previewWithdraw(uint256 amount) external view returns (uint256);
  function approve(address spender, uint256 amount) external returns (bool);
  function deposit(uint256 amount, address receiver) external returns (uint256);
  function withdraw(uint256 amount, address receiver, address owner) external returns (uint256);
  function redeem(uint256 amount, address receiver, address owner) external returns (uint256);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

interface IFeeSplitter {
	function requestRewards() external returns (uint256);
	function distribute(address token, uint256 amount) external;
}

// SPDX-License-Identifier: LGPL-3.0-only
pragma solidity 0.8.25;

interface IRegistryDelegate {
  function setRegistry(address registry) external;
  function setToExpire() external;
  struct Registry {
    uint256 start;      // when first registering, there is a delay until the next vlCVX voting epoch starts
    address to;         // forward rewards to alternate address OR 0x0 address for OPT OUT of rewards
    uint256 expiration; // when ending an active registration, expiration is set to the next vlCVX voting epoch
                        // an active registration cannot be changed until after it is expired (one vote round delay when changing active registration)
  }

  function registry(address from) external view returns (Registry memory);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

interface IVoteMarket {

  function claim(
    address account,
    address reward,
    uint256 claimable,
    bytes32[] calldata proof
  ) external returns (uint256 amount);

}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.25;

interface IVotiumMultiMerkleStash {
  struct claimParam {
    address token;
    uint256 index;
    uint256 amount;
    bytes32[] merkleProof;
  }

  function claim(
    address token,
    uint256 index,
    address account,
    uint256 amount,
    bytes32[] calldata merkleProof
  ) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.25;

interface IWETH {
  function deposit() external payable;
}

// SPDX-License-Identifier: GPL-3.0-or-later
import "@openzeppelin/contracts/interfaces/IERC20Metadata.sol";
import '@uniswap/v2-core/contracts/interfaces/IUniswapV2Pair.sol';

pragma solidity >=0.6.0;

// helper methods for interacting with ERC20 tokens and sending ETH that do not consistently return true/false
library ERC20Helpers {

  function safeApprove(
    address token,
    address to,
    uint256 value
  ) internal {
    // bytes4(keccak256(bytes('approve(address,uint256)')));
    (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x095ea7b3, to, value));
    require(
      success && (data.length == 0 || abi.decode(data, (bool))),
      'ERC20Helpers::safeApprove: approve failed'
    );
  }

  function safeTransfer(
    address token,
    address to,
    uint256 value
  ) internal {
    // bytes4(keccak256(bytes('transfer(address,uint256)')));
    (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0xa9059cbb, to, value));
    require(
      success && (data.length == 0 || abi.decode(data, (bool))),
      'ERC20Helpers::safeTransfer: transfer failed'
    );
  }

  function safeTransferFrom(
    address token,
    address from,
    address to,
    uint256 value
  ) internal {
    // bytes4(keccak256(bytes('transferFrom(address,address,uint256)')));
    (bool success, bytes memory data) = token.call(abi.encodeWithSelector(0x23b872dd, from, to, value));
    require(
      success && (data.length == 0 || abi.decode(data, (bool))),
      'ERC20Helpers::transferFrom: transferFrom failed'
    );
  }

  function safeTransferETH(address to, uint256 value) internal {
    (bool success, ) = to.call{value: value}(new bytes(0));
    require(success, 'ERC20Helpers::safeTransferETH: ETH transfer failed');
  }

}