Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

import "erc721a/contracts/ERC721A.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/security/Pausable.sol";
import "./ILoversNft.sol";
import "./Adminable.sol";

//  ╭╮╱╱╱╱╱╱╱╱╱╱╱╱╱╱╱╱╱╭╮╱╭╮╱╱╱╱╭╮╱╱╱╱╱╭━━━━┳╮╱╱╱╱╱╭━╮╭━╮
//  ┃┃╱╱╱╱╱╱╱╱╱╱╱╱╱╱╱╱╱┃┃╱┃┃╱╱╱╱┃┃╱╱╱╱╱┃╭╮╭╮┃┃╱╱╱╱╱┃┃╰╯┃┃
//  ┃┃╱╱╭━━┳╮╭┳━━┳━┳━━╮┃┃╱┃┣━╮╭━╯┣━━┳━╮╰╯┃┃╰┫╰━┳━━╮┃╭╮╭╮┣━━┳━━┳━╮
//  ┃┃╱╭┫╭╮┃╰╯┃┃━┫╭┫━━┫┃┃╱┃┃╭╮┫╭╮┃┃━┫╭╯╱╱┃┃╱┃╭╮┃┃━┫┃┃┃┃┃┃╭╮┃╭╮┃╭╮╮
//  ┃╰━╯┃╰╯┣╮╭┫┃━┫┃┣━━┃┃╰━╯┃┃┃┃╰╯┃┃━┫┃╱╱╱┃┃╱┃┃┃┃┃━┫┃┃┃┃┃┃╰╯┃╰╯┃┃┃┃
//  ╰━━━┻━━╯╰╯╰━━┻╯╰━━╯╰━━━┻╯╰┻━━┻━━┻╯╱╱╱╰╯╱╰╯╰┻━━╯╰╯╰╯╰┻━━┻━━┻╯╰╯

