Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

library DataTypes {
    struct OptionInfo {
        address underlyingToken;
        uint48 expiry;
        address settlementToken;
        uint48 earliestExercise;
        uint128 notional;
        uint128 strike;
        AdvancedSettings advancedSettings;
    }

    struct AdvancedSettings {
        uint64 borrowCap;
        address oracle;
        bool premiumTokenIsUnderlying;
        bool votingDelegationAllowed;
        address allowedDelegateRegistry;
    }

    struct AuctionInitialization {
        address underlyingToken;
        address settlementToken;
        uint128 notional;
        AuctionParams auctionParams;
        AdvancedSettings advancedSettings;
    }

    struct AuctionParams {
        uint128 relStrike;
        uint48 tenor;
        uint48 earliestExerciseTenor;
        uint32 decayStartTime;
        uint32 decayDuration;
        uint64 relPremiumStart;
        uint64 relPremiumFloor;
        uint128 minSpot;
        uint128 maxSpot;
    }

    struct RFQInitialization {
        OptionInfo optionInfo;
        RFQQuote rfqQuote;
    }

    struct RFQQuote {
        uint128 premium;
        uint256 validUntil;
        bytes signature;
        address eip1271Maker;
    }

    enum BidStatus {
        Success,
        SpotPriceTooLow,
        OutOfRangeSpotPrice,
        OptionAlreadyMinted,
        PremiumTooLow
    }

    struct BidPreview {
        BidStatus status;
        address settlementToken;
        address underlyingToken;
        uint128 strike;
        uint48 expiry;
        uint48 earliestExercise;
        uint128 premium;
        address premiumToken;
        uint256 oracleSpotPrice;
        uint64 currAsk;
        uint128 matchFeeProtocol;
        uint128 matchFeeDistPartner;
    }

    enum RFQStatus {
        Expired,
        InvalidQuote,
        AlreadyExecuted,
        QuotesPaused,
        Success,
        InvalidEIP1271Signature
    }

    struct TakeQuotePreview {
        RFQStatus status;
        bytes32 msgHash;
        address quoter;
        uint128 premium;
        address premiumToken;
        uint128 matchFeeProtocol;
        uint128 matchFeeDistPartner;
    }

    struct SwapQuote {
        address takerGiveToken;
        uint256 takerGiveAmount;
        address makerGiveToken;
        uint256 makerGiveAmount;
        uint256 validUntil;
        bytes signature;
        address eip1271Maker;
    }

    struct OptionNaming {
        string name;
        string symbol;
    }

    struct MatchFeePerPair {
        bool isSet;
        uint96 matchFee;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

library Errors {
    error AlreadyInitialized();
    error DistPartnerFeeUnchanged();
    error FeeHandlerAlreadySet();
    error InvalidAddress();
    error InvalidArrayLength();
    error InvalidBid();
    error InvalidBorrowAmount();
    error InvalidBorrowCap();
    error InvalidBorrowTime();
    error InvalidDistPartnerFeeShare();
    error InvalidEarliestExercise();
    error InvalidEarliestExerciseTenor();
    error InvalidEIP1271Signature();
    error InvalidExpiry();
    error InvalidExercise();
    error InvalidExerciseAmount();
    error InvalidExerciseFee();
    error InvalidExerciseTime();
    error InvalidGetEscrowsQuery();
    error InvalidMatchFee();
    error InvalidMaxTimeSinceLastUpdate();
    error InvalidMintFee();
    error InvalidMinMaxSpot();
    error InvalidNotional();
    error InvalidOracle();
    error InvalidOracleAnswer();
    error InvalidOracleDecimals();
    error InvalidRelPremiums();
    error InvalidRepayAmount();
    error InvalidRepayTime();
    error InvalidSender();
    error InvalidStrike();
    error InvalidTakeQuote();
    error InvalidTenor();
    error InvalidTokenPair();
    error InvalidWithdraw();
    error NoAllowedDelegateRegistry();
    error NoOptionMinted();
    error NoOracle();
    error NotAnEscrow();
    error NothingToRedeem();
    error NothingToRepay();
    error OnlyAvailableForAuctions();
    error OracleAlreadySet(address oracleAddr);
    error OwnerAlreadySet();
    error SwapQuoteAlreadyUsed();
    error SwapQuoteExpired();
    error SwapQuotePaused();
    error VotingDelegationNotAllowed();
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
import {DataTypes} from "../DataTypes.sol";
import {Errors} from "../errors/Errors.sol";
import {IFeeHandler} from "../interfaces/IFeeHandler.sol";

contract FeeHandler is Ownable, IFeeHandler {
    using SafeERC20 for IERC20Metadata;

    uint256 internal constant BASE = 1 ether;
    uint96 internal constant MAX_MATCH_FEE = 0.2 ether;
    uint96 internal constant MAX_EXERCISE_FEE = 0.005 ether;

    uint96 public matchFee;
    uint96 public exerciseFee;
    uint96 public mintFee;

    mapping(address => mapping(address => DataTypes.MatchFeePerPair))
        public matchFeePerPair;
    mapping(address => uint256) public distPartnerFeeShare;

    constructor(
        address initOwner,
        uint96 _matchFee,
        uint96 _exerciseFee,
        uint96 _mintFee
    ) Ownable(initOwner) {
        setMatchFee(_matchFee);
        setExerciseFee(_exerciseFee);
        setMintFee(_mintFee);
    }

    function provisionFees(
        address /*token*/,
        uint256 /*amount*/
    ) external virtual {
        // @dev: placeholder to add fee distribution
        // logic in derived contracts
    }

    function withdraw(
        address to,
        address token,
        uint256 amount
    ) external virtual onlyOwner {
        IERC20Metadata(token).safeTransfer(to, amount);
        emit Withdraw(to, token, amount);
    }

    function getMatchFeeInfo(
        address distPartner,
        uint128 /*optionPremium*/,
        DataTypes.OptionInfo calldata optionInfo
    )
        external
        view
        virtual
        returns (uint256 _matchFee, uint256 _matchFeeDistPartnerShare)
    {
        DataTypes.MatchFeePerPair memory _matchFeePerPair = matchFeePerPair[
            optionInfo.underlyingToken
        ][optionInfo.settlementToken];
        // @dev: use pair specific match fee if set; else use general match fee;
        // additional match fee rules can be added in derived contracts
        _matchFee = _matchFeePerPair.isSet
            ? _matchFeePerPair.matchFee
            : matchFee;
        _matchFeeDistPartnerShare = distPartnerFeeShare[distPartner];
    }

    function getMintFeeInfo(
        address distPartner
    )
        external
        view
        virtual
        returns (uint256 _mintFee, uint256 _mintFeeDistPartnerShare)
    {
        _mintFee = mintFee;
        _mintFeeDistPartnerShare = distPartnerFeeShare[distPartner];
    }

    function setDistPartnerFeeShares(
        address[] calldata accounts,
        uint256[] calldata feeShares
    ) external virtual onlyOwner {
        if (accounts.length == 0 || accounts.length != feeShares.length) {
            revert Errors.InvalidArrayLength();
        }
        for (uint256 i = 0; i < accounts.length; ++i) {
            if (feeShares[i] > BASE) {
                revert Errors.InvalidDistPartnerFeeShare();
            }
            if (distPartnerFeeShare[accounts[i]] == feeShares[i]) {
                revert Errors.DistPartnerFeeUnchanged();
            }
            distPartnerFeeShare[accounts[i]] = feeShares[i];
        }

        emit SetDistPartnerFeeShares(accounts, feeShares);
    }

    function setMatchFee(uint96 _matchFee) public virtual onlyOwner {
        if (_matchFee > MAX_MATCH_FEE) {
            revert Errors.InvalidMatchFee();
        }
        matchFee = _matchFee;
        emit SetMatchFee(_matchFee);
    }

    function setMatchFeesPerPair(
        address[] calldata underlyingTokens,
        address[] calldata settlementTokens,
        DataTypes.MatchFeePerPair[] calldata _matchFeesPerPair
    ) public virtual onlyOwner {
        uint256 length = underlyingTokens.length;
        if (
            length == 0 ||
            length != settlementTokens.length ||
            length != _matchFeesPerPair.length
        ) {
            revert Errors.InvalidArrayLength();
        }

        for (uint256 i = 0; i < length; ++i) {
            DataTypes.MatchFeePerPair memory feePerPair = _matchFeesPerPair[i];

            if (feePerPair.isSet) {
                if (feePerPair.matchFee > MAX_MATCH_FEE) {
                    revert Errors.InvalidMatchFee();
                }
                matchFeePerPair[underlyingTokens[i]][
                    settlementTokens[i]
                ] = feePerPair;
            } else {
                delete matchFeePerPair[underlyingTokens[i]][
                    settlementTokens[i]
                ];
            }
        }

        emit SetMatchFeesPerPair(
            underlyingTokens,
            settlementTokens,
            _matchFeesPerPair
        );
    }

    function setExerciseFee(uint96 _exerciseFee) public virtual onlyOwner {
        if (_exerciseFee > MAX_EXERCISE_FEE) {
            revert Errors.InvalidExerciseFee();
        }
        exerciseFee = _exerciseFee;
        emit SetExerciseFee(_exerciseFee);
    }

    function setMintFee(uint96 _mintFee) public virtual onlyOwner {
        // @dev: use same fee cap as match fee
        if (_mintFee > MAX_MATCH_FEE) {
            revert Errors.InvalidMintFee();
        }
        mintFee = _mintFee;
        emit SetMintFee(_mintFee);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.24;

import {DataTypes} from "../DataTypes.sol";

/// @title IFeeHandler
/// @dev Interface for the FeeHandler contract.
/// Provides functionality for managing and distributing fees, and setting fee configurations.

interface IFeeHandler {
    /// @notice Emitted when fees are provisioned.
    /// @param token The address of the token in which fees are provisioned.
    /// @param amount The amount of the token provisioned as fees.
    event ProvisionFees(address indexed token, uint256 amount);

    /// @notice Emitted when tokens are withdrawn from the FeeHandler.
    /// @param to The address receiving the withdrawn tokens.
    /// @param token The address of the token being withdrawn.
    /// @param amount The amount of tokens withdrawn.
    event Withdraw(address indexed to, address indexed token, uint256 amount);

    /// @notice Emitted when match fee is set.
    /// @param matchFee The match fee set as a percentage.
    event SetMatchFee(uint256 matchFee);

    /// @notice Emitted when token pair-specific match fees are set or removed.
    /// @param underlyingTokens The underlying tokens per pair.
    /// @param settlementTokens The settlement tokens per pair.
    /// @param matchFeesPerPair The match fee structs per pair.
    event SetMatchFeesPerPair(
        address[] underlyingTokens,
        address[] settlementTokens,
        DataTypes.MatchFeePerPair[] matchFeesPerPair
    );

    /// @notice Emitted when mint fee is set.
    /// @param mintFee The mint fee set as a percentage.
    event SetMintFee(uint256 mintFee);

    /// @notice Emitted when the exercise fee is set.
    /// @param exerciseFee The exercise fee set as a percentage.
    event SetExerciseFee(uint96 exerciseFee);

    /// @notice Emitted when distribution partners are set.
    /// @param accounts The addresses of the distribution partners.
    /// @param feeShares The fee shares for given distribution partners.
    event SetDistPartnerFeeShares(address[] accounts, uint256[] feeShares);

    /// @notice Provisions fees in a specified token.
    /// @param token The address of the token in which fees are provisioned.
    /// @param amount The amount of the token provisioned as fees.
    function provisionFees(address token, uint256 amount) external;

    /// @notice Withdraws a specified amount of tokens to a given address.
    /// @param to The address receiving the withdrawn tokens.
    /// @param token The address of the token to withdraw.
    /// @param amount The amount of tokens to withdraw.
    function withdraw(address to, address token, uint256 amount) external;

    /// @notice Returns the match fee and distribution partner fee share for a given option match.
    /// @param distPartner The address of the distribution partner.
    /// @param optionPremium The given option premium.
    /// @param optionInfo The given option info.
    /// @return _matchFee The applicable match fee for the given option.
    /// @return _matchFeeDistPartnerShare The distribution partner's share of the match fee.
    function getMatchFeeInfo(
        address distPartner,
        uint128 optionPremium,
        DataTypes.OptionInfo calldata optionInfo
    )
        external
        view
        returns (uint256 _matchFee, uint256 _matchFeeDistPartnerShare);

    /// @notice Returns the mint fee and fee share for given distribution partner.
    /// @param distPartner The address of the distribution partner.
    /// @return _mintFee The mint fee as a percentage.
    /// @return _mintFeeDistPartnerShare The share of the mint fee for the distribution partner.
    function getMintFeeInfo(
        address distPartner
    )
        external
        view
        returns (uint256 _mintFee, uint256 _mintFeeDistPartnerShare);

    /// @notice Sets distribution partners and their status.
    /// @param accounts The addresses of the distribution partners.
    /// @param feeShares The fee shares for given distribution partners.
    function setDistPartnerFeeShares(
        address[] calldata accounts,
        uint256[] calldata feeShares
    ) external;

    /// @notice Sets the match fee and distribution partner share.
    /// @param _matchFee The match fee as a percentage.
    function setMatchFee(uint96 _matchFee) external;

    /// @notice Sets or removes a token pair-specific match fee.
    /// @param underlyingTokens The underlying tokens per pair.
    /// @param settlementTokens The settlement tokens per pair.
    /// @param _matchFeePerPair The match fee structs per pair.
    function setMatchFeesPerPair(
        address[] calldata underlyingTokens,
        address[] calldata settlementTokens,
        DataTypes.MatchFeePerPair[] calldata _matchFeePerPair
    ) external;

    /// @notice Sets the exercise fee.
    /// @param _exerciseFee The exercise fee as a percentage.
    function setExerciseFee(uint96 _exerciseFee) external;

    /// @notice Returns the match fee set in the FeeHandler.
    /// @return The match fee as a percentage.
    function matchFee() external view returns (uint96);

    /// @notice Returns the distribution fee share for a given account.
    /// @param account The account to query the distribution fee share for.
    /// @return The fee share for the given distribution partner.
    function distPartnerFeeShare(
        address account
    ) external view returns (uint256);

    /// @notice Returns the exercise fee set in the FeeHandler.
    /// @return The exercise fee as a percentage.
    function exerciseFee() external view returns (uint96);
}