Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This extension of the {Ownable} contract includes a two-step mechanism to transfer
 * ownership, where the new owner must call {acceptOwnership} in order to replace the
 * old one. This can help prevent common mistakes, such as transfers of ownership to
 * incorrect accounts, or to contracts that are unable to interact with the
 * permission system.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     *
     * Setting `newOwner` to the zero address is allowed; this can be used to cancel an initiated ownership transfer.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC721/IERC721.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC-721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC-721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC-721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert Errors.FailedCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

/**
 * @title CrediHardStaking
 * @dev A contract for staking ERC20 tokens into multiple pools with defined staking periods.
 * Supports admin and whitelist management, as well as tracking of staking details.
 * Inherits security features from SafeERC20, ReentrancyGuard, and Ownable2Step.
 */
// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/Ownable2Step.sol";
import "@openzeppelin/contracts/token/ERC721/IERC721.sol";

contract CrediHardStaking is ReentrancyGuard, Ownable2Step {
    using SafeERC20 for IERC20;

    // -------------------------------------------- Variables {{{ --------------------------------------------
    /**
     * @dev ERC20 token used for staking.
     */
    IERC20 public stakingToken;

    /**
     * @notice Tracks the current number of admin accounts.
     * @dev This counter is updated when admins are added or removed. It is limited by `MAX_ADMINS`.
     */
    uint256 public adminCount;

    /**
     * @notice The maximum number of admins allowed for the contract.
     * @dev This value is set as a constant to 2 and ensures the number of admins does not exceed this limit.
     */
    uint256 private constant MAX_ADMINS = 2;

    /**
     * @dev Whitelist admin address.
     */
    address public whitelistAdmin;

    /**
     * @dev Array to track all created pool IDs.
     */
    bytes32[] public poolIds;

    struct StakingPeriod {
        bytes32 periodId;
        uint256 duration; // in seconds
        uint128 minAmount; // minimum amount to stake
        uint16 yield;
        uint8 yieldDecimals; // Number of decimals (e.g., 1 for 10.5, 2 for 10.55)
        uint8 yieldPaymentFreq;
    }

    struct Pool {
        uint256 startTime;
        uint256 endTime;
        bool isValid; // Pool status
        bool exists; // Explicit flag to track if the pool exists
        mapping(bytes32 periodId => StakingPeriod stakePeriod) stakingPeriods; // periodId => StakingPeriod
        uint8 totalPeriods;
        bytes32[] periodIds; // Stores periodIds for quick lookup
    }

    struct StakeInfo {
        bytes32 poolId;
        bytes32 periodId;
        uint128 amount;
        uint256 stakeTime;
        bool withdrawn;
    }

    /**
     * @dev Mapping of admin addresses.
     */
    mapping(address adminAddr => bool flag) public admins;

    /**
     * @dev Mapping of whitelisted wallets.
     */
    mapping(address walletAddr => bool flag) public whitelistedWallets;

    /**
     * @dev Mapping of pool IDs to their respective Pool structures.
     */
    mapping(bytes32 poolId => Pool poolData) public pools;

    /**
     * @dev Mapping of users to their respective staking records.
     */
    mapping(address userAddr => StakeInfo[] stakeRecords) public userStakes;
    // -------------------------------------------- Variables }}} --------------------------------------------

    // -------------------------------------------- Events {{{ --------------------------------------------
    /**
     * @dev Emitted when an admin is added.
     */
    event AdminAdded(address indexed admin);

    /**
     * @dev Emitted when an admin is removed.
     */
    event AdminRemoved(address indexed admin);

    /**
     * @dev Emitted when the whitelist admin is set.
     */
    event WhitelistAdminSet(address indexed whitelistAdmin);

    /**
     * @dev Emitted when multiple wallets are whitelisted in a batch.
     */
    event WalletsWhitelisted(string batchId);

    /**
     * @dev Emitted when multiple wallets are removed from the whitelist in a batch.
     */
    event WalletsRemovedFromWhitelist(string batchId);

    /**
     * @dev Emitted when a new pool is created.
     */
    event PoolCreated(bytes32 indexed poolId, uint256 startTime, uint256 endTime);

    /**
     * @dev Emitted when a pool's status is updated.
     */
    event PoolStatusUpdated(bytes32 indexed poolId, bool isValid);

    /**
     * @dev Emitted when a pool's end time is updated.
     */
    event PoolEndTimeUpdated(bytes32 indexed poolId, uint256 newEndTime);

    /**
     * @dev Emitted when a staking period is set within a pool.
     */
    event StakingPeriodSet(bytes32 indexed poolId, bytes32 indexed periodId, uint256 duration, uint128 minAmount);

    /**
     * @dev Emitted when the minimum staking amount for a period is updated.
     */
    event MinAmountUpdated(bytes32 indexed poolId, bytes32 indexed periodId, uint128 newMinAmount);

    /**
     * @dev Emitted when a user stakes tokens.
     */
    event Staked(address indexed user, bytes32 indexed poolId, bytes32 indexed periodId, uint128 amount, uint256 stakeTime);

    /**
     * @dev Emitted when a user unstakes tokens.
     */
    event Unstaked(address indexed user, bytes32 indexed poolId, bytes32 indexed periodId, uint128 amount, uint256 unstakeTime);
    // -------------------------------------------- Events }}} --------------------------------------------

    // -------------------------------------------- Custom Errors {{{ --------------------------------------------
    /**
     * @notice Thrown when the provided address is invalid (e.g., zero address).
     * @param providedAddress The invalid address provided.
     */
    error InvalidAddress(address providedAddress);
    /**
     * @notice Thrown when the contract does not have sufficient balance.
     * @param to The recipient address where the Ether was intended to be sent.
     * @param amount The amount of Ether that failed to transfer.
     */
    error EtherTransferFailed(address to, uint256 amount);
    /**
     * @notice Thrown when the contract does not have sufficient balance.
     * @param balance The current balance of the contract.
     * @param required The required balance for the operation.
     */
    error InsufficientContractBalance(uint256 balance, uint256 required);
    /**
     * @notice Thrown when the provided amount is invalid (e.g., zero).
     * @param amount The invalid amount provided.
     */
    error InvalidAmount(uint256 amount);
    /**
     * @notice Thrown when the contract does not own the specified NFT.
     * @param nft The address of the NFT contract.
     * @param id The ID of the NFT that the contract is expected to own.
     */
    error NotNFTOwner(address nft, uint256 id);
    /**
     * @notice Thrown when an invalid or unauthorized call is made to the contract.
     * @dev This error is used to signal that the caller attempted an operation 
     *      or interaction that is not allowed or supported by the contract.
     * @param sender The address of the caller who made the invalid call.
     */
    error InvalidCall(address sender);
    /**
     * @notice Thrown when the caller is neither an admin nor the owner.
     * @param caller The address of the caller.
     */
    error CallerNotWhitelistAdminOrAdminOrOwner(address caller);
    /**
     * @notice Thrown when the address is already an admin.
     * @param admin The address that is already an admin.
     */
    error AlreadyAnAdmin(address admin);
    /**
     * @notice Thrown when the maximum number of admins has been reached.
     */
    error AdminLimitReached();
    /**
     * @notice Thrown when trying to remove a non-existent admin.
     * @param admin The address that is not an admin.
     */
    error AdminDoesNotExist(address admin);
    /**
     * @dev Custom error for when a wallet is not whitelisted.
     * This occurs when a user attempts to perform an action that requires whitelisting.
     * @param caller The address of the user attempting the action.
     */
    error WalletNotWhitelisted(address caller);
    /**
     * @dev Custom error for when the provided time is invalid.
     * This occurs when the start or end time is not valid.
     * @param time The time which is failed the validation.
     */
    error InvalidTime(uint256 time);
    /**
     * @dev Custom error for when a pool with the given ID already exists.
     * Ensures pool uniqueness and prevents duplicate entries.
     */
    error PoolAlreadyExists();
    /**
     * @dev Custom error for when a pool does not exist.
     */
    error PoolDoesNotExist();
    /**
     * @dev Custom error for when a pool is already invalid.
     */
    error PoolAlreadyInvalid();
    /**
     * @dev Custom error for when a pool cannot be deactivated after its start time.
     */
    error CannotDeactivateAfterStartTime();
    /**
     * @dev Custom error for when a pool has already ended and its end time cannot be updated.
     */
    error PoolAlreadyEnded();
    /**
     * @dev Custom error for when a new end time is invalid because it is before the pool's start time.
     */
    error InvalidEndTime();
    /**
     * @dev Custom error for when a staking duration is invalid (duration is zero).
     */
    error InvalidStakingDuration();
    /**
     * @dev Custom error for when staking has not started yet.
     */
    error StakingNotStarted();
    /**
     * @dev Custom error for when the staking amount is below the minimum requirement.
     */
    error AmountBelowMinimum();
    /**
     * @dev Custom error for when the token transfer fails.
     */
    error TokenTransferFailed();
    /**
     * @dev Custom error for when the staking period or pool has not yet ended.
     */
    error StakingPeriodNotEnded();
    /**
     * @dev Custom error for when no matching active stake is found.
     */
    error NoActiveStakeFound();
    /**
     * @dev Custom error for when the same whitelistAdmin is added.
     * @param whitelistAdmin The address that is being set as whitelistAdmin.
     */
    error AlreadyWhitelistAdmin(address whitelistAdmin);
    /**
     * @dev Custom error for when the staking exceed the pool endtime.
     */
    error StakingPeriodExceedsPoolEnd();
    /**
     * @dev Custom error for when the staking period Id duplication.
     */
    error StakingPeriodAlreadyExists();
    /**
     * @dev Custom error for when the staking duration exceeds Pool duration.
     */
    error StakingDurationExceedsPoolDuration();
    /**
     * @dev Custom error for when the staking period Id not available in the Pool.
     */
    error PeriodDoesNotExist();
    // -------------------------------------------- Custom Errors }}} --------------------------------------------

    // -------------------------------------------- MODIFIERS {{{ --------------------------------------------
    /**
     * @dev Modifier to restrict access to only admins or the contract owner.
     */
    modifier onlyAdmin() {
        if (!admins[msg.sender] && msg.sender != owner()) {
            revert CallerNotWhitelistAdminOrAdminOrOwner(msg.sender);
        }
        _;
    }

    /**
     * @dev Modifier to restrict access to the whitelist admin, contract owner, or an admin.
     */
    modifier onlyWhitelistAdmin() {
        if (!admins[msg.sender] && msg.sender != owner() && msg.sender != whitelistAdmin) {
            revert CallerNotWhitelistAdminOrAdminOrOwner(msg.sender);
        }
        _;
    }

    /**
     * @dev Modifier to restrict actions to only whitelisted wallets.
     */
    modifier onlyWhitelisted() {
        if (!whitelistedWallets[msg.sender]) {
            revert WalletNotWhitelisted(msg.sender);
        }
        _;
    }
    // -------------------------------------------- MODIFIERS }}} --------------------------------------------

    /**
     * @dev Constructor that initializes the staking token and assigns the contract deployer as the owner.
     * @param _stakingToken Address of the ERC20 token that will be used for staking.
     */
    constructor(address _stakingToken) Ownable(_msgSender()) {
        if (_stakingToken == address(0)) {
            revert InvalidAddress(_stakingToken);
        }
        stakingToken = IERC20(_stakingToken);
    }

    /**
     * @notice Prevents the renouncement of contract ownership.
     * @dev Overrides the default `renounceOwnership` function to always revert. 
     *      This ensures that the contract ownership cannot be renounced.
     * @custom:throws Always reverts with the message "Ownership renouncement is disabled".
     */
    function renounceOwnership() public pure override {
        revert("Ownership renouncement is disabled");
    }

    // -------------------------------------------- OWNER Functions {{{ --------------------------------------------
    /**
     * @notice Adds a new admin to the contract.
     * @dev Only the contract owner can add a new admin. The number of admins is limited by `MAX_ADMINS`.
     * @param _admin The address to be added as an admin.
     * @custom:requirements
     * - `_admin` must not be the zero address.
     * - The total number of admins must not exceed `MAX_ADMINS`.
     * - The address must not already be an admin.
     * @custom:throws InvalidAddress Thrown if the `_admin` address is the zero address.
     * @custom:throws AdminLimitReached Thrown if the number of admins has reached the `MAX_ADMINS` limit.
     * @custom:throws AlreadyAnAdmin Thrown if the `_admin` address is already an admin.
     * @custom:emits Emits `AdminAdded` with the address of the new admin.
     */
    function addAdmin(address _admin) external onlyOwner {
        if (_admin == address(0) || _admin == owner()) {
            revert InvalidAddress(_admin);
        }
        if (adminCount >= MAX_ADMINS) {
            revert AdminLimitReached();
        }
        if (admins[_admin]) {
            revert AlreadyAnAdmin(_admin);
        }

        admins[_admin] = true;
        adminCount += 1;
        emit AdminAdded(_admin);
    }

    /**
     * @notice Removes an existing admin from the contract.
     * @dev Only the contract owner can remove an admin. The `adminCount` is decremented upon successful removal.
     * @param _admin The address of the admin to be removed.
     * @custom:requirements
     * - The `_admin` address must already be an admin.
     * @custom:throws AdminDoesNotExist Thrown if the `admin` address is not an admin.
     * @custom:emits Emits `AdminRemoved` with the address of the removed admin.
     */
    function removeAdmin(address _admin) external onlyOwner {
        if (!admins[_admin]) {
            revert AdminDoesNotExist(_admin);
        }

        admins[_admin] = false;
        adminCount -= 1;
        emit AdminRemoved(_admin);
    }

    /**
     * @dev Sets the whitelist admin for the contract.
     * Can only be called by the owner.
     * Ensures that the provided address is not a zero address.
     * @param _admin Address of the new whitelist admin.
     */
    function setWhitelistAdmin(address _admin) external onlyOwner {
        if (_admin == address(0)) {
            revert InvalidAddress(_admin);
        }
        if (_admin == whitelistAdmin) {
            revert AlreadyWhitelistAdmin(_admin);
        }

        whitelistAdmin = _admin;
        emit WhitelistAdminSet(_admin);
    }
    // -------------------------------------------- OWNER Functions }}} --------------------------------------------

    // -------------------------------------------- WhiteListAdmin Functions }}} --------------------------------------------
    /**
     * @dev Whitelists multiple wallets in a batch.
     * Emits a single event with a unique batch identifier to track the operation.
     * Can only be called by the whitelist admin.
     * @param _wallets Array of wallet addresses to be whitelisted.
     * @param batchId Unique identifier for this batch operation.
     */
    function whitelistWallets(address[] calldata _wallets, string calldata batchId) external onlyWhitelistAdmin {
        for (uint32 i = 0; i < _wallets.length; i++) {
            whitelistedWallets[_wallets[i]] = true;
        }
        emit WalletsWhitelisted(batchId); // Single event with batch identifier
    }

    /**
     * @dev Removes multiple wallets from the whitelist in a batch.
     * Emits a single event with a unique batch identifier to track the operation.
     * Can only be called by the whitelist admin.
     * @param _wallets Array of wallet addresses to be removed from the whitelist.
     * @param batchId Unique identifier for this batch operation.
     */
    // Remove multiple wallets from whitelist with a batch ID
    function removeWalletsFromWhitelist(address[] calldata _wallets, string calldata batchId) external onlyWhitelistAdmin {
        for (uint32 i = 0; i < _wallets.length; i++) {
            whitelistedWallets[_wallets[i]] = false;
        }
        emit WalletsRemovedFromWhitelist(batchId); // Single event with batch identifier
    }
    // -------------------------------------------- WhiteListAdmin Functions }}} --------------------------------------------

    // -------------------------------------------- Admin Functions {{{ --------------------------------------------
    // -------------------------------------------- Pool Management {{{ --------------------------------------------
    /**
     * @dev Creates a new staking pool with a specified start and end time.
     * Can only be called by an admin.
     * Ensures the pool ID is unique before creation.
     * Newly created pools start in an valid state.
     * @param poolId Unique identifier for the pool.
     * @param _startTime The timestamp when the pool starts accepting stakes.
     * @param _endTime The timestamp when the pool stops accepting stakes.
     */
    function createPool(bytes32 poolId, uint256 _startTime, uint256 _endTime) external onlyAdmin {
        if (_startTime == 0 || _startTime <= block.timestamp) {
            revert InvalidTime(_startTime);
        }
        if (_endTime <= _startTime) {
            revert InvalidTime(_endTime);
        }
        if (pools[poolId].exists) {
            revert PoolAlreadyExists();
        }

        Pool storage pool = pools[poolId];
        pool.startTime = _startTime;
        pool.endTime = _endTime;
        pool.isValid = true; // Pool starts as valid
        pool.exists = true; // Explicitly mark the pool as created

        poolIds.push(poolId); // Store the pool ID for tracking

        emit PoolCreated(poolId, _startTime, _endTime);
    }

    /**
     * @dev Sets a pool to invalid status.
     * Can only be called by an admin.
     * Ensures the pool exists and is currently valid.
     * The pool can only be deactivated before the start time.
     * @param _poolId Unique identifier of the pool to be deactivated.
     */
    function setPoolInvalid(bytes32 _poolId) external onlyAdmin {
        Pool storage pool = pools[_poolId]; // Use bytes32 as the key

        if (!pool.exists) {
            revert PoolDoesNotExist();
        }
        if (!pool.isValid) {
            revert PoolAlreadyInvalid();
        }
        if (block.timestamp >= pool.startTime) {
            revert CannotDeactivateAfterStartTime();
        }

        pool.isValid = false;
        emit PoolStatusUpdated(_poolId, false); // Updated event parameter type
    }

    /**
     * @dev Updates the end time of an existing pool.
     * Can only be called by an admin.
     * Ensures the pool exists and is still valid.
     * The new end time must be after the pool's start time.
     * The pool must not have already ended.
     * @param _poolId Unique identifier of the pool.
     * @param _newEndTime The new end time for the pool.
     */
    function updatePoolEndTime(bytes32 _poolId, uint256 _newEndTime) external onlyAdmin {
        Pool storage pool = pools[_poolId];
        if (!pool.exists) {
            revert PoolDoesNotExist();
        }
        if (!pool.isValid) {
            revert PoolAlreadyInvalid();
        }

        if (pool.endTime <= block.timestamp) {
            revert PoolAlreadyEnded();
        }
        if (_newEndTime <= pool.startTime) {
            revert InvalidEndTime();
        }

        pool.endTime = _newEndTime;
        emit PoolEndTimeUpdated(_poolId, _newEndTime);
    }
    // -------------------------------------------- Pool Management }}} --------------------------------------------

    // -------------------------------------------- Staking Period Management {{{ --------------------------------------------
    /**
     * @dev Sets a staking period within a specified pool.
     * Can only be called by an admin.
     * Ensures the pool exists and is valid before adding the staking period.
     * Stores the staking period with a unique period ID.
     * Updates the total number of staking periods in the pool.
     * @param _poolId Unique identifier of the pool.
     * @param _periodId Unique identifier of the staking period.
     * @param _duration Duration of the staking period in seconds.
     * @param _minAmount Minimum amount required to stake in this period.
     * @param _yield Yield percentage for the staking period.
     * @param _yieldDecimals Number of decimals in the yield.
     * @param _yieldPaymentFreq Frequency of yield payments for the staking period.
     */
    function setStakingPeriod(
        bytes32 _poolId,
        bytes32 _periodId,
        uint256 _duration,
        uint128 _minAmount,
        uint16 _yield,
        uint8 _yieldDecimals,
        uint8 _yieldPaymentFreq
    ) external onlyAdmin {
        Pool storage pool = pools[_poolId];
        if (!pool.exists) {
            revert PoolDoesNotExist();
        }
        if (!pool.isValid) {
            revert PoolAlreadyInvalid();
        }
        if (_duration == 0) {
            revert InvalidStakingDuration();
        }
        if (pool.stakingPeriods[_periodId].duration > 0) { // If duration is set, period exists
            revert StakingPeriodAlreadyExists();
        }
        // Ensure the staking period duration does not exceed the total pool duration
        if (_duration > pool.endTime - pool.startTime) {
            revert StakingDurationExceedsPoolDuration();
        }
        // Ensure that the staking period can still be valid considering the current time
        if (block.timestamp + _duration > pool.endTime) {
            revert StakingPeriodExceedsPoolEnd();
        }

        pool.stakingPeriods[_periodId] = StakingPeriod(_periodId, _duration, _minAmount, _yield, _yieldDecimals, _yieldPaymentFreq);
        pool.periodIds.push(_periodId); // Store period ID for quick lookup

        if (pool.periodIds.length > pool.totalPeriods) {
            pool.totalPeriods = uint8(pool.periodIds.length);
        }

        emit StakingPeriodSet(_poolId, _periodId, _duration, _minAmount);
    }

    /**
     * @dev Updates the minimum staking amount for a specific staking period within a pool.
     * Can only be called by an admin.
     * Ensures the pool exists and is valid before updating the staking period.
     * Ensures the staking period is valid before modifying the minimum amount.
     * @param _poolId Unique identifier of the pool.
     * @param _periodId Unique identifier of the staking period.
     * @param _newMinAmount The new minimum staking amount for the specified period.
     */
    function updateMinAmount(bytes32 _poolId, bytes32 _periodId, uint128 _newMinAmount) external onlyAdmin {
        Pool storage pool = pools[_poolId];
        if (!pool.exists) {
            revert PoolDoesNotExist();
        }
        if (!pool.isValid) {
            revert PoolAlreadyInvalid();
        }

        // check if periodId exists
        _validatePeriodExists(pool, _periodId);

        // Retrieve the staking period
        StakingPeriod storage period = pool.stakingPeriods[_periodId];

        // Check if the new minAmount is the same as the current one
        if (period.minAmount == _newMinAmount) {
            revert InvalidAmount(_newMinAmount);
        }

        // Now it's safe to update minAmount
        period.minAmount = _newMinAmount;

        emit MinAmountUpdated(_poolId, _periodId, _newMinAmount);
    }
    // -------------------------------------------- Staking Period Management }}} --------------------------------------------
    // -------------------------------------------- Admin Functions }}} --------------------------------------------

    // -------------------------------------------- Staking {{{ --------------------------------------------
    /**
     * @dev Allows a whitelisted user to stake a specified amount into a staking pool and period.
     * Ensures the pool exists and is valid before allowing staking.
     * Ensures the staking period is valid and the amount meets the minimum staking requirement.
     * Transfers the staked tokens from the user to the contract.
     * Emits a `Staked` event upon successful staking.
     * @param _poolId Unique identifier of the pool where tokens are staked.
     * @param _periodId Unique identifier of the staking period within the pool.
     * @param _amount Amount of tokens to be staked.
     */
    function stake(bytes32 _poolId, bytes32 _periodId, uint128 _amount) external onlyWhitelisted nonReentrant {
        if (_amount == 0) {
            revert InvalidAmount(_amount);
        }

        Pool storage pool = pools[_poolId];
        if (!pool.exists) {
            revert PoolDoesNotExist();
        }
        if (!pool.isValid) {
            revert PoolAlreadyInvalid();
        }

        if (block.timestamp < pool.startTime) {
            revert StakingNotStarted();
        }

        if (pool.endTime <= block.timestamp) {
            revert PoolAlreadyEnded();
        }

        // check if periodId exists
        _validatePeriodExists(pool, _periodId);

        StakingPeriod storage period = pool.stakingPeriods[_periodId];

        if (_amount < period.minAmount) {
            revert AmountBelowMinimum();
        }

        if (block.timestamp + period.duration > pool.endTime) {
            revert StakingPeriodExceedsPoolEnd();
        }

        userStakes[msg.sender].push(StakeInfo({
            poolId: _poolId,
            periodId: _periodId,
            amount: _amount,
            stakeTime: block.timestamp,
            withdrawn: false
        }));

        // Transfer tokens to contract
        stakingToken.safeTransferFrom(msg.sender, address(this), _amount);

        emit Staked(msg.sender, _poolId, _periodId, _amount, block.timestamp);
    }

    /**
     * @dev Allows a user to unstake tokens from a staking pool and period.
     * Ensures the pool exists and is valid before allowing unstaking.
     * Ensures the user has an active stake in the specified pool and period.
     * Ensures the staking period or pool has ended before unstaking is permitted.
     * Allows partial unstaking while keeping track of the remaining staked amount.
     * Transfers the unstaked tokens back to the user.
     * Emits an `Unstaked` event upon successful unstaking.
     * @param _poolId Unique identifier of the pool from which tokens are unstaked.
     * @param _periodId Unique identifier of the staking period from which tokens are unstaked.
     * @param _stakeTime Time at which the tokens are staked.
     */
    function unstake(bytes32 _poolId, bytes32 _periodId, uint256 _stakeTime) external nonReentrant {
        StakeInfo[] storage stakes = userStakes[msg.sender]; // Fetch user's stakes
        bool found = false;

        // Validate Pool Exists & Is Valid
        Pool storage pool = pools[_poolId];
        if (!pool.exists) {
            revert PoolDoesNotExist();
        }
        if (!pool.isValid) {
            revert PoolAlreadyInvalid();
        }

        // Validate Period Exists
        _validatePeriodExists(pool, _periodId);

        for (uint256 i = 0; i < stakes.length; i++) {
            StakeInfo storage stakeInfo = stakes[i];

            if (
                stakeInfo.poolId == _poolId &&
                stakeInfo.periodId == _periodId &&
                stakeInfo.stakeTime == _stakeTime &&
                !stakeInfo.withdrawn
            ) {
                // Ensure staking period or pool has ended
                if (block.timestamp < stakeInfo.stakeTime + pool.stakingPeriods[_periodId].duration &&
                    block.timestamp < pool.endTime) {
                    revert StakingPeriodNotEnded();
                }

                // Mark as withdrawn
                stakeInfo.withdrawn = true;

                // Transfer full staked amount back to user
                stakingToken.safeTransfer(msg.sender, stakeInfo.amount);

                emit Unstaked(msg.sender, _poolId, _periodId, stakeInfo.amount, block.timestamp);

                found = true;
                break; // Stop once the specific stake is found and processed
            }
        }

        if (!found) {
            revert NoActiveStakeFound();
        }
    }

    // -------------------------------------------- Staking }}} --------------------------------------------

    // -------------------------------------------- GET {{{ --------------------------------------------
    /**
     * @dev Retrieves all staking details of a specified user.
     * Returns an array of `StakeInfo` structs containing staking records.
     * @param user Address of the user whose staking details are being retrieved.
     * @return An array of `StakeInfo` structures containing the user's staking records.
     */
    function getUserStakingDetails(address user) external view returns (StakeInfo[] memory) {
        return userStakes[user];
    }

    /**
     * @dev Checks if a given wallet address is whitelisted.
     * @param _wallet Address of the wallet to check.
     * @return Boolean value indicating whether the wallet is whitelisted.
     */
    function isWalletWhitelisted(address _wallet) external view returns (bool) {
        return whitelistedWallets[_wallet];
    }

    /**
     * @dev Retrieves all created pool IDs.
     * @return An array of bytes32 values representing the pool IDs.
     */
    function getPoolIds() external view returns (bytes32[] memory) {
        return poolIds; // Directly return the stored pool IDs
    }

    /**
     * @notice Retrieves high-level information about a pool, including period IDs.
     * @dev Ensures the pool exists before returning its data.
     * @param poolId The unique identifier of the pool.
     * @return startTime The start time of the pool.
     * @return endTime The end time of the pool.
     * @return isValid The validity status of the pool.
     * @return periodIds The array of staking period IDs associated with the pool.
     * @dev Use `getStakingPeriod` to retrieve detailed staking period info.
     */
    function getPoolInfo(bytes32 poolId) external view returns (
            uint256 startTime,
            uint256 endTime,
            bool isValid,
            bytes32[] memory periodIds
        )
    {
        Pool storage pool = pools[poolId];

        if (!pool.exists) {
            revert PoolDoesNotExist();
        }

        return (pool.startTime, pool.endTime, pool.isValid, pool.periodIds);
    }

    /**
     * @notice Retrieves the staking period details for a given pool and period ID.
     * @dev Ensures the pool exists and that the specified period ID is part of the pool's `periodIds[]` list
     *      before accessing the stakingPeriods mapping. This prevents returning uninitialized data.
     * @param poolId The unique identifier of the pool.
     * @param periodId The unique identifier of the staking period.
     * @return duration The staking duration in seconds.
     * @return minAmount The minimum amount required to stake.
     * @return yield The yield percentage, stored as an integer with `yieldDecimals` precision.
     * @return yieldDecimals The number of decimal places in the yield value.
     * @return yieldPaymentFreq The frequency of yield payments.
     * @dev Reverts if the pool does not exist or if the period ID is not found in `periodIds[]`.
     */
    function getStakingPeriodInfo(bytes32 poolId, bytes32 periodId) 
        external 
        view 
        returns (
            uint256 duration, 
            uint128 minAmount, 
            uint16 yield, 
            uint8 yieldDecimals, 
            uint8 yieldPaymentFreq
        ) 
    {
        Pool storage pool = pools[poolId];

        if (!pool.exists) {
            revert PoolDoesNotExist();
        }

        // check if periodId exists
        _validatePeriodExists(pool, periodId);

        StakingPeriod storage period = pool.stakingPeriods[periodId];

        return (
            period.duration,
            period.minAmount,
            period.yield,
            period.yieldDecimals,
            period.yieldPaymentFreq
        );
    }

    /**
     * @dev Checks if a periodId exists in the given pool.
     * @param pool The pool struct to check within.
     * @param periodId The staking period ID to look for.
     * @return bool Returns `true` if the periodId exists, otherwise reverts.
     */
    function _validatePeriodExists(Pool storage pool, bytes32 periodId) internal view returns (bool) {
        for (uint256 i = 0; i < pool.periodIds.length; i++) {
            if (pool.periodIds[i] == periodId) {
                return true;
            }
        }
        revert PeriodDoesNotExist();
    }
    // -------------------------------------------- GET }}} --------------------------------------------

    // -------------------------------------------- RESCUE {{{ --------------------------------------------
    /**
     * @notice Withdraws all Ether from the contract and transfers it to a specified address.
     * @dev Allows an admin to rescue any Ether accidentally sent to the contract or reclaim fees.
     * @param to The recipient address to which the Ether will be sent.
     * 
     * @custom:requirements
     * - The caller must have the `onlyAdmin` role.
     * - The `to` address must not be the zero address.
     * - The contract must have a non-zero Ether balance.
     * - The Ether transfer must succeed.
     * 
     * @custom:throws InvalidAddress Thrown if the `to` address is the zero address.
     * @custom:throws EtherTransferFailed Thrown if the Ether transfer fails.
     * 
     * @custom:details
     * - The function transfers the entire Ether balance of the contract to the recipient address.
     * - Uses a low-level call with `call` to handle Ether transfer securely and check success.
     * 
     * @custom:emits None.
     */
    function rescue(address to) public nonReentrant onlyAdmin {
        if (to == address(0)) {
            revert InvalidAddress(to);
        }

        uint256 amount = address(this).balance;
        if (amount == 0) return; // No Ether to transfer

        (bool success, ) = to.call{value: amount}("");
        if (!success) {
            revert EtherTransferFailed(to, amount);
        }
    }

    /**
     * @notice Withdraws all ERC20 tokens of a specified type from the contract and transfers them to a recipient.
     * @dev Allows an admin to rescue ERC20 tokens accidentally sent to the contract.
     * @param token The address of the ERC20 token to be rescued.
     * @param to The recipient address to which the ERC20 tokens will be sent.
     * 
     * @custom:requirements
     * - The caller must have the `onlyAdmin` role.
     * - The `token` address must not be the zero address.
     * - The `to` address must not be the zero address.
     * - The contract must hold a non-zero balance of the specified ERC20 token.
     * 
     * @custom:throws InvalidAddress Thrown if the `token` or `to` address is the zero address.
     * 
     * @custom:emits None.
     */
    function rescueToken(address token, address to, uint256 amount) public nonReentrant onlyAdmin {
        if (token == address(0)) {
            revert InvalidAddress(token);
        }

        if (to == address(0)) {
            revert InvalidAddress(to);
        }

        IERC20 erc20Token = IERC20(token);
        uint256 contractBalance = erc20Token.balanceOf(address(this));

        if (contractBalance < amount) {
            revert InsufficientContractBalance(contractBalance, amount);
        }

        if (amount == 0 || contractBalance == 0) {
            revert InvalidAmount(amount);
        }

        erc20Token.safeTransfer(to, amount);
    }

    /**
     * @notice Withdraws an ERC721 NFT from the contract and transfers it to a specified address.
     * @dev Allows the admin to rescue an NFT that was accidentally sent to the contract.
     *      The function checks ownership of the NFT and uses a safe transfer mechanism.
     * @param receiver The address to which the NFT will be transferred.
     * @param nft The address of the ERC721 contract.
     * @param id The ID of the NFT to be rescued.
     * 
     * @custom:requirements
     * - The caller must have the `onlyAdmin` role.
     * - `receiver` must not be the zero address.
     * - `nft` must not be the zero address.
     * - The contract must own the NFT with the specified `id`.
     *
     * @custom:throws InvalidAddress Thrown if the `receiver` or `nft` address is the zero address.
     * @custom:throws NotNFTOwner Thrown if the contract does not own the NFT with the specified `id`.
     * 
     * @custom:emits None.
     */
    function rescueNFT(address receiver, address nft, uint256 id) public nonReentrant onlyAdmin {
        if (receiver == address(0)) {
            revert InvalidAddress(receiver);
        }
        if (nft == address(0)) {
            revert InvalidAddress(nft);
        }

        IERC721 nftContract = IERC721(nft);

        // Verify ownership of the NFT
        if (nftContract.ownerOf(id) != address(this)) {
            revert NotNFTOwner(nft, id);
        }

        // Safe transfer of the NFT
        nftContract.safeTransferFrom(address(this), receiver, id);
    }

    /**
     * @notice Reverts any unrecognized calls to the contract.
     * @dev This function is triggered when an unrecognized function selector is called on the contract.
     *      It also prevents Ether transfers since the function is not payable.
     *
     * @custom:requirements
     * - This function is triggered for calls to non-existent functions or invalid transactions.
     * - Ether cannot be sent to the contract as this function is not payable.
     *
     * @custom:throws InvalidCall Thrown when an unrecognized call is made to the contract.
     */
    fallback() external {
        revert InvalidCall(msg.sender);
    }
    // -------------------------------------------- RESCUE }}} --------------------------------------------
}