contract LoversNft is ILoversNft, ERC721A, Adminable, ReentrancyGuard, Pausable {
    /**
     * Maximum number of supply
     */
    uint256 public maximumSupply;

    /**
     *  To make token uri immutable permanently
     */
    bool public permanent;

    modifier notPermanent() {
        if (permanent) {
            revert ImmutableState();
        }
        _;
    }

    /**
     *  Minting rounds
     */
    mapping(uint16 => Round) rounds;

    uint256 public revealBlockOffset = 3000;

    /**
     *  Current round number
     */
    uint16 public currentRoundNumber;

    address private _receiver;

    /**
     * Base uri for token uri
     */
    string public baseURI;

    /**
     * Default unrevealed uri
     */
    string private defaultUnrevealedURI;

    constructor(
        address receiver,
        uint256 maxSupply,
        string memory _baseUri,
        string memory _defaultUnrevealedURI,
        address admin_
    ) ERC721A("Lovers Under The Moon", "LOVER")
        Adminable(admin_)
        Pausable()
    {
        _receiver = receiver;
        maximumSupply = maxSupply;
        baseURI = _baseUri;
        defaultUnrevealedURI = _defaultUnrevealedURI;
    }

    /**
     *  Create a new minting round
     *  For owner only
     */
    function newRound(
        MintingType mintingType,
        uint256 supply,   // total supply for the round
        uint256 startTime, // round starting time
        uint256 endTime, // round ending time
        uint256 mintingFee, // minting fee
        uint16 maxMintingQuantity, // maximum number of minting quantity per address
        bool revealed // reveal image or not
    ) external onlyOwner notPermanent {
        // wrap-up the existing round
        if (currentRoundNumber > 0) {
            endRound();
        }

        uint256 maxMintingId = _nextTokenId() + supply - 1;

        // the maxMintingId of new round can NOT exceed the maximumSupply
        if (maxMintingId > maximumSupply) {
            revert BadRequest("maxMintingId exceed the maximumSupply");
        }

        if (startTime >= endTime) {
            revert BadRequest("endTime should be bigger");
        }

        uint16 newRoundNumber = ++currentRoundNumber;

        rounds[newRoundNumber] = Round({
            roundNumber: newRoundNumber,
            mintingType: mintingType,
            startTime: startTime,
            endTime: endTime,
            maxMintingQuantity: maxMintingQuantity,
            mintingFee: mintingFee,

            maxMintingId: maxMintingId,
            startId: _nextTokenId(),
            lastMintedId: 0,
            tokenURIPrefix: "",
            revealed: revealed,
            revealBlockNumber: 0,
            randomSelection: 0,
            closedTime: 0
        });

        emit NewRoundCreated(newRoundNumber);
    }

    /**
     * End the current round
     * For owner and admin
     */
    function endRound() public onlyOwnerOrAdmin {
        Round storage currentRound = rounds[currentRoundNumber];
        currentRound.lastMintedId = _nextTokenId() - 1;
        currentRound.closedTime = block.timestamp;

        emit RoundEnded(currentRoundNumber);
    }

    /**
     *  Get the detail of the current round
     */
    function getCurrentRound() public view returns (Round memory) {
        return getRound(currentRoundNumber);
    }

    /**
     *  Get round detail
     */
    function getRound(uint16 roundNumber) public view returns (Round memory) {
        return rounds[roundNumber];
    }

    /**
     *  Get the STATE of the contract
     */
    function getState() public view returns (State) {
        if (currentRoundNumber == 0) {
            return State.DEPLOYED;
        }

        Round memory currentRound = rounds[currentRoundNumber];

        uint256 closedTime = currentRound.closedTime;
        uint256 startTime = currentRound.startTime;
        uint256 endTime = currentRound.endTime;
        uint256 currentTime = block.timestamp;

        State currentState;

        if (closedTime != 0) {
            currentState = State.END_MINTING;
        } else {
            if (currentTime < startTime) {
                currentState = State.PREPARE_MINTING;
            } else if (currentTime < endTime) {
                if (currentRound.maxMintingId > totalSupply()) {
                    currentState = State.ON_MINTING;
                } else {
                    currentState = State.END_MINTING;
                }
            } else {
                currentState = State.END_MINTING;
            }
        }

        return currentState;
    }

    /**
     * Minting
     */
    function mint(uint256 quantity)
        external
        payable
        nonReentrant
        whenNotPaused
        notPermanent
    {
        Round memory currentRound = getRound(currentRoundNumber);

        _sanityCheckForMinting(currentRound, quantity);

        require(safeMint(msg.sender, quantity));
    }

    /**
     * Admin minting
     * Only for owner or admin
     */
    function mint(address to, uint256 quantity)
        external
        payable
        onlyOwnerOrAdmin
        notPermanent
    {
        Round memory currentRound = rounds[currentRoundNumber];

        _sanityCheckForMinting(currentRound, quantity);

        require(safeMint(to, quantity));
    }

    /**
     * Change Minting type
     * For only owner or admin
     */
    function changeMintingType(uint16 roundNumber, MintingType mintingType) 
        external onlyOwnerOrAdmin notPermanent {
        Round storage round = rounds[roundNumber];
        round.mintingType = mintingType;

        emit MintingTypeChanged(roundNumber, mintingType);
    }

    /**
     *  Change the maximum minting id for the specified round
     *  For owner and admin
     */
    function changeMaxMintingId(uint16 roundNumber, uint256 maxId)
        public onlyOwnerOrAdmin notPermanent
    {
        if (maxId < _nextTokenId()) {
            revert MaxMintingIdLowerThanCurrentId();
        }

        if (maxId > maximumSupply) {
            revert ExceedMaximumSupply();
        }

        Round storage round = rounds[roundNumber];
        round.maxMintingId = maxId;

        emit MaxMintingIdChanged(roundNumber, maxId);
    }

    /**
     *  Change minting start time for the specified round
     *  Only for owner and admin
     */
    function changeStartTime(uint16 roundNumber, uint256 time)
        public onlyOwnerOrAdmin notPermanent
    {
        Round storage round = rounds[roundNumber];
        round.startTime = time;

        emit StartTimeChanged(roundNumber, time);
    }

    /**
     *  Change minting end time for the specified round
     *  Only for owner and admin
     */
    function changeEndTime(uint16 roundNumber, uint256 time)
        public onlyOwnerOrAdmin notPermanent
    {
        Round storage round = rounds[roundNumber];
        round.endTime = time;

        emit EndTimeChanged(roundNumber, time);
    }

    /**
     *  Change maximum minting quantity for an account
     *  For owner and admin
     */
    function changeMaxMintingQuantity(uint16 roundNumber, uint16 quantity)
        public onlyOwnerOrAdmin notPermanent
    {
        Round storage round = rounds[roundNumber];
        round.maxMintingQuantity = quantity;

        emit MaxMintingQuantityChanged(roundNumber, quantity);
    }

    /**
     *  Set the minting for the specified round
     *  OnlyOwner functions
     */
    function changeMintingFee(uint16 roundNumber, uint256 fee)
        external onlyOwnerOrAdmin notPermanent
    {
        Round storage round = rounds[roundNumber];
        round.mintingFee = fee;

        emit MintingFeeChanged(roundNumber, fee);
    }

    /**
     *  Set the token uri prefix for the specified round
     *  For owner and admin
     */
    function setTokenURIPrefix(uint16 roundNumber, string memory prefix)
        public onlyOwnerOrAdmin notPermanent
    {
        Round storage round = rounds[roundNumber];
        round.tokenURIPrefix = prefix;

        emit TokenURIPrefixUpdated(roundNumber, prefix);
    }

    function safeMint(address receiver, uint256 quantity)
        private
        returns (bool)
    {
        _safeMint(receiver, quantity);
        return true;
    }



    /**
     * Minting and transfer tokens
     * Only for owner
     */
    function adminMintTo(address[] calldata tos, uint256[] calldata quantities)
        external
        payable
        onlyOwnerOrAdmin 
        notPermanent
    {
        uint256 length = tos.length;
        if (length != quantities.length) {
            revert BadRequest("Input size not match");
        }

        uint256 totalQuantity = 0;

        for (uint256 i = 0; i < tos.length; i++) {
            totalQuantity += quantities[i];
        }

        Round memory currentRound = rounds[currentRoundNumber];
        // check if minting does not exceed the maximum tokens for the round
        uint256 maxMintingId = currentRound.maxMintingId;

        if (!_isTokenAvailable(totalQuantity, maxMintingId)) {
            revert ExceedMaximumForTheRound();
        }

        for (uint256 i = 0; i < length; i++) {
            require(safeMint(tos[i], quantities[i]));
        }
    }

    /**
     * Transfer multiple tokens to an account
     */
    function transferBatch(uint256[] calldata tokenIds, address to)
        external
        nonReentrant
        notPermanent
    {
        for (uint256 i = 0; i < tokenIds.length; i++) {
            safeTransferFrom(_msgSender(), to, tokenIds[i]);
        }
    }

    /**
     * Get token uri
     */
    function tokenURI(uint256 tokenId)
        public
        view
        override
        returns (string memory)
    {
        Round memory round = _getRoundByTokenId(tokenId);

        if (
            round.revealed &&
            keccak256(abi.encodePacked(round.tokenURIPrefix)) !=
            keccak256(abi.encodePacked(""))
        ) {
            return
                string(
                    abi.encodePacked(
                        baseURI,
                        round.tokenURIPrefix,
                        "/",
                        _toString(tokenId),
                        ".json"
                    )
                );
        } else {
            return
                string(
                    abi.encodePacked(
                        defaultUnrevealedURI,
                        _toString(tokenId),
                        ".json"
                    )
                );
        }
    }

    /**
     *  Trigger reveal process for the specified round
     *  For owner and admin
     */
    function setRevealBlock(uint16 roundNumber)
        public onlyOwnerOrAdmin notPermanent
    {
        Round storage round = rounds[roundNumber];

        if (round.lastMintedId == 0) {
            revert BadRequest("Round should be closed");
        }

        round.revealBlockNumber = block.number + revealBlockOffset;

        emit SetRevealBlock(round.revealBlockNumber);
    }

    /**
     *  Set random selection number based on entropy
     *  It set the reveal on
     */
    function setRandomSelection(uint16 roundNumber) public notPermanent {
        Round storage round = rounds[roundNumber];

        if (round.revealed) {
            revert AlreadyRevealed();
        }

        uint256 revealBlockNumber = round.revealBlockNumber;

        if (revealBlockNumber > block.number) {
            revert BadRequest("Random selection is not ready");
        }

        bytes32 entropy;

        if (blockhash(revealBlockNumber - 1) != 0) {
            entropy = keccak256(
                abi.encodePacked(
                    blockhash(revealBlockNumber),
                    blockhash(revealBlockNumber - 1),
                    block.timestamp
                )
            );
        } else {
            entropy = keccak256(
                abi.encodePacked(
                    blockhash(block.number - 1),
                    blockhash(block.number - 2),
                    block.timestamp
                )
            );
        }

        round.revealed = true;

        uint256 selected = _getRandomInRange(
            entropy,
            round.startId,
            round.lastMintedId
        );

        round.randomSelection = selected;

        emit Revealed(roundNumber);
    }

    /**
     *  Internal function to override the ERC721A _baseURI()
     */
    function _baseURI() internal view override returns (string memory) {
        return baseURI;
    }

    /**
     *  Get the base uri
     */
    function getBaseURI() external view returns (string memory) {
        return _baseURI();
    }

    /**
     * Set the base uri
     * Only for the owner
     */
    function setBaseURI(string memory _newBaseURI) external onlyOwner notPermanent {
        baseURI = _newBaseURI;
        emit BaseURIUpdated(_newBaseURI);
    }

    /**
     * Set the default unrevealed uri
     * Only for the owner
     */
    function setDefaultUnrevealedURI(string memory _defaultUnrevealedURI)
        external onlyOwner notPermanent
    {
        defaultUnrevealedURI = _defaultUnrevealedURI;
        emit DefaultUnrevealedURIUpdated(_defaultUnrevealedURI);
    }

    /**
     *  Paused the contract
     *  Only for the owner
     */
    function pause() external onlyOwner {
        _pause();
    }

    /**
     *  Unpause the contract
     *  Only for the owner
     */
    function unpause() external onlyOwner {
        _unpause();
    }

    /**
     *  Set the receiver
     *  Only for the owner
     */
    function setReceiver(address receiver) external onlyOwner {
        _receiver = receiver;
    }

    /**
     * Withdraw the balance in the contract
     */
    function withdraw() external payable onlyOwner {
        uint256 amount = address(this).balance;
        (bool success, ) = _receiver.call{value: amount}("");
        if (!success) {
            revert FailedToSendBalance();
        }
        emit Withdraw(_receiver, amount);
    }

    /**
     *  Fallback function
     */
    fallback() external payable {
        emit Received(_msgSender(), msg.value);
    }

    /**
     *  Fallback function
     */
    receive() external payable {
        emit Received(_msgSender(), msg.value);
    }

    /**
     * Set the 'perment' to true to prevent token uri change
     */
    function setPermanent() external onlyOwner {
        permanent = true;
    }

    function updateRevealBlockOffset(uint256 newOffset) external onlyOwner notPermanent {
        revealBlockOffset = newOffset;
    }

    function changeMaximumSupply(uint256 newMaximum) external onlyOwner notPermanent {
        maximumSupply = newMaximum;
    }

    /**
     *  Sanity check before transfer tokens
     */
    function _sanityCheckForMinting(Round memory currentRound, uint256 quantity)
        private
    {
        State currentState = getState();

        if (currentState != State.ON_MINTING) {
            revert MintingNotAllowed();
        }

        if (currentRound.mintingType == MintingType.ADMIN_ONLY 
            && owner() != _msgSender() && admin() != _msgSender()) {
            revert NotOwnerNorAdmin();
        }

        // check if not exceeding the maxAllowedMintingQuantity
        if (currentRound.maxMintingQuantity < quantity) {
            revert ExceedAllowedQuantity(
                currentRound.maxMintingQuantity
            );
        }

        // check if minting does not exceed the maximum tokens for the round
        if (!_isTokenAvailable(quantity, currentRound.maxMintingId)) {
            revert ExceedMaximumForTheRound();
        }

        // check if proper fee is received (except owner or admin)
        if (currentRound.mintingType == MintingType.REGULAR 
            && owner() != _msgSender() && admin() != _msgSender()) {
            uint256 neededFee = currentRound.mintingFee * quantity;
            if (neededFee != msg.value) revert NoMatchingFee();
        }
    }

    /**
     *  Check the availability of tokens mintable for the round
     */
    function _isTokenAvailable(uint256 quantity, uint256 maxId)
        private
        view
        returns (bool)
    {
        // check if minting does not exceed the maximum tokens for the round
        if ((_nextTokenId() + quantity) > (maxId + 1)) {
            return false;
        }

        return true;
    }

    /**
     *  Private function to get the round number with token id
     */
    function _getRoundByTokenId(uint256 tokenId)
        private
        view
        returns (Round memory r)
    {
        if (!_exists(tokenId)) revert NonExistingToken(tokenId);

        uint16 roundNumber = 1;

        while (roundNumber <= currentRoundNumber) {
            r = rounds[roundNumber];
            uint256 roundMax = r.lastMintedId != 0
                ? r.lastMintedId
                : r.maxMintingId;
            if (tokenId > roundMax) {
                roundNumber++;
                continue;
            }
            return r;
        }
    }

    function _getRandomInRange(
        bytes32 hash,
        uint256 begin,
        uint256 end
    ) private pure returns (uint256) {
        uint256 diff = end - begin + 1;
        return (uint256(hash) % diff) + begin;
    }

    function _startTokenId() internal pure override returns (uint256) {
        return 1;
    }
}

