Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

pragma solidity ^0.8.0;

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(
        address indexed previousOwner,
        address indexed newOwner
    );

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(
            newOwner != address(0),
            "Ownable: new owner is the zero address"
        );
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// OpenZeppelin Contracts (last updated v4.6.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(
        address indexed owner,
        address indexed spender,
        uint256 value
    );

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(
        address owner,
        address spender
    ) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);
}

// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(
            address(this).balance >= amount,
            "Address: insufficient balance"
        );

        (bool success, ) = recipient.call{value: amount}("");
        require(
            success,
            "Address: unable to send value, recipient may have reverted"
        );
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data
    ) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return
            functionCallWithValue(
                target,
                data,
                value,
                "Address: low-level call with value failed"
            );
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(
            address(this).balance >= value,
            "Address: insufficient balance for call"
        );
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(
            data
        );
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data
    ) internal view returns (bytes memory) {
        return
            functionStaticCall(
                target,
                data,
                "Address: low-level static call failed"
            );
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data
    ) internal returns (bytes memory) {
        return
            functionDelegateCall(
                target,
                data,
                "Address: low-level delegate call failed"
            );
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(isContract(target), "Address: delegate call to non-contract");

        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// OpenZeppelin Contracts v4.4.1 (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(token.transfer.selector, to, value)
        );
    }

    function safeTransferFrom(
        IERC20 token,
        address from,
        address to,
        uint256 value
    ) internal {
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(token.transferFrom.selector, from, to, value)
        );
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(token.approve.selector, spender, value)
        );
    }

    function safeIncreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        uint256 newAllowance = token.allowance(address(this), spender) + value;
        _callOptionalReturn(
            token,
            abi.encodeWithSelector(
                token.approve.selector,
                spender,
                newAllowance
            )
        );
    }

    function safeDecreaseAllowance(
        IERC20 token,
        address spender,
        uint256 value
    ) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(
                oldAllowance >= value,
                "SafeERC20: decreased allowance below zero"
            );
            uint256 newAllowance = oldAllowance - value;
            _callOptionalReturn(
                token,
                abi.encodeWithSelector(
                    token.approve.selector,
                    spender,
                    newAllowance
                )
            );
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address.functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(
            data,
            "SafeERC20: low-level call failed"
        );
        if (returndata.length > 0) {
            // Return data is optional
            require(
                abi.decode(returndata, (bool)),
                "SafeERC20: ERC20 operation did not succeed"
            );
        }
    }
}

pragma solidity 0.8.24;

// Definition of custom errors
error AlreadyPaid();
error ArrayLengthMismatch();
error AmountBelowMinimum(uint256 amount);
error EtherNotAccepted();
error SameValueError();
error ExceedsMaxFeePercentage();
error ZeroAddress();
error ZeroInput();

