Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/utils/Strings.sol";
import "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import "./OilXEnumDeclaration.sol";
import "./WithdrawContracts.sol";
import "./NftMinter.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol"; //OIA-10

abstract contract ChainlinkOracle {
  function latestAnswer() public view virtual returns (int256);

  function latestRoundData()
    public
    view
    virtual
    returns (
      uint80 roundId,
      int256 answer,
      uint256 startedAt,
      uint256 updatedAt,
      uint80 answeredInRound
    );
}

/* 
* @title OilXCoin NFT Sales Contract
* @notice This contract allows users to purchase OilXCoin NFTs by paying Ether. 
*         Each NFT represents a specified amount of OilXCoin tokens.
*/
contract SalesContractNft is WithdrawContractsOwnable, ReentrancyGuard {
  NftMinter nftMinter;

  address internal _oilXCoinContractAddress;
  address internal _salesWalletAddress;

  uint256 internal _exchangeRatePerOxcInUsd;
  uint256 internal _maxRateETH2USD;
  uint256 internal _minRateETH2USD;
  uint256 public totalOrders;

  uint256 private _exchangeRateETHUSDfixed;
  bool private _useexchangeRateETHUSDfixed; // Chainlink not exists on testnet
  address internal _addressChainlinkOracle;

  bool privateSaleOnly = true;

  event Purchase(
    address indexed to,
    OilXNftTokenType nftType,
    uint32 quantity,
    uint32 amountOXC,
    uint256 orderId,
    uint256 orderPos
  );

  /**
   * for ABI decode event in webshop
   */
  event MintOilXNFT(
    address indexed to,
    uint256 indexed tokenId,
    OilXNftTokenType tokenType,
    uint256 indexed amountOXC
  );

  /**
   * for ABI decode event in webshop
   */
  event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

  // store order information
  struct Basket {
    OilXNftTokenType purchaseNFTtype;
    uint32 quantity;
    uint32 amountOXC;
  }

  struct Order {
    address buyer;
    uint256 timestamp;
    uint256 exchangeRate;
    uint256 totalAmount;
    uint256 numPositions;
    mapping(uint256 => Basket) positions;
  }

  mapping(uint256 => Order) public orderbook;

  /*
  * @notice Constructor for the SalesContractNft contract
  * @param _addressNftMinter The address of the NftMinter contract
  * @dev NftMinter contract stores mint date for each NFT for vesting
  */
  constructor(address _addressNftMinter, address _salesWallet, address _owner)
    WithdrawContractsOwnable(_owner)
  {
    require(_addressNftMinter != address(0), "nft minter address not set");
    require(_salesWallet != address(0), "sales wallet address not set");
    require(_owner != address(0), "owner address not set");

    _salesWalletAddress = _salesWallet; //receives ETH from sales
    nftMinter = NftMinter(_addressNftMinter);

    // Chainlink Oracle address for ETH/USD rate
    _addressChainlinkOracle = 0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419;
    _useexchangeRateETHUSDfixed = false;
    _exchangeRateETHUSDfixed = 1750 * 10 ** decimals(); // price approx at 22.04.2025
    _maxRateETH2USD = 3000 * 10 ** decimals(); // 1 ETH = 3000 US$
    _minRateETH2USD = 1500 * 10 ** decimals();
    _exchangeRatePerOxcInUsd = 1 * 10 ** decimals(); // 1 OXC = 1 US$
  }

  function decimals() public pure returns (uint8) {
    return 18;
  }

  function getRateETH2USD() public view returns (uint256) {
    // ETH 2 USD rate - on testnet chainlink not exists
    uint256 rate;
    if (_useexchangeRateETHUSDfixed) {
      rate = uint256(_exchangeRateETHUSDfixed);
    } else {
      ChainlinkOracle oracle = ChainlinkOracle(_addressChainlinkOracle);
      (, int256 answer,, uint256 updatedAt,) = oracle.latestRoundData();
      require(block.timestamp - updatedAt <= 3600, "Stale price"); //OIA-02
      rate = uint256(answer);
      rate = rate * 10 ** (decimals() - 8); // convert from 10**8 to 10**18
    }
    require(rate > 0, "ETH2USD rate invalid");
    return rate;
  }

  function getRatePerOxcInUsd() public view returns (uint256) {
    return (_exchangeRatePerOxcInUsd);
  }

  function setExchangeRateOilXCoin(uint256 _newrate) public onlyOwner {
    require(_newrate > 0, "exchange rate USD / OilXCoin OXC must be greater than 0"); //OIA-03
    _exchangeRatePerOxcInUsd = _newrate;
  }

  // @dev tolerance for ETH2USD rate
  function setExchangeRateETHmin(uint256 minValue) public onlyOwner {
    _minRateETH2USD = minValue;
  }

  // @dev fallback for manual exchange rate
  function setexchangeRateETHUSDfixed(uint256 value) public onlyOwner {
    _exchangeRateETHUSDfixed = value;
  }

  // @dev fallback for manual exchange rate
  function setuseexchangeRateETHUSDfixed(bool value) public onlyOwner {
    _useexchangeRateETHUSDfixed = value;
  }

  // @dev tolerance for ETH2USD rate
  function setExchangeRateETHmax(uint256 maxValue) public onlyOwner {
    _maxRateETH2USD = maxValue;
  }

  function setChainLinkOracle(address address_) public onlyOwner {
    // depends on chain, can be deactivated by setting to address(0)
    _addressChainlinkOracle = address_;
  }

  /*
  * @notice read order history from orderbook
  * @param orderId The ID of the order
  * @return buyer The address of the buyer
  * @return timestamp The timestamp of the order
  * @return exchangeRate The exchange rate of the order
  * @return totalAmount The total amount of the order
    returns (
      address buyer,
      uint256 timestamp,
      uint256 exchangeRate,
      uint256 totalAmount,
      uint256 numPositions
    )
  {
    buyer = orderbook[orderId].buyer;
    timestamp = orderbook[orderId].timestamp;
    exchangeRate = orderbook[orderId].exchangeRate;
    totalAmount = orderbook[orderId].totalAmount;
    numPositions = orderbook[orderId].numPositions;
  }

  /*
  * @notice read order basket from orderbook
  * @param orderId The ID of the order
  * @return basket The basket of the order
  */
  function getOrderBasket(uint256 orderId) public view returns (Basket[] memory) {
    Basket[] memory basket = new Basket[](orderbook[orderId].numPositions);

    for (uint256 i = 0; i < orderbook[orderId].numPositions; i++) {
      basket[i] = orderbook[orderId].positions[i];
    }
    return basket;
  }

  /*
  * @notice get the contract address
  * @return _oilXCoinContractAddress The address of the OilXCoin NFT contract
  */
  function getContractAddress() public view returns (address) {
    return _oilXCoinContractAddress;
  }

  /*
  * @notice set the sales wallet address
  * @param salesWallet The address of the sales wallet
  */
  function setSalesWalletAddress(address salesWallet) public onlyOwner {
    require(salesWallet != address(0), "zero address not allowed");
    _salesWalletAddress = salesWallet;
  }

  function getSalesWalletAddress() public view returns (address) {
    return _salesWalletAddress;
  }

  /// @dev purchase NFTs with ETH directly
  function purchase(address to, Basket[] memory basket) public payable nonReentrant {
    require(!privateSaleOnly, "Error: private sale only");
    uint256 rateETHUSD = getRateETH2USD();
    uint256 rateOxcUsd = getRatePerOxcInUsd();

    // ETH / USD out of range?
    require(rateETHUSD >= _minRateETH2USD, "Error: exchange rate ETH/USD below minimum");
    require(rateETHUSD <= _maxRateETH2USD, "Error: exchange rate ETH/USD above maximum");

    // calculate total amount in USD, basis Salesrate for OXC
    uint256 remainingFunds = (msg.value * rateETHUSD) / 10 ** decimals();

    // Order Head
    orderbook[totalOrders].buyer = msg.sender;
    orderbook[totalOrders].timestamp = block.timestamp;
    orderbook[totalOrders].exchangeRate = rateETHUSD;

    for (uint8 i = 0; i < basket.length; i++) {
      /* save basket information */
      Basket memory pos = Basket(basket[i].purchaseNFTtype, basket[i].quantity, basket[i].amountOXC);
      orderbook[totalOrders].positions[orderbook[totalOrders].numPositions] = pos;
      orderbook[totalOrders].numPositions++;

      emit Purchase(
        to,
        basket[i].purchaseNFTtype,
        basket[i].quantity,
        basket[i].amountOXC,
        totalOrders,
        orderbook[totalOrders].numPositions - 1
      );

      /* mint NFTs for each basket position */
      for (uint8 amount = 0; amount < basket[i].quantity; amount++) {
        /* amountOXC sent without 18 decimals, but rateOXCUSD has 18 decimals */
        uint256 buyOilXCoinAmount = basket[i].amountOXC * rateOxcUsd;
        require(remainingFunds >= buyOilXCoinAmount, "Error: not enough funds sent"); // funds in
          // US$!
        orderbook[totalOrders].totalAmount += buyOilXCoinAmount; // Order Total Amount in US$
        // use NFT minter contract to store mint date for vesting
        nftMinter.safeMintTs(to, basket[i].purchaseNFTtype, basket[i].amountOXC);
        remainingFunds -= buyOilXCoinAmount;
      }
    }

    totalOrders++;
    // rate has 18 decimals, add decimals again!
    remainingFunds = (remainingFunds * 10 ** decimals()) / rateETHUSD;
    // withdraw to sales wallet
    payable(getSalesWalletAddress()).transfer(address(this).balance - remainingFunds);
    // withdraw remaining funds
    (bool success,) = msg.sender.call{value: remainingFunds}("");
    require(success, "Failed to withdraw remaining funds");
  }

  /*
  * @notice Defines if sales are allowed directly or require a signed message
  * @param value The value to set private sale only
  */
  function setPrivateSaleOnly(bool value) public onlyOwner {
    privateSaleOnly = value;
  }
}

