Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.18;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {Pausable} from "@openzeppelin/contracts/security/Pausable.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";

contract BCDTBurning is Pausable, Ownable {
    IERC20 private BCDT;

    // Global variables concerning token
    address public burnTokenToAddress =
        0x0000000000000000000000000000000000000001;

    // Initial addresses used for staging platform on mainnet or testnet
    address public BCDAddress;

    mapping(uint32 => uint256) public nbBytesToCertify;

    //Percentage of tokens burned when buying bytes to certified
    uint8 public burnRate = 25;

    //Percentage of tokens send to BCD used when buying bytes to certified
    uint8 public BCDRate = 75;

    // Size retained for a unit of data to be issued (aka "credit")
    uint32 public creditDataSize = 600;

    // Price retained for a credit (in euro cents)
    uint32 public creditPriceInEuro = 80;

    // Initial rate between ETH and EUR * 100, will be updated by Oracle
    uint32 public rateETHEUR = 15480;

    // Initial rate  between BCDT and ETH * 1E18, will be updated by Oracle
    uint256 public rateBCDTETH = 64100000000000;

    constructor(address _BCDTAddress) {
        BCDT = IERC20(_BCDTAddress);
    }

    function updateBurnRate(uint8 _newBurnRate) public onlyOwner {
        require(_newBurnRate <= 100);

        burnRate = _newBurnRate;
        BCDRate = 100 - _newBurnRate;
    }

    function updateCreditDataSize(uint32 _creditDataSize) public onlyOwner {
        creditDataSize = _creditDataSize;
    }

    function updateCreditPriceInEuro(
        uint32 _creditPriceInEuro
    ) public onlyOwner {
        creditPriceInEuro = _creditPriceInEuro;
    }

    function updateBCDAddress(address _newBCDAddress) public onlyOwner {
        BCDAddress = _newBCDAddress;
    }

    function updateRateETHEUR(uint32 _newRateETHEUR) public onlyOwner {
        rateETHEUR = _newRateETHEUR;
    }

    function updateRateBCDTETH(uint256 _newRateBCDTETH) public onlyOwner {
        rateBCDTETH = _newRateBCDTETH;
    }

    function getNeededTokensForBytesToCertify(
        uint256 _nbBytesToCertify
    ) public view returns (uint256) {
        // Tokens needed to prepaid X bytes of data to certified =
        // _nbBytesToCertify * creditPriceInEuro / creditDataSize / rateETHEUR / rateBCDTETH
        // , respecting decimals
        // Be aware that operations are executed sequentially
        // Multiplication by 1 ether to avoid conversion issues
        return
            (_nbBytesToCertify * creditPriceInEuro * 1 ether * 1 ether) /
            (creditDataSize * rateETHEUR * rateBCDTETH);
    }

    // Function to buy bytes with Tokens.
    function buyBytesToCertify(
        uint32 _issuerID,
        uint256 _nbBytesToCertify
    ) public whenNotPaused {
        require(rateETHEUR > 0, "buyBytesToCertify: RateETHEUR <= 0");
        require(rateBCDTETH > 0, "buyBytesToCertify: RateBCDTEUR <= 0");
        require(
            BCDAddress != address(0x0),
            "buyBytesToCertify: BCDAddress is 0x0"
        );

        require(_nbBytesToCertify >= creditDataSize, "nbBytes too low");
        uint256 neededTokens = getNeededTokensForBytesToCertify(
            _nbBytesToCertify
        );

        // Check if sender has enought tokens
        require(
            BCDT.balanceOf(msg.sender) >= neededTokens,
            "Insufficient balance"
        );
        require(
            BCDT.allowance(msg.sender, address(this)) >= neededTokens,
            "Insufficient allowance"
        );

        if (BCDRate > 0) {
            BCDT.transferFrom(
                msg.sender,
                BCDAddress,
                (neededTokens * BCDRate) / 100
            );
        }

        if (burnRate > 0) {
            BCDT.transferFrom(
                msg.sender,
                burnTokenToAddress,
                (neededTokens * burnRate) / 100
            );
        }
        nbBytesToCertify[_issuerID] += _nbBytesToCertify;
    }

    // Check how many bytes an issuer adress could certified
    function issuerNbBytesToCertifyBalance(
        uint32 _issuerId
    ) public view returns (uint256) {
        return nbBytesToCertify[_issuerId];
    }
}