// SPDX-License-Identifier: MIT
// ERC721A Contracts v4.0.0
// Creator: Chiru Labs

pragma solidity ^0.8.4;

import './IERC721A.sol';

/**
 * @dev ERC721 token receiver interface.
 */
interface ERC721A__IERC721Receiver {
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

/**
 * @dev Implementation of https://eips.ethereum.org/EIPS/eip-721[ERC721] Non-Fungible Token Standard, including
 * the Metadata extension. Built to optimize for lower gas during batch mints.
 *
 * Assumes serials are sequentially minted starting at _startTokenId() (defaults to 0, e.g. 0, 1, 2, 3..).
 *
 * Assumes that an owner cannot have more than 2**64 - 1 (max value of uint64) of supply.
 *
 * Assumes that the maximum token id cannot exceed 2**256 - 1 (max value of uint256).
 */
contract ERC721A is IERC721A {
    // Mask of an entry in packed address data.
    uint256 private constant BITMASK_ADDRESS_DATA_ENTRY = (1 << 64) - 1;

    // The bit position of `numberMinted` in packed address data.
    uint256 private constant BITPOS_NUMBER_MINTED = 64;

    // The bit position of `numberBurned` in packed address data.
    uint256 private constant BITPOS_NUMBER_BURNED = 128;

    // The bit position of `aux` in packed address data.
    uint256 private constant BITPOS_AUX = 192;

    // Mask of all 256 bits in packed address data except the 64 bits for `aux`.
    uint256 private constant BITMASK_AUX_COMPLEMENT = (1 << 192) - 1;

    // The bit position of `startTimestamp` in packed ownership.
    uint256 private constant BITPOS_START_TIMESTAMP = 160;

    // The bit mask of the `burned` bit in packed ownership.
    uint256 private constant BITMASK_BURNED = 1 << 224;
    
    // The bit position of the `nextInitialized` bit in packed ownership.
    uint256 private constant BITPOS_NEXT_INITIALIZED = 225;

    // The bit mask of the `nextInitialized` bit in packed ownership.
    uint256 private constant BITMASK_NEXT_INITIALIZED = 1 << 225;

    // The tokenId of the next token to be minted.
    uint256 private _currentIndex;

    // The number of tokens burned.
    uint256 private _burnCounter;

    // Token name
    string private _name;

    // Token symbol
    string private _symbol;

    // Mapping from token ID to ownership details
    // An empty struct value does not necessarily mean the token is unowned.
    // See `_packedOwnershipOf` implementation for details.
    //
    // Bits Layout:
    // - [0..159]   `addr`
    // - [160..223] `startTimestamp`
    // - [224]      `burned`
    // - [225]      `nextInitialized`
    mapping(uint256 => uint256) private _packedOwnerships;

    // Mapping owner address to address data.
    //
    // Bits Layout:
    // - [0..63]    `balance`
    // - [64..127]  `numberMinted`
    // - [128..191] `numberBurned`
    // - [192..255] `aux`
    mapping(address => uint256) private _packedAddressData;

    // Mapping from token ID to approved address.
    mapping(uint256 => address) private _tokenApprovals;

    // Mapping from owner to operator approvals
    mapping(address => mapping(address => bool)) private _operatorApprovals;

    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
        _currentIndex = _startTokenId();
    }

