Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity 0.8.30;

import { AccessControl } from "@openzeppelin/contracts/access/AccessControl.sol";
import { SafeERC20 } from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import { IOptimismBridge } from "../interfaces/IOptimismBridge.sol";
import { IBridgeAdapter } from "../interfaces/IBridgeAdapter.sol";
import { IBridgeRouter } from "../interfaces/IBridgeRouter.sol";
import { Constants } from "../Constants.sol";

interface IWETH9 {
    function deposit() external payable;

    function withdraw(uint256) external;
}

interface ICrossDomainMessenger {
    function sendMessage(address _target, bytes calldata _message, uint32 _minGasLimit) external;

    function xDomainMessageSender() external view returns (address);
}

/**
 * @title OptimismBridgeAdapter
 *
 * @dev This contract works identically on both L1 and L2. The main difference is
 *      the configuration of the peer chains.
 *
 * FOR L1 DEPLOYMENT:
 * - deploymentsForPeer[l2ChainId] = bridge and messenger addresses for the L2 chain.
 * - peerChains[l2ChainId] = L2 adapter and token mappings.
 * - Can manage multiple L2 connections.
 *
 * FOR L2 DEPLOYMENT:
 * - deploymentsForPeer[1] = bridge and messenger addresses for Ethereum.
 * - peerChains[1] = L1 adapter and token mappings.
 * - It should only manage a single connection.
 */
