Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/structs/EnumerableSet.sol)
// This file was procedurally generated from scripts/generate/templates/EnumerableSet.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for managing
 * https://en.wikipedia.org/wiki/Set_(abstract_data_type)[sets] of primitive
 * types.
 *
 * Sets have the following properties:
 *
 * - Elements are added, removed, and checked for existence in constant time
 * (O(1)).
 * - Elements are enumerated in O(n). No guarantees are made on the ordering.
 *
 * ```solidity
 * contract Example {
 *     // Add the library methods
 *     using EnumerableSet for EnumerableSet.AddressSet;
 *
 *     // Declare a set state variable
 *     EnumerableSet.AddressSet private mySet;
 * }
 * ```
 *
 * As of v3.3.0, sets of type `bytes32` (`Bytes32Set`), `address` (`AddressSet`)
 * and `uint256` (`UintSet`) are supported.
 *
 * [WARNING]
 * ====
 * Trying to delete such a structure from storage will likely result in data corruption, rendering the structure
 * unusable.
 * See https://github.com/ethereum/solidity/pull/11843[ethereum/solidity#11843] for more info.
 *
 * In order to clean an EnumerableSet, you can either remove all elements one by one or create a fresh instance using an
 * array of EnumerableSet.
 * ====
 */
library EnumerableSet {
    // To implement this library for multiple types with as little code
    // repetition as possible, we write it in terms of a generic Set type with
    // bytes32 values.
    // The Set implementation uses private functions, and user-facing
    // implementations (such as AddressSet) are just wrappers around the
    // underlying Set.
    // This means that we can only create new EnumerableSets for types that fit
    // in bytes32.

    struct Set {
        // Storage of set values
        bytes32[] _values;
        // Position is the index of the value in the `values` array plus 1.
        // Position 0 is used to mean a value is not in the set.
        mapping(bytes32 value => uint256) _positions;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function _add(Set storage set, bytes32 value) private returns (bool) {
        if (!_contains(set, value)) {
            set._values.push(value);
            // The value is stored at length-1, but we add 1 to all indexes
            // and use 0 as a sentinel value
            set._positions[value] = set._values.length;
            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function _remove(Set storage set, bytes32 value) private returns (bool) {
        // We cache the value's position to prevent multiple reads from the same storage slot
        uint256 position = set._positions[value];

        if (position != 0) {
            // Equivalent to contains(set, value)
            // To delete an element from the _values array in O(1), we swap the element to delete with the last one in
            // the array, and then remove the last element (sometimes called as 'swap and pop').
            // This modifies the order of the array, as noted in {at}.

            uint256 valueIndex = position - 1;
            uint256 lastIndex = set._values.length - 1;

            if (valueIndex != lastIndex) {
                bytes32 lastValue = set._values[lastIndex];

                // Move the lastValue to the index where the value to delete is
                set._values[valueIndex] = lastValue;
                // Update the tracked position of the lastValue (that was just moved)
                set._positions[lastValue] = position;
            }

            // Delete the slot where the moved value was stored
            set._values.pop();

            // Delete the tracked position for the deleted slot
            delete set._positions[value];

            return true;
        } else {
            return false;
        }
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function _contains(Set storage set, bytes32 value) private view returns (bool) {
        return set._positions[value] != 0;
    }

    /**
     * @dev Returns the number of values on the set. O(1).
     */
    function _length(Set storage set) private view returns (uint256) {
        return set._values.length;
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function _at(Set storage set, uint256 index) private view returns (bytes32) {
        return set._values[index];
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function _values(Set storage set) private view returns (bytes32[] memory) {
        return set._values;
    }

    // Bytes32Set

    struct Bytes32Set {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _add(set._inner, value);
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(Bytes32Set storage set, bytes32 value) internal returns (bool) {
        return _remove(set._inner, value);
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(Bytes32Set storage set, bytes32 value) internal view returns (bool) {
        return _contains(set._inner, value);
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(Bytes32Set storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(Bytes32Set storage set, uint256 index) internal view returns (bytes32) {
        return _at(set._inner, index);
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(Bytes32Set storage set) internal view returns (bytes32[] memory) {
        bytes32[] memory store = _values(set._inner);
        bytes32[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // AddressSet

    struct AddressSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(AddressSet storage set, address value) internal returns (bool) {
        return _add(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(AddressSet storage set, address value) internal returns (bool) {
        return _remove(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(AddressSet storage set, address value) internal view returns (bool) {
        return _contains(set._inner, bytes32(uint256(uint160(value))));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(AddressSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(AddressSet storage set, uint256 index) internal view returns (address) {
        return address(uint160(uint256(_at(set._inner, index))));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(AddressSet storage set) internal view returns (address[] memory) {
        bytes32[] memory store = _values(set._inner);
        address[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }

    // UintSet

    struct UintSet {
        Set _inner;
    }

    /**
     * @dev Add a value to a set. O(1).
     *
     * Returns true if the value was added to the set, that is if it was not
     * already present.
     */
    function add(UintSet storage set, uint256 value) internal returns (bool) {
        return _add(set._inner, bytes32(value));
    }

    /**
     * @dev Removes a value from a set. O(1).
     *
     * Returns true if the value was removed from the set, that is if it was
     * present.
     */
    function remove(UintSet storage set, uint256 value) internal returns (bool) {
        return _remove(set._inner, bytes32(value));
    }

    /**
     * @dev Returns true if the value is in the set. O(1).
     */
    function contains(UintSet storage set, uint256 value) internal view returns (bool) {
        return _contains(set._inner, bytes32(value));
    }

    /**
     * @dev Returns the number of values in the set. O(1).
     */
    function length(UintSet storage set) internal view returns (uint256) {
        return _length(set._inner);
    }

    /**
     * @dev Returns the value stored at position `index` in the set. O(1).
     *
     * Note that there are no guarantees on the ordering of values inside the
     * array, and it may change when more values are added or removed.
     *
     * Requirements:
     *
     * - `index` must be strictly less than {length}.
     */
    function at(UintSet storage set, uint256 index) internal view returns (uint256) {
        return uint256(_at(set._inner, index));
    }

    /**
     * @dev Return the entire set in an array
     *
     * WARNING: This operation will copy the entire storage to memory, which can be quite expensive. This is designed
     * to mostly be used by view accessors that are queried without any gas fees. Developers should keep in mind that
     * this function has an unbounded cost, and using it as part of a state-changing function may render the function
     * uncallable if the set grows to a point where copying to memory consumes too much gas to fit in a block.
     */
    function values(UintSet storage set) internal view returns (uint256[] memory) {
        bytes32[] memory store = _values(set._inner);
        uint256[] memory result;

        /// @solidity memory-safe-assembly
        assembly {
            result := store
        }

        return result;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity =0.8.24;
import '@openzeppelin/contracts/access/Ownable2Step.sol';
import '@openzeppelin/contracts/utils/structs/EnumerableSet.sol';

interface INavRegistry {
  struct ModuleParams {
    bytes4 moduleId;
    bytes cd;
  }

  struct Enumerable {
    EnumerableSet.Bytes32Set moduleIds;
  }

  // modules
  function getModuleIds() external view returns (bytes4[] memory);

  function getModuleDetails(bytes4 moduleId) external view returns (address, string memory);

  function getModuleAddress(bytes4 moduleId) external view returns (address);

  function isModuleRegistered(bytes4 moduleId) external view returns (bool);

  // nav
  function getStrategyModules(address strategy) external view returns (bytes4[] memory moduleIds);

  function getStrategyModuleCalldata(address strategy, bytes4 moduleId) external view returns (bytes memory);

  function getStrategyNav(
    address strategy,
    ModuleParams[] calldata dynamicModuleParams
  ) external view returns (uint navInUnderlying);
}

contract NavRegistry is INavRegistry, Ownable2Step {
  using EnumerableSet for EnumerableSet.Bytes32Set;

  bytes32 public constant DYNAMIC = keccak256('NavRegistry.dynamic');

  error EntryAlreadyExistsError(bytes4);
  error EntryNonExistentError(bytes4);
  error EmptyPrevAddrError(bytes4);
  error GetNavFailed(bytes4);
  error AlreadyAttached(bytes4);
  error NotAttached(bytes4);
  error MissingDynamicModule(bytes4);

  event AddNewContract(bytes4, address);
  event UpdateContract(bytes4, address active, address old);
  event RevertToPreviousAddress(bytes4, address active, address old);

  struct Entry {
    address addr;
    bool exists;
    string name;
  }

  mapping(bytes4 moduleId => Entry entries) public modules;
  mapping(bytes4 moduleId => address) public previousModuleAddresses;
  bytes4[] private _moduleIds;

  mapping(address strategy => mapping(bytes4 moduleId => bytes cd)) public strategyModuleCd;
  mapping(address strategy => Enumerable moduleIds) private _strategyModuleIds;

  constructor() Ownable(msg.sender) {}

  //////////////////////////// Modules ////////////////////////////
  /**
   * @notice Returns list of module ids
   */
  function getModuleIds() external view returns (bytes4[] memory) {
    return _moduleIds;
  }

  /**
   * @notice Returns registered contract details
   * @param id id of contract
   * @return address and name of contract
   */
  function getModuleDetails(bytes4 id) external view returns (address, string memory) {
    return (modules[id].addr, modules[id].name);
  }

  /**
   * @notice Returns registered contract given id
   * @param id id of contract
   * @return address of contract
   */
  function getModuleAddress(bytes4 id) external view returns (address) {
    return modules[id].addr;
  }

  /**
   * @notice Helper function to query if id is registered
   * @param id 1st 4 bytes of keccak256 of the contract name
   * @return is id registered
   */
  function isModuleRegistered(bytes4 id) public view returns (bool) {
    return modules[id].exists;
  }

  /**
   * @notice Adds a new contract to the registry
   * @param id id of contract
   * @param addr address of contract to register
   * @param name human readable module name
   */
  function registerModule(bytes4 id, address addr, string calldata name) external onlyOwner {
    if (modules[id].exists) {
      revert EntryAlreadyExistsError(id);
    }

    modules[id] = Entry({ addr: addr, exists: true, name: name });
    _moduleIds.push(id);

    emit AddNewContract(id, addr);
  }

  /**
   * @notice Starts an address change for an existing entry
   * @param id Id of contract
   * @param newAddr address of the new contract
   * @param name human readable module name
   */
  function updateModule(bytes4 id, address newAddr, string calldata name) external onlyOwner {
    if (!modules[id].exists) {
      revert EntryNonExistentError(id);
    }
    address _oldAddr = modules[id].addr;
    previousModuleAddresses[id] = _oldAddr;
    modules[id].addr = newAddr;
    modules[id].name = name;

    emit UpdateContract(id, newAddr, _oldAddr);
  }

  /**
   * @notice reverts to the previous address immediately
   * @dev In case the new version has a fault, a quick way to fallback to the old contract
   * @param id Id of contract
   */
  function revertModule(bytes4 id) external onlyOwner {
    if (!(modules[id].exists)) {
      revert EntryNonExistentError(id);
    }
    if (previousModuleAddresses[id] == address(0)) {
      revert EmptyPrevAddrError(id);
    }

    address currentAddr = modules[id].addr;
    modules[id].addr = previousModuleAddresses[id];

    emit RevertToPreviousAddress(id, modules[id].addr, currentAddr);
  }

  //////////////////////////// Strategies ////////////////////////////

  /**
   * @notice Attaches a module to a strategy
   * @param strategy strategy address to attach module
   * @param params module parameters
   */
  function attachTo(address strategy, ModuleParams calldata params) external onlyOwner {
    if (_strategyModuleIds[strategy].moduleIds.add(params.moduleId) == false) revert AlreadyAttached(params.moduleId);
    strategyModuleCd[strategy][params.moduleId] = params.cd;
  }

  /**
   * @notice Detaches a module from a strategy
   * @param strategy strategy address to detach module from
   * @param moduleId 4-byte module id
   */
  function detachFrom(address strategy, bytes4 moduleId) external onlyOwner {
    if (_strategyModuleIds[strategy].moduleIds.remove(moduleId) == false) revert NotAttached(moduleId);
    delete strategyModuleCd[strategy][moduleId];
  }

  /**
   * @notice Update an attached strategy's parameters
   * @param strategy strategy address
   * @param params updated module parameters
   */
  function updateParams(address strategy, ModuleParams calldata params) external onlyOwner {
    if (_strategyModuleIds[strategy].moduleIds.contains(params.moduleId) == false) revert NotAttached(params.moduleId);
    strategyModuleCd[strategy][params.moduleId] = params.cd;
  }

  /**
   * @notice Get module Ids attached to a particular strategy
   * @param strategy strategy address
   * @return moduleIds array of 4-byte module ids
   */
  function getStrategyModules(address strategy) external view returns (bytes4[] memory moduleIds) {
    uint _len = _strategyModuleIds[strategy].moduleIds.length();
    moduleIds = new bytes4[](_len);
    for (uint i; i < _len; ++i) {
      moduleIds[i] = bytes4(_strategyModuleIds[strategy].moduleIds.at(i));
    }
  }

  /**
   * @notice Get calldata of module attached to strategy
   * @param strategy strategy address
   * @param moduleId 4-byte module Id
   * @return _calldata array of 4-byte module ids
   */
  function getStrategyModuleCalldata(address strategy, bytes4 moduleId) external view returns (bytes memory) {
    if (_strategyModuleIds[strategy].moduleIds.contains(moduleId) == false) revert NotAttached(moduleId);

    return strategyModuleCd[strategy][moduleId];
  }

  /**
   * @notice Get Nav of a strategy
   *
   * @dev loop `moduleIds.length` times, if module is dynamic,
   * loop dynamicModuleParams to retrieve first instance of moduleId + cd.
   * dynamicModuleParams must not have duplicates.
   *
   * @param strategy strategy address
   * @param dynamicModuleParams array of dynamic module params
   * @return _navInUnderlying sum of all attached modules
   */
  function getStrategyNav(
    address strategy,
    ModuleParams[] calldata dynamicModuleParams
  ) external view returns (uint _navInUnderlying) {
    uint256 moduleIdsLength = _strategyModuleIds[strategy].moduleIds.length();
    for (uint i; i < moduleIdsLength; ++i) {
      bytes4 moduleId = bytes4(_strategyModuleIds[strategy].moduleIds.at(i));
      if (bytes32(strategyModuleCd[strategy][moduleId]) != DYNAMIC) {
        (bool success, bytes memory info) = address(modules[moduleId].addr).staticcall(
          strategyModuleCd[strategy][moduleId]
        );

        if (!success) revert GetNavFailed(moduleId);

        unchecked {
          _navInUnderlying += uint(bytes32(info));
        }
      } else {
        // get first instance of dynamic cd
        bool executed = false;

        for (uint j; j < dynamicModuleParams.length; ++j) {
          if (dynamicModuleParams[j].moduleId == moduleId) {
            (bool success, bytes memory info) = address(modules[moduleId].addr).staticcall(dynamicModuleParams[j].cd);
            if (!success) revert GetNavFailed(moduleId);

            unchecked {
              _navInUnderlying += uint(bytes32(info));
            }

            executed = true;
            break;
          }
        }

        if (!executed) revert MissingDynamicModule(moduleId);
      }
    }
  }
}