    /**
     * @dev Returns the starting token ID. 
     * To change the starting token ID, please override this function.
     */
    function _startTokenId() internal view virtual returns (uint256) {
        return 0;
    }

    /**
     * @dev Returns the next token ID to be minted.
     */
    function _nextTokenId() internal view returns (uint256) {
        return _currentIndex;
    }

    /**
     * @dev Returns the total number of tokens in existence.
     * Burned tokens will reduce the count. 
     * To get the total number of tokens minted, please see `_totalMinted`.
     */
    function totalSupply() public view override returns (uint256) {
        // Counter underflow is impossible as _burnCounter cannot be incremented
        // more than `_currentIndex - _startTokenId()` times.
        unchecked {
            return _currentIndex - _burnCounter - _startTokenId();
        }
    }

    /**
     * @dev Returns the total amount of tokens minted in the contract.
     */
    function _totalMinted() internal view returns (uint256) {
        // Counter underflow is impossible as _currentIndex does not decrement,
        // and it is initialized to `_startTokenId()`
        unchecked {
            return _currentIndex - _startTokenId();
        }
    }

    /**
     * @dev Returns the total number of tokens burned.
     */
    function _totalBurned() internal view returns (uint256) {
        return _burnCounter;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        // The interface IDs are constants representing the first 4 bytes of the XOR of
        // all function selectors in the interface. See: https://eips.ethereum.org/EIPS/eip-165
        // e.g. `bytes4(i.functionA.selector ^ i.functionB.selector ^ ...)`
        return
            interfaceId == 0x01ffc9a7 || // ERC165 interface ID for ERC165.
            interfaceId == 0x80ac58cd || // ERC165 interface ID for ERC721.
            interfaceId == 0x5b5e139f; // ERC165 interface ID for ERC721Metadata.
    }

    /**
     * @dev See {IERC721-balanceOf}.
     */
    function balanceOf(address owner) public view override returns (uint256) {
        if (owner == address(0)) revert BalanceQueryForZeroAddress();
        return _packedAddressData[owner] & BITMASK_ADDRESS_DATA_ENTRY;
    }

    /**
     * Returns the number of tokens minted by `owner`.
     */
    function _numberMinted(address owner) internal view returns (uint256) {
        return (_packedAddressData[owner] >> BITPOS_NUMBER_MINTED) & BITMASK_ADDRESS_DATA_ENTRY;
    }

    /**
     * Returns the number of tokens burned by or on behalf of `owner`.
     */
    function _numberBurned(address owner) internal view returns (uint256) {
        return (_packedAddressData[owner] >> BITPOS_NUMBER_BURNED) & BITMASK_ADDRESS_DATA_ENTRY;
    }

    /**
     * Returns the auxillary data for `owner`. (e.g. number of whitelist mint slots used).
     */
    function _getAux(address owner) internal view returns (uint64) {
        return uint64(_packedAddressData[owner] >> BITPOS_AUX);
    }

    /**
     * Sets the auxillary data for `owner`. (e.g. number of whitelist mint slots used).
     * If there are multiple variables, please pack them into a uint64.
     */
    function _setAux(address owner, uint64 aux) internal {
        uint256 packed = _packedAddressData[owner];
        uint256 auxCasted;
        assembly { // Cast aux without masking.
            auxCasted := aux
        }
        packed = (packed & BITMASK_AUX_COMPLEMENT) | (auxCasted << BITPOS_AUX);
        _packedAddressData[owner] = packed;
    }

    /**
     * Returns the packed ownership data of `tokenId`.
     */
    function _packedOwnershipOf(uint256 tokenId) private view returns (uint256) {
        uint256 curr = tokenId;

        unchecked {
            if (_startTokenId() <= curr)
                if (curr < _currentIndex) {
                    uint256 packed = _packedOwnerships[curr];
                    // If not burned.
                    if (packed & BITMASK_BURNED == 0) {
                        // Invariant:
                        // There will always be an ownership that has an address and is not burned
                        // before an ownership that does not have an address and is not burned.
                        // Hence, curr will not underflow.
                        //
                        // We can directly compare the packed value.
                        // If the address is zero, packed is zero.
                        while (packed == 0) {
                            packed = _packedOwnerships[--curr];
                        }
                        return packed;
                    }
                }
        }
        revert OwnerQueryForNonexistentToken();
    }

    /**
     * Returns the unpacked `TokenOwnership` struct from `packed`.
     */
    function _unpackedOwnership(uint256 packed) private pure returns (TokenOwnership memory ownership) {
        ownership.addr = address(uint160(packed));
        ownership.startTimestamp = uint64(packed >> BITPOS_START_TIMESTAMP);
        ownership.burned = packed & BITMASK_BURNED != 0;
    }