contract OptimismBridgeAdapter is IBridgeAdapter, AccessControl {
    using SafeERC20 for IERC20;

    bytes32 public constant SETTER_ROLE = keccak256("SETTER_ROLE");
    bytes32 public constant RESCUE_ROLE = keccak256("RESCUE_ROLE");

    error ZeroAmount();
    error ZeroAddress();
    error ZeroChainId();
    error ZeroGasLimit();
    error ZeroIdentifier();
    error ChainIdCannotBeThis();
    error CallerNotRouter(address caller);
    error InvalidRemoteToken(address token);
    error UnsupportedRemote(uint256 chainId);
    error CallerNotOtherAdapter(address caller, address messengerSender);
    error InsufficientFunds(address token, uint256 available, uint256 required);

    event PeerAdapterSet(uint256 indexed chainId, address indexed adapter);
    event PeerTokenSet(uint256 indexed chainId, address indexed localToken, address indexed remoteToken);
    event PeerDeploymentSet(uint256 indexed chainId, address indexed l1Bridge, address indexed messenger);
    event BridgeRouterSet(address indexed bridgeRouter);

    event OptimismAdapterTriggered(
        address indexed localToken,
        uint256 amount,
        uint256 indexed destChainId,
        bytes32 indexed destAddress,
        bytes data
    );

    /// @notice Peer chain configuration
    /// @dev This contract communicates with its instance on the peer chain.
    ///      That is why we need to know the peer adapter.
    ///      Also, the optimism bridge requires knowing the token addresses on both chains.
    struct PeerChain {
        address adapter;
        mapping(address => address) localToRemoteToken;
    }

    /// @notice Bridge and messenger configuration for peer chains.
    /// @dev There is a bridge and messenger on L1 for each L2 chain.
    ///      For L2 chains, there is a single bridge and messenger that connect to Ethereum.
    ///      Since it is the same format, we can use the same data structures for both.
    /// @param bridge Address of the optimism bridge contract for peer chain
    /// @param bridgeMinGasLimit Minimum gas limit for bridge operations
    /// @param messenger Address of the CrossDomainMessenger contract for peer chain
    /// @param messengerMinGasLimit Minimum gas limit for messenger operations
    struct PeerDeployments {
        address bridge;
        uint32 bridgeMinGasLimit;
        address messenger;
        uint32 messengerMinGasLimit;
    }

    /// @dev Bridge/messenger addresses for each peer chain
    mapping(uint256 chainId => PeerDeployments) public deploymentsForPeer;

    /// @dev Adapter and token mappings for each peer chain
    mapping(uint256 chainId => PeerChain) public peerChains;

    /// @dev the router is only contract allowed to call the bridge function
    IBridgeRouter public router;

    /// @notice L1 chain ID
    /// @dev L2s need to first send funds to L1 even if the dest chain is not L1‚
    uint256 public immutable L1_CHAIN_ID;
    bool public immutable IS_L2;
    address public immutable weth;

    modifier onlyRouter() {
        if (msg.sender != address(router)) revert CallerNotRouter(msg.sender);
        _;
    }

    modifier onlyMessengerOrRescue(uint256 srcChainId) {
        if (!hasRole(RESCUE_ROLE, msg.sender)) {
            address messenger = deploymentsForPeer[srcChainId].messenger;
            address peerAdapter = peerChains[srcChainId].adapter;

            if (messenger != msg.sender || ICrossDomainMessenger(messenger).xDomainMessageSender() != peerAdapter) {
                revert CallerNotOtherAdapter(msg.sender, ICrossDomainMessenger(messenger).xDomainMessageSender());
            }
        }
        _;
    }

    constructor(address admin, address _weth, uint256 l1ChainId) {
        if (_weth == address(0) || admin == address(0)) revert ZeroAddress();
        if (l1ChainId == 0) revert ZeroChainId();

        weth = _weth;
        L1_CHAIN_ID = l1ChainId;
        IS_L2 = block.chainid != L1_CHAIN_ID;

        _grantRole(DEFAULT_ADMIN_ROLE, admin);
    }

    function forwardFunds(
        address localToken,
        uint256 amount,
        uint256 destChainId,
        bytes32 destAddress,
        bytes calldata data
    ) external payable onlyRouter {
        if (localToken == Constants.ETH_ADDRESS) {
            _bridgeETH(localToken, amount, destChainId, destAddress, data);
        } else if (localToken == weth) {
            // pull WETH from caller
            IERC20(localToken).safeTransferFrom(msg.sender, address(this), amount);

            // unwrap to ETH
            IWETH9(localToken).withdraw(amount);

            // then bridge ETH
            _bridgeETH(localToken, amount, destChainId, destAddress, data);
        } else {
            IERC20(localToken).safeTransferFrom(msg.sender, address(this), amount);
            _bridgeERC20(localToken, amount, destChainId, destAddress, data);
        }

        emit OptimismAdapterTriggered(localToken, amount, destChainId, destAddress, data);
    }

    function _bridgeERC20(
        address localToken,
        uint256 amount,
        uint256 destChainId,
        bytes32 destAddress,
        bytes memory data
    ) internal {
        // if this contract is deployed on L2, the funds go through ethereum
        // therefore, hopChainId should be set to the Ethereum chain ID
        uint256 hopChainId = IS_L2 ? L1_CHAIN_ID : destChainId;

        // The usage of "storage" is for optimization.
        // These two variables should NOT BE modified.
        PeerDeployments storage destDeployment = deploymentsForPeer[hopChainId];
        PeerChain storage destPeer = peerChains[hopChainId];

        address remoteToken = destPeer.localToRemoteToken[localToken];
        address remoteAdapter = destPeer.adapter;

        if (remoteToken == address(0)) revert InvalidRemoteToken(localToken);
        if (remoteAdapter == address(0)) revert UnsupportedRemote(hopChainId);
        if (destDeployment.bridge == address(0) || destDeployment.messenger == address(0))
            revert UnsupportedRemote(hopChainId);

        IERC20(localToken).forceApprove(address(destDeployment.bridge), amount);
        IOptimismBridge(destDeployment.bridge).bridgeERC20To(
            localToken,
            remoteToken,
            remoteAdapter,
            amount,
            destDeployment.bridgeMinGasLimit,
            data
        );

        bytes memory message = abi.encodeWithSelector(
            this.receiveFunds.selector,
            remoteToken,
            amount,
            block.chainid,
            destChainId,
            destAddress,
            data
        );

        ICrossDomainMessenger(destDeployment.messenger).sendMessage({
            _target: remoteAdapter,
            _message: message,
            _minGasLimit: destDeployment.messengerMinGasLimit
        });
    }

    function _bridgeETH(
        address localToken,
        uint256 amount,
        uint256 destChainId,
        bytes32 destAddress,
        bytes memory data
    ) internal {
        // if this contract is deployed on L2, the funds go through ethereum
        // therefore, hopChainId should be set to the Ethereum chain ID
        uint256 hopChainId = IS_L2 ? L1_CHAIN_ID : destChainId;

        // The usage of "storage" is for optimization.
        // These variables should NOT BE modified.
        PeerDeployments storage destDeployment = deploymentsForPeer[hopChainId];
        PeerChain storage destPeer = peerChains[hopChainId];

        address remoteToken = destPeer.localToRemoteToken[localToken];
        address remoteAdapter = destPeer.adapter;

        if (remoteToken == address(0)) revert InvalidRemoteToken(localToken);
        if (remoteAdapter == address(0)) revert UnsupportedRemote(hopChainId);
        if (destDeployment.bridge == address(0) || destDeployment.messenger == address(0))
            revert UnsupportedRemote(hopChainId);

        IOptimismBridge(destDeployment.bridge).bridgeETHTo{ value: amount }(
            remoteAdapter,
            destDeployment.bridgeMinGasLimit,
            data
        );

        bytes memory message = abi.encodeWithSelector(
            this.receiveFunds.selector,
            remoteToken, // should be ETH_ADDRESS or WETH address on the remote chain
            amount,
            block.chainid,
            destChainId,
            destAddress,
            data
        );

        ICrossDomainMessenger(destDeployment.messenger).sendMessage({
            _target: remoteAdapter,
            _message: message,
            _minGasLimit: destDeployment.messengerMinGasLimit
        });
    }

    /// @notice This function gets called by the messenger of the respective peer chain.
    /// @dev    The funds should have been sent already by the bridge operation by the time this function is called.
    /// @param localToken Address of the token token received
    /// @param amount Amount of the token received
    /// @param srcChainId ID of the source chain
    /// @param destChainId ID of the destination chain
    /// @param destAddress Address on the destination chain to receive the tokens
    /// @param data Additional data to include with the message
    function receiveFunds(
        address localToken,
        uint256 amount,
        uint256 srcChainId,
        uint256 destChainId,
        bytes32 destAddress,
        bytes calldata data
    ) external payable onlyMessengerOrRescue(srcChainId) {
        uint256 ethAmount;

        IBridgeRouter bridgeRouter = router;

        if (localToken == Constants.ETH_ADDRESS) {
            uint256 ethBalance = address(this).balance;
            if (ethBalance < amount) revert InsufficientFunds(Constants.ETH_ADDRESS, ethBalance, amount);
            ethAmount = amount;
        } else if (localToken == weth) {
            uint256 ethBalance = address(this).balance;
            if (ethBalance < amount) revert InsufficientFunds(Constants.ETH_ADDRESS, ethBalance, amount);

            // wrap to WETH
            IWETH9(localToken).deposit{ value: amount }();

            // Transfer tokens to the bridgeRouter
            IERC20(localToken).safeTransfer(address(bridgeRouter), amount);
        } else {
            uint256 tokenBalance = IERC20(localToken).balanceOf(address(this));
            if (tokenBalance < amount) revert InsufficientFunds(localToken, tokenBalance, amount);

            // Transfer tokens to the bridgeRouter
            IERC20(localToken).safeTransfer(address(bridgeRouter), amount);
        }

        bridgeRouter.handleReceivedFunds{ value: ethAmount }(
            localToken,
            amount,
            srcChainId,
            destChainId,
            destAddress,
            data
        );
    }

    // ========= ADMIN FUNCTIONS ========= //

    function setBridgeRouter(address _router) external onlyRole(SETTER_ROLE) {
        if (_router == address(0)) revert ZeroAddress();
        router = IBridgeRouter(_router);
        emit BridgeRouterSet(_router);
    }

    function setAdapter(uint256 chainId, address adapter) external onlyRole(SETTER_ROLE) {
        if (chainId == block.chainid) revert ChainIdCannotBeThis();
        if (adapter == address(0)) revert ZeroAddress();
        if (chainId == 0) revert ZeroChainId();

        peerChains[chainId].adapter = adapter;
        emit PeerAdapterSet(chainId, adapter);
    }

    function setLocalToRemoteToken(
        uint256 chainId,
        address localToken,
        address remoteToken
    ) external onlyRole(SETTER_ROLE) {
        if (localToken == address(0) || remoteToken == address(0)) revert ZeroAddress();
        if (chainId == block.chainid) revert ChainIdCannotBeThis();
        if (chainId == 0) revert ZeroChainId();

        peerChains[chainId].localToRemoteToken[localToken] = remoteToken;
        emit PeerTokenSet(chainId, localToken, remoteToken);
    }

    function setPeerDeployments(
        uint256 chainId,
        address _bridge,
        address messenger,
        uint32 bridgeGasLimit,
        uint32 messengerGasLimit
    ) external onlyRole(SETTER_ROLE) {
        if (_bridge == address(0) || messenger == address(0)) revert ZeroAddress();
        if (bridgeGasLimit == 0 || messengerGasLimit == 0) revert ZeroGasLimit();
        if (IS_L2 && chainId != L1_CHAIN_ID) revert UnsupportedRemote(chainId);
        if (chainId == block.chainid) revert ChainIdCannotBeThis();
        if (chainId == 0) revert ZeroChainId();

        deploymentsForPeer[chainId].bridge = _bridge;
        deploymentsForPeer[chainId].messenger = messenger;
        deploymentsForPeer[chainId].bridgeMinGasLimit = bridgeGasLimit;
        deploymentsForPeer[chainId].messengerMinGasLimit = messengerGasLimit;

        emit PeerDeploymentSet(chainId, _bridge, messenger);
    }

    // ========= GETTER FUNCTIONS ========= //

    function getPeerChainRemoteToken(uint256 chainId, address localToken) external view returns (address) {
        return peerChains[chainId].localToRemoteToken[localToken];
    }

    /// @notice Allow contract to receive ETH from bridge operations
    receive() external payable {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (access/AccessControl.sol)

pragma solidity ^0.8.20;

import {IAccessControl} from "./IAccessControl.sol";
import {Context} from "../utils/Context.sol";
import {IERC165, ERC165} from "../utils/introspection/ERC165.sol";

/**
 * @dev Contract module that allows children to implement role-based access
 * control mechanisms. This is a lightweight version that doesn't allow enumerating role
 * members except through off-chain means by accessing the contract event logs. Some
 * applications may benefit from on-chain enumerability, for those cases see
 * {AccessControlEnumerable}.
 *
 * Roles are referred to by their `bytes32` identifier. These should be exposed
 * in the external API and be unique. The best way to achieve this is by
 * using `public constant` hash digests:
 *
 * ```solidity
 * bytes32 public constant MY_ROLE = keccak256("MY_ROLE");
 * ```
 *
 * Roles can be used to represent a set of permissions. To restrict access to a
 * function call, use {hasRole}:
 *
 * ```solidity
 * function foo() public {
 *     require(hasRole(MY_ROLE, msg.sender));
 *     ...
 * }
 * ```
 *
 * Roles can be granted and revoked dynamically via the {grantRole} and
 * {revokeRole} functions. Each role has an associated admin role, and only
 * accounts that have a role's admin role can call {grantRole} and {revokeRole}.
 *
 * By default, the admin role for all roles is `DEFAULT_ADMIN_ROLE`, which means
 * that only accounts with this role will be able to grant or revoke other
 * roles. More complex role relationships can be created by using
 * {_setRoleAdmin}.
 *
 * WARNING: The `DEFAULT_ADMIN_ROLE` is also its own admin: it has permission to
 * grant and revoke this role. Extra precautions should be taken to secure
 * accounts that have been granted it. We recommend using {AccessControlDefaultAdminRules}
 * to enforce additional security measures for this role.
 */
abstract contract AccessControl is Context, IAccessControl, ERC165 {
    struct RoleData {
        mapping(address account => bool) hasRole;
        bytes32 adminRole;
    }

    mapping(bytes32 role => RoleData) private _roles;

    bytes32 public constant DEFAULT_ADMIN_ROLE = 0x00;

    /**
     * @dev Modifier that checks that an account has a specific role. Reverts
     * with an {AccessControlUnauthorizedAccount} error including the required role.
     */
    modifier onlyRole(bytes32 role) {
        _checkRole(role);
        _;
    }

    /// @inheritdoc IERC165
    function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
        return interfaceId == type(IAccessControl).interfaceId || super.supportsInterface(interfaceId);
    }

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) public view virtual returns (bool) {
        return _roles[role].hasRole[account];
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `_msgSender()`
     * is missing `role`. Overriding this function changes the behavior of the {onlyRole} modifier.
     */
    function _checkRole(bytes32 role) internal view virtual {
        _checkRole(role, _msgSender());
    }

    /**
     * @dev Reverts with an {AccessControlUnauthorizedAccount} error if `account`
     * is missing `role`.
     */
    function _checkRole(bytes32 role, address account) internal view virtual {
        if (!hasRole(role, account)) {
            revert AccessControlUnauthorizedAccount(account, role);
        }
    }

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) public view virtual returns (bytes32) {
        return _roles[role].adminRole;
    }

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleGranted} event.
     */
    function grantRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _grantRole(role, account);
    }

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     *
     * May emit a {RoleRevoked} event.
     */
    function revokeRole(bytes32 role, address account) public virtual onlyRole(getRoleAdmin(role)) {
        _revokeRole(role, account);
    }

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been revoked `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     *
     * May emit a {RoleRevoked} event.
     */
    function renounceRole(bytes32 role, address callerConfirmation) public virtual {
        if (callerConfirmation != _msgSender()) {
            revert AccessControlBadConfirmation();
        }

        _revokeRole(role, callerConfirmation);
    }

    /**
     * @dev Sets `adminRole` as ``role``'s admin role.
     *
     * Emits a {RoleAdminChanged} event.
     */
    function _setRoleAdmin(bytes32 role, bytes32 adminRole) internal virtual {
        bytes32 previousAdminRole = getRoleAdmin(role);
        _roles[role].adminRole = adminRole;
        emit RoleAdminChanged(role, previousAdminRole, adminRole);
    }

    /**
     * @dev Attempts to grant `role` to `account` and returns a boolean indicating if `role` was granted.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleGranted} event.
     */
    function _grantRole(bytes32 role, address account) internal virtual returns (bool) {
        if (!hasRole(role, account)) {
            _roles[role].hasRole[account] = true;
            emit RoleGranted(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Attempts to revoke `role` from `account` and returns a boolean indicating if `role` was revoked.
     *
     * Internal function without access restriction.
     *
     * May emit a {RoleRevoked} event.
     */
    function _revokeRole(bytes32 role, address account) internal virtual returns (bool) {
        if (hasRole(role, account)) {
            _roles[role].hasRole[account] = false;
            emit RoleRevoked(role, account, _msgSender());
            return true;
        } else {
            return false;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.5.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        if (!_safeTransfer(token, to, value, true)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        if (!_safeTransferFrom(token, from, to, value, true)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _safeTransfer(token, to, value, false);
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _safeTransferFrom(token, from, to, value, false);
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        if (!_safeApprove(token, spender, value, false)) {
            if (!_safeApprove(token, spender, 0, true)) revert SafeERC20FailedOperation(address(token));
            if (!_safeApprove(token, spender, value, true)) revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that relies on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that relies on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Oppositely, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity `token.transfer(to, value)` call, relaxing the requirement on the return value: the
     * return value is optional (but if data is returned, it must not be false).
     *
     * @param token The token targeted by the call.
     * @param to The recipient of the tokens
     * @param value The amount of token to transfer
     * @param bubble Behavior switch if the transfer call reverts: bubble the revert reason or return a false boolean.
     */
    function _safeTransfer(IERC20 token, address to, uint256 value, bool bubble) private returns (bool success) {
        bytes4 selector = IERC20.transfer.selector;

        assembly ("memory-safe") {
            let fmp := mload(0x40)
            mstore(0x00, selector)
            mstore(0x04, and(to, shr(96, not(0))))
            mstore(0x24, value)
            success := call(gas(), token, 0, 0x00, 0x44, 0x00, 0x20)
            // if call success and return is true, all is good.
            // otherwise (not success or return is not true), we need to perform further checks
            if iszero(and(success, eq(mload(0x00), 1))) {
                // if the call was a failure and bubble is enabled, bubble the error
                if and(iszero(success), bubble) {
                    returndatacopy(fmp, 0x00, returndatasize())
                    revert(fmp, returndatasize())
                }
                // if the return value is not true, then the call is only successful if:
                // - the token address has code
                // - the returndata is empty
                success := and(success, and(iszero(returndatasize()), gt(extcodesize(token), 0)))
            }
            mstore(0x40, fmp)
        }
    }

    /**
     * @dev Imitates a Solidity `token.transferFrom(from, to, value)` call, relaxing the requirement on the return
     * value: the return value is optional (but if data is returned, it must not be false).
     *
     * @param token The token targeted by the call.
     * @param from The sender of the tokens
     * @param to The recipient of the tokens
     * @param value The amount of token to transfer
     * @param bubble Behavior switch if the transfer call reverts: bubble the revert reason or return a false boolean.
     */
    function _safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value,
        bool bubble
    ) private returns (bool success) {
        bytes4 selector = IERC20.transferFrom.selector;

        assembly ("memory-safe") {
            let fmp := mload(0x40)
            mstore(0x00, selector)
            mstore(0x04, and(from, shr(96, not(0))))
            mstore(0x24, and(to, shr(96, not(0))))
            mstore(0x44, value)
            success := call(gas(), token, 0, 0x00, 0x64, 0x00, 0x20)
            // if call success and return is true, all is good.
            // otherwise (not success or return is not true), we need to perform further checks
            if iszero(and(success, eq(mload(0x00), 1))) {
                // if the call was a failure and bubble is enabled, bubble the error
                if and(iszero(success), bubble) {
                    returndatacopy(fmp, 0x00, returndatasize())
                    revert(fmp, returndatasize())
                }
                // if the return value is not true, then the call is only successful if:
                // - the token address has code
                // - the returndata is empty
                success := and(success, and(iszero(returndatasize()), gt(extcodesize(token), 0)))
            }
            mstore(0x40, fmp)
            mstore(0x60, 0)
        }
    }

    /**
     * @dev Imitates a Solidity `token.approve(spender, value)` call, relaxing the requirement on the return value:
     * the return value is optional (but if data is returned, it must not be false).
     *
     * @param token The token targeted by the call.
     * @param spender The spender of the tokens
     * @param value The amount of token to transfer
     * @param bubble Behavior switch if the transfer call reverts: bubble the revert reason or return a false boolean.
     */
    function _safeApprove(IERC20 token, address spender, uint256 value, bool bubble) private returns (bool success) {
        bytes4 selector = IERC20.approve.selector;

        assembly ("memory-safe") {
            let fmp := mload(0x40)
            mstore(0x00, selector)
            mstore(0x04, and(spender, shr(96, not(0))))
            mstore(0x24, value)
            success := call(gas(), token, 0, 0x00, 0x44, 0x00, 0x20)
            // if call success and return is true, all is good.
            // otherwise (not success or return is not true), we need to perform further checks
            if iszero(and(success, eq(mload(0x00), 1))) {
                // if the call was a failure and bubble is enabled, bubble the error
                if and(iszero(success), bubble) {
                    returndatacopy(fmp, 0x00, returndatasize())
                    revert(fmp, returndatasize())
                }
                // if the return value is not true, then the call is only successful if:
                // - the token address has code
                // - the returndata is empty
                success := and(success, and(iszero(returndatasize()), gt(extcodesize(token), 0)))
            }
            mstore(0x40, fmp)
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.30;

interface IOptimismBridge {
    function bridgeERC20To(
        address _localToken,
        address _remoteToken,
        address _to,
        uint256 _amount,
        uint32 _minGasLimit,
        bytes calldata _extraData
    ) external;

    function bridgeETHTo(address _to, uint32 _minGasLimit, bytes calldata _extraData) external payable;
}

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.30;

interface IBridgeAdapter {
    struct CrossChainData {
        uint256 amount;
        address localToken;
        uint256 srcChainId;
        uint256 destChainId;
    }

    /**
     * @notice Executes a bridge operation.
     * @param token The address of the token to bridge.
     * @param amount The amount of tokens to bridge.
     * @param destChainId The ID of the destination chain.
     * @param destAddress The destination identifier (low 20 bytes MUST encode an EVM address when applicable).
     * @param data Additional data to be passed to destAddress.
     */
    function forwardFunds(
        address token,
        uint256 amount,
        uint256 destChainId,
        bytes32 destAddress,
        bytes calldata data
    ) external payable;
}

// SPDX-License-Identifier: AGPL-3.0
pragma solidity 0.8.30;

/// @notice Interface for the IBridgeRouter
interface IBridgeRouter {
    function bridge(
        address token,
        uint256 amount,
        uint256 destChainId,
        bytes32 destAddress,
        bytes calldata extraData
    ) external payable;

    function handleReceivedFunds(
        address token,
        uint256 amount,
        uint256 srcChainId,
        uint256 destChainId,
        bytes32 destAddress,
        bytes calldata extraData
    ) external payable;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.30;

library Constants {
    /// @notice ETH sentinel address for consistent ETH handling
    address public constant ETH_ADDRESS = 0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (access/IAccessControl.sol)

pragma solidity >=0.8.4;

/**
 * @dev External interface of AccessControl declared to support ERC-165 detection.
 */
interface IAccessControl {
    /**
     * @dev The `account` is missing a role.
     */
    error AccessControlUnauthorizedAccount(address account, bytes32 neededRole);

    /**
     * @dev The caller of a function is not the expected one.
     *
     * NOTE: Don't confuse with {AccessControlUnauthorizedAccount}.
     */
    error AccessControlBadConfirmation();

    /**
     * @dev Emitted when `newAdminRole` is set as ``role``'s admin role, replacing `previousAdminRole`
     *
     * `DEFAULT_ADMIN_ROLE` is the starting admin for all roles, despite
     * {RoleAdminChanged} not being emitted to signal this.
     */
    event RoleAdminChanged(bytes32 indexed role, bytes32 indexed previousAdminRole, bytes32 indexed newAdminRole);

    /**
     * @dev Emitted when `account` is granted `role`.
     *
     * `sender` is the account that originated the contract call. This account bears the admin role (for the granted role).
     * Expected in cases where the role was granted using the internal {AccessControl-_grantRole}.
     */
    event RoleGranted(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Emitted when `account` is revoked `role`.
     *
     * `sender` is the account that originated the contract call:
     *   - if using `revokeRole`, it is the admin role bearer
     *   - if using `renounceRole`, it is the role bearer (i.e. `account`)
     */
    event RoleRevoked(bytes32 indexed role, address indexed account, address indexed sender);

    /**
     * @dev Returns `true` if `account` has been granted `role`.
     */
    function hasRole(bytes32 role, address account) external view returns (bool);

    /**
     * @dev Returns the admin role that controls `role`. See {grantRole} and
     * {revokeRole}.
     *
     * To change a role's admin, use {AccessControl-_setRoleAdmin}.
     */
    function getRoleAdmin(bytes32 role) external view returns (bytes32);

    /**
     * @dev Grants `role` to `account`.
     *
     * If `account` had not been already granted `role`, emits a {RoleGranted}
     * event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function grantRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from `account`.
     *
     * If `account` had been granted `role`, emits a {RoleRevoked} event.
     *
     * Requirements:
     *
     * - the caller must have ``role``'s admin role.
     */
    function revokeRole(bytes32 role, address account) external;

    /**
     * @dev Revokes `role` from the calling account.
     *
     * Roles are often managed via {grantRole} and {revokeRole}: this function's
     * purpose is to provide a mechanism for accounts to lose their privileges
     * if they are compromised (such as when a trusted device is misplaced).
     *
     * If the calling account had been granted `role`, emits a {RoleRevoked}
     * event.
     *
     * Requirements:
     *
     * - the caller must be `callerConfirmation`.
     */
    function renounceRole(bytes32 role, address callerConfirmation) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/ERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "./IERC165.sol";

/**
 * @dev Implementation of the {IERC165} interface.
 *
 * Contracts that want to implement ERC-165 should inherit from this contract and override {supportsInterface} to check
 * for the additional interface id that will be supported. For example:
 *
 * ```solidity
 * function supportsInterface(bytes4 interfaceId) public view virtual override returns (bool) {
 *     return interfaceId == type(MyInterface).interfaceId || super.supportsInterface(interfaceId);
 * }
 * ```
 */
abstract contract ERC165 is IERC165 {
    /// @inheritdoc IERC165
    function supportsInterface(bytes4 interfaceId) public view virtual returns (bool) {
        return interfaceId == type(IERC165).interfaceId;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;

import {IERC165} from "../utils/introspection/IERC165.sol";