Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface IGetCCIPAdmin {
  /// @notice Returns the admin of the token.
  /// @dev This method is named to never conflict with existing methods.
  function getCCIPAdmin() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC6093.sol)
pragma solidity ^0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * All two of these values are immutable: they can only be set once during
     * construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /**
     * @dev See {IERC20-totalSupply}.
     */
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /**
     * @dev See {IERC20-balanceOf}.
     */
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /**
     * @dev See {IERC20-allowance}.
     */
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner` s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner` s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

import { IERC20Errors } from "./interfaces/ierc20errors.sol";
import { IERC20 } from "./interfaces/ierc20.sol";

import { ERC20Allocatable } from "./base/erc20allocatable.sol";
import { ERC20Exchangeable } from "./base/erc20exchangeable.sol";

contract OneXMM is ERC20Allocatable, ERC20Exchangeable {
    modifier isApproved(address account) {
        require(_approvedDepositors[account], "Not Approved");
        _;
    }

    /**********
     * Events *
     **********/
    event DepositorStatusChanged(address indexed account, bool status);
    event Deposited(address indexed from, uint256 amountETH, uint256 amountToken);
    event ChangedBack(address indexed beneficiary, uint256 amountTokens);
    event ChangedBackFor(address indexed beneficiary, address tokenReceived, uint256 amount);
    event Withdrawn(address indexed from, uint256 amount);   

    /**************
     * Properties *
     **************/
    mapping(address account => bool) private _approvedDepositors;

    /**
     * @dev Constructor
     * @param symbol_ The symbol of the token
     * @param name_ The name of the token
     * @param initialSupply_ The initial supply
     * @param initialOwnerAllocation_ The initial allocation to the owner
     */
    constructor(string memory symbol_, string memory name_, uint32 initialSupply_, uint32 initialOwnerAllocation_)
        ERC20Allocatable(msg.sender, initialSupply_, name_, symbol_, 18)
        ERC20Exchangeable(msg.sender) payable {

        // Owners is allocated with his share of the initial supply
        uint256 amount = uint256(initialOwnerAllocation_) * (10 ** 18);
        allocate(msg.sender, amount);
    }

    receive() external payable {
        emit Deposited(msg.sender, msg.value, 0);
    }

    /// @notice Adds an approved depositor who will be able to deposit ETH against Token
    function changeDepositorStatus(address account, bool status) external onlyOwner {
        _approvedDepositors[account] = status;
        emit DepositorStatusChanged(account, status);
    }

    /// @notice Enables a user to deposit ETH and receive Tokens in exchange
    /// @dev The conversion rate applies at a fixed rate, updated by Owner
    function depositEther() external payable ethDepositIsAllowed isApproved(msg.sender) returns(uint256 amountToken) {
        uint256 amountETH = msg.value;
        if (amountETH == 0) return 0;

        amountToken = uint256((amountETH * uint256(EthExchangeRate)) / uint256(_precision));
        
        if (amountToken > _availableTokens) {
            // We compute the number of ETH corresponding to the amount of tokens available
            amountETH = (_availableTokens * uint256(_precision)) / uint256(EthExchangeRate);
            amountToken = _availableTokens;

            address payable receiver = payable(msg.sender);
            // We transfer back extra ETH to the msg.sender
            receiver.call{value:msg.value - amountETH}("");
        }

        _update(address(this), msg.sender, amountToken);

        emit Deposited(msg.sender, amountETH, amountToken);
        emit Allocated(msg.sender, amountToken);
    }

    /// @notice Enables owner to send back some tokens to the Token contract
    function ownerTransfersBack(uint256 amount) external onlyOwner {
        if (amount > balanceOf(_owner)) revert IERC20Errors.ERC20InsufficientBalance(_owner, balanceOf(_owner), amount);
        _update(_owner, address(this), amount);
    }

    /// @notice Enables a user to sell back an amount of Tokens against ETH
    /// if there is enough ETH available, and if the change is authorized.
    /// @dev Sold-back tokens are automatically burnt.
    /// @param amountToken The amount of tokens to be exchanged
    function sellBack(uint128 amountToken) external ethExchangeIsAllowed {
        if (balanceOf(msg.sender) < uint256(amountToken)) revert IERC20Errors.ERC20InsufficientBalance(msg.sender, balanceOf(msg.sender), amountToken);
        
        uint256 amt256 = uint256(amountToken);
        uint256 amountETH = (amt256 * uint256(_precision)) / uint256(EthExchangeRate);
        uint256 availableQuantityOfETH = address(this).balance;

        if (amountETH > availableQuantityOfETH) {
            amountETH = availableQuantityOfETH;
            amountToken = uint128((amountETH * uint256(EthExchangeRate)) / uint256(_precision));
        }
        
        payable(msg.sender).call{value:amountETH}("");
        
        // Now we burn the tokens
        burn(amountToken);

        emit ChangedBack(msg.sender, amountETH);
        emit Withdrawn(msg.sender, amountToken);
    }

    /// @notice Enables a user to sell back an amount of Tokens against a preferred token
    /// if there is enough token available, and if the change is authorized.
    /// @dev Sold-back tokens are automatically burnt.
    /// @param amountToken The amount of tokens to be exchanged
    /// @param tokenToBeReceived The address of the token to be exchanged for
    function sellBackAgainst(uint128 amountToken, address tokenToBeReceived) external exchangeIsAllowedForToken(tokenToBeReceived) {
        if (balanceOf(msg.sender) < uint256(amountToken)) revert IERC20Errors.ERC20InsufficientBalance(msg.sender, balanceOf(msg.sender), amountToken);

        uint8 decimalAdjust = 18 - _approvedTokenDecimals[tokenToBeReceived];
        uint256 amt256 = uint256(amountToken);

        uint256 amountExpectedToken = (amt256 * uint256(_precision)) / uint256(_exchangeRates[tokenToBeReceived]);
        if (decimalAdjust != 0) amountExpectedToken /= (10 ** decimalAdjust);
        uint256 availableQuantity = getAvailableQuantityOfToken(tokenToBeReceived);

        // We make sure that the available quantity of expected token is bigger than the requested amount of expected token
        if (amountExpectedToken > availableQuantity) {
            amountExpectedToken = availableQuantity;
            // We adjust down the quantity of token to be delivered
            amountToken = uint128((amountExpectedToken * uint256(_exchangeRates[tokenToBeReceived])) / uint256(_precision));
        }
        
        // We transfer the expected to token to msg.sender
        // Then, we adjust msg.sender's balance
        IERC20(tokenToBeReceived).transfer(msg.sender, amountExpectedToken);
        
        // Now we burn the tokens
        burn(amountToken);

        emit ChangedBackFor(msg.sender, tokenToBeReceived, amountExpectedToken);
        emit Withdrawn(msg.sender, amountToken);
    }

    /// @notice Enables the Owner to buy back tokens from a user, in exchange of ETH and at a specified rate
    /// @param from The beneficiary
    /// @param amountToken The amount of tokens
    /// @param rate The conversion rate
    function buyBack(address payable from, uint128 amountToken, uint64 rate) external onlyOwner {
        if (from == address(0)) revert IERC20Errors.ERC20InvalidReceiver(from);
        if (balanceOf(from) < uint256(amountToken)) revert IERC20Errors.ERC20InsufficientBalance(msg.sender, balanceOf(msg.sender), amountToken);

        uint256 availableQuantityOfETH = address(this).balance;
        require (availableQuantityOfETH != 0, "E106");

        uint256 amountETH = (uint256(amountToken) * uint256(_precision)) / uint256(rate); 

        // We make sure that the available quantity of ETH is bigger than the expected ETH amount
        // If not, we adjust down the quantity of token to be withdrawn
        if (amountETH > availableQuantityOfETH) {
            amountETH = availableQuantityOfETH;
            amountToken = uint128((amountETH * uint256(rate)) / uint256(_precision));
        }

        // We check the allowance first
        // If allowance is not enough, it triggers an error
        _spendAllowance(from, _owner, amountToken);

        from.call{value:amountETH}("");
        _update(from, address(this), amountToken); // In this case, we don't burn the tokens; tokens can be reallocated.

        emit ChangedBack(from, amountETH);
        emit Withdrawn(from, amountToken);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

import { DurationUnits } from  "../enums.sol";
import { ERC20Vested } from "./utils/erc20vested.sol";
import { ERC20Burnable } from "./utils/erc20burnable.sol";

import { IERC20 } from "../interfaces/ierc20.sol";
import { IERC20Errors } from "../interfaces/ierc20errors.sol";

import { IGetCCIPAdmin } from "@chainlink/contracts-ccip/src/v0.8/ccip/interfaces/IGetCCIPAdmin.sol";
import { IBurnMint } from "../interfaces/iburnmint.sol";

contract ERC20Allocatable is ERC20Vested, IGetCCIPAdmin, IBurnMint {
    /// @dev Modifier that checks if the msg.sender is the ccipAdmin.
    // This function shall be called only when tokens are transferred from one chain to another.
    // Owner has no right to mint.
    modifier onlyMinter() {
        require(msg.sender == _ccipAdmin, "Denied");
        _;
    }

    /**********
     * Events *
     **********/
    /// @notice Event emitted when CCIP Admin is transferred to a new address
    event CCIPAdminTransferred(address indexed previousAdmin, address indexed newAdmin);
    /// @notice The Allocated event is triggered when Owner allocates some token to a beneficiary
    event Allocated(address indexed beneficiary, uint256 amount);

    /**************
     * Properties *
     **************/
    // Mapping to keep track of allowlisted destination chains.
    mapping(uint64 chainId => bool) private _allowlistedChains;

    // The address of the CCIP Admin
    address private _ccipAdmin;

    /***************
     * Constructor *
     ***************/
    constructor(address owner_, uint32 initialSupply_, string memory name_, string memory symbol_, uint8 decimals_)
        ERC20Vested(owner_, initialSupply_, name_, symbol_, decimals_)
    { }

    /// @notice Allocates a number of token to a beneficiary
    /// @param to The beneficiary
    /// @param amount The amount to allocate
    /// @param cliffDuration The duration of the cliff
    /// @param cliffDurationUnit The unit of the cliff duration
    /// @param upfrontRelease The amount released when cliff period ends
    /// @param vestingDuration The duration of the vesting
    /// @param vestingDurationUnit The unit of the vesting duration
    function allocateWithVesting(address to, uint256 amount, uint16 cliffDuration, DurationUnits cliffDurationUnit, uint8 upfrontRelease, uint16 vestingDuration, 
    DurationUnits vestingDurationUnit) external onlyOwner {
        uint vestingStart = _addDuration(block.timestamp, cliffDuration, cliffDurationUnit);
        allocateWithVesting(to,amount, vestingStart, upfrontRelease, vestingDuration, vestingDurationUnit);
    }

    /// @notice Allocates a number of token to a beneficiary
    /// @param to The beneficiary
    /// @param amount The amount to allocate
    /// @param cliffEnd The timsestamp of cliff end
    /// @param upfrontRelease The amount released when cliff period ends
    /// @param vestingDuration The duration of the vesting
    /// @param vestingDurationUnit The unit of the vesting duration
    function allocateWithVesting(address to, uint256 amount, uint cliffEnd, uint8 upfrontRelease, uint16 vestingDuration, DurationUnits vestingDurationUnit) 
    public onlyOwner {
        allocate(to, amount);

        if (upfrontRelease > 100) upfrontRelease = 100;
        _createVestingSchedule(to,upfrontRelease, cliffEnd, vestingDuration, vestingDurationUnit, amount);
    }

    /// @notice Gets whether a chain id is allowed
    function isChainIdAllowed(uint64 chainId) external view returns(bool) {
        return _allowlistedChains[chainId];
    }

    /// @notice Updates the allowlist status of a destination chain for transactions.
    /// @dev This function can only be called by the owner.
    /// @param _destinationChainSelector The selector of the destination chain to be updated.
    /// @param allowed The allowlist status to be set for the destination chain.
    function allowlistDestinationChain(uint64 _destinationChainSelector, bool allowed) external onlyOwner {
        _allowlistedChains[_destinationChainSelector] = allowed;
    }

    /// @notice Allocates a number of token to a beneficiary
    /// @param to The beneficiary
    /// @param amount The amount
    function allocate(address to, uint256 amount) public onlyOwner {
        require(to != address(0), "E103");
        if (amount > balanceOf(address(this))) revert IERC20Errors.ERC20AllocationFailed(amount, totalSupply());

        _update(address(this), to, amount);
        emit Allocated(to, amount);
    }

    /// @notice Allocates a number of token to a beneficiary
    /// @param to The beneficiaries
    /// @param amount The amounts
    function massAllocation(address[] memory to, uint256[] memory amount) external onlyOwner {
        require(to.length == amount.length, "E104");

        for (uint i = 0; i < to.length; i++) {
            allocate(to[i], amount[i]);
        }
    }

    /// @notice Returns the token administrator's address
    function getCCIPAdmin() external view returns(address) {
        return _ccipAdmin;
    }

    /// @notice Transfers the CCIPAdmin role to a new address
    /// @dev only the owner can call this function, NOT the current ccipAdmin, and 1-step ownership transfer is used.
    /// @param newAdmin The address to transfer the CCIPAdmin role to. Setting to address(0) is a valid way to revoke
    /// the role
    function setCCIPAdmin(address newAdmin) public onlyOwner {
        emit CCIPAdminTransferred(_ccipAdmin, newAdmin);
        _ccipAdmin = newAdmin;
    }

    /*******************
     *  IBurnMintImpl  *
     *******************/
    /// @notice Mints 'value' amount of tokens when a cross-chain transfer is performed
    /// @dev This function can only be called by the ccipAdmin.
    /// @param account The account to receive the tokens
    /// @param value The amount of tokens to be minted
    function mint(address account, uint256 value) public onlyMinter {
        if (totalSupply() + value > _cap) revert ERC20ExceededCap(totalSupply(), _cap);
        _mint(account, value);
        _availableTokens = totalSupply() - circulatingSupply();

        emit Minted(account, _ccipAdmin, value);
    }

    /// @inheritdoc ERC20Burnable
    function burn(uint256 amount) public override(ERC20Burnable) {
        // Owner or CCIPAdmin cannot burn non-allocated tokens
        if (msg.sender == _owner) {
            require(amount <= _availableTokens, "E1");
            super._update(address(this), address(0), amount);
        }
        else {
            super._burn(msg.sender, amount);
        }
        
        emit Burnt(amount);
    }

    /// @notice IBurnMint
    function burn(address account, uint256 amount) public override(IBurnMint) {
        if (account == msg.sender) burn(amount);
        else burnFrom(account, amount);
    }

    /// @inheritdoc ERC20Burnable
    function burnFrom(address account, uint256 amount) public override(ERC20Burnable, IBurnMint) {
        _spendAllowance(account, msg.sender, amount);

        super._burn(account, amount);
        emit Burnt(amount);
    }

    /********************/
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

import { IERC20 } from "../interfaces/ierc20.sol";
import { IExchangeable } from "../interfaces/iexchangeable.sol";

abstract contract ERC20Exchangeable is IExchangeable {
    /*************
     * Modifiers *
     *************/
     modifier _onlyOwner {
        require(msg.sender == _owner, "E0");
        _;
    }

    modifier ethDepositIsAllowed {
        require(EthDepositIsAllowed, "E2");
        _;
    }

    modifier ethExchangeIsAllowed {
        require(EthExchangeIsAllowed && EthExchangeRate != 0, "E3");
        _;
    }

    modifier exchangeIsAllowedForToken(address token) {
        require(_tokenIsApproved[token] && _exchangeIsAllowed[token] && _exchangeRates[token] != 0, "E4");
        _;
    }

    modifier tokenIsApproved(address token) {
        require(_tokenIsApproved[token], "E5");
        _;
    }

     /**************
     * Properties *
     **************/
     // Private Properties
     address private _owner;

    // Public properties linked to IExchangeable
    /// @notice Gets whether the exchange of ETH is allowed or not
    bool public EthExchangeIsAllowed;
    /// @notice Gets whether the deposit of ETH is allowed or not
    bool public EthDepositIsAllowed;
    /// @notice The exchange rate represents a real number with 4 digits precision
    uint64 public EthExchangeRate;

    uint16 internal _precision = 10_000;

    /// Parameters to manage other token exchanges
    mapping(address tokenAddress => bool) internal _tokenIsApproved;
    mapping(address tokenAddress => uint64) internal _exchangeRates;
    mapping(address tokenAddress => bool) internal _exchangeIsAllowed;

    /// @notice The list of tokens approved for exchange
    address[] public ApprovedTokens;
    mapping(address tokenAddress => uint8) internal _approvedTokenDecimals;

    /***************
     * Constructor *
     ***************/
    constructor(address owner_) {
        _owner = owner_;
        EthDepositIsAllowed = false;
        EthExchangeIsAllowed = false;
    }

    /// @notice Sets the change authorization status for ETH to false
    function removeEthExchangeAuthorization() external _onlyOwner {
        EthExchangeIsAllowed = false;
    }

    /// @notice Sets the change authorization status for a token to false
    function removeExchangeAuthorizationForToken(address tokenToBeReceived) external _onlyOwner tokenIsApproved(tokenToBeReceived) {
        _exchangeIsAllowed[tokenToBeReceived] = false;
    }

    /// @notice Sets whether the deposit of ETH against token is allowed or not
    /// @dev The exchange rate is expressed in pips
    function setEthDepositExchangeRate(uint64 exchangeRate) external _onlyOwner {
        EthExchangeRate = exchangeRate;
        EthDepositIsAllowed = true;
    }

    /// @notice Sets the ETH deposit authorization to false
    function removeEthDepositAuthorization() external _onlyOwner {
        EthDepositIsAllowed = false;
    }

    /// @notice Updates the exchange rate between ETH and the Token
    /// @dev The exchange rate is expressed in pips
    function updateEthExchangeRate(uint64 exchangeRate) external _onlyOwner {
        EthExchangeRate = exchangeRate;
        EthExchangeIsAllowed = true;
    }

    /// @notice Updates the exchange rate between a token and our Token
    /// @param  tokenToBeReceived The token to be received in exchange of our Token
    /// @param  exchangeRate The exchange rate, with 4 digits precision (in pips)
    function updateTokenExchangeRate(address tokenToBeReceived, uint64 exchangeRate) external _onlyOwner tokenIsApproved(tokenToBeReceived) {
        _exchangeRates[tokenToBeReceived] = exchangeRate;
        _exchangeIsAllowed[tokenToBeReceived] = true;
    }

    /// @notice Returns the quantity of ETH available for change against Token
    function getAvailableQuantityOfETH() external view returns(uint256) {
        return address(this).balance;
    }

    /// @notice Returns the latest exchange rate associated to the token to be received
    /// @return isAllowed true if the exchange is authorized
    /// @return rate the exchange rate
    function getExchangeInfoForToken(address tokenToBeReceived) external view tokenIsApproved(tokenToBeReceived) returns(bool isAllowed, uint64 rate) {
        isAllowed = _exchangeIsAllowed[tokenToBeReceived];
        rate = _exchangeRates[tokenToBeReceived];
    }

    /// @notice Returns the available quantity of a token to be exchanged
    function getAvailableQuantityOfToken(address tokenToBeReceived) public tokenIsApproved(tokenToBeReceived) returns(uint256 availableQuantity) {
        availableQuantity = 0;

        (bool success , bytes memory res) = tokenToBeReceived.call(abi.encodeWithSelector(IERC20.balanceOf.selector, address(this)));
        if (success) availableQuantity = abi.decode(res, (uint256));
    }

    /// @notice Adds a token which can be traded against our Token
    function addApprovedToken(address token, uint8 decimals) external _onlyOwner {
        require(decimals <= 18, "E105");
        if (_tokenIsApproved[token]) return;

        _tokenIsApproved[token] = true;
        _exchangeIsAllowed[token] = false;

        ApprovedTokens.push(token);
        _approvedTokenDecimals[token] = decimals;
    }

    /// @notice Gets approved tokens
    function getApprovedTokens() external view returns(address[] memory) {
        return ApprovedTokens;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Capped.sol)

pragma solidity >= 0.8.20;

import { ERC20CappedAndOwned } from "./erc20cappedandowned.sol";

/**
 * @dev Extension of {ERC20} that adds a cap to the supply of tokens.
 */
abstract contract ERC20Burnable is ERC20CappedAndOwned {
    /**********
     * Events *
     **********/
    /// @notice The Burnt event is triggered when tokens are burnt
    event Burnt(uint256 amount);

    /**************
     * Properties *
     **************/
    // Private Properties
    uint256 internal _availableTokens;

    /**
     * @notice Sets the value of the `cap`. This value is immutable, it can only be
     * set once during construction.
     */
    constructor(address owner_, uint32 initialSupply_, string memory name_, string memory symbol_, uint8 decimals_)
        ERC20CappedAndOwned(owner_, initialSupply_, name_, symbol_, decimals_) {}

    /**
     * @notice Gets the amount of tokens which remains to be allocated
     */
    function availableTokens() external view returns(uint256) {
        return _availableTokens;
    }

    /**
     * @notice Destroys a `amount` of tokens.
     * @param amount The amount of tokens to be burnt
     *
     * @dev The burn function allows the owner to burn tokens
     * which are available but not allocated.
     */
    function burn(uint256 amount) public virtual;

    /**
     * @notice Destroys a `amount` of tokens.
     * @param account The account to burn from
     * @param amount The amount of tokens to be burnt
     *
     */
    function burnFrom(address account, uint256 amount) public virtual;

    /**
     * @dev See {ERC20-_update}.
     */
    function _update(address from, address to, uint256 value) internal override(ERC20CappedAndOwned) {
        super._update(from, to, value);
        _availableTokens = totalSupply() - circulatingSupply();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/ERC20Capped.sol)

pragma solidity >= 0.8.20;

import { ERC20 } from "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import { Owned } from "./owned.sol";

/**
 * @dev Extension of {ERC20} that adds a cap to the supply of tokens.
 */
abstract contract ERC20CappedAndOwned is ERC20, Owned {
    uint256 internal _cap;

    /**
     * @notice Total supply cap has been exceeded.
     */
    error ERC20ExceededCap(uint256 increasedSupply, uint256 cap);

    /// @notice The decimal property
    uint8 private _decimals;

    /**
     * @notice Sets the value of the `cap`. This value is immutable, it can only be
     * set once during construction.
     */
    constructor(address owner_, uint32 initialSupply_, string memory name_, string memory symbol_, uint8 decimals_)
        ERC20(name_, symbol_)
        Owned(owner_) {

        _decimals = decimals_;
        _cap = uint256(initialSupply_) * (10 ** decimals_);

        // We set the initial supply to the Contract
        super._update(address(0), address(this), _cap);
    }

    /**
     * @notice Returns the token's number of decimals.
     */
    function decimals() public view override(ERC20) returns (uint8) {
        return _decimals;
    }

    /**
     * @notice Returns the cap of total supply.
     */
    function cap() external view returns (uint256) {
        return _cap;
    }

    /**
     * @notice The number of tokens which are circulating.
     * @dev The circulating supply is the total supply minus the amount of tokens held by the contract itself.
     */
    function circulatingSupply() public view returns (uint256) {
        return totalSupply() - balanceOf(address(this));
    }

    /**
     * @dev See {ERC20-_update}.
     */
    function _update(address from, address to, uint256 value) internal virtual override(ERC20) {
        if (from == address(0)) {
            uint256 maxSupply = totalSupply();
            uint256 circSupply = circulatingSupply();

            if (circSupply + value > maxSupply) revert ERC20ExceededCap(circSupply, maxSupply);
        }

        super._update(from, to, value);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

import { IERC20 } from  "../../interfaces/ierc20.sol";
import { IERC20Errors } from  "../../interfaces/ierc20errors.sol";

import { DurationUnits } from  "../../enums.sol";
import { VestingSchedule } from  "../../structures/vestingschedule.sol";

import { ERC20Burnable } from  "./erc20burnable.sol";

abstract contract ERC20Vested is ERC20Burnable {
    /**********
     * Events *
     **********/
    /// @notice Emitted when a vesting schedule is created
    event VestingScheduleCreated(address indexed beneficiary, uint start, uint end, uint8 upfrontRelease, uint256 amount);
    /// @notice Emitted when a vesting schedule is created
    event TokensAddedToVestingSchedule(address indexed beneficiary, uint256 amount);
    /// @notice Emitted when tokens are released
    event TokensReleased(address indexed beneficiary, uint256 amount);

    /*************
     * Modifiers *
     *************/
    /// @notice Modifier that checks if the contract is unlocked
    modifier unlocked() {
        require(_unlocked, "Locked");
        _;
    }

    /**************
     * Properties *
     **************/
    /// @notice The vesting schedules for each beneficiary
    mapping(address beneficiary => VestingSchedule) private _vestingSchedules;
    mapping(address beneficiary => bool) private _hasVestingSchedule;

    // Private properties
    bool private _unlocked = false;

    /***************
     * Constructor *
     ***************/
    constructor(address owner_, uint32 initialSupply_, string memory name_, string memory symbol_, uint8 decimals_)
        ERC20Burnable(owner_, initialSupply_, name_, symbol_, decimals_)
    {}

    /// @notice Transfers tokens from the msg sender to another address
    /// overrides the transfer function of ERC20
    function transfer(address to, uint256 value) public override unlocked returns(bool) {
        if (msg.sender == address(0)) revert IERC20Errors.ERC20InvalidSender(address(0));
        if (to == address(0)) revert IERC20Errors.ERC20InvalidReceiver(address(0));
        uint256 releasableAmount = _releaseTokens(msg.sender, value);
        require(releasableAmount >= value, "E102");

        return super.transfer(to, value);
    }

    /// @notice Transfers tokens from one address to another
    /// overrides the transferFrom function of ERC20
    function transferFrom(address from, address to, uint256 value) public override unlocked returns(bool) {
        if (from == address(0)) revert IERC20Errors.ERC20InvalidSender(address(0));
        if (to == address(0)) revert IERC20Errors.ERC20InvalidReceiver(address(0));
        uint256 releasableAmount = _releaseTokens(from, value);
        require(releasableAmount >= value, "E102");

        return super.transferFrom(from, to, value);
    }

    /// @notice Gets the remaining amount of tokens which are vested
    function getRemainingVestedAmount() public view returns(uint256 remainingVestedAmt) {
        remainingVestedAmt = 0;

        if (_hasVestingSchedule[msg.sender]) {
            VestingSchedule storage schedule = _vestingSchedules[msg.sender];
            remainingVestedAmt = schedule.totalAmount - schedule.released;
        }
    }

    /// @notice Gets the amount of vested tokens which can be withdrawn by the msg.sender
    function getReleasableAmount() external view returns(uint256 releasableAmt) {
        (releasableAmt, ) = _getReleasableAmount(msg.sender);
    }

    /// @notice Unlocks the contract and allows transfers to be made
    /// @dev This function can only be called to set the unlocked property to true
    // Once the contract is unlocked, it cannot be locked again
    function unlockTransfers() external onlyOwner {
        _unlocked = true;
    }

    /// @dev Gets the amount of vested tokens which can be withdrawn by the beneficiary
    function _getReleasableAmount(address beneficiary) internal view returns(uint256 releasableAmt, bool vestingEnded) {
        releasableAmt = 0;
        vestingEnded = false;

        if (_hasVestingSchedule[beneficiary]) {
            VestingSchedule storage schedule = _vestingSchedules[beneficiary];
            
            // if end of cliff period has not been reached, 0 can be released
            if (block.timestamp < schedule.start) return (releasableAmt, vestingEnded);
            if (block.timestamp >= schedule.end) {
                vestingEnded = true;
                releasableAmt = schedule.totalAmount - schedule.released;
                return (releasableAmt, vestingEnded);
            }
            
            uint256 upfrontRelease = uint256((schedule.totalAmount * schedule.upfrontRelease) / 100);
            releasableAmt = upfrontRelease + uint256(((schedule.totalAmount - upfrontRelease) * (block.timestamp - schedule.start)) / schedule.totalDuration);
            
            // Sanity check - we make sure to always release at max the total amount of tokens
            if (releasableAmt > schedule.totalAmount) releasableAmt = schedule.totalAmount;
            releasableAmt -= schedule.released;
        }
    }

    /// @dev Gets the amount of tokens which are not vested
    function _getNonVestedAmount(address beneficiary) internal view returns(uint256 nonVestedAmt) {
        nonVestedAmt = 0;

        if (_hasVestingSchedule[beneficiary]) {
            VestingSchedule storage schedule = _vestingSchedules[beneficiary];

            uint256 currentBalance = IERC20(address(this)).balanceOf(beneficiary);
            if (currentBalance > schedule.totalAmount) nonVestedAmt = currentBalance - (schedule.totalAmount - schedule.released);
        }
    }

    /// @dev Computes the amount of tokens which can be released and updates the schedule (if ever)
    function _releaseTokens(address beneficiary, uint256 amount) internal returns(uint256) {
        if (_hasVestingSchedule[beneficiary]) {
            (uint256 releasableAmount, bool canDelete) = _getReleasableAmount(beneficiary);
            uint256 extraAmount = 0;

            if (releasableAmount < amount) extraAmount = _getNonVestedAmount(beneficiary);
            else releasableAmount = amount;

            if (canDelete) {
                _hasVestingSchedule[beneficiary] = false;
                delete _vestingSchedules[beneficiary];
            } else {
                _vestingSchedules[beneficiary].released += releasableAmount;
                emit TokensReleased(beneficiary, releasableAmount);
            }
            
            return releasableAmount + extraAmount;
        }

        return amount;
    }

     /**
     * @dev Creates a vesting schedule
     * @param beneficiary The address of the beneficiary
     * @param upfrontRelease The amount released when cliff period ends
     * @param start The start UNIX timestamp of the vesting period - this can correspond to a cliff period
     * @param duration The duration of the vesting period in DurationUnits
     * @param durationUnit The units of the duration(0 = days, 1 = weeks, 2 = months)
     * @param amount The total amount of tokens to be vested
     */
    function _createVestingSchedule(address beneficiary, uint8 upfrontRelease, uint start, uint16 duration, DurationUnits durationUnit, uint256 amount) internal {
        // perform input checks
        require(beneficiary != address(0) && amount > 0 && start >= block.timestamp && duration > 0, "E101");

        // if beneficiary already has a vesting schedule, we just add the amount to the existing schedule
        if (_hasVestingSchedule[beneficiary]) {
            VestingSchedule storage schedule = _vestingSchedules[beneficiary];
            schedule.totalAmount += amount;
            emit TokensAddedToVestingSchedule(beneficiary, amount);
            return;
        }
        
        uint end = _addDuration(start, duration, durationUnit);
        
        // create the vesting schedule and add it to the list of schedules for the beneficiary
        _vestingSchedules[beneficiary] = VestingSchedule(beneficiary, upfrontRelease, start, end, end - start, amount, 0);
        _hasVestingSchedule[beneficiary] = true;

        emit VestingScheduleCreated(beneficiary, start, end, upfrontRelease, amount);
    }

    /*******************
     * Private Methods *
     *******************/
    /// @dev Adds a duration to a timestamp
    function _addDuration(uint start, uint16 duration, DurationUnits durationUnit) internal pure returns(uint) {
        if (durationUnit == DurationUnits.Days) return start + duration * 86_400;
        if (durationUnit == DurationUnits.Weeks) return start + duration * 604_800;
        return start + duration * 2_592_000;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

import { IOwned } from  "../../interfaces/iowned.sol";

abstract contract Owned is IOwned {
     /*****************
     * The modifiers *
     *****************/
    modifier onlyOwner {
        require(msg.sender == _owner, "Err0");
        _;
    }

    /**************
     * Properties *
     **************/
    // Private Properties
    address internal _owner;

    /**
     * @dev Sets the values for {owner}.
     */
    constructor(address owner_) {
        _owner = owner_;
    }

    /// @dev Returns the current owner of the contract
    function owner() external view returns (address) {
        return _owner;
    }

    /// @dev Changes the ownership of the contract
    /// @param newOwner The new owner
    function changeOwnership(address newOwner) external onlyOwner {
        _owner = newOwner;
        emit OwnerChanged(block.timestamp, msg.sender, newOwner);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.0;

enum LongShort { Long, Short }
enum FixingTypes { Previous, Next }
enum Terms { OneDay, OneWeek, TwoWeeks, ThreeWeeks, OneMonth, TwoMonths, ThreeMonths }
enum UpdateIntervals { OneMin, TwoMin, ThreeMin, FiveMin, TenMin, FifteenMin, TwentyMin, ThirtyMin, OneH, TwoH, ThreeH, FourH }
enum CompensatedSides {None, Long, Short, All}
enum OptionTypes { Call, Put }
enum DurationUnits { Days, Weeks, Months }

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

interface IBurnMint {
  /// @notice Emitted when new tokens have been minted by the CCIPAmdin
  event Minted(address indexed account, address indexed mintedby, uint256 amount);

  /// @notice Mints new tokens for a given address.
  /// @param account The address to mint the new tokens to.
  /// @param amount The number of tokens to be minted.
  /// @dev this function increases the total supply.
  function mint(address account, uint256 amount) external;

  /// @notice Burns tokens from a given address..
  /// @param account The address to burn tokens from.
  /// @param amount The number of tokens to be burned.
  /// @dev this function decreases the total supply.
  function burn(address account, uint256 amount) external;

  /// @notice Burns tokens from a given address..
  /// @param account The address to burn tokens from.
  /// @param amount The number of tokens to be burned.
  /// @dev this function decreases the total supply.
  function burnFrom(address account, uint256 amount) external;
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

interface IERC20 {
    /// @notice Emitted when `value` tokens are moved from one account to another
    event Transfer(address indexed from, address indexed to, uint256 value);

    /// @notice Emitted when the allowance of a `spender` for an `owner` is set
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /// @notice Returns the value of tokens in existence.
    function totalSupply() external view returns (uint256);

    /// @notice Returns the amount of tokens owned by account
    /// @param account The address of the account
    function balanceOf(address account) external view returns(uint256);

    /// @notice Transfers tokens
    /// @param to The recipient wallet
    /// @param value The amount to be transferred
    // Throws Transfer event
    function transfer(address to, uint256 value) external returns(bool);

    /// @notice Returns the remaining number of tokens that `spender` will be
    /// allowed to spend on behalf of `owner` through {transferFrom}. This is
    /// zero by default.
    /// @param owner The wallet which has given the allowance
    /// @param spender The spender
    function allowance(address owner, address spender) external view returns (uint256);

    /// @notice Sets a `value` amount of tokens as the allowance of `spender` over the
    /// caller's tokens.
    /// @param spender The spender
    /// @param value The approved amount
    function approve(address spender, uint256 value) external returns (bool);

    /// @notice Moves a `value` amount of tokens from `from` to `to` using the
    /// allowance mechanism. `value` is then deducted from the caller's
    /// allowance.
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);

    /**
     * @dev Indicates a failure with the `amount` to be approved. Used in approvals.
     * @param from Address of the sender.
     * @param to Address of the receiver.
     * @param amount Amount of tokens to be approved.
     */
    error ERC20TransferFailed(address from, address to, uint256 amount);

    /**
     * @dev Indicates a failure with the `amount` to be allocated.
     * @param allocation The increase of circulating supply.
     * @param totalSupply The total supply.
     */
    error ERC20AllocationFailed(uint256 allocation, uint256 totalSupply);
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

interface IExchangeable {
    /// @notice Sets the change authorization status to false
    function removeEthExchangeAuthorization() external;

    /// @notice Sets the change authorization status for a token to false
    function removeExchangeAuthorizationForToken(address tokenToBeReceived) external;

    /// @notice Sets whether the deposit of ETH against token is allowed or not
    function setEthDepositExchangeRate(uint64 exchangeRate) external;

    /// @notice Sets the ETH deposit authorization to false
    function removeEthDepositAuthorization() external;

    /// @notice Updates the exchange rate between ETH and the Token
    function updateEthExchangeRate(uint64 exchangeRate) external;

    /// @notice Updates the exchange rate between a token and our Token
    /// @param  tokenToBeReceived The token to be received in exchange of our Token
    /// @param  exchangeRate The exchange rate
    function updateTokenExchangeRate(address tokenToBeReceived, uint64 exchangeRate) external;

    /// @notice Returns the quantity of ETH available for change against Token
    function getAvailableQuantityOfETH() external view returns(uint256);

    /// @notice Returns the available quantity of a token to be exchanged
    function getExchangeInfoForToken(address tokenToBeReceived) external view returns(bool, uint64);

    /// @notice Returns the available quantity of a token to be exchanged against our Token
    function getAvailableQuantityOfToken(address tokenToBeReceived) external returns(uint256);

    /// @notice Enables a user to deposit ETH and receive Tokens in exchange
    /// The conversion rate applies at a fixed rate, updated by Owner
    function depositEther() external payable returns(uint256);

    /// @notice Enables a user to sell back an amount of Tokens against ETH
    /// if there is enough ETH available, and if the change is authorized
    /// @param amountToken The amount of tokens to be exchanged
    function sellBack(uint128 amountToken) external;

    /// @notice Enables a user to sell back an amount of Tokens against a preferred token
    /// if there is enough token available, and if the change is authorized
    /// @param amountToken The amount of tokens to be exchanged
    /// @param tokenToBeReceived The address of the token to be exchanged for
    function sellBackAgainst(uint128 amountToken, address tokenToBeReceived) external;

    /// @notice Enables the Owner to buy back tokens from a user, in exchange of ETH
    /// and at a specified rate
    /// @param from The beneficiary
    /// @param amountToken The amount of tokens
    /// @param rate The conversion rate
    function buyBack(address payable from, uint128 amountToken, uint64 rate) external;
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

interface IOwned {
    /// @notice Emitted when ownership of the contracted is transferred to a new owner
    event OwnerChanged(uint indexed timestamp, address prevOwner, address newOwner);

    /// @notice Returns the current owner of the contract
    function owner() external view returns (address owner);

    /// @notice Changes the ownership of the contract
    /// @param newOwner The address of the new owner
    function changeOwnership(address newOwner) external;
}

// SPDX-License-Identifier: MIT
pragma solidity >= 0.8.20;

import { DurationUnits } from  "../enums.sol";

struct VestingSchedule {
    // beneficiary of tokens after they are released
    address beneficiary;
    // The upfront release when the vesting starts
    uint8 upfrontRelease;
    // start time of the vesting period
    uint start;
    // end of the vesting period in DurationUnits
    uint end;
    // the number of seconds between start and end
    uint totalDuration;
    // total amount of tokens to be released at the end of the vesting;
    uint256 totalAmount;
    // amount of tokens released
    uint256 released;
}