    /**
     * Returns the unpacked `TokenOwnership` struct at `index`.
     */
    function _ownershipAt(uint256 index) internal view returns (TokenOwnership memory) {
        return _unpackedOwnership(_packedOwnerships[index]);
    }

    /**
     * @dev Initializes the ownership slot minted at `index` for efficiency purposes.
     */
    function _initializeOwnershipAt(uint256 index) internal {
        if (_packedOwnerships[index] == 0) {
            _packedOwnerships[index] = _packedOwnershipOf(index);
        }
    }

    /**
     * Gas spent here starts off proportional to the maximum mint batch size.
     * It gradually moves to O(1) as tokens get transferred around in the collection over time.
     */
    function _ownershipOf(uint256 tokenId) internal view returns (TokenOwnership memory) {
        return _unpackedOwnership(_packedOwnershipOf(tokenId));
    }

    /**
     * @dev See {IERC721-ownerOf}.
     */
    function ownerOf(uint256 tokenId) public view override returns (address) {
        return address(uint160(_packedOwnershipOf(tokenId)));
    }

    /**
     * @dev See {IERC721Metadata-name}.
     */
    function name() public view virtual override returns (string memory) {
        return _name;
    }

    /**
     * @dev See {IERC721Metadata-symbol}.
     */
    function symbol() public view virtual override returns (string memory) {
        return _symbol;
    }

    /**
     * @dev See {IERC721Metadata-tokenURI}.
     */
    function tokenURI(uint256 tokenId) public view virtual override returns (string memory) {
        if (!_exists(tokenId)) revert URIQueryForNonexistentToken();

        string memory baseURI = _baseURI();
        return bytes(baseURI).length != 0 ? string(abi.encodePacked(baseURI, _toString(tokenId))) : '';
    }

    /**
     * @dev Base URI for computing {tokenURI}. If set, the resulting URI for each
     * token will be the concatenation of the `baseURI` and the `tokenId`. Empty
     * by default, can be overriden in child contracts.
     */
    function _baseURI() internal view virtual returns (string memory) {
        return '';
    }

    /**
     * @dev Casts the address to uint256 without masking.
     */
    function _addressToUint256(address value) private pure returns (uint256 result) {
        assembly {
            result := value
        }
    }

    /**
     * @dev Casts the boolean to uint256 without branching.
     */
    function _boolToUint256(bool value) private pure returns (uint256 result) {
        assembly {
            result := value
        }
    }

    /**
     * @dev See {IERC721-approve}.
     */
    function approve(address to, uint256 tokenId) public override {
        address owner = address(uint160(_packedOwnershipOf(tokenId)));
        if (to == owner) revert ApprovalToCurrentOwner();

        if (_msgSenderERC721A() != owner)
            if (!isApprovedForAll(owner, _msgSenderERC721A())) {
                revert ApprovalCallerNotOwnerNorApproved();
            }

        _tokenApprovals[tokenId] = to;
        emit Approval(owner, to, tokenId);
    }

    /**
     * @dev See {IERC721-getApproved}.
     */
    function getApproved(uint256 tokenId) public view override returns (address) {
        if (!_exists(tokenId)) revert ApprovalQueryForNonexistentToken();

        return _tokenApprovals[tokenId];
    }

    /**
     * @dev See {IERC721-setApprovalForAll}.
     */
    function setApprovalForAll(address operator, bool approved) public virtual override {
        if (operator == _msgSenderERC721A()) revert ApproveToCaller();

        _operatorApprovals[_msgSenderERC721A()][operator] = approved;
        emit ApprovalForAll(_msgSenderERC721A(), operator, approved);
    }

    /**
     * @dev See {IERC721-isApprovedForAll}.
     */
    function isApprovedForAll(address owner, address operator) public view virtual override returns (bool) {
        return _operatorApprovals[owner][operator];
    }

    /**
     * @dev See {IERC721-transferFrom}.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        _transfer(from, to, tokenId);
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) public virtual override {
        safeTransferFrom(from, to, tokenId, '');
    }

    /**
     * @dev See {IERC721-safeTransferFrom}.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) public virtual override {
        _transfer(from, to, tokenId);
        if (to.code.length != 0)
            if (!_checkContractOnERC721Received(from, to, tokenId, _data)) {
                revert TransferToNonERC721ReceiverImplementer();
            }
    }

    /**
     * @dev Returns whether `tokenId` exists.
     *
     * Tokens can be managed by their owner or approved accounts via {approve} or {setApprovalForAll}.
     *
     * Tokens start existing when they are minted (`_mint`),
     */
    function _exists(uint256 tokenId) internal view returns (bool) {
        return
            _startTokenId() <= tokenId &&
            tokenId < _currentIndex && // If within bounds,
            _packedOwnerships[tokenId] & BITMASK_BURNED == 0; // and not burned.
    }

    /**
     * @dev Equivalent to `_safeMint(to, quantity, '')`.
     */
    function _safeMint(address to, uint256 quantity) internal {
        _safeMint(to, quantity, '');
    }

    /**
     * @dev Safely mints `quantity` tokens and transfers them to `to`.
     *
     * Requirements:
     *
     * - If `to` refers to a smart contract, it must implement
     *   {IERC721Receiver-onERC721Received}, which is called for each safe transfer.
     * - `quantity` must be greater than 0.
     *
     * Emits a {Transfer} event.
     */
    function _safeMint(
        address to,
        uint256 quantity,
        bytes memory _data
    ) internal {
        uint256 startTokenId = _currentIndex;
        if (to == address(0)) revert MintToZeroAddress();
        if (quantity == 0) revert MintZeroQuantity();

        _beforeTokenTransfers(address(0), to, startTokenId, quantity);

        // Overflows are incredibly unrealistic.
        // balance or numberMinted overflow if current value of either + quantity > 1.8e19 (2**64) - 1
        // updatedIndex overflows if _currentIndex + quantity > 1.2e77 (2**256) - 1
        unchecked {
            // Updates:
            // - `balance += quantity`.
            // - `numberMinted += quantity`.
            //
            // We can directly add to the balance and number minted.
            _packedAddressData[to] += quantity * ((1 << BITPOS_NUMBER_MINTED) | 1);

            // Updates:
            // - `address` to the owner.
            // - `startTimestamp` to the timestamp of minting.
            // - `burned` to `false`.
            // - `nextInitialized` to `quantity == 1`.
            _packedOwnerships[startTokenId] =
                _addressToUint256(to) |
                (block.timestamp << BITPOS_START_TIMESTAMP) |
                (_boolToUint256(quantity == 1) << BITPOS_NEXT_INITIALIZED);

            uint256 updatedIndex = startTokenId;
            uint256 end = updatedIndex + quantity;

            if (to.code.length != 0) {
                do {
                    emit Transfer(address(0), to, updatedIndex);
                    if (!_checkContractOnERC721Received(address(0), to, updatedIndex++, _data)) {
                        revert TransferToNonERC721ReceiverImplementer();
                    }
                } while (updatedIndex < end);
                // Reentrancy protection
                if (_currentIndex != startTokenId) revert();
            } else {
                do {
                    emit Transfer(address(0), to, updatedIndex++);
                } while (updatedIndex < end);
            }
            _currentIndex = updatedIndex;
        }
        _afterTokenTransfers(address(0), to, startTokenId, quantity);
    }

