Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "../utils/Context.sol";
import {ERC165} from "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` to `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/IAccessControl.sol)

pragma solidity ^0.8.20;

/**
 * @dev External interface of AccessControl declared to support ERC-165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted signaling this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call. This account bears the admin role (for the granted role).
     * Expected in cases where the role was granted using the internal {AccessControl-_grantRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.7.0) (security/Pausable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which allows children to implement an emergency stop
 * mechanism that can be triggered by an authorized account.
 *
 * This module is used through inheritance. It will make available the
 * modifiers `whenNotPaused` and `whenPaused`, which can be applied to
 * the functions of your contract. Note that they will not be pausable by
 * simply including this module, only once the modifiers are put in place.
 */
abstract contract Pausable is Context {
    /**
     * @dev Emitted when the pause is triggered by `account`.
     */
    event Paused(address account);

    /**
     * @dev Emitted when the pause is lifted by `account`.
     */
    event Unpaused(address account);

    bool private _paused;

    /**
     * @dev Initializes the contract in unpaused state.
     */
    constructor() {
        _paused = false;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is not paused.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    modifier whenNotPaused() {
        _requireNotPaused();
        _;
    }

    /**
     * @dev Modifier to make a function callable only when the contract is paused.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    modifier whenPaused() {
        _requirePaused();
        _;
    }

    /**
     * @dev Returns true if the contract is paused, and false otherwise.
     */
    function paused() public view virtual returns (bool) {
        return _paused;
    }

    /**
     * @dev Throws if the contract is paused.
     */
    function _requireNotPaused() internal view virtual {
        require(!paused(), "Pausable: paused");
    }

    /**
     * @dev Throws if the contract is not paused.
     */
    function _requirePaused() internal view virtual {
        require(paused(), "Pausable: not paused");
    }

    /**
     * @dev Triggers stopped state.
     *
     * Requirements:
     *
     * - The contract must not be paused.
     */
    function _pause() internal virtual whenNotPaused {
        _paused = true;
        emit Paused(_msgSender());
    }

    /**
     * @dev Returns to normal state.
     *
     * Requirements:
     *
     * - The contract must be paused.
     */
    function _unpause() internal virtual whenPaused {
        _paused = false;
        emit Unpaused(_msgSender());
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC-165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /**
     * @dev See {IERC165-supportsInterface}.
     */
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

// +========================================================+
// | ██╗          ██████╗███████╗   ███████╗██╗         ██╗ |
// |██╔╝         ██╔════╝██╔════╝   ██╔════╝██║         ╚██╗|
// |██║█████╗    ██║     █████╗     █████╗  ██║    █████╗██║|
// |██║╚════╝    ██║     ██╔══╝     ██╔══╝  ██║    ╚════╝██║|
// |╚██╗         ╚██████╗███████╗██╗██║     ██║         ██╔╝|
// | ╚═╝          ╚═════╝╚══════╝╚═╝╚═╝     ╚═╝         ╚═╝ |
// +========================================================+
//Visit https://CE.FI
//CE.FI: Decentralized AI-Driven Finance for Real-World Assets
//Stake with Confidence for Optimal APR Powered by DeFi, AI, and RWA!

//⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡⚡
//─────────────────────────────────────────────────────────────────────────────────────────────────────
//─██████─██████─██████─██████████████─██████─────────██████████████─████████████████───██████████████─
//─██░░██─██░░██─██░░██─██░░░░░░░░░░██─██░░██─────────██░░░░░░░░░░██─██░░░░░░░░░░░░██───██░░░░░░░░░░██─
//─██░░██─██░░██─██░░██─██░░██████░░██─██░░██─────────██░░██████████─██░░████████░░██───██████░░██████─
//─██░░██─██░░██─██░░██─██░░██──██░░██─██░░██─────────██░░██─────────██░░██────██░░██───────██░░██─────
//─██░░██─██░░██─██░░██─██░░██████░░██─██░░██─────────██░░██████████─██░░████████░░██───────██░░██─────
//─██░░██─██░░██─██░░██─██░░░░░░░░░░██─██░░██─────────██░░░░░░░░░░██─██░░░░░░░░░░░░██───────██░░██─────
//─██████─██████─██████─██░░██████░░██─██░░██─────────██░░██████████─██░░██████░░████───────██░░██─────
//──────────────────────██░░██──██░░██─██░░██─────────██░░██─────────██░░██──██░░██─────────██░░██─────
//─██████─██████─██████─██░░██──██░░██─██░░██████████─██░░██████████─██░░██──██░░██████─────██░░██─────
//─██░░██─██░░██─██░░██─██░░██──██░░██─██░░░░░░░░░░██─██░░░░░░░░░░██─██░░██──██░░░░░░██─────██░░██─────
//─██████─██████─██████─██████──██████─██████████████─██████████████─██████──██████████─────██████─────
//─────────────────────────────────────────────────────────────────────────────────────────────────────
//⚠️ Encounter a bug or issue? Email [email protected] to report and earn a bounty reward! 🚀
//💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡💡


import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
import "@openzeppelin/contracts/access/AccessControl.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/security/Pausable.sol";

contract CeFidApp is ReentrancyGuard, AccessControl, Pausable {
    using SafeERC20 for IERC20;

    bytes32 public constant ADMIN_ROLE = keccak256("ADMIN_ROLE");
    bytes32 public constant MANAGER_ROLE = keccak256("MANAGER_ROLE");

    address public admin;

    struct DepositRecord {
        uint256 amount;
        uint256 depositTime;
        bool withdrawn;
        uint256 lockInTime; // Added: Store lock-in time at deposit
        uint256 interestRate; // Added: Store interest rate at deposit
    }

    struct Pool {
        uint256 poolSize;
        uint256 interestRate;
        uint256 lockInTime;
        uint256 totalDeposits;
        uint256 lastUpdated;
        bool isETHPool;
        address tokenAddress;
        uint256 managerWithdrawals; // Added: Track manager withdrawals
        mapping(address => DepositRecord[]) deposits;
        address[] depositors;
    }

    struct Manager {
        uint256 limit;
        bool isActive;
    }

    mapping(uint256 => Pool) public pools;
    mapping(address => Manager) public managers;
    uint256 public poolCount;

    event Deposit(address indexed user, uint256 indexed poolId, uint256 amount);
    event Withdraw(
        address indexed user,
        uint256 indexed poolId,
        uint256 amount,
        uint256 reward
    );
    event ManagerWithdraw(
        address indexed manager,
        uint256 indexed poolId,
        uint256 amount
    );
    event PoolCreated(
        uint256 indexed poolId,
        bool isETHPool,
        address tokenAddress
    );
    event PoolUpdated(
        uint256 indexed poolId,
        uint256 interestRate,
        uint256 lockInTime
    );
    event ManagerAdded(address indexed manager, uint256 limit);
    event ManagerLimitUpdated(address indexed manager, uint256 newLimit);
    event ManagerRemoved(address indexed manager);

    modifier onlyAdmin() {
        require(hasRole(ADMIN_ROLE, msg.sender), "Not an admin");
        _;
    }

    modifier onlyManager() {
        require(hasRole(MANAGER_ROLE, msg.sender), "Not a manager");
        _;
    }

    modifier validPool(uint256 poolId) {
        require(poolId < poolCount, "Invalid pool ID");
        _;
    }

    constructor() {
        admin = msg.sender;
        _grantRole(ADMIN_ROLE, admin);
    }

    // 🔹 ADMIN FUNCTIONS
    function addETHPool(
        uint256 poolSize,
        uint256 interestRate,
        uint256 lockInTime
    ) public onlyAdmin whenNotPaused {
        require(poolSize > 0, "Invalid pool size");
        require(interestRate > 0, "Interest rate must be greater than 0");
        require(lockInTime > 0, "Lock-in time must be greater than 0");

        uint256 poolId = poolCount++;
        Pool storage pool = pools[poolId];
        pool.poolSize = poolSize;
        pool.interestRate = interestRate;
        pool.lockInTime = lockInTime;
        pool.isETHPool = true;
        pool.tokenAddress = address(0);
        pool.lastUpdated = block.timestamp;

        emit PoolCreated(poolId, true, address(0));
    }

    function addERC20Pool(
        uint256 poolSize,
        uint256 interestRate,
        uint256 lockInTime,
        address tokenAddress
    ) public onlyAdmin whenNotPaused {
        require(poolSize > 0, "Invalid pool size");
        require(interestRate > 0, "Interest rate must be greater than 0");
        require(lockInTime > 0, "Lock-in time must be greater than 0");
        require(tokenAddress != address(0), "Invalid token address");

        uint256 poolId = poolCount++;
        Pool storage pool = pools[poolId];
        pool.poolSize = poolSize;
        pool.interestRate = interestRate;
        pool.lockInTime = lockInTime;
        pool.isETHPool = false;
        pool.tokenAddress = tokenAddress;
        pool.lastUpdated = block.timestamp;

        emit PoolCreated(poolId, false, tokenAddress);
    }

    function updatePool(
        uint256 poolId,
        uint256 interestRate,
        uint256 lockInTime
    ) public onlyAdmin validPool(poolId) whenNotPaused {
        require(interestRate > 0, "Interest rate must be greater than 0");
        require(lockInTime > 0, "Lock-in time must be greater than 0");

        Pool storage pool = pools[poolId];
        pool.interestRate = interestRate;
        pool.lockInTime = lockInTime;

        emit PoolUpdated(poolId, interestRate, lockInTime);
    }

    function addManager(address manager, uint256 limit)
        public
        onlyAdmin
        whenNotPaused
    {
        require(manager != address(0), "Invalid manager address");
        require(limit > 0, "Limit must be greater than 0");

        managers[manager] = Manager({limit: limit, isActive: true});
        _grantRole(MANAGER_ROLE, manager);

        emit ManagerAdded(manager, limit);
    }

    function updateManagerLimit(address manager, uint256 newLimit)
        public
        onlyAdmin
        whenNotPaused
    {
        require(newLimit > 0, "New limit must be greater than 0");
        require(managers[manager].isActive, "Manager is not active");

        managers[manager].limit = newLimit;

        emit ManagerLimitUpdated(manager, newLimit);
    }

    function removeManager(address manager) public onlyAdmin whenNotPaused {
        require(managers[manager].isActive, "Manager is not active");

        managers[manager].isActive = false;
        _revokeRole(MANAGER_ROLE, manager);

        emit ManagerRemoved(manager);
    }

    function pause() public onlyAdmin {
        _pause();
    }

    function unpause() public onlyAdmin {
        _unpause();
    }

    // 🔹 USER FUNCTIONS
    function deposit(uint256 poolId, uint256 amount)
        public
        payable
        nonReentrant
        validPool(poolId)
        whenNotPaused
    {
        require(amount > 0, "Deposit amount must be greater than 0");

        Pool storage pool = pools[poolId];
        require(
            pool.totalDeposits + amount <= pool.poolSize,
            "Exceeds pool size"
        );

        if (pool.isETHPool) {
            require(msg.value == amount, "ETH amount mismatch");
            pool.totalDeposits += msg.value;
        } else {
            IERC20(pool.tokenAddress).safeTransferFrom(
                msg.sender,
                address(this),
                amount
            );
            pool.totalDeposits += amount;
        }

        if (pool.deposits[msg.sender].length == 0) {
            pool.depositors.push(msg.sender);
        }

        pool.deposits[msg.sender].push(
            DepositRecord({
                amount: amount,
                depositTime: block.timestamp,
                withdrawn: false,
                lockInTime: pool.lockInTime, // Store lock-in time
                interestRate: pool.interestRate // Store interest rate
            })
        );

        pool.lastUpdated = block.timestamp;

        emit Deposit(msg.sender, poolId, amount);
    }

    function withdraw(uint256 poolId)
        public
        nonReentrant
        validPool(poolId)
        whenNotPaused
    {
        Pool storage pool = pools[poolId];
        uint256 totalWithdrawable = 0;
        uint256 totalReward = 0;

        DepositRecord[] storage userDeposits = pool.deposits[msg.sender];

        for (uint256 i = 0; i < userDeposits.length; ) {
            DepositRecord storage depositRecord = userDeposits[i];

            if (
                !depositRecord.withdrawn &&
                block.timestamp >=
                depositRecord.depositTime + depositRecord.lockInTime // Use stored lock-in time
            ) {
                uint256 reward = (depositRecord.amount *
                    depositRecord.interestRate * // Use stored interest rate
                    (block.timestamp - depositRecord.depositTime)) /
                    (365 days * 10000);
                totalReward += reward;
                totalWithdrawable += depositRecord.amount;
                depositRecord.withdrawn = true;
            }

            unchecked {
                i++;
            }
        }

        require(totalWithdrawable > 0, "No unlocked funds to withdraw");

        pool.totalDeposits -= totalWithdrawable;
        uint256 totalPayout = totalWithdrawable + totalReward;

        require(
            getAvailablePoolBalance(poolId) >= totalPayout,
            "Insufficient contract balance"
        );

        if (pool.isETHPool) {
            (bool success, ) = msg.sender.call{value: totalPayout}("");
            require(success, "ETH withdrawal failed");
        } else {
            IERC20(pool.tokenAddress).safeTransfer(msg.sender, totalPayout);
        }

        emit Withdraw(msg.sender, poolId, totalWithdrawable, totalReward);
    }

    // 🔹 MANAGER FUNCTIONS
    function withdrawByManager(uint256 poolId, uint256 amount)
        public
        nonReentrant
        onlyManager
        validPool(poolId)
        whenNotPaused
    {
        Pool storage pool = pools[poolId];
        Manager storage manager = managers[msg.sender];

        require(manager.isActive, "Manager is inactive");
        require(amount > 0, "Withdrawal amount must be greater than 0");
        require(amount <= manager.limit, "Exceeds manager's withdrawal limit");
        require(
            getAvailablePoolBalance(poolId) >= amount,
            "Insufficient pool balance"
        );

        // Update manager's limit and pool state
        manager.limit -= amount;
        pool.managerWithdrawals += amount; // Track manager withdrawals

        // Transfer funds
        if (pool.isETHPool) {
            (bool success, ) = msg.sender.call{value: amount}("");
            require(success, "ETH withdrawal failed");
        } else {
            IERC20(pool.tokenAddress).safeTransfer(msg.sender, amount);
        }

        emit ManagerWithdraw(msg.sender, poolId, amount);
    }

    // 🔹 PUBLIC READ FUNCTIONS
    function getDepositors(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (address[] memory)
    {
        return pools[poolId].depositors;
    }

    function getUserDeposits(uint256 poolId, address user)
        public
        view
        validPool(poolId)
        returns (DepositRecord[] memory)
    {
        return pools[poolId].deposits[user];
    }

    function getTotalDeposits(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        return pools[poolId].totalDeposits;
    }

    function getPoolSize(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        return pools[poolId].poolSize;
    }

    function getPoolPercentageFull(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        Pool storage pool = pools[poolId];
        require(pool.poolSize > 0, "Pool size must be greater than 0");
        return (pool.totalDeposits * 100) / pool.poolSize;
    }

    function getUserDeposit(uint256 poolId, address user)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        uint256 totalDeposit = 0;
        DepositRecord[] storage userDeposits = pools[poolId].deposits[user];

        for (uint256 i = 0; i < userDeposits.length; ) {
            if (!userDeposits[i].withdrawn) {
                totalDeposit += userDeposits[i].amount;
            }
            unchecked {
                i++;
            }
        }

        return totalDeposit;
    }

    function getUserReward(uint256 poolId, address user)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        Pool storage pool = pools[poolId];
        uint256 totalReward = 0;

        DepositRecord[] storage userDeposits = pool.deposits[user];

        for (uint256 i = 0; i < userDeposits.length; ) {
            DepositRecord storage depositRecord = userDeposits[i];

            // Only calculate reward for non-withdrawn deposits
            if (!depositRecord.withdrawn) {
                uint256 timeElapsed = block.timestamp -
                    depositRecord.depositTime;
                uint256 reward = (depositRecord.amount *
                    depositRecord.interestRate *
                    timeElapsed) / (365 days * 10000);
                totalReward += reward;
            }

            unchecked {
                i++;
            }
        }

        return totalReward;
    }

    function getMaxWithdrawableAmount(uint256 poolId, address user)
        public
        view
        validPool(poolId)
        returns (uint256, uint256)
    {
        Pool storage pool = pools[poolId];
        uint256 totalWithdrawable = 0;
        uint256 totalReward = 0;

        DepositRecord[] storage userDeposits = pool.deposits[user];

        for (uint256 i = 0; i < userDeposits.length; ) {
            DepositRecord storage depositRecord = userDeposits[i];

            if (
                !depositRecord.withdrawn &&
                block.timestamp >=
                depositRecord.depositTime + depositRecord.lockInTime
            ) {
                uint256 reward = (depositRecord.amount *
                    depositRecord.interestRate *
                    (block.timestamp - depositRecord.depositTime)) /
                    (365 days * 10000);
                totalReward += reward;
                totalWithdrawable += depositRecord.amount;
            }

            unchecked {
                i++;
            }
        }

        return (totalWithdrawable, totalReward);
    }

    function getAvailablePoolBalance(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        Pool storage pool = pools[poolId];
        if (pool.isETHPool) {
            return address(this).balance - pool.managerWithdrawals;
        } else {
            return
                IERC20(pool.tokenAddress).balanceOf(address(this)) -
                pool.managerWithdrawals;
        }
    }

    function getInterestRate(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        return pools[poolId].interestRate;
    }

    function getLockInTime(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (uint256)
    {
        return pools[poolId].lockInTime;
    }

    function getIsETHPool(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (bool)
    {
        return pools[poolId].isETHPool;
    }

    function getTokenAddress(uint256 poolId)
        public
        view
        validPool(poolId)
        returns (address)
    {
        return pools[poolId].tokenAddress;
    }

    function getUnlockTimeAndAmountsForActiveDeposits(
        uint256 poolId,
        address user
    )
        public
        view
        validPool(poolId)
        returns (uint256[] memory unlockTimestamps, uint256[] memory amounts)
    {
        Pool storage pool = pools[poolId];
        DepositRecord[] storage userDeposits = pool.deposits[user];

        // Count the number of active deposits (not withdrawn)
        uint256 activeCount = 0;
        for (uint256 i = 0; i < userDeposits.length; i++) {
            if (!userDeposits[i].withdrawn) {
                activeCount++;
            }
        }

        // Initialize arrays to store the unlock timestamps and amounts
        unlockTimestamps = new uint256[](activeCount);
        amounts = new uint256[](activeCount);
        uint256 index = 0;

        // Iterate through deposits and collect unlock timestamps and amounts for active deposits
        for (uint256 i = 0; i < userDeposits.length; i++) {
            DepositRecord storage depositRecord = userDeposits[i];

            if (!depositRecord.withdrawn) {
                uint256 unlockTimestamp = depositRecord.depositTime +
                    depositRecord.lockInTime;
                unlockTimestamps[index] = unlockTimestamp;
                amounts[index] = depositRecord.amount;
                index++;
            }
        }

        return (unlockTimestamps, amounts);
    }
}