Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.30;

import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "./ISecurityDepositPool.sol";

library Errors {
    error ZeroFundsManagerAddress();
    error ZeroBackupFundsManagerAddress();
    error DuplicateFundsManagerAddress();
    error ZeroUSDTAddress();
    error ZeroFlatDepositAmount();
    error CourseFinalizedTimeInPast();
    error CourseFinalizedTimeInDistantFuture();

    error AlreadyDeposited();
    error USDTTransferFailed();
    error CourseFinalized();

    error InsufficientDeposit();
    error ArrayLengthMismatch();

    error NoRemainingDeposit();
    error HasNotDeposited();
    error CourseNotFinalized();

    error NotFundsManagerOrOwner();
    error NoSlashedAmountToTransfer();
    error SlashedAmountAlreadyTransferred();
}

/**
 * @title SecurityDepositPool
 * @notice This contract manages the security deposits for a course.
 * It allows students to deposit USDT, slashes deposits based on the
 * discretion of the owner (instructor), and facilitates the return of
 * deposits after the course ends.
 */
contract SecurityDepositPool is Ownable, ISecurityDepositPool {
    using SafeERC20 for IERC20;

    address public immutable fundsManager;
    // In case the funds manager is not functional anymore, the backup funds manager can be used
    address public immutable backupFundsManager;
    // USDT on Ethereum does not comply fully with the ERC20 standard,
    // so we need to use .safeTransferFrom() or .safeTransfer()
    IERC20 public immutable usdt;
    uint256 public immutable flatDepositAmount;
    // Timestamp at which the course is supposed to end.
    // Also the time after which deposits can be claimed back
    uint256 public immutable courseFinalizedTime;

    uint256 public totalSlashed;
    bool public isTotalSlashedTransferred;

    mapping(address => uint256) public deposits;
    mapping(address => bool) public hasDeposited;

    modifier onlyFundsManagerOrOwner() {
        if (msg.sender != fundsManager && msg.sender != owner()) revert Errors.NotFundsManagerOrOwner();
        _;
    }

    // Asserts that the function is called after the course has been finalized
    modifier afterCourseFinalized() {
        // If current time is before course's end time, revert
        if (block.timestamp < courseFinalizedTime) revert Errors.CourseNotFinalized();
        _;
    }

    // Asserts that the function is called before the course has been finalized
    modifier beforeCourseFinalized() {
        // If current time is after course's end time, revert
        if (block.timestamp >= courseFinalizedTime) revert Errors.CourseFinalized();
        _;
    }

    /**
     * @dev Initializes the contract with instructor, funds manager, USDT token, deposit amount, and course end time.
     * Performs validation on input parameters.
     */
    constructor(
        address _instructor,
        address _fundsManager,
        address _backupFundsManager,
        address _usdt,
        uint256 _flatDepositAmount,
        uint256 _courseFinalizedTime
    ) Ownable(_instructor) {
        if (_fundsManager == address(0)) revert Errors.ZeroFundsManagerAddress();
        if (_backupFundsManager == address(0)) revert Errors.ZeroBackupFundsManagerAddress();
        if (_fundsManager == _backupFundsManager) revert Errors.DuplicateFundsManagerAddress();
        if (_usdt == address(0)) revert Errors.ZeroUSDTAddress();
        if (_flatDepositAmount == 0) revert Errors.ZeroFlatDepositAmount();
        // slither-disable-next-line timestamp
        if (_courseFinalizedTime < block.timestamp) revert Errors.CourseFinalizedTimeInPast();
        // slither-disable-next-line timestamp
        if (_courseFinalizedTime > block.timestamp + 60 days) revert Errors.CourseFinalizedTimeInDistantFuture();

        fundsManager = _fundsManager;
        backupFundsManager = _backupFundsManager;
        usdt = IERC20(_usdt);
        flatDepositAmount = _flatDepositAmount;
        courseFinalizedTime = _courseFinalizedTime;
    }

    /**
     * @dev Allows a student to deposit a flat USDT collateral before the course ends. Reverts if already deposited.
     */
    function deposit()
        external
        // Ensure the course has not ended (a student can join during the course too)
        beforeCourseFinalized
    {
        // Ensure the student has not already deposited
        if (hasDeposited[msg.sender]) revert Errors.AlreadyDeposited();

        deposits[msg.sender] = flatDepositAmount;
        hasDeposited[msg.sender] = true;
        emit Deposited(msg.sender, flatDepositAmount);

        // USDT contract is trusted, so no reentry protection is needed
        // slither-disable-next-line reentrancy-no-eth
        usdt.safeTransferFrom(msg.sender, address(this), flatDepositAmount);
    }

    /**
     * @dev Allows a student to withdraw their remaining deposit after the course is finalized.
     */
    function withdraw() external afterCourseFinalized {
        emit Withdrawn(msg.sender);

        _withdraw(msg.sender);
    }

    /**
     * @dev Allows the owner to withdraw deposits for multiple students after the course is finalized.
     *
     * Gas might be a problem if the list of students is too long, but
     * 1. it is expected that the list will be reasonably short, and
     * 2. it can always be called in multiple batches.
     *
     * In the worst case scenario, the user can call withdraw() himself by paying for his own gas.
     */
    function withdrawMany(
        // List of students will be externally indexed
        // to save gas
        address[] calldata students
    ) external onlyOwner afterCourseFinalized {
        emit WithdrawnMany(students);

        for (uint256 i = 0; i < students.length; i++) {
            _withdraw(students[i]);
        }
    }

    /**
     * @dev Allows the owner to slash deposits of multiple students before the course ends.
     * Slashed funds are tracked for later transfer.
     *
     * Gas might be a problem if the list of students is too long, but
     * 1. it is expected that the list will be reasonably short, and
     * 2. it can always be called in multiple batches.
     */
    function slashMany(address[] calldata students, uint256[] calldata amounts)
        external
        onlyOwner
        // If the course has ended, slashing is not allowed anymore
        beforeCourseFinalized
    {
        // Transferring the slashed amount is one-time operation.
        // If it is already done, can't slash anymore because the slashed funds
        // can't be transferred anymore.
        //
        // In fact, the function will revert at beforeCourseFinalized already because
        // transferSlashedToFundsManager() will be called after the course has ended, whereas
        // slashMany() can be called only before the course has ended, so it's safe to comment
        // this out. Leaving it for reference.
        //
        // if (isTotalSlashedTransferred) revert Errors.SlashedAmountAlreadyTransferred();

        // Ensure the lengths of the arrays match
        if (students.length != amounts.length) revert Errors.ArrayLengthMismatch();

        emit SlashedMany(students, amounts);

        for (uint256 i = 0; i < students.length; i++) {
            _slash(students[i], amounts[i]);
        }
    }

    /**
     * @dev Transfers the total slashed amount to the funds manager after the course is finalized.
     * Can only be called once.
     *
     * Backup funds manager is ONLY effective in the case the funds manager can't be accessed anymore
     * (e.g. lost private key or hardware wallet, etc). It does not prevent the funds manager
     * from transferring the slashed amount to himself if his private key is compromised.
     */
    function transferSlashedToFundsManager(bool useBackupFundsManager)
        external
        onlyFundsManagerOrOwner
        // Transferring the slashed amount can only be done after the course has been finalized
        afterCourseFinalized
    {
        // Ensure the slashed amount has not been transferred already.
        // Transferring the slashed amount is a one-time operation in the
        // lifetime of the contract, so if it is already done, can't transfer again.
        if (isTotalSlashedTransferred) revert Errors.SlashedAmountAlreadyTransferred();
        // Ensure there is a slashed amount to transfer
        if (totalSlashed == 0) revert Errors.NoSlashedAmountToTransfer();

        isTotalSlashedTransferred = true;
        uint256 amount = totalSlashed;
        totalSlashed = 0;

        address effectiveFundsManager = useBackupFundsManager ? backupFundsManager : fundsManager;
        emit SlashedTransferred(effectiveFundsManager, amount);

        // USDT contract is trusted
        usdt.safeTransfer(effectiveFundsManager, amount);
    }

    /**
     * @dev Internal function to withdraw a student's remaining deposit.
     * Reverts if no deposit or deposit is zero.
     *
     * Any functions that call _withdraw should ensure the course has ended
     */
    function _withdraw(address student) internal {
        // Ensure the student has deposited
        if (!hasDeposited[student]) revert Errors.HasNotDeposited();

        uint256 remainingAmount = deposits[student];
        // If the student has no remaining deposit due to slashing, revert
        if (remainingAmount == 0) revert Errors.NoRemainingDeposit();

        deposits[student] = 0;
        // USDT contract is trusted
        // slither-disable-next-line calls-loop
        usdt.safeTransfer(student, remainingAmount);
    }

    /**
     * @dev Internal function to slash a student's deposit by a given amount.
     * Reverts if insufficient deposit.
     *
     * Any functions that call _slash should ensure the course has not ended.
     */
    function _slash(address student, uint256 amount) internal {
        // Ensure the student has deposited
        if (!hasDeposited[student]) revert Errors.HasNotDeposited();
        // Ensure the amount to slash is valid
        if (deposits[student] < amount) revert Errors.InsufficientDeposit();

        deposits[student] -= amount;
        totalSlashed += amount;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.30;

interface ISecurityDepositPool {
    event Deposited(address indexed student, uint256 amount);
    event SlashedMany(address[] students, uint256[] amounts);
    event Withdrawn(address indexed student);
    event WithdrawnMany(address[] students);
    event SlashedTransferred(address indexed fundsManager, uint256 amount);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}