    /**
     * @dev Mints `quantity` tokens and transfers them to `to`.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `quantity` must be greater than 0.
     *
     * Emits a {Transfer} event.
     */
    function _mint(address to, uint256 quantity) internal {
        uint256 startTokenId = _currentIndex;
        if (to == address(0)) revert MintToZeroAddress();
        if (quantity == 0) revert MintZeroQuantity();

        _beforeTokenTransfers(address(0), to, startTokenId, quantity);

        // Overflows are incredibly unrealistic.
        // balance or numberMinted overflow if current value of either + quantity > 1.8e19 (2**64) - 1
        // updatedIndex overflows if _currentIndex + quantity > 1.2e77 (2**256) - 1
        unchecked {
            // Updates:
            // - `balance += quantity`.
            // - `numberMinted += quantity`.
            //
            // We can directly add to the balance and number minted.
            _packedAddressData[to] += quantity * ((1 << BITPOS_NUMBER_MINTED) | 1);

            // Updates:
            // - `address` to the owner.
            // - `startTimestamp` to the timestamp of minting.
            // - `burned` to `false`.
            // - `nextInitialized` to `quantity == 1`.
            _packedOwnerships[startTokenId] =
                _addressToUint256(to) |
                (block.timestamp << BITPOS_START_TIMESTAMP) |
                (_boolToUint256(quantity == 1) << BITPOS_NEXT_INITIALIZED);

            uint256 updatedIndex = startTokenId;
            uint256 end = updatedIndex + quantity;

            do {
                emit Transfer(address(0), to, updatedIndex++);
            } while (updatedIndex < end);

            _currentIndex = updatedIndex;
        }
        _afterTokenTransfers(address(0), to, startTokenId, quantity);
    }

    /**
     * @dev Transfers `tokenId` from `from` to `to`.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     *
     * Emits a {Transfer} event.
     */
    function _transfer(
        address from,
        address to,
        uint256 tokenId
    ) private {
        uint256 prevOwnershipPacked = _packedOwnershipOf(tokenId);

        if (address(uint160(prevOwnershipPacked)) != from) revert TransferFromIncorrectOwner();

        bool isApprovedOrOwner = (_msgSenderERC721A() == from ||
            isApprovedForAll(from, _msgSenderERC721A()) ||
            getApproved(tokenId) == _msgSenderERC721A());

        if (!isApprovedOrOwner) revert TransferCallerNotOwnerNorApproved();
        if (to == address(0)) revert TransferToZeroAddress();

        _beforeTokenTransfers(from, to, tokenId, 1);

        // Clear approvals from the previous owner.
        delete _tokenApprovals[tokenId];

        // Underflow of the sender's balance is impossible because we check for
        // ownership above and the recipient's balance can't realistically overflow.
        // Counter overflow is incredibly unrealistic as tokenId would have to be 2**256.
        unchecked {
            // We can directly increment and decrement the balances.
            --_packedAddressData[from]; // Updates: `balance -= 1`.
            ++_packedAddressData[to]; // Updates: `balance += 1`.

            // Updates:
            // - `address` to the next owner.
            // - `startTimestamp` to the timestamp of transfering.
            // - `burned` to `false`.
            // - `nextInitialized` to `true`.
            _packedOwnerships[tokenId] =
                _addressToUint256(to) |
                (block.timestamp << BITPOS_START_TIMESTAMP) |
                BITMASK_NEXT_INITIALIZED;

            // If the next slot may not have been initialized (i.e. `nextInitialized == false`) .
            if (prevOwnershipPacked & BITMASK_NEXT_INITIALIZED == 0) {
                uint256 nextTokenId = tokenId + 1;
                // If the next slot's address is zero and not burned (i.e. packed value is zero).
                if (_packedOwnerships[nextTokenId] == 0) {
                    // If the next slot is within bounds.
                    if (nextTokenId != _currentIndex) {
                        // Initialize the next slot to maintain correctness for `ownerOf(tokenId + 1)`.
                        _packedOwnerships[nextTokenId] = prevOwnershipPacked;
                    }
                }
            }
        }

        emit Transfer(from, to, tokenId);
        _afterTokenTransfers(from, to, tokenId, 1);
    }

    /**
     * @dev Equivalent to `_burn(tokenId, false)`.
     */
    function _burn(uint256 tokenId) internal virtual {
        _burn(tokenId, false);
    }

