Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.19;

import "../admin_panel/PlatformAdminPanel.sol";

/**
 * @title Abstract contract from which platform contracts with admin function are inherited
 * @dev Contains the platform admin panel
 * Contains modifier that checks whether sender is platform admin, use platform admin panel
 */
abstract contract PlatformAccessController {
    address public _panel;

    error CallerNotAdmin();
    error AlreadyInitialized();

    function _initiatePlatformAccessController(address adminPanel) internal {
        if(address(_panel) != address(0))
            revert AlreadyInitialized();

        _panel = adminPanel;
    }

    /**
     * @dev Modifier that makes function available for platform admins only
     */
    modifier onlyPlatformAdmin() {
        if(!PlatformAdminPanel(_panel).isAdmin(msgSender()))
            revert CallerNotAdmin();
        _;
    }

    function _isAdmin() internal view returns (bool) {
        return PlatformAdminPanel(_panel).isAdmin(msgSender());
    }

    function msgSender() internal view virtual returns (address) {
        return msg.sender;
    }
}

// SPDX-License-Identifier: MIT

pragma solidity 0.8.19;

interface IPlatformAdminPanel {
    function isAdmin(address wallet) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;
import "./Iplatform_admin_panel/IPlatformAdminPanel.sol";

/**
 * @title Platform admins holder contract
 * @notice Used to check accessibility of senders to admin functions in platform contracts
 */
contract PlatformAdminPanel is IPlatformAdminPanel {
    /**
     * @notice Emit during root admin set and reset
     */
    event SetRootAdmin(address indexed wallet);

    event InsertAdminList(address[] adminList);

    event RemoveAdminList(address[] adminList);

    mapping(address => bool) private _adminMap;
    address private _rootAdmin;

    modifier onlyRootAdmin() {
        require(_rootAdmin == msg.sender, "sender is not root admin");
        _;
    }

    /**
     * @notice Specify the root admin, only he has the rights to add and remove admins
     */
    constructor(address rootAdminWallet) {
        _setRootAdmin(rootAdminWallet);
    }

    /**
     * @notice Needed to determine if the user has admin rights for platform contracts
     */
    function isAdmin(address wallet)
        external
        view
        virtual
        override
        returns (bool)
    {
        return wallet == _rootAdmin || _adminMap[wallet];
    }

    function rootAdmin() external view returns (address) {
        return _rootAdmin;
    }

    /**
     * @notice Only root admin can call
     */
    function insertAdminList(address[] calldata adminList)
        external
        onlyRootAdmin
    {
        require(0 < adminList.length, "empty admin list");
        require(20 >= adminList.length, "list too large");

        uint256 index = adminList.length;
        while (0 < index) {
            --index;

            _adminMap[adminList[index]] = true;
        }

        emit InsertAdminList(adminList);
    }

    /**
     * @notice Only root admin can call
     */
    function removeAdminList(address[] calldata adminList)
        external
        onlyRootAdmin
    {
        require(0 < adminList.length, "empty admin list");
        require(20 >= adminList.length, "list too large");

        uint256 index = adminList.length;
        while (0 < index) {
            --index;

            _adminMap[adminList[index]] = false;
        }

        emit RemoveAdminList(adminList);
    }

    /**
     * @notice Only root admin can call
     */
    function setRootAdmin(address rootAdminWallet) external onlyRootAdmin {
        _setRootAdmin(rootAdminWallet);
    }

    function _setRootAdmin(address wallet) private {
        require(wallet != address(0), "wallet is zero address");

        _rootAdmin = wallet;

        emit SetRootAdmin(wallet);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.19;

/**
 * @author
 *  Creator: Yash Gupta (GitHub: @theyashgupta)
 *  Contributor: Ajibade Sokunbi (GitHub: @AjibadeSokunbi)
 */

import '@openzeppelin/contracts/token/ERC20/IERC20.sol';
import '@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol';
import '@openzeppelin/contracts/security/ReentrancyGuard.sol';
import '../access_controller/PlatformAccessController.sol';

/// @notice Interface for treasury funding strategy.
interface ITreasury {
    function transferReward(IERC20 token, address to, uint256 amount) external;

    function withdrawStake(IERC20 token, address to, uint256 amount) external;
}

/**
 * @title WelfStaking
 * @dev A staking contract that allows users to stake tokens and earn rewards based on predefined tiers and APYs.
 * The contract supports multiple staking pools, each with its own configuration and reward strategy.
 * It includes functionalities for creating and managing pools, staking, initiating unstake, claiming rewards, and withdrawing tokens.
 * The contract also supports restricted pools where only whitelisted addresses can stake.
 */
contract WelfStaking is ReentrancyGuard, PlatformAccessController {
    using SafeERC20 for IERC20;

    /// @dev Custom errors for gas-efficient reverts.
    error PoolPaused(uint256 poolId);
    error BelowMinStake(uint256 amount, uint256 minStake);
    error ArrayLengthMismatch();
    error InsufficientStakeAmount(uint256 index, uint256 requested, uint256 available);
    error IndexOutOfBounds(uint256 index);
    error NoCooldownReady();
    error PartialUnstakeNotAllowed();
    error NotAllowedToStake(uint256 poolId, address staker);
    error InvalidAddress();
    error PoolDoesNotExist(uint256 poolId);

    /// @notice Reward funding strategy options.
    enum RewardStrategy {
        RewardWallet,
        Treasury
    }

    // ========================================================
    //                          Constants
    // ========================================================
    uint256 public constant MIN_STAKE_AMOUNT = 1 ether;
    uint256 public constant SECONDS_IN_DAY = 1 days;
    uint256 public constant YEAR_DIVISOR = 365 days * 10000;

    // ========================================================
    //                        Data Structures
    // ========================================================

    /// @notice Configuration for each staking pool.
    struct PoolConfig {
        string name;
        IERC20 stakingToken;
        IERC20 rewardToken;
        uint256 cooldownPeriod; // in seconds
        uint256 currentTierVersion;
        bool isPaused;
        uint256 minStake;
        RewardStrategy rewardStrategy;
        address rewardAddress; // For RewardWallet: wallet (with approved allowance); for Treasury: treasury contract.
        bool restricted; // If true, only allowed addresses may stake.
        bool allowPartialUnstake; // If false, only full unstaking is allowed.
    }

    /// @notice A TierSet defines milestone durations and corresponding APYs.
    /// Each update records its effective time.
    struct TierSet {
        uint256 version;
        uint256 effectiveTime;
        uint256[] durations; // Cumulative tier boundaries (in seconds) relative to stake start.
        uint256[] apys; // APYs in basis points (e.g. 500 = 5%).
    }

    /// @notice A Stake holds a user's staked amount and timing data.
    struct Stake {
        uint256 amount;
        uint256 startTime;
        uint256 lastClaimTime;
    }

    /// @notice A Cooldown entry represents unstaked tokens pending withdrawal.
    struct Cooldown {
        uint256 amount;
        uint256 reward;
        uint256 endTime;
    }

    // ========================================================
    //                     Storage Variables
    // ========================================================
    uint256 public poolCounter;
    mapping(uint256 => PoolConfig) private pools; // poolId => PoolConfig
    mapping(uint256 => TierSet[]) private poolTiers; // poolId => array of TierSet (in order of effectiveTime)
    mapping(uint256 => mapping(address => Stake[])) private userStakes; // poolId => user => Stakes
    mapping(uint256 => mapping(address => Cooldown[])) private userCooldowns; // poolId => user => Cooldown entries
    mapping(uint256 => uint256) private poolTotalStaked; // poolId => total staked amount
    mapping(uint256 => uint256) private poolActiveUserCount; // poolId => active user count

    // For restricted pools: mapping of allowed staker addresses.
    mapping(uint256 => mapping(address => bool)) private poolAllowedStakers;

    // ========================================================
    //                           Events
    // ========================================================
    event PoolCreated(uint256 indexed poolId, string name);
    event TiersUpdated(uint256 indexed poolId, uint256 newVersion);
    event Staked(address indexed user, uint256 indexed poolId, uint256 index, uint256 amount);
    event UnstakeInitiated(
        address indexed user,
        uint256 indexed poolId,
        uint256 index,
        uint256 amount,
        uint256 pendingReward,
        uint256 stakeTimestamp
    );
    event Withdrawn(address indexed user, uint256 indexed poolId, uint256 amount, uint256 reward);
    event RewardsClaimed(address indexed user, uint256 indexed poolId, uint256 amount);

    event PoolRestrictionSet(uint256 indexed poolId, bool restricted);
    event PoolAllowedStakerSet(uint256 indexed poolId, address indexed staker, bool allowed);
    event PoolPauseSet(uint256 indexed poolId, bool isPaused);
    event PoolCooldownSet(uint256 indexed poolId, uint256 cooldownSeconds);
    event PoolMinStakeSet(uint256 indexed poolId, uint256 newMinStake);
    event PoolRewardConfigSet(uint256 indexed poolId, RewardStrategy newStrategy, address rewardAddress);

    /**
     * @param adminPanel platform admin panel address
     */
    constructor(address adminPanel) {
        if (adminPanel == address(0)) revert InvalidAddress();
        _initiatePlatformAccessController(adminPanel);
    }

    // ========================================================
    //                Pool Management Functions
    // ========================================================

    /**
     * @notice Creates a new pool.
     * @param stakingToken Token to be staked.
     * @param rewardToken Reward token.
     * @param cooldownDays Cooldown period (in days) before withdrawal.
     * @param initialDurationsDays Tier boundaries (in days).
     * @param initialAPYs APYs for each tier (in basis points).
     * @param rewardStrategy Funding strategy (RewardWallet or Treasury).
     * @param rewardAddress For RewardWallet: wallet address; for Treasury: treasury contract.
     * @param restricted If true, only whitelisted addresses may stake.
     * @param allowPartialUnstake If false, only full unstaking is permitted.
     */
    function createPool(
        string memory name,
        IERC20 stakingToken,
        IERC20 rewardToken,
        uint256 cooldownDays,
        uint256[] calldata initialDurationsDays,
        uint256[] calldata initialAPYs,
        RewardStrategy rewardStrategy,
        address rewardAddress,
        bool restricted,
        bool allowPartialUnstake
    ) external onlyPlatformAdmin {
        if (initialDurationsDays.length != initialAPYs.length) revert ArrayLengthMismatch();
        uint256 poolId = poolCounter++;
        uint256 cooldownSeconds = daysToSeconds(cooldownDays);

        pools[poolId] = PoolConfig({
            name: name,
            stakingToken: stakingToken,
            rewardToken: rewardToken,
            cooldownPeriod: cooldownSeconds,
            currentTierVersion: 1,
            isPaused: false,
            minStake: MIN_STAKE_AMOUNT,
            rewardStrategy: rewardStrategy,
            rewardAddress: rewardAddress,
            restricted: restricted,
            allowPartialUnstake: allowPartialUnstake
        });

        _addTierSet(poolId, initialDurationsDays, initialAPYs);
        emit PoolCreated(poolId, name);
    }

    /**
     * @notice Updates the TierSet for a pool.
     * @param poolId The pool identifier.
     * @param newDurationsDays New tier boundaries (in days).
     * @param newAPYs New APYs for each tier (in basis points).
     */
    function updateTiers(
        uint256 poolId,
        uint256[] calldata newDurationsDays,
        uint256[] calldata newAPYs
    ) external onlyPlatformAdmin {
        if (poolId >= poolCounter) revert PoolDoesNotExist(poolId); 
        if (newDurationsDays.length != newAPYs.length) revert ArrayLengthMismatch();
        PoolConfig storage pool = pools[poolId];
        pool.currentTierVersion++;
        _addTierSet(poolId, newDurationsDays, newAPYs);
        emit TiersUpdated(poolId, pool.currentTierVersion);
    }

    /**
     * @notice Sets the restriction flag for a pool.
     * @param poolId The pool identifier.
     * @param restricted True to restrict staking.
     */
    function setPoolRestriction(uint256 poolId, bool restricted) external onlyPlatformAdmin {
        pools[poolId].restricted = restricted;
        emit PoolRestrictionSet(poolId, restricted);
    }

    /**
     * @notice Batch update allowed stakers for a restricted pool.
     * @param poolId The pool identifier.
     * @param stakers Array of addresses.
     * @param allowed True to allow staking, false to remove.
     */
    function setPoolAllowedStakers(
        uint256 poolId,
        address[] calldata stakers,
        bool allowed
    ) external onlyPlatformAdmin {
        for (uint256 i = 0; i < stakers.length; i++) {
            poolAllowedStakers[poolId][stakers[i]] = allowed;
            emit PoolAllowedStakerSet(poolId, stakers[i], allowed);
        }
    }

    /**
     * @notice Pauses or unpauses a pool.
     * @param poolId The pool identifier.
     * @param pause True to pause; false to unpause.
     */
    function setPoolPause(uint256 poolId, bool pause) external onlyPlatformAdmin {
        pools[poolId].isPaused = pause;
        emit PoolPauseSet(poolId, pause);
    }

    /**
     * @notice Updates the cooldown period for a pool.
     * @param poolId The pool identifier.
     * @param cooldownDays New cooldown period (in days).
     */
    function setPoolCooldown(uint256 poolId, uint256 cooldownDays) external onlyPlatformAdmin {
        uint256 cooldownSeconds = daysToSeconds(cooldownDays);
        pools[poolId].cooldownPeriod = cooldownSeconds;
        emit PoolCooldownSet(poolId, cooldownSeconds);
    }

    /**
     * @notice Updates the minimum stake for a pool.
     * @param poolId The pool identifier.
     * @param newMinStake New minimum stake amount.
     */
    function setPoolMinStake(uint256 poolId, uint256 newMinStake) external onlyPlatformAdmin {
        pools[poolId].minStake = newMinStake;
        emit PoolMinStakeSet(poolId, newMinStake);
    }

    /**
     * @notice Updates the reward configuration for a pool.
     * This updates both the reward strategy and the reward address.
     * @param poolId The pool identifier.
     * @param newStrategy New reward strategy.
     * @param newRewardAddress New reward address.
     */
    function setPoolRewardConfig(
        uint256 poolId,
        RewardStrategy newStrategy,
        address newRewardAddress
    ) external onlyPlatformAdmin {
        PoolConfig storage pool = pools[poolId];
        pool.rewardStrategy = newStrategy;
        pool.rewardAddress = newRewardAddress;
        emit PoolRewardConfigSet(poolId, newStrategy, newRewardAddress);
    }

    // ========================================================
    //                   Staking Functions
    // ========================================================

    /**
     * @notice Stakes a specified amount into a pool.
     * @param poolId The pool identifier.
     * @param amount Amount to stake.
     */
    function stake(uint256 poolId, uint256 amount) external nonReentrant {
        PoolConfig storage pool = pools[poolId];
        if (pool.isPaused) revert PoolPaused(poolId);
        if (amount < pool.minStake) revert BelowMinStake(amount, pool.minStake);
        if (pool.restricted && !poolAllowedStakers[poolId][msg.sender]) revert NotAllowedToStake(poolId, msg.sender);

        if (userStakes[poolId][msg.sender].length == 0) {
            poolActiveUserCount[poolId]++;
        }

        if (pool.rewardStrategy == RewardStrategy.Treasury) {
            pool.stakingToken.safeTransferFrom(msg.sender, pool.rewardAddress, amount);
        } else {
            pool.stakingToken.safeTransferFrom(msg.sender, address(this), amount);
        }

        userStakes[poolId][msg.sender].push(
            Stake({ amount: amount, startTime: block.timestamp, lastClaimTime: block.timestamp })
        );
        emit Staked(msg.sender, poolId, userStakes[poolId][msg.sender].length - 1, amount);

        poolTotalStaked[poolId] += amount;
    }

    /**
     * @notice Internal function to initiate unstaking for a given stake index.
     * If partial unstaking is disabled, the unstake amount must equal the full stake.
     * @param poolId The pool identifier.
     * @param index The stake index.
     * @param amount The amount to unstake.
     */
    function _initiateUnstake(uint256 poolId, uint256 index, uint256 amount) internal {
        PoolConfig storage pool = pools[poolId];
        Stake[] storage stakes = userStakes[poolId][msg.sender];
        if (index >= stakes.length) revert IndexOutOfBounds(index);
        Stake storage userStake = stakes[index];

        uint256 currentStakeAmount = userStake.amount;
        uint256 stakeStartTime = userStake.startTime;

        if (currentStakeAmount < amount) revert InsufficientStakeAmount(index, amount, currentStakeAmount);
        if (!pool.allowPartialUnstake && amount != currentStakeAmount) revert PartialUnstakeNotAllowed();

        uint256 totalAccrued = _calculateRewards(poolId, userStake, block.timestamp);
        uint256 rewardForUnstake = (totalAccrued * amount) / currentStakeAmount;

        if (amount < currentStakeAmount) {
            userStake.amount = currentStakeAmount - amount;
            userStake.lastClaimTime = block.timestamp;
        } else {
            stakes[index] = stakes[stakes.length - 1];
            stakes.pop();

            if (stakes.length == 0) {
                poolActiveUserCount[poolId]--;
            }
        }

        userCooldowns[poolId][msg.sender].push(
            Cooldown({ amount: amount, reward: rewardForUnstake, endTime: block.timestamp + pool.cooldownPeriod })
        );

        emit UnstakeInitiated(msg.sender, poolId, index, amount, rewardForUnstake, stakeStartTime);

        poolTotalStaked[poolId] -= amount;
    }

    /**
     * @notice Initiates unstaking for a given stake index.
     * @param poolId The pool identifier.
     * @param index The stake index.
     * @param amount The amount to unstake.
     */
    function initiateUnstake(uint256 poolId, uint256 index, uint256 amount) external nonReentrant {
        _initiateUnstake(poolId, index, amount);
    }

    /**
     * @notice Batch initiates unstake operations.
     * @param poolId The pool identifier.
     * @param indices Array of stake indices.
     * @param amounts Array of unstake amounts.
     */
    function batchInitiateUnstake(
        uint256 poolId,
        uint256[] calldata indices,
        uint256[] calldata amounts
    ) external nonReentrant {
        if (indices.length != amounts.length) revert ArrayLengthMismatch();
        for (uint256 i = 0; i < indices.length; i++) {
            _initiateUnstake(poolId, indices[i], amounts[i]);
        }
    }

    /**
     * @notice Claims rewards for all active stakes in a pool.
     * @param poolId The pool identifier.
     */
    function batchClaimRewards(uint256 poolId) external nonReentrant {
        Stake[] storage stakes = userStakes[poolId][msg.sender];
        uint256 totalRewards;
        for (uint256 i = 0; i < stakes.length; i++) {
            totalRewards += _calculateRewards(poolId, stakes[i], block.timestamp);
            stakes[i].lastClaimTime = block.timestamp;
        }
        if (totalRewards > 0) {
            _transferRewards(poolId, msg.sender, totalRewards);
            emit RewardsClaimed(msg.sender, poolId, totalRewards);
        }
    }

    /**
     * @notice Withdraws tokens and rewards from expired cooldown entries.
     * @param poolId The pool identifier.
     */
    function withdrawCooldown(uint256 poolId) external nonReentrant {
        Cooldown[] storage cooldowns = userCooldowns[poolId][msg.sender];
        uint256 totalAmount;
        uint256 totalReward;
        uint256 i = 0;
        while (i < cooldowns.length) {
            if (block.timestamp >= cooldowns[i].endTime) {
                totalAmount += cooldowns[i].amount;
                totalReward += cooldowns[i].reward;
                cooldowns[i] = cooldowns[cooldowns.length - 1];
                cooldowns.pop();
            } else {
                unchecked {
                    i++;
                }
            }
        }

        if (totalAmount == 0) revert NoCooldownReady();

        PoolConfig storage pool = pools[poolId];

        if (pool.rewardStrategy == RewardStrategy.Treasury) {
            ITreasury(pool.rewardAddress).withdrawStake(pool.stakingToken, msg.sender, totalAmount);
        } else {
            pool.stakingToken.safeTransfer(msg.sender, totalAmount);
        }

        if (totalReward > 0) {
            _transferRewards(poolId, msg.sender, totalReward);
        }
        emit Withdrawn(msg.sender, poolId, totalAmount, totalReward);
    }

    // ========================================================
    //              Reward Funding Management
    // ========================================================

    /**
     * @notice Internal function to transfer rewards based on pool configuration.
     */
    function _transferRewards(uint256 poolId, address to, uint256 amount) internal {
        PoolConfig storage pool = pools[poolId];
        if (pool.rewardStrategy == RewardStrategy.RewardWallet) {
            pool.rewardToken.safeTransferFrom(pool.rewardAddress, to, amount);
        } else {
            ITreasury(pool.rewardAddress).transferReward(pool.rewardToken, to, amount);
        }
    }

    // ========================================================
    //                      View Functions
    // ========================================================

    /**
     * @notice Checks if a given address is allowed to stake in a restricted pool.
     * @param poolId The pool identifier.
     * @param staker The address to check.
     * @return True if allowed; otherwise false.
     */
    function isAddressAllowed(uint256 poolId, address staker) external view returns (bool) {
        return poolAllowedStakers[poolId][staker];
    }

    /**
     * @notice Returns the full tier history for a pool.
     * @param poolId The pool identifier.
     * @return Array of TierSet.
     */
    function getPoolTierHistory(uint256 poolId) external view returns (TierSet[] memory) {
        return poolTiers[poolId];
    }

    /**
     * @notice Returns all stakes for a user in a pool.
     * @param poolId The pool identifier.
     * @param user The user's address.
     * @return Array of Stake.
     */
    function getUserStakes(uint256 poolId, address user) external view returns (Stake[] memory) {
        return userStakes[poolId][user];
    }

    /**
     * @notice Returns the total pending rewards for a user in a pool.
     * @param poolId The pool identifier.
     * @param user The user's address.
     * @return totalRewards Sum of pending rewards across all stakes.
     */
    function getPendingRewards(uint256 poolId, address user) external view returns (uint256 totalRewards) {
        Stake[] memory stakes = userStakes[poolId][user];
        for (uint256 i = 0; i < stakes.length; i++) {
            totalRewards += _calculateRewards(poolId, stakes[i], block.timestamp);
        }
    }

    /**
     * @notice Returns the pending reward for a specific stake (by index) using the current time.
     * @param poolId The pool identifier.
     * @param user The user's address.
     * @param stakeIndex The stake index.
     * @return reward The pending reward.
     */
    function getPendingRewardsByStakeId(
        uint256 poolId,
        address user,
        uint256 stakeIndex
    ) external view returns (uint256 reward) {
        Stake[] memory stakes = userStakes[poolId][user];
        if (stakeIndex >= stakes.length) revert IndexOutOfBounds(stakeIndex);
        reward = _calculateRewards(poolId, stakes[stakeIndex], block.timestamp);
    }

    /**
     * @notice Previews the reward for a specific stake up to a future timestamp.
     * @param poolId The pool identifier.
     * @param user The user's address.
     * @param stakeIndex The stake index.
     * @param futureTimestamp Future timestamp for preview.
     * @return reward The previewed reward.
     */
    function previewRewardForTimestampByStakeId(
        uint256 poolId,
        address user,
        uint256 stakeIndex,
        uint256 futureTimestamp
    ) external view returns (uint256 reward) {
        Stake memory stakeData = userStakes[poolId][user][stakeIndex];
        if (futureTimestamp <= stakeData.lastClaimTime) return 0;
        reward = _calculateRewards(poolId, stakeData, futureTimestamp);
    }

    /**
     * @notice Previews the total future rewards for all stakes of a user up to a given timestamp.
     * @param poolId The pool identifier.
     * @param user The user's address.
     * @param futureTimestamp Future timestamp for preview.
     * @return totalReward The sum of previewed rewards.
     */
    function previewRewardsForUser(
        uint256 poolId,
        address user,
        uint256 futureTimestamp
    ) external view returns (uint256 totalReward) {
        Stake[] memory stakes = userStakes[poolId][user];
        for (uint256 i = 0; i < stakes.length; i++) {
            totalReward += _calculateRewards(poolId, stakes[i], futureTimestamp);
        }
    }

    /**
     * @notice Returns the current active TierSet for a pool.
     * @dev The active tier is assumed to be the last TierSet in the array.
     * @param poolId The pool identifier.
     * @return activeTier The active TierSet.
     */
    function getCurrentActiveTier(uint256 poolId) public view returns (TierSet memory activeTier) {
        TierSet[] memory tiers = poolTiers[poolId];
        require(tiers.length > 0, 'No tier set');
        activeTier = tiers[tiers.length - 1];
    }

    /**
     * @notice Returns the pool configuration along with its current active TierSet.
     * @param poolId The pool identifier.
     * @return config The PoolConfig.
     * @return activeTier The active TierSet.
     */
    function getPoolInfo(uint256 poolId) external view returns (PoolConfig memory config, TierSet memory activeTier) {
        config = pools[poolId];
        activeTier = getCurrentActiveTier(poolId);
    }

    /**
     * @notice Returns all cooldown entries for a user in a pool.
     * @param poolId The pool identifier.
     * @param user The user's address.
     * @return Array of Cooldown entries.
     */
    function getUserCooldowns(uint256 poolId, address user) external view returns (Cooldown[] memory) {
        return userCooldowns[poolId][user];
    }

    /**
     * @notice Returns the total amount staked in a pool.
     * @param poolId The pool identifier.
     * @return Total amount staked in the pool.
     */
    function getPoolTotalStaked(uint256 poolId) external view returns (uint256) {
        return poolTotalStaked[poolId];
    }

    /**
     * @notice Returns the total number of users currently staking in a pool.
     * @param poolId The pool identifier.
     * @return The active staker count.
     */
    function getActiveUserCount(uint256 poolId) external view returns (uint256) {
        return poolActiveUserCount[poolId];
    }

    // ========================================================
    //                Internal Helper Functions
    // ========================================================

    /**
     * @notice Converts days to seconds.
     * @param days_ Number of days.
     * @return Seconds equivalent.
     */
    function daysToSeconds(uint256 days_) public pure returns (uint256) {
        return days_ * SECONDS_IN_DAY;
    }

    /**
     * @dev Adds a new TierSet for a pool using the current block timestamp.
     */
    function _addTierSet(uint256 poolId, uint256[] calldata durationsDays, uint256[] calldata apys) internal {
        uint256 len = durationsDays.length;
        uint256[] memory durationsSeconds = new uint256[](len);
        for (uint256 i = 0; i < len; i++) {
            durationsSeconds[i] = daysToSeconds(durationsDays[i]);
        }
        poolTiers[poolId].push(
            TierSet({
                version: pools[poolId].currentTierVersion,
                effectiveTime: block.timestamp,
                durations: durationsSeconds,
                apys: apys
            })
        );
    }

    /**
     * @dev Calculates rewards for a stake from its last claim time until a specified end time,
     * prorating across TierSet updates.
     */
    function _calculateRewards(
        uint256 poolId,
        Stake memory stakeData,
        uint256 endTime
    ) internal view returns (uint256 totalReward) {
        TierSet[] memory tierHistory = poolTiers[poolId];
        uint256 L = stakeData.lastClaimTime;
        uint256 N = endTime;
        uint256 segmentStart = L;

        for (uint256 i = 0; i < tierHistory.length; i++) {
            if (tierHistory[i].effectiveTime > segmentStart && tierHistory[i].effectiveTime < N) {
                uint256 segmentEnd = tierHistory[i].effectiveTime;
                TierSet memory activeTier = _findTierSet(tierHistory, segmentStart);
                totalReward += _calculateSegmentReward(activeTier, stakeData, segmentStart, segmentEnd);
                segmentStart = segmentEnd;
            }
        }
        if (segmentStart < N) {
            TierSet memory activeTier = _findTierSet(tierHistory, segmentStart);
            totalReward += _calculateSegmentReward(activeTier, stakeData, segmentStart, N);
        }
    }

    /**
     * @dev Finds the TierSet in effect at a given timestamp.
     * Assumes tierHistory is sorted in ascending order by effectiveTime.
     */
    function _findTierSet(
        TierSet[] memory tierHistory,
        uint256 timestamp
    ) internal pure returns (TierSet memory activeTier) {
        for (uint256 i = tierHistory.length; i > 0; i--) {
            if (tierHistory[i - 1].effectiveTime <= timestamp) {
                return tierHistory[i - 1];
            }
        }
        return tierHistory[0];
    }

    /**
     * @dev Calculates the reward for a time segment [segStart, segEnd] using a given TierSet.
     */
    function _calculateSegmentReward(
        TierSet memory tier,
        Stake memory stakeData,
        uint256 segStart,
        uint256 segEnd
    ) internal pure returns (uint256 reward) {
        uint256 startOffset = segStart - stakeData.startTime;
        uint256 endOffset = segEnd - stakeData.startTime;
        uint256 tiersLength = tier.durations.length;
        for (uint256 i = 0; i < tiersLength; i++) {
            uint256 tierStart = i == 0 ? 0 : tier.durations[i - 1];
            uint256 tierEnd = i < tiersLength - 1 ? tier.durations[i] : type(uint256).max;
            uint256 overlapStart = startOffset > tierStart ? startOffset : tierStart;
            uint256 overlapEnd = endOffset < tierEnd ? endOffset : tierEnd;
            if (overlapEnd > overlapStart) {
                uint256 durationInTier = overlapEnd - overlapStart;
                reward += (stakeData.amount * tier.apys[i] * durationInTier) / YEAR_DIVISOR;
            }
        }
    }
}