Cryo Explorer Ethereum Mainnet

//SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

import {STETH as STETH_ADDRESS, WSTETH as WSTETH_ADDRESS, BRKT_ETH as BRKTETH_ADDRESS, BRKT_MULTISIG, ROCKET_DEPOSIT_POOL as ROCKET_DEPOSIT_POOL_ADDRESS, RETH as RETH_ADDRESS, WETH as WETH_ADDRESS} from "script/Config.sol";
import {IBrktETHRouter} from "src/token/IBrktETHRouter.sol";
import {IERC20} from "openzeppelin-contracts/interfaces/IERC20.sol";
import {IBrktETH} from "src/token/IBrktETH.sol";
import {IstETH} from "src/interfaces/stETH/IstETH.sol";
import {IwstETH} from "src/interfaces/stETH/IwstETH.sol";
import {IWETH} from "src/interfaces/IWETH.sol";
import {RocketTokenRETHInterface} from "src/interfaces/rETH/RocketTokenRETHInterface.sol";
import {RocketDepositPoolInterface} from "src/interfaces/rETH/RocketDepositPoolInterface.sol";

contract BrktETHRouter is IBrktETHRouter {

    address constant OWNER = payable(BRKT_MULTISIG);

    IBrktETH public constant BRKTETH = IBrktETH(address(BRKTETH_ADDRESS));

    IstETH public constant STETH = IstETH(address(STETH_ADDRESS));
    IwstETH public constant WSTETH = IwstETH(address(WSTETH_ADDRESS));
    IWETH public constant WETH = IWETH(address(WETH_ADDRESS));

    RocketDepositPoolInterface public constant ROCKET_DEPOSIT_POOL = RocketDepositPoolInterface(address(ROCKET_DEPOSIT_POOL_ADDRESS));
    RocketTokenRETHInterface public constant RETH = RocketTokenRETHInterface(address(RETH_ADDRESS));

    modifier onlyOwner() {
        if (msg.sender != OWNER) revert Unauthorized();
        _;
    }

    constructor() {
        STETH.approve(address(WSTETH), type(uint256).max);
        WSTETH.approve(address(BRKTETH), type(uint256).max);
        RETH.approve(address(BRKTETH), type(uint256).max);
    }


    function ethToBrktETH(uint256 mintBrktAmount) public payable returns (uint256) {
        (address lstToken, uint256 brktAmount) = _ethToBrktETH(msg.value, mintBrktAmount);

        emit ETHToBrktETH(msg.sender, msg.value, mintBrktAmount, lstToken, false);

        return brktAmount;
    }

    function wethToBrktETH(uint256 amount, uint256 mintBrktAmount) public returns (uint256) {
        WETH.transferFrom(msg.sender, address(this), amount);
        WETH.withdraw(amount);

        (address lstToken, uint256 brktAmount) = _ethToBrktETH(amount, mintBrktAmount);

        emit ETHToBrktETH(msg.sender, amount, mintBrktAmount, lstToken, true);

        return brktAmount;
    }

    function _ethToBrktETH(uint256 value, uint256 mintBrktAmount) internal returns (address, uint256) {
        uint256 stEthLimit = lidoLimit();

        if (value <= stEthLimit) {
            uint256 brktAmount = _lidoEthToBrktETH(value, mintBrktAmount);
            BRKTETH.transfer(msg.sender, brktAmount);
            return (address(WSTETH), brktAmount);
        } else if (value <= rocketPoolLimit()) {
            uint256 brktAmount = _rocketPoolETHToBrktETH(value, mintBrktAmount);
            BRKTETH.transfer(msg.sender, brktAmount);
            return (address(RETH), brktAmount);
        } else {
            revert AmountOverStakingLimit();
        }
    }
    

    function lidoLimit() public view returns (uint256) {
        if (STETH.isStakingPaused()) {
            return 0;
        }
        return STETH.getCurrentStakeLimit();
    }

    function rocketPoolLimit() public view returns (uint256) {
        return ROCKET_DEPOSIT_POOL.getMaximumDepositAmount();
    }

    function _lidoEthToBrktETH(uint256 value, uint256 mintBrktAmount) internal returns (uint256) {
        uint256 stEthAmount = STETH.submit{value: value}(address(0));
        uint256 wstEthAmount = WSTETH.wrap(stEthAmount);
        return BRKTETH.mint(address(WSTETH), wstEthAmount, mintBrktAmount);
    }

    function _rocketPoolETHToBrktETH(uint256 value, uint256 mintBrktAmount) internal returns (uint256) {
        uint256 rEthBalanceBefore = RETH.balanceOf(address(this));

        ROCKET_DEPOSIT_POOL.deposit{value: value}();
        uint256 rEthAmount = RETH.balanceOf(address(this)) - rEthBalanceBefore;

        return BRKTETH.mint(address(RETH), rEthAmount, mintBrktAmount);
    }

    function recoverETH(uint256 amount) external onlyOwner {
        (bool success, ) = OWNER.call{value: amount}("");
        if (!success) revert ETHTransferFailed();
    }

    function withdrawToken(address token, uint256 amount) external onlyOwner {
        IERC20(token).transfer(OWNER, amount);
    }

    receive() external payable {}

    fallback() external payable {}
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

// Lido's Wrapped Staked ETH
address constant STETH = 0x17144556fd3424EDC8Fc8A4C940B2D04936d17eb;
address constant WSTETH = 0x7f39C581F595B53c5cb19bD0b3f8dA6c935E2Ca0;
// Rocket Pool's ETH
address constant RETH = 0xae78736Cd615f374D3085123A210448E74Fc6393;
address constant ROCKET_DEPOSIT_POOL = 0xDD3f50F8A6CafbE9b31a427582963f465E745AF8;
// Renzo's Staked ETH
address constant EZETH = 0xbf5495Efe5DB9ce00f80364C8B423567e58d2110;
address constant RENZO_RATE_PROVIDER = 0x387dBc0fB00b26fb085aa658527D5BE98302c84C;
// Etherfi's ETH
address constant WEETH = 0xCd5fE23C85820F7B72D0926FC9b05b43E359b7ee;
// Kelp's DAO rsETH
address constant RSETH = 0xA1290d69c65A6Fe4DF752f95823fae25cB99e5A7;
address constant RSETH_LRT_ORACLE = 0x349A73444b1a310BAe67ef67973022020d70020d;
// Ankr's ETH
address constant ANKRETH = 0xE95A203B1a91a908F9B9CE46459d101078c2c3cb;
// Stakewise's osETH
address constant OSETH = 0xf1C9acDc66974dFB6dEcB12aA385b9cD01190E38;
address constant STAKEWISE_VAULT_CONTROLLER = 0x2A261e60FB14586B474C208b1B7AC6D0f5000306;
// Coinbase's cbETH
address constant CBETH = 0xBe9895146f7AF43049ca1c1AE358B0541Ea49704;
// Frax's sfrxETH
address constant SFRXETH = 0xac3E018457B222d93114458476f3E3416Abbe38F;
// StakeStone's ETH
address constant STONE = 0x7122985656e38BDC0302Db86685bb972b145bD3C;
address constant STONE_ORACLE = 0xcF45D565252D56b5d377631982c8543e80a4c6a1;
// Wrapped Ether
address constant WETH = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;

// Bracket Contracts
address constant BRKT_ORACLE = 0x65e9aB10f4C4b9005E13195f94E4a2c6db041154;
address constant BRKT_ETH = 0x6C8550167BbD06D4610a6A443eCbEd84Bd1AccD6;
address constant BRKT_VAULT_FACTORY = 0xd206701137299635191Cf3cdf524B42923F97485;
address constant BRKT_VAULT_BEACON = 0x8c24Dda4B2124D0fD8334D731EA345c7745C00d1;
// Bracket Accounts
address constant BRKT_MULTISIG = 0x2375022E90098b6a1bf1Bda066F550022beb0BFA;
address constant NAV_UPDATER_MULTISIG = 0xc3AFCcfC3B59F9f5046477cd9410C263191161e2;
address constant BRKT_STRATEGY_DEPLOYER = 0xF037FaddD03f9E4FBe2c22314f483C4dca5b06A2;

/*
- Bracket Public Contracts -
Bracket Oracle: 0x65e9aB10f4C4b9005E13195f94E4a2c6db041154
BrktETH: 0x6C8550167BbD06D4610a6A443eCbEd84Bd1AccD6
Vault Factory: 0xd206701137299635191Cf3cdf524B42923F97485

- Implementation Contracts -
BrktETH Implementation: 0x22ad51aDcb087eD283F05173E1dB478C0bDC0640
Vault Beacon: 0x8c24Dda4B2124D0fD8334D731EA345c7745C00d1
*/

//SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

interface IBrktETHRouter {
    error AmountOverStakingLimit();
    error ETHTransferFailed();
    error Unauthorized();

    event ETHToBrktETH(address indexed sender, uint256 value, uint256 mintBrktAmount, address lstToken, bool wrapped);

    function ethToBrktETH(uint256 mintBrktAmount) external payable returns (uint256);

    function wethToBrktETH(uint256 amount, uint256 mintBrktAmount) external returns (uint256);

    function lidoLimit() external view returns (uint256);

    function rocketPoolLimit() external view returns (uint256);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";

//SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

import {IERC20} from "openzeppelin-contracts/interfaces/IERC20.sol";

interface IBrktETH is IERC20 {
    enum WithdrawalStatus {
        Unset,
        Queued,
        Ready,
        Completed
    }

    struct CollateralInfo {
        address collateral;
        bool whitelisted;
        uint256 totalDeposit;
    }

    error CollateralNotSupported();
    error CollateralNotWhitelisted();
    error CollateralNotBlacklisted();
    error CollateralAlreadyExists();
    error CollateralNotExists();
    error CollateralNotEmpty();
    error DiffArraySize();
    error MaxAmountInExceeded();
    error MaxCollateralsReached();
    error MinAmountOutNotMet();
    error NotEnoughCollateral();
    error SameCollateral();
    error WithdrawalAlreadyQueued();
    error WithdrawalNotReady();
    error ZeroAddress();
    error ZeroAmount();

    event Mint(address indexed user, address token, uint256 colAmount, uint256 brktAmount);
    event Mint(address indexed user, address[] tokens, uint256[] colAmounts, uint256 brktAmount);
    event WithdrawalScheduled(
        address indexed user, address token, uint256 colAmount, uint256 brktAmount, uint256 timestamp, bytes32 salt
    );
    event WithdrawalClaimed(address indexed user, address token, uint256 colAmount, uint256 scheduledTimestamp);

    /// @notice Mints brktETH tokens in exchange for a single collateral token
    /// @param token Address of the collateral token
    /// @param amount Amount of collateral token to deposit
    /// @param minBrktAmount Minimum amount of brktETH to receive
    /// @return brktAmount Amount of brktETH minted
    function mint(address token, uint256 amount, uint256 minBrktAmount) external returns (uint256 brktAmount);
    
    /// @notice Burns brktETH tokens and queues withdrawal of a specific collateral token
    /// @param token Address of the collateral token to receive
    /// @param amount Amount of brktETH to burn
    /// @param minColAmount Minimum amount of collateral token to receive
    /// @param salt A random bytes32 value to prevent hash collisions
    /// @return Amount of collateral token returned
    function burn(address token, uint256 amount, uint256 minColAmount, bytes32 salt) external returns (uint256);

    /// @notice Claims a previously scheduled withdrawal of collateral tokens
    /// @dev This function can only be called after the withdrawal delay has passed
    /// @param token The address of the collateral token to be withdrawn
    /// @param amount The amount of collateral token to be withdrawn
    /// @param salt A random bytes32 value to prevent hash collisions
    /// @param timestamp The timestamp when the withdrawal delay is over
    function claimWithdrawal(address token, uint256 amount, uint256 timestamp, bytes32 salt) external;

    /// @notice Calculates the amount of brktETH that would be minted for a given collateral deposit
    /// @param token Address of the collateral token
    /// @param amount Amount of collateral token
    /// @return Amount of brktETH that would be minted
    function calculateMint(address token, uint256 amount) external view returns (uint256);

    /// @notice Whitelists a collateral token
    /// @param token Address of the collateral token to whitelist
    function whitelistCollateral(address token) external;

    /// @notice Blacklists a collateral token
    /// @param token Address of the collateral token to blacklist
    function blacklistCollateral(address token) external;

    function getBracketRate() external view returns (uint256);

    function getCollateralInfo(address token) external view returns (CollateralInfo memory);

    /// @notice Sets the oracle contract address
    /// @param _oracle New oracle contract address
    function setOracle(address _oracle) external;

    /// @notice Adds a new collateral token
    /// @param token Address of the new collateral token
    function addCollateral(address token) external;

    /// @notice Gets the value in ETH for a given amount of brktETH
    /// @param amount Amount of brktETH
    /// @return Value in ETH
    function getBracketValue(uint256 amount) external view returns (uint256);

    /// @notice Gets the total value of all collateral held by the contract
    /// @return TVL in ETH
    function getTotalValue() external returns (uint256);

    /// @dev Calculates the amount of brktETH to mint for a given value
    /// @param value Value in ETH
    /// @return brktAmount Amount of brktETH to mint
    function calculateMint(uint256 value) external returns (uint256 brktAmount);

    /// @dev Calculates the amount of collateral to return when burning brktETH
    /// @param brktAmount Amount of brktETH to burn
    /// @param token Address of the collateral token to return
    /// @return Amount of collateral token to return
    function calculateBurn(uint256 brktAmount, address token) external returns (uint256);

    /// @notice Computes the hash of a withdrawal request
    /// @dev This hash is used as a unique identifier for each withdrawal request
    /// @param user The address of the user requesting the withdrawal
    /// @param token The address of the token to be withdrawn
    /// @param amount The amount of tokens to be withdrawn
    /// @param time The timestamp when the withdrawal will be available
    /// @param salt A random bytes32 value to prevent hash collisions
    /// @return The keccak256 hash of the encoded withdrawal request parameters
    function hashWithdrawal(address user, address token, uint256 amount, uint256 time, bytes32 salt) external returns (bytes32);

    /// @notice Retrieves the status and hash of a withdrawal request
    /// @dev This function checks the current status of a withdrawal and returns its corresponding hash
    /// @param user The address of the user who initiated the withdrawal
    /// @param token The address of the token to be withdrawn
    /// @param amount The amount of tokens to be withdrawn
    /// @param timestamp The timestamp when the withdrawal was initiated
    /// @param salt A random bytes32 value to prevent hash collisions
    /// @return WithdrawalStatus The current status of the withdrawal (Unset, Queued, Ready, or Completed)
    /// @return bytes32 The unique hash identifying the withdrawal request
    function getWithdrawalStatusAndHash(address user, address token, uint256 amount, uint256 timestamp, bytes32 salt)
        external
        view
        returns (WithdrawalStatus, bytes32);
}

//SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

import {IERC20} from "openzeppelin-contracts/interfaces/IERC20.sol";

interface IstETH is IERC20 {
    /**
     * @notice Send funds to the pool with optional _referral parameter
     * @dev This function is alternative way to submit funds. Supports optional referral address.
     * @return Amount of StETH shares generated
     */
    function submit(address _referral) external payable returns (uint256);

    /**
     * @notice Check staking state: whether it's paused or not
     */
    function isStakingPaused() external view returns (bool);

    /**
     * @notice Returns how much Ether can be staked in the current block
     * @dev Special return values:
     * - 2^256 - 1 if staking is unlimited;
     * - 0 if staking is paused or if limit is exhausted.
     */
    function getCurrentStakeLimit() external view returns (uint256);
}

//SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.25;

import {IERC20} from "openzeppelin-contracts/interfaces/IERC20.sol";

interface IwstETH is IERC20 {
    /**
     * @notice Exchanges stETH to wstETH
     * @param _stETHAmount amount of stETH to wrap in exchange for wstETH
     * @dev Requirements:
     *  - `_stETHAmount` must be non-zero
     *  - msg.sender must approve at least `_stETHAmount` stETH to this
     *    contract.
     *  - msg.sender must have at least `_stETHAmount` of stETH.
     * User should first approve _stETHAmount to the WstETH contract
     * @return Amount of wstETH user receives after wrap
     */
    function wrap(uint256 _stETHAmount) external returns (uint256);
}

//SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IWETH {

    function deposit() external payable;

    function withdraw(uint) external;

    function approve(address, uint) external returns(bool);

    function transfer(address, uint) external returns(bool);

    function transferFrom(address, address, uint) external returns(bool);

    function balanceOf(address) external view returns(uint);

}

/**
  *       .
  *      / \
  *     |.'.|
  *     |'.'|
  *   ,'|   |`.
  *  |,-'-|-'-.|
  *   __|_| |         _        _      _____           _
  *  | ___ \|        | |      | |    | ___ \         | |
  *  | |_/ /|__   ___| | _____| |_   | |_/ /__   ___ | |
  *  |    // _ \ / __| |/ / _ \ __|  |  __/ _ \ / _ \| |
  *  | |\ \ (_) | (__|   <  __/ |_   | | | (_) | (_) | |
  *  \_| \_\___/ \___|_|\_\___|\__|  \_|  \___/ \___/|_|
  * +---------------------------------------------------+
  * |    DECENTRALISED STAKING PROTOCOL FOR ETHEREUM    |
  * +---------------------------------------------------+
  *
  *  Rocket Pool is a first-of-its-kind Ethereum staking pool protocol, designed to
  *  be community-owned, decentralised, and trustless.
  *
  *  For more information about Rocket Pool, visit https://rocketpool.net
  *
  *  Authors: David Rugendyke, Jake Pospischil, Kane Wallmann, Darren Langley, Joe Clapis, Nick Doherty
  *
  */

pragma solidity >0.5.0 <0.9.0;

// SPDX-License-Identifier: GPL-3.0-only

import {IERC20} from "openzeppelin-contracts/interfaces/IERC20.sol";

interface RocketTokenRETHInterface is IERC20 {
    function getEthValue(uint256 _rethAmount) external view returns (uint256);
    function getRethValue(uint256 _ethAmount) external view returns (uint256);
    function getExchangeRate() external view returns (uint256);
    function getTotalCollateral() external view returns (uint256);
    function getCollateralRate() external view returns (uint256);
    function depositExcess() external payable;
    function depositExcessCollateral() external;
    function mint(uint256 _ethAmount, address _to) external;
    function burn(uint256 _rethAmount) external;
}

/**
  *       .
  *      / \
  *     |.'.|
  *     |'.'|
  *   ,'|   |`.
  *  |,-'-|-'-.|
  *   __|_| |         _        _      _____           _
  *  | ___ \|        | |      | |    | ___ \         | |
  *  | |_/ /|__   ___| | _____| |_   | |_/ /__   ___ | |
  *  |    // _ \ / __| |/ / _ \ __|  |  __/ _ \ / _ \| |
  *  | |\ \ (_) | (__|   <  __/ |_   | | | (_) | (_) | |
  *  \_| \_\___/ \___|_|\_\___|\__|  \_|  \___/ \___/|_|
  * +---------------------------------------------------+
  * |  DECENTRALISED STAKING PROTOCOL FOR ETHEREUM 2.0  |
  * +---------------------------------------------------+
  *
  *  Rocket Pool is a first-of-its-kind ETH2 Proof of Stake protocol, designed to be community owned,
  *  decentralised, trustless and compatible with staking in Ethereum 2.0.
  *
  *  For more information about Rocket Pool, visit https://rocketpool.net
  *
  *  Authors: David Rugendyke, Jake Pospischil, Kane Wallmann, Darren Langley, Joe Clapis, Nick Doherty
  *
  */

pragma solidity >0.5.0 <0.9.0;

// SPDX-License-Identifier: GPL-3.0-only

interface RocketDepositPoolInterface {
    function getBalance() external view returns (uint256);
    function getNodeBalance() external view returns (uint256);
    function getUserBalance() external view returns (int256);
    function getExcessBalance() external view returns (uint256);
    function deposit() external payable;
    function getMaximumDepositAmount() external view returns (uint256);
    function nodeDeposit(uint256 _totalAmount) external payable;
    function nodeCreditWithdrawal(uint256 _amount) external;
    function recycleDissolvedDeposit() external payable;
    function recycleExcessCollateral() external payable;
    function recycleLiquidatedStake() external payable;
    function assignDeposits() external;
    function maybeAssignDeposits() external returns (bool);
    function withdrawExcessBalance(uint256 _amount) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}