    /**
     * @dev Destroys `tokenId`.
     * The approval is cleared when the token is burned.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     *
     * Emits a {Transfer} event.
     */
    function _burn(uint256 tokenId, bool approvalCheck) internal virtual {
        uint256 prevOwnershipPacked = _packedOwnershipOf(tokenId);

        address from = address(uint160(prevOwnershipPacked));

        if (approvalCheck) {
            bool isApprovedOrOwner = (_msgSenderERC721A() == from ||
                isApprovedForAll(from, _msgSenderERC721A()) ||
                getApproved(tokenId) == _msgSenderERC721A());

            if (!isApprovedOrOwner) revert TransferCallerNotOwnerNorApproved();
        }

        _beforeTokenTransfers(from, address(0), tokenId, 1);

        // Clear approvals from the previous owner.
        delete _tokenApprovals[tokenId];

        // Underflow of the sender's balance is impossible because we check for
        // ownership above and the recipient's balance can't realistically overflow.
        // Counter overflow is incredibly unrealistic as tokenId would have to be 2**256.
        unchecked {
            // Updates:
            // - `balance -= 1`.
            // - `numberBurned += 1`.
            //
            // We can directly decrement the balance, and increment the number burned.
            // This is equivalent to `packed -= 1; packed += 1 << BITPOS_NUMBER_BURNED;`.
            _packedAddressData[from] += (1 << BITPOS_NUMBER_BURNED) - 1;

            // Updates:
            // - `address` to the last owner.
            // - `startTimestamp` to the timestamp of burning.
            // - `burned` to `true`.
            // - `nextInitialized` to `true`.
            _packedOwnerships[tokenId] =
                _addressToUint256(from) |
                (block.timestamp << BITPOS_START_TIMESTAMP) |
                BITMASK_BURNED | 
                BITMASK_NEXT_INITIALIZED;

            // If the next slot may not have been initialized (i.e. `nextInitialized == false`) .
            if (prevOwnershipPacked & BITMASK_NEXT_INITIALIZED == 0) {
                uint256 nextTokenId = tokenId + 1;
                // If the next slot's address is zero and not burned (i.e. packed value is zero).
                if (_packedOwnerships[nextTokenId] == 0) {
                    // If the next slot is within bounds.
                    if (nextTokenId != _currentIndex) {
                        // Initialize the next slot to maintain correctness for `ownerOf(tokenId + 1)`.
                        _packedOwnerships[nextTokenId] = prevOwnershipPacked;
                    }
                }
            }
        }

        emit Transfer(from, address(0), tokenId);
        _afterTokenTransfers(from, address(0), tokenId, 1);

        // Overflow not possible, as _burnCounter cannot be exceed _currentIndex times.
        unchecked {
            _burnCounter++;
        }
    }

    /**
     * @dev Internal function to invoke {IERC721Receiver-onERC721Received} on a target contract.
     *
     * @param from address representing the previous owner of the given token ID
     * @param to target address that will receive the tokens
     * @param tokenId uint256 ID of the token to be transferred
     * @param _data bytes optional data to send along with the call
     * @return bool whether the call correctly returned the expected magic value
     */
    function _checkContractOnERC721Received(
        address from,
        address to,
        uint256 tokenId,
        bytes memory _data
    ) private returns (bool) {
        try ERC721A__IERC721Receiver(to).onERC721Received(_msgSenderERC721A(), from, tokenId, _data) returns (
            bytes4 retval
        ) {
            return retval == ERC721A__IERC721Receiver(to).onERC721Received.selector;
        } catch (bytes memory reason) {
            if (reason.length == 0) {
                revert TransferToNonERC721ReceiverImplementer();
            } else {
                assembly {
                    revert(add(32, reason), mload(reason))
                }
            }
        }
    }

    /**
     * @dev Hook that is called before a set of serially-ordered token ids are about to be transferred. This includes minting.
     * And also called before burning one token.
     *
     * startTokenId - the first token id to be transferred
     * quantity - the amount to be transferred
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, `from`'s `tokenId` will be
     * transferred to `to`.
     * - When `from` is zero, `tokenId` will be minted for `to`.
     * - When `to` is zero, `tokenId` will be burned by `from`.
     * - `from` and `to` are never both zero.
     */
    function _beforeTokenTransfers(
        address from,
        address to,
        uint256 startTokenId,
        uint256 quantity
    ) internal virtual {}

    /**
     * @dev Hook that is called after a set of serially-ordered token ids have been transferred. This includes
     * minting.
     * And also called after one token has been burned.
     *
     * startTokenId - the first token id to be transferred
     * quantity - the amount to be transferred
     *
     * Calling conditions:
     *
     * - When `from` and `to` are both non-zero, `from`'s `tokenId` has been
     * transferred to `to`.
     * - When `from` is zero, `tokenId` has been minted for `to`.
     * - When `to` is zero, `tokenId` has been burned by `from`.
     * - `from` and `to` are never both zero.
     */
    function _afterTokenTransfers(
        address from,
        address to,
        uint256 startTokenId,
        uint256 quantity
    ) internal virtual {}