/*
* @title SalesContractNftPurchaseWithOffer
* @notice This contract allows to purchase through signed offers from the webshop
* @dev private sale only with signed offers*/
contract SalesContractNftPurchaseWithOffer is SalesContractNft {
  using ECDSA for bytes32;

  bytes constant prefix = "\x19Ethereum Signed Message:\n";

  address SalesSigner;
  mapping(bytes => uint256) public signatureUsed; //list of used signatures

  event LogHash(bytes32 indexed msg);
  event LogMessage(bytes msg);
  event OfferTotalAmount(uint256 totalOilX, uint256 sendETH, uint256 estETH);
  event NewSalesSigner(address indexed oldSigner, address indexed newSigner);

  event PurchaseOffer(
    address indexed _to,
    OilXNftTokenType nftType,
    uint32 quantity,
    uint32 amountOilXCoin,
    uint256 orderID,
    uint256 orderPos,
    uint256 totalAmount,
    string signer
  );

  /**
   * @notice Error indicating that a signature has already been used
   * @param signature The signature that was used
   * @param timestamp The timestamp when the signature was used
   */
  error SignatureAlreadyUsed(bytes signature, uint256 timestamp);

  /**
   * @notice Constructor for the SalesContractNftPurchaseWithOffer contract
   * @param _addressOilXNft The address of the OilXNft contract
   * @param _salesWallet The address of the sales wallet
   * @param _owner The address of the owner of the contract
   */
  constructor(address _addressOilXNft, address _salesWallet, address _owner)
    SalesContractNft(_addressOilXNft, _salesWallet, _owner)
  {}

  /**
   * @notice Sets the sales signer address, only one signer is possible
   * @param newSigner The new sales signer address
   */
  function setSalesSigner(address newSigner) public onlyOwner {
    require(newSigner != address(0), "zero address not allowed");
    emit NewSalesSigner(SalesSigner, newSigner);
    SalesSigner = newSigner;
  }

  /**
   * @notice Creates a message for the sales signer
   * @param to The address of the buyer
   * @param totalAmount The total amount of the sale
   * @param basket The basket of the sale
   * @param validUntilBlockTimeStamp The valid until block time stamp
   * @param confirmLowPrice Whether to confirm a lower price than the estimated price
   * @return The message for the sales signer to sign
   */
  function createSignerMessage(
    address to,
    uint256 totalAmount,
    Basket[] memory basket,
    uint256 validUntilBlockTimeStamp,
    bool confirmLowPrice
  ) public view returns (bytes memory) {
    uint256 estTotal;

    //* OIA-04 hashing strings removed *//
    bytes memory message;
    for (uint256 i = 0; i < basket.length; i++) {
      message = abi.encode(
        message, uint256(basket[i].purchaseNFTtype), basket[i].quantity, basket[i].amountOXC
      );

      estTotal += basket[i].quantity * basket[i].amountOXC;
    }

    message =
      abi.encode(to, totalAmount, message, validUntilBlockTimeStamp, block.chainid, address(this));

    /* validate and confirm - totalAmount below estimated price */
    /**
     * calculcation:
     *  estTotal = TotalOXC amount without decimals
     *  estTotal = estTotal * getRatePerOxcInUsd() --> price for OXC in USD$ with 18 decimals
     *  estTotal = estTotal * 10 ** decimals() / getRateETH2USD() --> price in ETH with 18 decimals
     *  estTotal = estTotal * 97 / 100; // 3% tolerance
     */
    uint256 exchangeRate = getRateETH2USD();
    require(exchangeRate >= _minRateETH2USD, "Error: exchange rate ETH/USD below minimum");
    require(exchangeRate <= _maxRateETH2USD, "Error: exchange rate ETH/USD above maximum");
    estTotal = estTotal * getRatePerOxcInUsd() * 10 ** decimals() / exchangeRate; //OIA-16
    estTotal = estTotal * 97 / 100; // 3% tolerance

    if (estTotal > totalAmount && !confirmLowPrice) revert("totalAmount out of tolerance");
    return message;
  }

  function verifySignature(bytes memory message, bytes memory signature) public returns (bool) {
    address signer = SalesSigner; // public key/wallet address
    bytes32 hash = keccak256(abi.encodePacked(prefix, Strings.toString(message.length), message));
    emit LogHash(hash);
    address recoveredSigner = hash.recover(signature);
    return signer == recoveredSigner;
  }

  function offerValid(
    address to,
    uint256 totalAmount,
    Basket[] memory basket,
    uint256 validUntilBlockTimeStamp,
    bytes memory signature
  ) internal returns (bool) {
    bytes memory unsignedMsg =
      createSignerMessage(to, totalAmount, basket, validUntilBlockTimeStamp, false); //OIA-06
    emit LogMessage(unsignedMsg);

    return verifySignature(unsignedMsg, signature);
  }

  /**
   * @notice Purchase NFTs with a signed offer
   * @param to The address of the buyer
   * @param totalAmount The total amount of the sale
   * @param basket The basket of the sale
   * @param validUntilBlockTimeStamp The valid until block time stamp
   * @param signature The signature of the sales signer for createSignerMessage
   */
  function purchaseWithOffer(
    address to,
    uint256 totalAmount,
    Basket[] memory basket,
    uint256 validUntilBlockTimeStamp,
    bytes memory signature
  ) public payable nonReentrant {
    /* offer still valid? */
    require(
      offerValid(to, totalAmount, basket, validUntilBlockTimeStamp, signature),
      "Signature check failed."
    );
    require(validUntilBlockTimeStamp > block.timestamp, "Offer expired.");
    if (signatureUsed[signature] != 0) {
      //OIA-05
      /* signatures cannot be reused to prevent duplicate execution */
      revert SignatureAlreadyUsed(signature, signatureUsed[signature]);
    }
    require(msg.value >= totalAmount, "not enough funds send."); // sell for fix price!

    // ETH / USD out of range?
    uint256 exchangeRate = getRateETH2USD();
    require(exchangeRate >= _minRateETH2USD, "Error: exchange rate ETH/USD below minimum");
    require(exchangeRate <= _maxRateETH2USD, "Error: exchange rate ETH/USD above maximum");

    // Order Head
    orderbook[totalOrders].buyer = msg.sender;
    orderbook[totalOrders].timestamp = block.timestamp;
    orderbook[totalOrders].exchangeRate = exchangeRate;
    signatureUsed[signature] = block.timestamp; //OIA-05

    uint256 _rateOxcUsd = getRatePerOxcInUsd();
    for (uint256 i = 0; i < basket.length; i++) {
      /* save basket information */
      Basket memory pos = Basket(basket[i].purchaseNFTtype, basket[i].quantity, basket[i].amountOXC);
      orderbook[totalOrders].positions[orderbook[totalOrders].numPositions] = pos;
      orderbook[totalOrders].numPositions++;

      emit Purchase(
        to,
        basket[i].purchaseNFTtype,
        basket[i].quantity,
        basket[i].amountOXC,
        totalOrders,
        orderbook[totalOrders].numPositions - 1
      );

      for (uint256 amount = 0; amount < basket[i].quantity; amount++) {
        // update orderbook
        orderbook[totalOrders].totalAmount += (basket[i].amountOXC * _rateOxcUsd); // Order
          // Total OilXCoin OXC Amount in US$

        /* mint NFTs for each basket position */
        nftMinter.safeMintTs(to, basket[i].purchaseNFTtype, basket[i].amountOXC);
      }
    }

    /**
     * calculation with off-chain exchange rate
     *  orderbook[totalOrders].totalAmount = TotalOilXCoin OXC Amount in US$ with 18 decimals
     *  estimatedETH = orderbook[totalOrders].totalAmount * 10 ** decimals() / exchangeRate; //
     * Exchange
     *     // rate has 18 decimals
     */
    uint256 estimatedETH = orderbook[totalOrders].totalAmount * 10 ** decimals() / exchangeRate; // Exchange
      // rate has 18 decimals
    emit OfferTotalAmount(orderbook[totalOrders].totalAmount, totalAmount, estimatedETH);

    totalOrders++; //OIA-10
    payable(getSalesWalletAddress()).transfer(totalAmount); // withdrawal to sales wallet

    if (msg.value - totalAmount > 0) payable(msg.sender).transfer(msg.value - totalAmount); // send
      // the rest back
  }

  function getValidToBlockTime(uint256 offset) public view returns (uint256) {
    return block.timestamp + offset;
  }

  function getStringLength(string memory string_) private pure returns (uint256) {
    return bytes(string_).length;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Strings.sol)

pragma solidity ^0.8.20;

import {Math} from "./math/Math.sol";
import {SignedMath} from "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant HEX_DIGITS = "0123456789abcdef";
    uint8 private constant ADDRESS_LENGTH = 20;

    /**
     * @dev The `value` string doesn't fit in the specified `length`.
     */
    error StringsInsufficientHexLength(uint256 value, uint256 length);

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), HEX_DIGITS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toStringSigned(int256 value) internal pure returns (string memory) {
        return string.concat(value < 0 ? "-" : "", toString(SignedMath.abs(value)));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        uint256 localValue = value;
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = HEX_DIGITS[localValue & 0xf];
            localValue >>= 4;
        }
        if (localValue != 0) {
            revert StringsInsufficientHexLength(value, length);
        }
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal
     * representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return bytes(a).length == bytes(b).length && keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.20;

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS
    }

    /**
     * @dev The signature derives the `address(0)`.
     */
    error ECDSAInvalidSignature();

    /**
     * @dev The signature has an invalid length.
     */
    error ECDSAInvalidSignatureLength(uint256 length);

    /**
     * @dev The signature has an S value that is in the upper half order.
     */
    error ECDSAInvalidSignatureS(bytes32 s);

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with `signature` or an error. This will not
     * return address(0) without also returning an error description. Errors are documented using an enum (error type)
     * and a bytes32 providing additional information about the error.
     *
     * If no error is returned, then the address can be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError, bytes32) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength, bytes32(signature.length));
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, signature);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError, bytes32) {
        unchecked {
            bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
            // We do not check for an overflow here since the shift operation results in 0 or 1.
            uint8 v = uint8((uint256(vs) >> 255) + 27);
            return tryRecover(hash, v, r, s);
        }
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, r, vs);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address, RecoverError, bytes32) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS, s);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature, bytes32(0));
        }

        return (signer, RecoverError.NoError, bytes32(0));
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, v, r, s);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Optionally reverts with the corresponding custom error according to the `error` argument provided.
     */
    function _throwError(RecoverError error, bytes32 errorArg) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert ECDSAInvalidSignature();
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert ECDSAInvalidSignatureLength(uint256(errorArg));
        } else if (error == RecoverError.InvalidSignatureS) {
            revert ECDSAInvalidSignatureS(errorArg);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

enum OilXNftTokenType {
  DIAMOND,
  PLATINUM,
  GOLD,
  SILVER,
  BLACK
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/interfaces/IERC20.sol";
import "@openzeppelin/contracts/interfaces/IERC721.sol";
import "@openzeppelin/contracts/interfaces/IERC1155.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
/*
* @title Contract to Recover Tokens or ETH sent by mistake to the contract
* @author OilXCoin.io Dev Team
* @notice Release Tests
*/

contract WithdrawContractsOwnable is Ownable {
  using SafeERC20 for IERC20;

  constructor(address _initialOwner) Ownable(_initialOwner) {}

  event WithdrawERC20(address indexed tokenAddress, address indexed to, uint256 amount);
  event WithdrawERC721(address indexed tokenAddress, address indexed to, uint256 tokenId);
  event WithdrawERC1155(
    address indexed tokenAddress, address indexed to, uint256 tokenId, uint256 amount
  );
  event WithdrawNativeToken(address indexed to, uint256 amount);

  /**
   * @dev Withdraw all ERC20 tokens from the contract
   * @param _tokenAddress Address of the ERC20 contract
   * @param _to Address to send the tokens to
   */
  function withdrawERC20(address _tokenAddress, address _to) public virtual onlyOwner {
    IERC20 token = IERC20(_tokenAddress);
    uint256 balance = token.balanceOf(address(this));
    require(balance > 0, "no tokens to withdraw");
    emit WithdrawERC20(_tokenAddress, _to, balance);
    token.safeTransfer(_to, balance); //WCO-01
  }

  /**
   * @dev Withdraw all ERC721 tokens from the contract
   * @param _tokenAddress Address of the ERC721 contract
   * @param _to Address to send the tokens to
   */
  function withdrawERC721(address _tokenAddress, address _to, uint256 _tokenId) public onlyOwner {
    emit WithdrawERC721(_tokenAddress, _to, _tokenId);
    IERC721(_tokenAddress).safeTransferFrom(address(this), _to, _tokenId);
  }

  /**
   * @dev Withdraw all ERC1155 tokens from the contract
   * @param _tokenAddress Address of the ERC1155 contract
   * @param _to Address to send the tokens to
   */
  function withdrawERC1155(address _tokenAddress, address _to, uint256 _tokenId) public onlyOwner {
    IERC1155 token = IERC1155(_tokenAddress);
    uint256 balance = token.balanceOf(address(this), _tokenId);
    emit WithdrawERC1155(_tokenAddress, _to, _tokenId, balance);
    token.safeTransferFrom(address(this), _to, _tokenId, balance, "");
  }

  /**
   * @dev Withdraw all ETH from the contract
   */
  function withdrawNativeToken(address payable _to) public onlyOwner {
    uint256 balance = address(this).balance;
    emit WithdrawNativeToken(_to, balance);
    (bool success,) = _to.call{value: balance}(""); //WCO-01 OXO-12
    require(success, "Failed to withdraw Ether"); //OXO-12
  }
}

/*
* @title Contract to Recover Tokens or ETH sent by mistake to the contract
* @author OilXCoin.io Dev Team
* @notice Release Tests
*/
contract WithdrawContractsAccessControl is AccessControl {
  using SafeERC20 for IERC20;

  bytes32 public constant WITHDRAWCONTRACT_ROLE = keccak256("WITHDRAWCONTRACT_ROLE");

  constructor(address _initialOwner) {
    _grantRole(WITHDRAWCONTRACT_ROLE, _initialOwner);
  }

  event WithdrawERC20(address indexed tokenAddress, address indexed to, uint256 amount);
  event WithdrawERC721(address indexed tokenAddress, address indexed to, uint256 tokenId);
  event WithdrawERC1155(
    address indexed tokenAddress, address indexed to, uint256 tokenId, uint256 amount
  );
  event WithdrawNativeToken(address indexed to, uint256 amount);

  /**
   * @dev Withdraw all ERC20 tokens from the contract
   * @param _tokenAddress Address of the ERC20 contract
   * @param _to Address to send the tokens to
   */
  function withdrawERC20(address _tokenAddress, address _to)
    public
    virtual
    onlyRole(WITHDRAWCONTRACT_ROLE)
  {
    IERC20 token = IERC20(_tokenAddress);
    uint256 balance = token.balanceOf(address(this));
    require(balance > 0, "no tokens to withdraw");
    emit WithdrawERC20(_tokenAddress, _to, balance);
    token.safeTransfer(_to, balance); //WCO-01
  }

  /**
   * @dev Withdraw all ERC721 tokens from the contract
   * @param _tokenAddress Address of the ERC721 contract
   * @param _to Address to send the tokens to
   */
  function withdrawERC721(address _tokenAddress, address _to, uint256 _tokenId)
    public
    onlyRole(WITHDRAWCONTRACT_ROLE)
  {
    emit WithdrawERC721(_tokenAddress, _to, _tokenId);
    IERC721(_tokenAddress).safeTransferFrom(address(this), _to, _tokenId);
  }

  /**
   * @dev Withdraw all ERC1155 tokens from the contract
   * @param _tokenAddress Address of the ERC1155 contract
   * @param _to Address to send the tokens to
   */
  function withdrawERC1155(address _tokenAddress, address _to, uint256 _tokenId)
    public
    onlyRole(WITHDRAWCONTRACT_ROLE)
  {
    IERC1155 token = IERC1155(_tokenAddress);
    uint256 balance = token.balanceOf(address(this), _tokenId);
    emit WithdrawERC1155(_tokenAddress, _to, _tokenId, balance);
    token.safeTransferFrom(address(this), _to, _tokenId, balance, "");
  }

  /**
   * @dev Withdraw all native Token from the contract
   */
  function withdrawNativeToken(address payable _to) public onlyRole(WITHDRAWCONTRACT_ROLE) {
    uint256 balance = address(this).balance;
    emit WithdrawNativeToken(_to, balance);
    // _to.transfer(balance);
    (bool success,) = _to.call{value: balance}(""); //WCO-01 OXO-12
    require(success, "Failed to withdraw Ether"); //OXO-12
  }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./IOilXCoinNFT.sol";
import "./WithdrawContracts.sol";

interface INftOXC is IOilXCoinNFT {
  function ownerOf(uint256 tokenId) external view returns (address owner);
  function totalSupply() external view returns (uint256);
  function balanceOf(address owner) external view returns (uint256);
  function tokenOfOwnerByIndex(address owner, uint256 index) external view returns (uint256);
  function safeMint(address to) external;
}

/**
 * @title NftMinter
 * @notice Contract for minting NFTs with timestamp tracking
 * @dev grant NFT minter role to this contract and remove minter role form old salescontract and
 * batchminter, grant this MINTER_ROLE to new salescontract
 */
contract NftMinter is WithdrawContractsAccessControl {
  bytes32 public constant MINTER_ROLE = keccak256("MINTER_ROLE");

  INftOXC oilXNftContract;
  bool public allowBatchMint;

  mapping(uint256 => uint256) public NftMintTs;

  event MintOilXNFT(
    address indexed to,
    uint256 indexed tokenId,
    OilXNftTokenType tokenType,
    uint256 indexed amountOilX
  );

  event MintOilXCoinNftTs(
    address indexed to, uint256 indexed tokenId, uint256 indexed amountOilXCoin, uint256 timestamp
  );

  /**
   * for ABI decode event from NFT
   */
  event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

  struct Basket {
    OilXNftTokenType purchaseNFTtype;
    uint32 quantity;
    uint32 amountOilX;
  }

  /**
   * @notice Emitted when batch minting is enabled or disabled
   * @param enabled The new state of batch minting
   */
  event BatchMintEnabled(bool enabled);

  /**
   * @notice Emitted when NFT contract address is updated
   * @param oldAddress Previous NFT contract address
   * @param newAddress New NFT contract address
   */
  event NFTContractAddressUpdated(address indexed oldAddress, address indexed newAddress);

  /**
   * @notice Emitted when NFT is minted with timestamp
   * @param to Address receiving the NFT
   * @param tokenId ID of minted NFT
   * @param timestamp Block timestamp when NFT was minted
   */
  event NFTMintedWithTimestamp(address indexed to, uint256 indexed tokenId, uint256 timestamp);

  constructor(address _addressOilXNft, address _admin, address _minter)
    WithdrawContractsAccessControl(_admin)
  {
    _grantRole(DEFAULT_ADMIN_ROLE, _admin);
    _grantRole(MINTER_ROLE, _minter);
    oilXNftContract = INftOXC(_addressOilXNft);
    allowBatchMint = true;
  }

  function getNFTAddress() public view returns (address) {
    return address(oilXNftContract);
  }

  function setOnOff(bool _allowBatchMint) public onlyRole(DEFAULT_ADMIN_ROLE) {
    allowBatchMint = _allowBatchMint;
  }

  /**
   * @notice Mints multiple NFTs in a single transaction
   * @param to The address that will own the minted NFTs
   * @param basket An array of Basket structs containing the NFT type and quantity
   * @dev Requires batchmint to be enabled and valid address
   */
  function batchmint(address to, Basket[] memory basket) public onlyRole(MINTER_ROLE) {
    require(allowBatchMint, "Error: batchmint is off");
    require(to != address(0), "Error: address is zero");

    for (uint8 i = 0; i < basket.length; i++) {
      /* mint NFTs for each basket position */
      for (uint8 amount = 0; amount < basket[i].quantity; amount++) {
        safeMintTs(to, basket[i].purchaseNFTtype, basket[i].amountOilX);
      }
    }
  }

  /**
   * @notice Mints a new NFT with timestamp tracking
   * @param to The address that will own the minted NFT
   * @param tokenType The type of NFT to mint (PLATINUM, GOLD, SILVER, BLACK)
   * @param oilXTokenClaimable The amount of OILX tokens that can be claimed with this NFT
   * @dev Mints NFT via nftContract.safeMint() and records timestamp
   * @dev Emits MintOilXCoinNftTs event with token details and timestamp
   */
  function safeMintTs(address to, OilXNftTokenType tokenType, uint256 oilXTokenClaimable)
    public
    onlyRole(MINTER_ROLE)
  {
    uint256 tokenId = oilXNftContract.totalSupply();
    oilXNftContract.safeMint(to, tokenType, oilXTokenClaimable);
    uint256 newSupply = oilXNftContract.totalSupply();
    require(newSupply == tokenId + 1, "nothing minted");
    require(to == oilXNftContract.ownerOf(tokenId), "token belongs to other address");
    // uint256 balance = nftEnumerable.balanceOf(to);
    // require(balance > 0, "Nothing minted");
    // uint256 tokenId = nftEnumerable.tokenOfOwnerByIndex(to, balance - 1);
    // require(totalSupply == tokenId, "Token ID mismatch");

    NftMintTs[tokenId] = block.timestamp;
    emit MintOilXCoinNftTs(to, tokenId, oilXTokenClaimable, block.timestamp);
  }

  /**
   * @notice Retrieves the timestamp when an NFT was minted
   * @param tokenId The ID of the NFT to check
   * @return The timestamp when the NFT was minted
   * @dev Requires the NFT to exist and be minted
   */
  function getNftMintTs(uint256 tokenId) public view returns (uint256) {
    require(oilXNftContract.ownerOf(tokenId) != address(0), "token not minted");
    return NftMintTs[tokenId];
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    /**
     * @dev Muldiv operation overflow.
     */
    error MathOverflowedMulDiv();

    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            return a / b;
        }

        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0 = x * y; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            if (denominator <= prod1) {
                revert MathOverflowedMulDiv();
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC721} from "../token/ERC721/IERC721.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC1155.sol)

pragma solidity ^0.8.20;

import {IERC1155} from "../token/ERC1155/IERC1155.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "../utils/Context.sol";
import {ERC165} from "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "./OilXEnumDeclaration.sol";

/**
 * @dev OilXCoin Interfaces for contract interactions
 */

/*
* @title OilXNft
* @author OilXCoin.io Dev Team
* @notice Interface for OilXNft
*/
interface IOilXCoinNFT {
  event OilXClaimed(uint256 indexed tokenId, uint256 amount);
  event ClaimedFeeIncreased(uint256 indexed tokenId, uint256 feeAmount);
  event RewardsBlackNFT(uint256 indexed tokenId, uint256 amount);
  event MintOilXNFT(
    address indexed to,
    uint256 indexed tokenId,
    OilXNftTokenType tokenType,
    uint256 indexed amountOilX
  );
  event AddressOilXCoinChanged(address indexed oldAddress, address indexed newAddress);
  event AddressFeeClaimerChanged(address indexed oldAddress, address indexed newAddress);
  event AddressNFTTokenClaimerChanged(address indexed oldAddress, address indexed newAddress);
  event RewardProgrammClosed();

  /**
   * @notice mint a new OilX NFT
   * @param to The address of the new NFT owner
   * @param tokenType The type of the NFT (PLATINUM, GOLD, SILVER, BLACK)
   * @param oilXTokenClaimable The amount of OILX tokens the NFT can claim
   */
  function safeMint(address to, OilXNftTokenType tokenType, uint256 oilXTokenClaimable) external;

  /**
   * @notice returns claimable OILX and resets to 0, for a given tokenId
   * @param tokenId ID of an OilXNFT
   * @return The amount of OILX which can be claimed
   */
  function resetClaimableOilX(uint256 tokenId) external returns (uint256);

  /**
   * @notice OilXCoin token contract can set the address of the token sale claimer contract
   * @param newAddress The address of the new token sale claimer contract
   */
  function setAddressTokenSaleClaimer(address newAddress) external;

  function increaseOilXRewards(uint256 tokenId, uint256 oilXAmount) external;
  function closeRewardProgram() external;

  /**
   * @notice increase amount of claimed ERC-20 fees for NFT. Function will be called by the fee
   * claiming contract
   * @param tokenId The ID of the NFT to increase the claimed fee amount
   * @param feeAmount The amount of ERC-20 fees to increase
   */
  function increaseClaimedOilXFee(uint256 tokenId, uint256 feeAmount) external;

  /**
   * @notice OilXCoin token contract can set the address of the fee claimer contract
   * @param newAddress The address of the new fee claimer contract
   */
  function setAddressFeeClaimer(address newAddress) external;

  /**
   * @notice set OilXCoin ERC-20 token contract address once
   * @param finalAddress The address of the OilXCoin ERC-20 token contract
   */
  function setAddressOilXCoin(address finalAddress) external;

  function updateMetaData(address newAddr) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (token/ERC1155/IERC1155.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC1155 compliant contract, as defined in the
 * https://eips.ethereum.org/EIPS/eip-1155[EIP].
 */
interface IERC1155 is IERC165 {
    /**
     * @dev Emitted when `value` amount of tokens of type `id` are transferred from `from` to `to` by `operator`.
     */
    event TransferSingle(address indexed operator, address indexed from, address indexed to, uint256 id, uint256 value);

    /**
     * @dev Equivalent to multiple {TransferSingle} events, where `operator`, `from` and `to` are the same for all
     * transfers.
     */
    event TransferBatch(
        address indexed operator,
        address indexed from,
        address indexed to,
        uint256[] ids,
        uint256[] values
    );

    /**
     * @dev Emitted when `account` grants or revokes permission to `operator` to transfer their tokens, according to
     * `approved`.
     */
    event ApprovalForAll(address indexed account, address indexed operator, bool approved);

    /**
     * @dev Emitted when the URI for token type `id` changes to `value`, if it is a non-programmatic URI.
     *
     * If an {URI} event was emitted for `id`, the standard
     * https://eips.ethereum.org/EIPS/eip-1155#metadata-extensions[guarantees] that `value` will equal the value
     * returned by {IERC1155MetadataURI-uri}.
     */
    event URI(string value, uint256 indexed id);

    /**
     * @dev Returns the value of tokens of token type `id` owned by `account`.
     *
     * Requirements:
     *
     * - `account` cannot be the zero address.
     */
    function balanceOf(address account, uint256 id) external view returns (uint256);

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {balanceOf}.
     *
     * Requirements:
     *
     * - `accounts` and `ids` must have the same length.
     */
    function balanceOfBatch(
        address[] calldata accounts,
        uint256[] calldata ids
    ) external view returns (uint256[] memory);

    /**
     * @dev Grants or revokes permission to `operator` to transfer the caller's tokens, according to `approved`,
     *
     * Emits an {ApprovalForAll} event.
     *
     * Requirements:
     *
     * - `operator` cannot be the caller.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns true if `operator` is approved to transfer ``account``'s tokens.
     *
     * See {setApprovalForAll}.
     */
    function isApprovedForAll(address account, address operator) external view returns (bool);

    /**
     * @dev Transfers a `value` amount of tokens of type `id` from `from` to `to`.
     *
     * WARNING: This function can potentially allow a reentrancy attack when transferring tokens
     * to an untrusted contract, when invoking {onERC1155Received} on the receiver.
     * Ensure to follow the checks-effects-interactions pattern and consider employing
     * reentrancy guards when interacting with untrusted contracts.
     *
     * Emits a {TransferSingle} event.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - If the caller is not `from`, it must have been approved to spend ``from``'s tokens via {setApprovalForAll}.
     * - `from` must have a balance of tokens of type `id` of at least `value` amount.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155Received} and return the
     * acceptance magic value.
     */
    function safeTransferFrom(address from, address to, uint256 id, uint256 value, bytes calldata data) external;

    /**
     * @dev xref:ROOT:erc1155.adoc#batch-operations[Batched] version of {safeTransferFrom}.
     *
     * WARNING: This function can potentially allow a reentrancy attack when transferring tokens
     * to an untrusted contract, when invoking {onERC1155BatchReceived} on the receiver.
     * Ensure to follow the checks-effects-interactions pattern and consider employing
     * reentrancy guards when interacting with untrusted contracts.
     *
     * Emits either a {TransferSingle} or a {TransferBatch} event, depending on the length of the array arguments.
     *
     * Requirements:
     *
     * - `ids` and `values` must have the same length.
     * - If `to` refers to a smart contract, it must implement {IERC1155Receiver-onERC1155BatchReceived} and return the
     * acceptance magic value.
     */
    function safeBatchTransferFrom(
        address from,
        address to,
        uint256[] calldata ids,
        uint256[] calldata values,
        bytes calldata data
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call, an admin role
     * bearer except when using {AccessControl-_setupRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[EIP].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}