Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "../utils/Context.sol";
import {ERC165} from "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` from `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC-165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted to signal this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call. This account bears the admin role (for the granted role).
     * Expected in cases where the role was granted using the internal {AccessControl-_grantRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC-165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.27;

import {AccessControl} from "@openzeppelin/contracts/access/AccessControl.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {ICoindepoSaleDistribution} from "./ICoindepoSaleDistribution.sol";

/**
 * @title CoindepoSaleDistribution
 * @author PixelPlex.inc
 * @notice Manages vesting and distribution of tokens for the Coindepo sale event.
 * @dev Uses a two-phase vesting logic: phase one claims daily for N days, phase two claims daily for M days.
 */
contract CoindepoSaleDistribution is ICoindepoSaleDistribution, AccessControl {
    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");

    uint256 public constant ONE_DAY = 1 days;
    uint256 public constant ONE_MONTH = 30 days;

    IERC20 public immutable coinDepoToken;

    bool private _started;
    uint256 private _startedAt;
    uint256 private _totalLockAmount;

    uint256 private immutable _phaseOneTotalX18;
    uint256 private immutable _phaseOneDuration;
    uint256 private immutable _phaseTwoTotalWindows;
    uint256 private immutable _phaseTwoWindowX18;

    CustodyPart private _custodyPart;
    mapping(address user => VestingData) private _userToVestingData;

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function started() external view returns (bool status) {
        return _started;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function startedAt() external view returns (uint256 timestamp) {
        return _startedAt;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function totalLockAmount() external view returns (uint256 amount) {
        return _totalLockAmount;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function phaseOneTotalX18() external view returns (uint256 phaseOneShareX18) {
        return _phaseOneTotalX18;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function phaseOneDuration() external view returns (uint256 duration) {
        return _phaseOneDuration;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function phaseTwoDuration() external view returns (uint256 duration) {
        return _phaseTwoTotalWindows * ONE_MONTH;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function phaseTwoTotalWindows() external view returns (uint256 countOfWindows) {
        return _phaseTwoTotalWindows;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function phaseTwoWindowX18() external view returns (uint256 windowShareX18) {
        return _phaseTwoWindowX18;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function getCustodyPart() external view returns (CustodyPart memory custodyPart) {
        return _custodyPart;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function getVestingDataByUser(address user) external view returns (VestingData memory vestingData) {
        return _userToVestingData[user];
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function getAvailableCustodyPartClaimAmount() external view returns (uint256 amount) {
        CustodyPart memory custodyPart = _custodyPart;
        amount = _availableToClaim(
            custodyPart.amount,
            custodyPart.phaseOneTotalAmount,
            custodyPart.phaseOneDaily,
            custodyPart.phaseTwoWindowAmount,
            custodyPart.withdrawn
        );
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function getAvailableUserClaimAmount(address user) external view returns (uint256 amount) {
        VestingData memory vestingData = _userToVestingData[user];
        require(vestingData.amount != 0, HasNoVesting());
        amount = _availableToClaim(
            vestingData.amount,
            vestingData.phaseOneTotalAmount,
            vestingData.phaseOneDaily,
            vestingData.phaseTwoWindowAmount,
            vestingData.withdrawn
        );
    }

    /**
     * @notice Initializes the contract with the specified parameters.
     * @dev Sets up roles, immutable references and global phase params.
     *
     * Requirements:
     *  - `admin_` must not be zero address.
     *  - `coinDepoToken_` must not be zero address.
     *  - Vesting parameters must be valid:
     *      - `phaseOneTotalX18_` > 0 and <= 1e18.
     *      - `phaseOneDuration_` > 0.
     *      - `phaseTwoTotalWindows_` > 0.
     *      - `phaseTwoWindowX18_` > 0 and <= 1e18.
     *      - (`phaseTwoTotalWindows_` * `phaseTwoWindowX18_`) == 1e18.
     *
     * @param admin_ The address to be granted admin rights.
     * @param coinDepoToken_ The ERC20 token used for distribution.
     * @param phaseOneTotalX18_ The X18 fixed-point ratio (parts per 1e18) of phase one allocation.
     * @param phaseOneDuration_ Duration of phase one in seconds.
     * @param phaseTwoTotalWindows_ Number of vesting windows in phase two.
     * @param phaseTwoWindowX18_ Fraction (X18) of the phase two allocation for each window
     *                           (sum of all windows must be 1e18).
     */
    constructor(
        address admin_,
        address coinDepoToken_,
        uint256 phaseOneTotalX18_,
        uint256 phaseOneDuration_,
        uint256 phaseTwoTotalWindows_,
        uint256 phaseTwoWindowX18_
    )
        onlyValidAddress(admin_)
        onlyValidAddress(coinDepoToken_)
        onlyValidPhasesConfiguration(phaseOneTotalX18_, phaseOneDuration_, phaseTwoTotalWindows_, phaseTwoWindowX18_)
    {
        _grantRole(DEFAULT_ADMIN_ROLE, admin_);
        _grantRole(ADMIN_ROLE, admin_);
        coinDepoToken = IERC20(coinDepoToken_);
        _phaseOneTotalX18 = phaseOneTotalX18_;
        _phaseOneDuration = phaseOneDuration_;
        _phaseTwoTotalWindows = phaseTwoTotalWindows_;
        _phaseTwoWindowX18 = phaseTwoWindowX18_;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function start(uint256 startTimestamp) external onlyRole(ADMIN_ROLE) onlyNotStarted returns (uint256 startedAt_) {
        uint256 totalLockAmount_ = _totalLockAmount;
        require(totalLockAmount_ != 0, NoDistribution());
        require(startTimestamp >= block.timestamp, InvalidStartTimestamp());
        _started = true;
        _startedAt = startedAt_ = startTimestamp;
        coinDepoToken.transferFrom(msg.sender, address(this), totalLockAmount_);
        emit VestingStarted(totalLockAmount_, startedAt_);
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function createCustodyPart(
        address beneficiary,
        uint256 amount
    )
        external
        onlyRole(ADMIN_ROLE)
        onlyNotStarted
        onlyValidAddress(beneficiary)
        onlyValidAmount(amount)
        returns (bool)
    {
        CustodyPart storage custodyPart = _custodyPart;
        require(_custodyPart.amount == 0, CustodyPartAlreadyExists());
        custodyPart.beneficiary = beneficiary;
        custodyPart.amount = amount;
        (uint256 phaseOneTotalAmount, uint256 phaseTwoTotalAmount) = _calculatePhasesAmount(amount);
        custodyPart.phaseOneTotalAmount = phaseOneTotalAmount;
        custodyPart.phaseOneDaily = (phaseOneTotalAmount * ONE_DAY) / _phaseOneDuration;
        custodyPart.phaseTwoWindowAmount = (phaseTwoTotalAmount * _phaseTwoWindowX18) / 1e18;
        _totalLockAmount += amount;
        emit CustodyPartCreated(custodyPart);
        return true;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function createVestingData(
        address user,
        uint256 amount
    ) external onlyNotStarted onlyRole(ADMIN_ROLE) returns (bool) {
        _createVestingData(user, amount);
        return true;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function batchCreateVestingData(
        address[] calldata users,
        uint256[] calldata amounts
    ) external onlyNotStarted onlyRole(ADMIN_ROLE) returns (bool) {
        uint256 length = users.length;
        require(length == amounts.length, InvalidBatchInput(length, amounts.length));
        for (uint256 i = 0; i < length; i++) {
            _createVestingData(users[i], amounts[i]);
        }
        return true;
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function claimCustodyPart() external onlyRole(ADMIN_ROLE) onlyStarted returns (uint256 claimAmount) {
        CustodyPart storage custodyPart = _custodyPart;
        claimAmount = _availableToClaim(
            custodyPart.amount,
            custodyPart.phaseOneTotalAmount,
            custodyPart.phaseOneDaily,
            custodyPart.phaseTwoWindowAmount,
            custodyPart.withdrawn
        );
        if (claimAmount != 0) {
            custodyPart.withdrawn = custodyPart.withdrawn + claimAmount;
            coinDepoToken.transfer(custodyPart.beneficiary, claimAmount);
            emit CustodyPartClaimed(claimAmount);
        }
    }

    /**
     * @inheritdoc ICoindepoSaleDistribution
     */
    function claimVesting() external onlyStarted returns (uint256 claimAmount) {
        address caller = msg.sender;
        VestingData storage vestingData = _userToVestingData[caller];
        require(vestingData.amount != 0, HasNoVesting());
        claimAmount = _availableToClaim(
            vestingData.amount,
            vestingData.phaseOneTotalAmount,
            vestingData.phaseOneDaily,
            vestingData.phaseTwoWindowAmount,
            vestingData.withdrawn
        );
        if (claimAmount != 0) {
            vestingData.withdrawn = vestingData.withdrawn + claimAmount;
            coinDepoToken.transfer(caller, claimAmount);
            emit VestingClaimed(caller, claimAmount);
        }
    }

    /**
     * @notice Creates and stores vesting data for a user.
     * @param user The address of the user.
     * @param amount The total vesting amount for the user.
     */
    function _createVestingData(address user, uint256 amount) private onlyValidAddress(user) onlyValidAmount(amount) {
        VestingData storage vestingData = _userToVestingData[user];
        require(vestingData.amount == 0, VestingDataAlreadyExists(user, vestingData));
        vestingData.amount = amount;
        (uint256 phaseOneTotalAmount, uint256 phaseTwoTotalAmount) = _calculatePhasesAmount(amount);
        vestingData.phaseOneTotalAmount = phaseOneTotalAmount;
        vestingData.phaseOneDaily = (phaseOneTotalAmount * ONE_DAY) / _phaseOneDuration;
        vestingData.phaseTwoWindowAmount = (phaseTwoTotalAmount * _phaseTwoWindowX18) / 1e18;
        _totalLockAmount += amount;
        emit VestingDataCreated(user, vestingData);
    }

    /**
     * @notice Calculates absolute token amounts for phase one and phase two vesting periods.
     * @dev Uses `_phaseOneTotalX18` as share (fixed point, 18 decimals) for phase one.
     * @param amount The total allocation to split into phases.
     * @return phaseOneTotalAmount The token amount for phase one.
     * @return phaseTwoTotalAmount The token amount for phase two.
     */
    function _calculatePhasesAmount(
        uint256 amount
    ) private view returns (uint256 phaseOneTotalAmount, uint256 phaseTwoTotalAmount) {
        phaseOneTotalAmount = (amount * _phaseOneTotalX18) / 1e18;
        phaseTwoTotalAmount = amount - phaseOneTotalAmount;
    }

    /**
     * @dev Internal function to calculate the currently claimable amount for a vesting entry.
     * @param amount Total allocation for the entry.
     * @param phaseOneTotalAmount Allocated amount for phase one.
     * @param phaseOneDaily Per-day claimable amount for phase one.
     * @param phaseTwoWindowAmount Per-window claimable amount for phase two.
     * @param withdrawn Already withdrawn amount.
     * @return claimAmount The currently available amount to claim.
     */
    function _availableToClaim(
        uint256 amount,
        uint256 phaseOneTotalAmount,
        uint256 phaseOneDaily,
        uint256 phaseTwoWindowAmount,
        uint256 withdrawn
    ) private view returns (uint256 claimAmount) {
        uint256 timestamp = block.timestamp;
        uint256 phaseOneStartTimestamp = _startedAt;
        uint256 phaseTwoStartTimestamp = phaseOneStartTimestamp + _phaseOneDuration;
        uint256 phaseTwoEndTimestamp = phaseTwoStartTimestamp + ONE_MONTH * _phaseTwoTotalWindows;
        if (timestamp < phaseOneStartTimestamp) return 0;
        else if (timestamp >= phaseTwoEndTimestamp) return amount - withdrawn;
        else if (timestamp < phaseTwoStartTimestamp) {
            uint256 closedDaysInPhaseOne = (timestamp - phaseOneStartTimestamp) / ONE_DAY;
            claimAmount = phaseOneDaily * closedDaysInPhaseOne;
        } else {
            claimAmount = phaseOneTotalAmount; // phase one amount
            uint256 passedTimeInPhaseTwo = timestamp - phaseTwoStartTimestamp;
            uint256 closedWindowsInPhaseTwo = passedTimeInPhaseTwo / ONE_MONTH; // number of fully elapsed phase two windows
            uint256 closedDaysInCurrentWindow = (passedTimeInPhaseTwo % ONE_MONTH) / ONE_DAY; // number of closed days in current window
            claimAmount += phaseTwoWindowAmount * closedWindowsInPhaseTwo; // amount for closed windows
            claimAmount += (phaseTwoWindowAmount * closedDaysInCurrentWindow) / (ONE_MONTH / ONE_DAY); // amount for closed days in current window
        }
        claimAmount = claimAmount <= withdrawn ? 0 : claimAmount - withdrawn;
    }

    /**
     * @notice Checks the correctness of vesting phase parameters.
     * @dev Ensures that:
     *  - phaseOneTotalX18_ is not zero (non-zero phase one ratio, X18 fixed point).
     *  - phaseOneDuration_ is not zero (non-zero phase one duration).
     *  - phaseTwoTotalWindows_ is not zero (non-zero number of phase two windows).
     *  - phaseTwoWindowX18_ is not zero (non-zero window share for phase two).
     *  - The sum of all phase two windows strictly equals 1e18 (i.e. 100% of phase two allocation is distributed).
     * @param phaseOneTotalX18_ Ratio of phase one allocation, X18 fixed point.
     * @param phaseOneDuration_ Duration of phase one in seconds.
     * @param phaseTwoTotalWindows_ Number of vesting windows in phase two.
     * @param phaseTwoWindowX18_ Fraction of phase two allocation per window, X18 fixed point.
     */
    modifier onlyValidPhasesConfiguration(
        uint256 phaseOneTotalX18_,
        uint256 phaseOneDuration_,
        uint256 phaseTwoTotalWindows_,
        uint256 phaseTwoWindowX18_
    ) {
        require(
            phaseOneTotalX18_ != 0 &&
                phaseOneTotalX18_ <= 1e18 &&
                phaseOneDuration_ != 0 &&
                phaseTwoTotalWindows_ != 0 &&
                phaseTwoWindowX18_ != 0 &&
                phaseTwoWindowX18_ <= 1e18 &&
                phaseTwoTotalWindows_ * phaseTwoWindowX18_ == 1e18,
            InvalidPhasesConfiguration(phaseOneTotalX18_, phaseOneDuration_, phaseTwoTotalWindows_, phaseTwoWindowX18_)
        );
        _;
    }

    /**
     * @notice Modifier that checks that the passed address is not zero address.
     * @dev Checks the `address_` is not zero address.
     * @param address_ Address to check.
     */
    modifier onlyValidAddress(address address_) {
        require(address_ != address(0), InvalidAddress());
        _;
    }

    /**
     * @notice Modifier that checks that the passed amount is not zero.
     * @dev Checks that `amount` is greater than zero.
     * @param amount Amount to check.
     */
    modifier onlyValidAmount(uint256 amount) {
        require(amount != 0, InvalidAmount());
        _;
    }

    /**
     * @notice Modifier that allows functions to execute only if the lockup has started.
     * @dev Checks the `_started` flag to ensure the lockup process is active.
     */
    modifier onlyStarted() {
        require(_started, NotStarted());
        _;
    }

    /**
     * @notice Modifier that allows functions to execute only if the lockup has not started.
     * @dev Checks the `_started` flag to ensure the lockup process is inactive.
     */
    modifier onlyNotStarted() {
        require(!_started, AlreadyStarted());
        _;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.27;

/**
 * @title ICoindepoSaleDistribution
 * @author PixelPlex.inc
 * @notice Interface for Coindepo sale distribution contract with split vesting logic.
 */
interface ICoindepoSaleDistribution {
    struct CustodyPart {
        address beneficiary; ///< Address receiving claimed tokens for the custody part.
        uint256 amount; ///< Total allocation for the custody part.
        uint256 phaseOneTotalAmount; ///< Total amount for phase one.
        uint256 phaseOneDaily; ///< Amount claimed daily during phase one.
        uint256 phaseTwoWindowAmount; ///< Amount for each window during phase two.
        uint256 withdrawn; ///< Total amount already claimed.
    }

    struct VestingData {
        uint256 amount; ///< Total allocation for the user.
        uint256 phaseOneTotalAmount; ///< Total amount for phase one.
        uint256 phaseOneDaily; ///< Amount claimed daily during phase one.
        uint256 phaseTwoWindowAmount; ///< Amount for each window during phase two.
        uint256 withdrawn; ///< Total amount already claimed.
    }

    /**
     * @notice Emitted when the vesting process is started.
     * @param totalLockAmount Total amount of tokens locked for distribution.
     * @param startedAt Timestamp when vesting starts.
     */
    event VestingStarted(uint256 totalLockAmount, uint256 startedAt);

    /**
     * @notice Emitted when the custody allocation is created.
     * @param custodyPart Struct containing custody allocation details.
     */
    event CustodyPartCreated(CustodyPart custodyPart);

    /**
     * @notice Emitted when user vesting data is created.
     * @param user Address of the user.
     * @param vestingData Struct containing user's vesting allocation details.
     */
    event VestingDataCreated(address indexed user, VestingData vestingData);

    /**
     * @notice Emitted when the custody beneficiary claims tokens.
     * @param amount Amount of tokens claimed.
     */
    event CustodyPartClaimed(uint256 amount);

    /**
     * @notice Emitted when a user claims unlocked tokens.
     * @param user Address of the user claiming tokens.
     * @param amount Amount of tokens claimed.
     */
    event VestingClaimed(address indexed user, uint256 amount);

    /**
     * @notice Indicates that phases configuration was provided with invalid values.
     * @param phaseOneTotalX18 Total amount for phase one in X18 format.
     * @param phaseOneDuration Duration of phase one in seconds.
     * @param phaseTwoTotalWindows Number of vesting windows in phase two.
     * @param phaseTwoWindowX18 Fraction (X18) of the phase two allocation for each window.
     */
    error InvalidPhasesConfiguration(
        uint256 phaseOneTotalX18,
        uint256 phaseOneDuration,
        uint256 phaseTwoTotalWindows,
        uint256 phaseTwoWindowX18
    );

    /**
     * @notice Indicates that a zero address was provided where a valid address is required.
     */
    error InvalidAddress();

    /**
     * @notice Indicates that an invalid (zero) amount was provided where a positive amount is required.
     */
    error InvalidAmount();

    /**
     * @notice Indicates that the batch input lengths for users and amounts do not match.
     * @param usersLength The length of the users array.
     * @param amountLength The length of the amounts array.
     */
    error InvalidBatchInput(uint256 usersLength, uint256 amountLength);

    /**
     * @notice Indicates that the provided start timestamp is invalid.
     */
    error InvalidStartTimestamp();

    /**
     * @notice Indicates that the custody part has already been created and cannot be created again.
     */
    error CustodyPartAlreadyExists();

    /**
     * @notice Indicates that the vesting data for this user already exists.
     * @param user Address of the user for which vesting data already exists.
     * @param vestingData Existing vesting data for the user.
     */
    error VestingDataAlreadyExists(address user, VestingData vestingData);

    /**
     * @notice Indicates that the distribution is not initialized or has no tokens allocated.
     */
    error NoDistribution();

    /**
     * @notice Indicates that the user has no vesting allocation.
     */
    error HasNoVesting();

    /**
     * @notice Indicates that vesting has not started yet.
     */
    error NotStarted();

    /**
     * @notice Indicates that vesting has already started.
     */
    error AlreadyStarted();

    /**
     * @notice Returns whether the vesting process has started.
     * @return status True if vesting is active, false otherwise.
     */
    function started() external view returns (bool status);

    /**
     * @notice Returns the timestamp when the vesting process started.
     * @return timestamp The Unix timestamp of vesting start.
     */
    function startedAt() external view returns (uint256 timestamp);

    /**
     * @notice Returns the total amount of tokens locked for vesting.
     * @return amount The total lock amount in tokens.
     */
    function totalLockAmount() external view returns (uint256 amount);

    /**
     * @notice Returns the total amount of tokens allocated for phase one in X18 format.
     * @return phaseOneShareX18 The total amount of tokens allocated for phase one in X18 format.
     */
    function phaseOneTotalX18() external view returns (uint256 phaseOneShareX18);

    /**
     * @notice Returns the duration of the first phase (in seconds).
     * @return duration The duration of phase one.
     */
    function phaseOneDuration() external view returns (uint256 duration);

    /**
     * @notice Returns the total duration of phase two in seconds.
     * @dev Duration is calculated as phaseTwoTotalWindows × ONE_MONTH (30 days).
     * @return duration Total seconds in phase two.
     */
    function phaseTwoDuration() external view returns (uint256 duration);

    /**
     * @notice Returns the total number of vesting windows in phase two.
     * @return countOfWindows Number of phase two windows.
     */
    function phaseTwoTotalWindows() external view returns (uint256 countOfWindows);

    /**
     * @notice Returns the X18 fraction representing the share of each window in phase two.
     * @dev The sum over all windows must be 1e18.
     * @return windowShareX18 Fraction of phase two allocation for each window (X18).
     */
    function phaseTwoWindowX18() external view returns (uint256 windowShareX18);

    /**
     * @notice Returns the custody part information.
     * @return custodyPart The current custody part data structure.
     */
    function getCustodyPart() external view returns (CustodyPart memory custodyPart);

    /**
     * @notice Returns the vesting data for a specific user.
     * @param user The address of the user.
     * @return vestingData The vesting data structure for the user.
     */
    function getVestingDataByUser(address user) external view returns (VestingData memory vestingData);

    /**
     * @notice Returns the amount available for claim by the custody beneficiary.
     * @return amount The amount currently available to claim.
     */
    function getAvailableCustodyPartClaimAmount() external view returns (uint256 amount);

    /**
     * @notice Returns the amount available for claim by a specific user.
     * @param user The address of the user.
     * @return amount The amount currently available to claim for the user.
     */
    function getAvailableUserClaimAmount(address user) external view returns (uint256 amount);

    /**
     * @notice Starts the vesting process and locks the tokens in the contract.
     * @dev
     *  - Transfers all required tokens from the admin to the contract.
     *
     * Requirements:
     *  - Can only be called by an account with `ADMIN_ROLE`.
     *  - Can only be called before the vesting process has started.
     *  - The total lock amount must be non-zero.
     *  - The specified `startTimestamp` must not be less than the current block timestamp.
     *
     * - Emits a {VestingStarted} event.
     *
     * @param startTimestamp The Unix timestamp at which the vesting should start.
     * @return startedAt_ The actual timestamp when vesting was started.
     */
    function start(uint256 startTimestamp) external returns (uint256 startedAt_);

    /**
     * @notice Registers the custody part (off-chain distribution) for a specific beneficiary.
     * @dev
     *  - Updates the internal custody state.
     *
     * Requirements:
     *  - Can only be called by an account with `ADMIN_ROLE`.
     *  - Can only be called before the vesting process has started.
     *  - `beneficiary` must not be the zero address.
     *  - `amount` must be greater than zero.
     *  - The custody part must not already exist.
     *
     *  - Emits a {CustodyPartCreated} event.
     *
     * @param beneficiary The address to receive the custody part tokens.
     * @param amount The total amount of tokens to allocate.
     * @return True if successfully created.
     */
    function createCustodyPart(address beneficiary, uint256 amount) external returns (bool);

    /**
     * @notice Registers vesting allocation for a user.
     * @dev
     *  - Updates the internal vesting state for the user.
     *
     * Requirements:
     *  - Can only be called by an account with `ADMIN_ROLE`.
     *  - Can only be called before the vesting process has started.
     *  - `user` must not be the zero address.
     *  - `amount` must be greater than zero.
     *  - The vesting data for the user must not already exist.
     *
     *  - Emits a {VestingDataCreated} event.
     *
     * @param user The address of the user.
     * @param amount The total amount of tokens to allocate to the user.
     * @return True if successfully created.
     */
    function createVestingData(address user, uint256 amount) external returns (bool);

    /**
     * @notice Registers vesting allocations for multiple users in a single transaction.
     * @dev
     *  - Updates the internal vesting state for all users.
     *
     * Requirements:
     *  - Can only be called by an account with `ADMIN_ROLE`.
     *  - Can only be called before the vesting process has started.
     *  - `users` and `amounts` arrays must be the same length and not empty.
     *  - Each user address must not be zero.
     *  - Each amount must be greater than zero.
     *  - No user must already have vesting data.
     *
     *  - Emits a {VestingDataCreated} event for each user.
     *
     * @param users Array of user addresses.
     * @param amounts Array of token amounts to allocate to each user.
     * @return True if all allocations were successfully created.
     */
    function batchCreateVestingData(address[] calldata users, uint256[] calldata amounts) external returns (bool);

    /**
     * @notice Claims available tokens for the custody beneficiary, according to the vesting schedule.
     * @dev
     *  - Transfers tokens to the custody beneficiary if available.
     *
     * Requirements:
     *  - Can only be called by an account with `ADMIN_ROLE`.
     *  - Can only be called after the vesting process has started.
     *  - There must be tokens available to claim.
     *
     *  - Emits a {CustodyPartClaimed} event.
     *
     * @return claimAmount The amount of tokens claimed.
     */
    function claimCustodyPart() external returns (uint256 claimAmount);

    /**
     * @notice Claims available tokens for the caller (user) according to the vesting schedule.
     * @dev
     *  - Transfers tokens to the caller if available.
     *
     * Requirements:
     *  - Can only be called after the vesting process has started.
     *  - The caller must have vesting data.
     *  - There must be tokens available to claim.
     *
     *  - Emits a {VestingClaimed} event.
     *
     * @return claimAmount The amount of tokens claimed.
     */
    function claimVesting() external returns (uint256 claimAmount);
}