    /**
     * @dev Returns the message sender (defaults to `msg.sender`).
     *
     * If you are writing GSN compatible contracts, you need to override this function.
     */
    function _msgSenderERC721A() internal view virtual returns (address) {
        return msg.sender;
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function _toString(uint256 value) internal pure returns (string memory ptr) {
        assembly {
            // The maximum value of a uint256 contains 78 digits (1 byte per digit), 
            // but we allocate 128 bytes to keep the free memory pointer 32-byte word aliged.
            // We will need 1 32-byte word to store the length, 
            // and 3 32-byte words to store a maximum of 78 digits. Total: 32 + 3 * 32 = 128.
            ptr := add(mload(0x40), 128)
            // Update the free memory pointer to allocate.
            mstore(0x40, ptr)

            // Cache the end of the memory to calculate the length later.
            let end := ptr

            // We write the string from the rightmost digit to the leftmost digit.
            // The following is essentially a do-while loop that also handles the zero case.
            // Costs a bit more than early returning for the zero case,
            // but cheaper in terms of deployment and overall runtime costs.
            for { 
                // Initialize and perform the first pass without check.
                let temp := value
                // Move the pointer 1 byte leftwards to point to an empty character slot.
                ptr := sub(ptr, 1)
                // Write the character to the pointer. 48 is the ASCII index of '0'.
                mstore8(ptr, add(48, mod(temp, 10)))
                temp := div(temp, 10)
            } temp { 
                // Keep dividing `temp` until zero.
                temp := div(temp, 10)
            } { // Body of the for loop.
                ptr := sub(ptr, 1)
                mstore8(ptr, add(48, mod(temp, 10)))
            }
            
            let length := sub(end, ptr)
            // Move the pointer 32 bytes leftwards to make room for the length.
            ptr := sub(ptr, 32)
            // Store the length.
            mstore(ptr, length)
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// ERC721A Contracts v4.0.0
// Creator: Chiru Labs

pragma solidity ^0.8.4;

/**
 * @dev Interface of an ERC721A compliant contract.
 */
interface IERC721A {
    /**
     * The caller must own the token or be an approved operator.
     */
    error ApprovalCallerNotOwnerNorApproved();

    /**
     * The token does not exist.
     */
    error ApprovalQueryForNonexistentToken();

    /**
     * The caller cannot approve to their own address.
     */
    error ApproveToCaller();

    /**
     * The caller cannot approve to the current owner.
     */
    error ApprovalToCurrentOwner();

    /**
     * Cannot query the balance for the zero address.
     */
    error BalanceQueryForZeroAddress();

    /**
     * Cannot mint to the zero address.
     */
    error MintToZeroAddress();

    /**
     * The quantity of tokens minted must be more than zero.
     */
    error MintZeroQuantity();

    /**
     * The token does not exist.
     */
    error OwnerQueryForNonexistentToken();

    /**
     * The caller must own the token or be an approved operator.
     */
    error TransferCallerNotOwnerNorApproved();

    /**
     * The token must be owned by `from`.
     */
    error TransferFromIncorrectOwner();

    /**
     * Cannot safely transfer to a contract that does not implement the ERC721Receiver interface.
     */
    error TransferToNonERC721ReceiverImplementer();

    /**
     * Cannot transfer to the zero address.
     */
    error TransferToZeroAddress();

    /**
     * The token does not exist.
     */
    error URIQueryForNonexistentToken();

    struct TokenOwnership {
        // The address of the owner.
        address addr;
        // Keeps track of the start time of ownership with minimal overhead for tokenomics.
        uint64 startTimestamp;
        // Whether the token has been burned.
        bool burned;
    }

    /**
     * @dev Returns the total amount of tokens stored by the contract.
     *
     * Burned tokens are calculated here, use `_totalMinted()` if you want to count just minted tokens.
     */
    function totalSupply() external view returns (uint256);

    // ==============================
    //            IERC165
    // ==============================

    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[EIP section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);

    // ==============================
    //            IERC721
    // ==============================

    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId,
        bytes calldata data
    ) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be have been allowed to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Usage of this method is discouraged, use {safeTransferFrom} whenever possible.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the caller.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool _approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);

    // ==============================
    //        IERC721Metadata
    // ==============================

    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        require(!paused(), "Pausable: paused");
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        require(paused(), "Pausable: not paused");
        _;
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.4;

interface ILoversNft {
    error MintingNotAllowed();
    error ExceedMaximumForTheRound();
    error ExceedMaximumSupply();
    error ExceedAllowedQuantity(uint16 maximumAllowedQuantity);
    error MaxMintingIdLowerThanCurrentId();
    error NoMatchingFee();
    error NonExistingToken(uint256 tokenId);
    error FailedToSendBalance();
    error BadRequest(string reason);
    error AlreadyRevealed();
    error ImmutableState();

    enum MintingType {
        REGULAR,
        ADMIN_ONLY
    }

    enum State {
        DEPLOYED,
        PREPARE_MINTING,
        ON_MINTING,
        END_MINTING,
        ALL_MINTING_DONE
    }

    struct Round {
        uint16 roundNumber; // round number
        MintingType mintingType;
        uint256 startTime; // round start time
        uint256 endTime; // round end time (if zero, no end time)
        uint16 maxMintingQuantity; // max number of tokens for an account (if zero, no limit)
        uint256 mintingFee; // minting for the round

        uint256 maxMintingId; // maximum token id for this round
        uint256 startId; // beginning of the tokenId for the round
        uint256 lastMintedId; // last token id actually minted before the next round starts
        string tokenURIPrefix; // directory hash value for token uri
        bool revealed; // released token is revealed or not
        uint256 revealBlockNumber; // blocknubmer which entropy will calculated
        uint256 randomSelection;
        uint256 closedTime;  // round closed timestamp
    }

    event NewRoundCreated(uint16 roundNumber);
    event RoundEnded(uint16 roundNumber);
    event MintingTypeChanged(uint16 roundNumber, MintingType mintingType);
    event MaxMintingIdChanged(uint16 roundNumber, uint256 maxId);
    event StartTimeChanged(uint16 roundNumber, uint256 time);
    event EndTimeChanged(uint16 roundNumber, uint256 time);
    event MaxMintingQuantityChanged(uint16 roundNumber, uint16 count);
    event MintingFeeChanged(uint16 roundNumber, uint256 newFee);
    event AdminUpdated(uint16 roundNumber, address admin);
    event TokenURIPrefixUpdated(uint16 roundNumber, string prefix);
    event SetRevealBlock(uint256 revealBlockNumber);
    event Revealed(uint16 roundNumber);
    event BaseURIUpdated(string baseURI);
    event DefaultUnrevealedURIUpdated(string defaultUnrevealedURI);
    event Received(address called, uint256 amount);
    event Withdraw(address receiver, uint256 amount);
}

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

import "@openzeppelin/contracts/access/Ownable.sol";

abstract contract Adminable is Ownable {
    address private _admin;

    event AdminTransferred(address indexed previousAdmin, address indexed newAdmin);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner and admin.
     */
    constructor(address admin_) {
        _transferOwnership(_msgSender());
        _transferAdmin(admin_);
    }

    /**
     * @dev Returns the address of the current admin.
     */
    function admin() public view virtual returns (address) {
        return _admin;
    }

    error NotAdmin();
    error NotOwnerNorAdmin();

    /**
     * @dev Throws if called by any account other than the admin.
     */
    modifier onlyAdmin() {
        if(admin() != _msgSender()) {
            revert NotAdmin();
        }
        _;
        // require(admin() == _msgSender(), "Adminable: caller is not the admin");
        // _;
    }

    /**
     * @dev Throws if called by any account other than the owner nor the admin.
     */
    modifier onlyOwnerOrAdmin() {
        if(admin() != _msgSender() && owner() != _msgSender()) {
            revert NotOwnerNorAdmin();
        }
        _;

        // require(admin() == _msgSender() || owner() == _msgSender(), "Adminable: caller is not the owner nor the admin");
        // _;
    }

    /**
     * @dev Leaves the contract without admin. It will not be possible to call
     * `onlyAdmin` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing admin will leave the contract without an admin,
     * thereby removing any functionality that is only available to the admin.
     */
    function renounceAdmin() public virtual onlyOwner {
        _transferAdmin(address(0));
    }

    /**
     * @dev Transfers admin of the contract to a new account (`newAdmin`).
     * Can only be called by the current owner.
     */
    function transferAdmin(address newAdmin) public virtual onlyOwner {
        require(newAdmin != address(0), "Adminable: new admin is the zero address");
        _transferAdmin(newAdmin);
    }

    /**
     * @dev Transfers admin of the contract to a new account (`newAdmin`).
     * Internal function without access restriction.
     */
    function _transferAdmin(address newAdmin) internal virtual {
        address oldAdmin = _admin;
        _admin = newAdmin;
        emit AdminTransferred(oldAdmin, newAdmin);
    }
}