/// @title NodelyAI Payment Gateway
/// @notice This contract facilitates payments in NodelyAI tokens for GPU rentals.
contract NodelyAIPaymentGateway is Ownable {
    using SafeERC20 for IERC20;

    // Address of the NodelyAI token
    IERC20 public immutable nodeToken;

    // Struct to track order balance and payment status.
    /// @dev `netAmount` only increases when a user pays and is not adjusted when the admin pays the gpu owner.
    struct OrderBalance {
        uint256 netAmount; // Net amount paid by the user after deducting fees.
        bool isPaid; // Indicates whether the admin has paid the GPU owner.
    }

    // Mapping to track the balance and payment status for each order ID.
    mapping(uint256 => OrderBalance) public orderBalances;

    // Address where platform fees are sent
    address public platformFeeRecipient;

    // Current platform fee percentage (in basis points, where 10000 = 100%)
    uint96 public platformFeeBps;

    // Maximum platform fee percentage (in basis points) that can be set by the admin
    uint256 public constant MAX_PLATFORM_FEE_BPS = 2000; // 20%

    // Precision used for percentage calculations (10000 = 100%)
    uint256 public constant BASIS_POINTS_DIVISOR = 10_000;

    // Minimum payment amount is 1 (1e9) NodelyAI token
    uint256 public constant MIN_PAYMENT_AMOUNT = 1e9; // 1 NodelyAI token = 1e9

    // Event emitted when the platform fee recipient is updated
    event PlatformFeeRecipientUpdated(
        address indexed oldRecipient,
        address indexed newRecipient
    );

    // Event emitted when the platform fee percentage is updated
    event PlatformFeeUpdated(uint96 oldFeeBps, uint96 newFeeBps);

    // Event emitted when a payment is successfully processed
    event PaymentProcessed(
        address indexed payer,
        uint256 indexed orderId,
        uint256 indexed totalAmount,
        uint256 netAmount,
        uint256 feeAmount
    );

    // Event emitted when payment is released to the GPU owner.
    event PaymentReleased(
        address indexed contractOwner,
        address indexed gpuOwner,
        uint256 indexed orderId,
        uint256 tokensPaid
    );

    /**
     * @notice Initializes the contract with the necessary parameters.
     * @dev Ensures the `_nodeToken` and `_platformFeeRecipient` are valid addresses.
     * @param _nodeToken The address of the NODE token used for transactions.
     * @param _platformFeeRecipient The address that will receive platform fees.
     * @param _platformFeeBps The platform fee percentage in basis points (1 BPS = 0.01%).
     */
    constructor(
        IERC20 _nodeToken,
        address _platformFeeRecipient,
        uint96 _platformFeeBps
    ) {
        // Check if the `_nodeToken` or `_platformFeeRecipient` is the zero address
        if (
            address(_nodeToken) == address(0) ||
            _platformFeeRecipient == address(0)
        ) revert ZeroAddress(); // Revert if any address is a zero address

        nodeToken = _nodeToken;

        // Set the platform fee recipient
        platformFeeRecipient = _platformFeeRecipient;

        // Set the platform fee in basis points, if greater than 0
        if (_platformFeeBps > 0) {
            platformFeeBps = _platformFeeBps;
        }

        emit PlatformFeeRecipientUpdated(address(0), _platformFeeRecipient);
        emit PlatformFeeUpdated(0, _platformFeeBps);
    }
    receive() external payable {
        revert EtherNotAccepted(); // Revert if Ether is sent
    }

    fallback() external payable {
        revert EtherNotAccepted(); // Revert if Ether is sent
    }

    /**
     * @notice Changes the platform fee recipient address.
     * @param _newPlatformFeeRecipient The address of the new fee recipient.
     * @dev Only callable by the contract owner.
     */
    function changePlatformFeeRecipient(
        address _newPlatformFeeRecipient
    ) external onlyOwner {
        // Ensure the new fee recipient address is not the zero address
        if (address(0) == _newPlatformFeeRecipient) revert ZeroAddress();

        // Ensure the new address is not the same as the current fee recipient
        if (platformFeeRecipient == _newPlatformFeeRecipient)
            revert SameValueError();

        emit PlatformFeeRecipientUpdated(
            platformFeeRecipient,
            _newPlatformFeeRecipient
        );

        // Update the platform fee recipient address
        platformFeeRecipient = _newPlatformFeeRecipient;
    }

    /**
     * @notice Changes the platform fee percentage.
     * @param _newPlatformFeeBps The new fee percentage in basis points (1 BPS = 0.01%).
     * @dev Only callable by the contract owner.
     */
    function changeFeePercentage(uint96 _newPlatformFeeBps) external onlyOwner {
        // Ensure the new fee percentage is not the same as the current one
        if (platformFeeBps == _newPlatformFeeBps) revert SameValueError();

        // Ensure the new fee percentage does not exceed the maximum allowed fee percentage
        if (_newPlatformFeeBps > MAX_PLATFORM_FEE_BPS)
            revert ExceedsMaxFeePercentage();

        emit PlatformFeeUpdated(platformFeeBps, _newPlatformFeeBps);

        // Update the platform fee percentage
        platformFeeBps = _newPlatformFeeBps;
    }

    /**
     * @notice Processes the payment by transferring tokens, deducting the platform's fee, and updating the order balance.
     * @param _orderId The order ID associated with the payment.
     * @param _tokenAmount The total number of tokens being paid.
     */
    function processPayment(uint256 _orderId, uint256 _tokenAmount) external {
        // Ensures that the token amount is not less than the minimum required payment
        if (_tokenAmount < MIN_PAYMENT_AMOUNT) {
            revert AmountBelowMinimum(_tokenAmount); // Revert if _tokenAmount is less than 1 Nodely AI token
        }

        // Calculate the platform fee based on the provided fee percentage
        uint256 _platformFee = (_tokenAmount * platformFeeBps) /
            BASIS_POINTS_DIVISOR;

        // Calculate the net amount after deducting the platform fee
        uint256 _netAmount = _tokenAmount - _platformFee;

        // Update the amount paid for the given ID, subtracting platform fee
        orderBalances[_orderId].netAmount += _netAmount;

        // Transfer the tokens from the sender to the contract
        nodeToken.safeTransferFrom(msg.sender, address(this), _tokenAmount);

        // Transfer the platform fee to the fee recipient, if it is greater than 0
        if (_platformFee > 0) {
            nodeToken.safeTransfer(platformFeeRecipient, _platformFee);
        }

        emit PaymentProcessed(
            msg.sender,
            _orderId,
            _tokenAmount,
            _netAmount,
            _platformFee
        );
    }

    /**
     * @notice Releases payment to the GPU owner for a specific order.
     * @param _orderIds The array of unique order IDs.
     * @param _gpuOwners The array of GPU owners' addresses receiving the payments.
     * @param _totalAmounts The array of total amounts of tokens to be paid to the GPU owners.
     * @dev Only callable by the contract owner.
     */
    function releasePayment(
        uint256[] calldata _orderIds,
        address[] calldata _gpuOwners,
        uint256[] calldata _totalAmounts
    ) external onlyOwner {
        // Ensure arrays are of the same length
        uint256 length = _orderIds.length;
        if (length != _gpuOwners.length || length != _totalAmounts.length) {
            revert ArrayLengthMismatch();
        }

        // Iterate over each order and process payments
        for (uint256 i = 0; i < length; i++) {
            uint256 _orderId = _orderIds[i];
            address _gpuOwner = _gpuOwners[i];
            uint256 _totalAmount = _totalAmounts[i];

            // Ensure the total amount is greater than zero
            if (_totalAmount == 0) revert ZeroInput();

            // Ensure GPU owner address is not the zero address
            if (address(0) == _gpuOwner) revert ZeroAddress();

            // Check if the payment has already been released for this order
            if (orderBalances[_orderId].isPaid) revert AlreadyPaid();

            // Mark the order as paid
            orderBalances[_orderId].isPaid = true;

            // Transfer tokens to the GPU owner
            nodeToken.safeTransfer(_gpuOwner, _totalAmount);

            emit PaymentReleased(msg.sender, _gpuOwner, _orderId, _totalAmount);
        }
    }
}