Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

enum AntennaStatus {
    Off,
    On,
    ConnectedToSatellite
}

enum AntennaModification {
    TurnedAntennaOff,
    TurnedAntennaOn,
    TunedToCapturedSatelliteConnection,
    CapturedSatelliteConnection
}

enum Activation {
    Cascade,
    Plague
}

enum Status {
    Terrain,
    Daydream,
    Terraformed,
    OriginDaydream,
    OriginTerraformed
}

struct SVGParams {
    uint256[32][32] heightmapIndices;
    uint256 level;
    uint256 tile;
    uint256 resourceLvl;
    uint256 resourceDirection;
    uint256 status;
    uint256 font;
    uint256 fontSize;
    uint256 biome;
    int attunement;
    AntennaStatus antenna;
    string zoneName;
    string script;
    string[9] chars;
    string[10] zoneColors;
}

struct AnimParams {
    Activation activation; // Token's animation type
    uint256 classesAnimated; // Classes animated
    uint256 duration; // Base animation duration for first class
    uint256 durationInc; // Duration increment for each class
    uint256 delay; // Base delay for first class
    uint256 delayInc; // Delay increment for each class
    uint256 bgDuration; // Animation duration for background
    uint256 bgDelay; // Delay for background
    string easing; // Animation mode, e.g. steps(), linear, ease-in-out
    string[2] altColors;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

library ToString {
    function toString(uint256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT license
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol

        if (value == 0) {
            return "0";
        }
        uint256 temp = value;
        uint256 digits;
        while (temp != 0) {
            digits++;
            temp /= 10;
        }
        bytes memory buffer = new bytes(digits);
        while (value != 0) {
            digits -= 1;
            buffer[digits] = bytes1(uint8(48 + uint256(value % 10)));
            value /= 10;
        }
        return string(buffer);
    }

    function toString(int256 value) internal pure returns (string memory) {
        // Inspired by OraclizeAPI's implementation - MIT license
        // https://github.com/oraclize/ethereum-api/blob/b42146b063c7d6ee1358846c198246239e9360e8/oraclizeAPI_0.4.25.sol
        if (value < 0) {
            return string.concat("-", toString(uint256(-value)));
        }
        return toString(uint256(value));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import {AntennaStatus} from "../lib/Types.sol";

interface IBeacon {
    function getParcelCode(
        uint256
    ) external view returns (AntennaStatus, string memory);

    function getParcelCodeFromPlacement(
        uint256
    ) external view returns (AntennaStatus, string memory);

    function scriptFonts(uint) external view returns (string memory);
    function scriptLibraries(uint) external view returns (string memory);
    function scriptBodies(uint) external view returns (string memory);
    function scriptLoopStarts(uint) external view returns (string memory);
    function scriptLoopEnds(uint) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
import {OwnableUpgradeable} from "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import {IBeacon} from "./interfaces/IBeacon.sol";
import {ITerraforms, Status} from "./interfaces/ITerraforms.sol";
import {ITerraformsCharacters} from "./interfaces/ITerraformsCharacters.sol";
import {ISatellite} from "./interfaces/ISatellite.sol";
import {AntennaStatus, AntennaModification} from "./lib/Types.sol";
import {ToString} from "./lib/ToString.sol";

/// @author xaltgeist, with code direction and consultation from 113
/// @title A beacon for Terraforms parcels, version 2.0
contract TerraformsBeacon_v2_0 is
    IBeacon,
    Initializable,
    UUPSUpgradeable,
    OwnableUpgradeable
{
    using ToString for uint256;

    enum ScriptComponent {
        Library,
        Font,
        Extra1,
        Body,
        UI,
        Extra2,
        LoopStart,
        LoopEnd
    }

    struct Broadcast {
        address satellite;
        uint256 duration;
    }

    struct CapturedSatelliteConnection {
        address satellite;
        uint256 timestamp;
    }

    struct AntennaModificationRecord {
        AntennaModification modification;
        address satellite;
        uint256 timestamp;
    }

    // Contract data
    string public version;
    uint256 public MAX_SUPPLY;
    ITerraforms terraforms;

    // Broadcast data
    Broadcast[] public broadcasts;
    uint256[] public broadcastOrder;
    uint256[8] public defaultScriptComponentIndices;

    // Parcel data
    mapping(uint256 => uint256) public placementToParcelId;
    mapping(uint256 => AntennaStatus) public parcelToAntennaStatus;
    mapping(uint256 => CapturedSatelliteConnection[])
        public parcelToCapturedSatelliteConnections;
    mapping(uint256 => uint256) public parcelToActiveSatelliteConnectionIndex;
    mapping(uint256 => AntennaModificationRecord[]) public parcelToAntennaMods;

    // Script data
    mapping(uint256 => string) public scriptLibraries;
    mapping(uint256 => string) public scriptFonts;
    mapping(uint256 => string) public scriptExtras1;
    mapping(uint256 => string) public scriptBodies;
    mapping(uint256 => string) public scriptUIs;
    mapping(uint256 => string) public scriptExtras2;
    mapping(uint256 => string) public scriptLoopStarts;
    mapping(uint256 => string) public scriptLoopEnds;
    uint public nScriptLibraries;
    uint public nScriptFonts;
    uint public nScriptExtras1;
    uint public nScriptBodies;
    uint public nScriptUIs;
    uint public nScriptExtras2;
    uint public nScriptLoopStarts;
    uint public nScriptLoopEnds;

    // Events
    event ParcelModified(uint256 tokenId, AntennaModification modification);
    event BroadcastAdded(address satellite, uint256 duration);
    event BroadcastRemoved(address satellite);
    event BroadcastModified(address satellite, uint256 duration);
    event BroadcastOrderModified(uint256[] order);
    event ScriptComponentModified(ScriptComponent componentType, uint256 index);

    /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
     * INITIALIZER
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
    /// @custom:oz-upgrades-unsafe-allow constructor
    constructor() {
        _disableInitializers();
    }

    function initialize(
        string memory _scriptLibrary,
        string memory _scriptBody,
        string memory _scriptUI,
        string memory _scriptLoopStart,
        string memory _scriptLoopEnd
    ) public initializer {
        __Ownable_init();
        version = "Version 2.0";
        terraforms = ITerraforms(0x4E1f41613c9084FdB9E34E11fAE9412427480e56); // Main (ERC721) contract
        MAX_SUPPLY = 11104;

        setScriptLibrary(0, _scriptLibrary);
        setScriptBody(0, _scriptBody);
        setScriptUI(0, _scriptUI);
        setScriptLoopStart(0, _scriptLoopStart);
        setScriptLoopEnd(0, _scriptLoopEnd);
    }

    function _authorizeUpgrade(
        address newImplementation
    ) internal override onlyOwner {}

    /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
     * PUBLIC: WRITE FUNCTIONS
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
    /// @notice Turns the antenna on for a parcel
    /// @param tokenId The parcel's token ID
    function turnAntennaOn(uint256 tokenId) public {
        require(terraforms.ownerOf(tokenId) == msg.sender, "Only owner");
        require(
            terraforms.tokenToStatus(tokenId) != Status.Terrain,
            "Cannot be terrain"
        );

        require(
            parcelToAntennaStatus[tokenId] != AntennaStatus.On,
            "Antenna already on"
        );

        if (parcelToAntennaMods[tokenId].length == 0) {
            placementToParcelId[terraforms.tokenToPlacement(tokenId)] = tokenId;
        }

        parcelToAntennaStatus[tokenId] = AntennaStatus.On;

        parcelToAntennaMods[tokenId].push(
            AntennaModificationRecord(
                AntennaModification.TurnedAntennaOn,
                address(0),
                block.timestamp
            )
        );

        emit ParcelModified(tokenId, AntennaModification.TurnedAntennaOn);
    }

    /// @notice Turns the antenna off for a parcel
    /// @param tokenId The parcel's token ID
    function turnAntennaOff(uint256 tokenId) public {
        require(terraforms.ownerOf(tokenId) == msg.sender, "Only owner");
        require(
            parcelToAntennaStatus[tokenId] != AntennaStatus.Off,
            "Antenna is off"
        );

        parcelToAntennaStatus[tokenId] = AntennaStatus.Off;

        parcelToAntennaMods[tokenId].push(
            AntennaModificationRecord(
                AntennaModification.TurnedAntennaOff,
                address(0),
                block.timestamp
            )
        );

        emit ParcelModified(tokenId, AntennaModification.TurnedAntennaOff);
    }

    /// @notice Saves a connection to the current satellite
    /// @param tokenId The parcel's token ID
    function saveConnectionToCurrentSatellite(uint256 tokenId) public {
        require(terraforms.ownerOf(tokenId) == msg.sender, "Only owner");
        require(
            parcelToAntennaStatus[tokenId] != AntennaStatus.Off,
            "Antenna is off"
        );

        int256 index = getCurrentBroadcastIndex();
        require(index >= 0, "No active satellite broadcasts");
        Broadcast memory b = broadcasts[uint256(index)];

        ISatellite(b.satellite).capture(tokenId);
        parcelToCapturedSatelliteConnections[tokenId].push(
            CapturedSatelliteConnection(b.satellite, block.timestamp)
        );

        parcelToAntennaMods[tokenId].push(
            AntennaModificationRecord(
                AntennaModification.CapturedSatelliteConnection,
                b.satellite,
                block.timestamp
            )
        );

        emit ParcelModified(
            tokenId,
            AntennaModification.TunedToCapturedSatelliteConnection
        );
        tuneToCapturedSatelliteConnection(
            tokenId,
            parcelToCapturedSatelliteConnections[tokenId].length - 1
        );
    }

    /// @notice Tunes a parcel's antenna to a captured broadcast
    /// @param tokenId The parcel's token ID
    /// @param index The index of the captured broadcast to tune to
    function tuneToCapturedSatelliteConnection(
        uint256 tokenId,
        uint256 index
    ) public {
        require(
            parcelToAntennaStatus[tokenId] != AntennaStatus.Off,
            "Antenna is off"
        );
        require(terraforms.ownerOf(tokenId) == msg.sender, "Only owner");
        require(
            index < parcelToCapturedSatelliteConnections[tokenId].length,
            "Out of range"
        );
        AntennaModificationRecord memory lastMod = getLastAntennaModification(
            tokenId
        );
        if (
            lastMod.modification ==
            AntennaModification.TunedToCapturedSatelliteConnection
        ) {
            require(
                lastMod.satellite !=
                    parcelToCapturedSatelliteConnections[tokenId][index]
                        .satellite,
                "Already connected to this satellite"
            );
        }

        parcelToActiveSatelliteConnectionIndex[tokenId] = index;
        parcelToAntennaStatus[tokenId] = AntennaStatus.ConnectedToSatellite;

        parcelToAntennaMods[tokenId].push(
            AntennaModificationRecord(
                AntennaModification.TunedToCapturedSatelliteConnection,
                parcelToCapturedSatelliteConnections[tokenId][index].satellite,
                block.timestamp
            )
        );

        emit ParcelModified(
            tokenId,
            AntennaModification.TunedToCapturedSatelliteConnection
        );
    }

    /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
     * PUBLIC: READ FUNCTIONS
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
    /// @notice Gets the status of a parcel's antenna
    /// @param tokenId The parcel's token ID
    /// @return status The status of the parcel's antenna
    function getAntennaStatus(
        uint256 tokenId
    ) public view returns (AntennaStatus status) {
        require(tokenId <= MAX_SUPPLY);
        return parcelToAntennaStatus[tokenId];
    }

    /// @notice Gets the first antenna modification for a parcel
    /// @param tokenId The parcel's token ID
    /// @return modification The first antenna modification
    function getFirstAntennaModification(
        uint256 tokenId
    ) public view returns (AntennaModificationRecord memory) {
        AntennaModificationRecord[] storage mods = parcelToAntennaMods[tokenId];
        require(mods.length > 0, "No antenna modifications");
        return mods[0];
    }

    /// @notice Gets the last antenna modification for a parcel
    /// @param tokenId The parcel's token ID
    /// @return modification The last antenna modification
    function getLastAntennaModification(
        uint256 tokenId
    ) public view returns (AntennaModificationRecord memory) {
        AntennaModificationRecord[] storage mods = parcelToAntennaMods[tokenId];
        require(mods.length > 0, "No antenna modifications");
        return mods[mods.length - 1];
    }

    /// @notice Gets the antenna modification at a given index for a parcel
    /// @param tokenId The parcel's token ID
    /// @param index The index of the antenna modification
    /// @return modification The antenna modification
    function getAntennaModificationAtIndex(
        uint256 tokenId,
        uint256 index
    ) public view returns (AntennaModificationRecord memory) {
        AntennaModificationRecord[] storage mods = parcelToAntennaMods[tokenId];
        require(index < mods.length, "Index out of range");
        return mods[index];
    }

    /// @notice Gets the number of antenna modifications for a parcel
    /// @param tokenId The parcel's token ID
    /// @return The number of antenna modifications
    function getNumberOfAntennaModifications(
        uint256 tokenId
    ) public view returns (uint256) {
        AntennaModificationRecord[] storage mods = parcelToAntennaMods[tokenId];
        return mods.length;
    }

    /// @notice Gets the index of the current broadcast
    /// @return index The index of the current broadcast
    function getCurrentBroadcastIndex() public view returns (int256 index) {
        uint256 cycleDuration = getBroadcastCycleDuration();
        if (cycleDuration == 0) {
            return -1;
        }
        uint256 locationInCycle = block.timestamp % cycleDuration;
        uint256 aggregator;
        Broadcast memory b;

        for (uint256 i; i < broadcastOrder.length; i++) {
            if (broadcastOrder[i] < broadcasts.length) {
                b = broadcasts[broadcastOrder[i]];
                if (ISatellite(b.satellite).isBroadcasting()) {
                    aggregator += broadcasts[broadcastOrder[i]].duration;
                }
                if (locationInCycle < aggregator) {
                    return int256(broadcastOrder[i]);
                }
            }
        }
        return -1;
    }

    /// @notice Gets the duration of the current cycle
    /// @return result The duration of the current cycle
    function getBroadcastCycleDuration() public view returns (uint256 result) {
        for (uint256 i; i < broadcastOrder.length; i++) {
            if (
                broadcastOrder[i] < broadcasts.length &&
                ISatellite(broadcasts[broadcastOrder[i]].satellite)
                    .isBroadcasting()
            ) {
                result += broadcasts[broadcastOrder[i]].duration;
            }
        }
    }

    /// @notice Gets the default script
    /// @return script The default script (a JavaScript string)
    function getCoreScript(uint tokenId) public view returns (string memory) {
        return
            string.concat(
                assembleScriptVars(tokenId),
                getFont(defaultScriptComponentIndices[0]),
                scriptLibraries[defaultScriptComponentIndices[1]],
                scriptBodies[defaultScriptComponentIndices[2]],
                scriptUIs[defaultScriptComponentIndices[3]],
                scriptLoopStarts[defaultScriptComponentIndices[3]],
                "t.m1=dist(c,15.5,r,c)+airship*.05*SEED*.00045",
                scriptLoopEnds[defaultScriptComponentIndices[4]]
            );
    }

    /// @notice Gets the code for a parcel
    /// @param tokenId The parcel's token ID
    /// @return status The status of the parcel's antenna
    /// @return parcelCode The code for the parcel (a JavaScript string)
    function getParcelCode(
        uint256 tokenId
    ) public view returns (AntennaStatus status, string memory parcelCode) {
        status = parcelToAntennaStatus[tokenId];
        int256 index = getCurrentBroadcastIndex();
        if (status == AntennaStatus.Off) {
            parcelCode = getCoreScript(tokenId);
        } else if (status == AntennaStatus.ConnectedToSatellite) {
            CapturedSatelliteConnection
                memory c = parcelToCapturedSatelliteConnections[tokenId][
                    parcelToActiveSatelliteConnectionIndex[tokenId]
                ];

            parcelCode = ISatellite(c.satellite).getBroadcast(tokenId);
        } else if (index >= 0) {
            parcelCode = ISatellite(broadcasts[uint256(index)].satellite)
                .getBroadcast(tokenId);
        } else {
            parcelCode = getCoreScript(tokenId);
        }
    }

    /// @notice Gets the script for a parcel's placement
    /// @param placement The parcel's placement
    /// @return status The status of the parcel's antenna
    /// @return script The script for the parcel (a JavaScript string)
    function getParcelCodeFromPlacement(
        uint256 placement
    ) public view returns (AntennaStatus status, string memory script) {
        return getParcelCode(placementToParcelId[placement]);
    }

    function assembleScriptVars(
        uint tokenId
    ) public view returns (string memory vars) {
        uint atime;
        if (getNumberOfAntennaModifications(tokenId) > 0) {
            atime = getFirstAntennaModification(tokenId).timestamp;
        }
        return
            string.concat(
                "let ATIME=",
                atime.toString(),
                ";let TIME=",
                uint(block.timestamp).toString(),
                ";"
            );
    }

    /// @notice Gets the font for a parcel
    /// @param index The index of the font
    /// @return font The font for the parcel (wrapped base64 string)
    function getFont(uint256 index) public view returns (string memory font) {
        font = scriptFonts[index];
        if (keccak256(bytes(font)) == keccak256(bytes(""))) {
            font = ITerraformsCharacters(
                0xC9e417B7e67E387026161E50875D512f29630D7B
            ).font(0);
        }
        return
            string.concat(
                "let extraFont = `@font-face {font-family:'MathcastlesRemix-Extra';font-display:block;src:url(data:application/font-woff2;charset=utf-8;base64,",
                font,
                ") format('woff');}`; document.head.insertAdjacentHTML('beforeend', '<style>'+extraFont+'</style>');"
            );
    }

    /* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
     * PUBLIC: ADMINISTRATIVE
     * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * */
    /// @notice Adds a broadcast to the list of broadcasts
    /// @param satellite The satellite contract address
    /// @param duration The duration of the broadcast
    function addBroadcast(
        address satellite,
        uint256 duration
    ) public onlyOwner {
        broadcasts.push(Broadcast(satellite, duration));
        emit BroadcastAdded(satellite, duration);
    }

    /// @notice Removes the last broadcast from the list of broadcasts
    function removeLastBroadcast() public onlyOwner {
        require(broadcasts.length > 0, "No broadcasts");
        Broadcast memory b = broadcasts[broadcasts.length - 1];
        broadcasts.pop();
        emit BroadcastRemoved(b.satellite);
    }

    /// @notice Modifies a broadcast
    /// @param index The index of the broadcast to modify
    /// @param satellite The satellite contract address
    /// @param duration The duration of the broadcast
    function modifyBroadcast(
        uint256 index,
        address satellite,
        uint256 duration
    ) public onlyOwner {
        require(index < broadcasts.length, "Index out of range");

        Broadcast storage b = broadcasts[index];

        if (b.duration != duration) {
            b.duration = duration;
        }
        if (b.satellite != satellite) {
            b.satellite = satellite;
        }
        emit BroadcastModified(b.satellite, b.duration);
    }

    /// @notice Modifies the broadcast order
    /// @param order The new broadcast order
    function modifyBroadcastOrder(uint256[] calldata order) public onlyOwner {
        uint256 nBroadcasts = broadcasts.length;
        for (uint256 i; i < order.length; i++) {
            require(order[i] < nBroadcasts, "Index out of range");
        }
        broadcastOrder = order;
        emit BroadcastOrderModified(order);
    }

    /// @notice Sets a script library component
    /// @param index The index of the script library component
    /// @param scriptLibrary The script library component
    function setScriptLibrary(
        uint index,
        string memory scriptLibrary
    ) public onlyOwner {
        if (index == nScriptLibraries) {
            nScriptLibraries++;
        }
        scriptLibraries[index] = scriptLibrary;
        emit ScriptComponentModified(ScriptComponent.Library, index);
    }

    /// @notice Sets a script font component
    /// @param index The index of the script font component
    /// @param scriptFont The script font component
    function setScriptFont(
        uint index,
        string memory scriptFont
    ) public onlyOwner {
        if (index == nScriptFonts) {
            nScriptFonts++;
        }
        scriptFonts[index] = scriptFont;
        emit ScriptComponentModified(ScriptComponent.Font, index);
    }

    /// @notice Sets a script extra1 component
    /// @param index The index of the script extra1 component
    /// @param scriptExtra1 The script extra1 component
    function setScriptExtra1(
        uint index,
        string memory scriptExtra1
    ) public onlyOwner {
        if (index == nScriptExtras1) {
            nScriptExtras1++;
        }
        scriptExtras1[index] = scriptExtra1;
        emit ScriptComponentModified(ScriptComponent.Extra1, index);
    }

    /// @notice Sets a script body component
    /// @param index The index of the script body component
    /// @param scriptBody The script body component
    function setScriptBody(
        uint index,
        string memory scriptBody
    ) public onlyOwner {
        if (index == nScriptBodies) {
            nScriptBodies++;
        }
        scriptBodies[index] = scriptBody;
        emit ScriptComponentModified(ScriptComponent.Body, index);
    }

    /// @notice Sets a script UI component
    /// @param index The index of the script UI component
    /// @param scriptUI The script UI component
    function setScriptUI(uint index, string memory scriptUI) public onlyOwner {
        if (index == nScriptUIs) {
            nScriptUIs++;
        }
        scriptUIs[index] = scriptUI;
        emit ScriptComponentModified(ScriptComponent.UI, index);
    }

    /// @notice Sets a script extra2 component
    /// @param index The index of the script extra2 component
    /// @param scriptExtra2 The script extra2 component
    function setScriptExtra2(
        uint index,
        string memory scriptExtra2
    ) public onlyOwner {
        if (index == nScriptExtras2) {
            nScriptExtras2++;
        }
        scriptExtras2[index] = scriptExtra2;
        emit ScriptComponentModified(ScriptComponent.Extra2, index);
    }

    /// @notice Sets a script loop start component
    /// @param index The index of the script loop start component
    /// @param scriptLoopStart The script loop start component
    function setScriptLoopStart(
        uint index,
        string memory scriptLoopStart
    ) public onlyOwner {
        if (index == nScriptLoopStarts) {
            nScriptLoopStarts++;
        }
        scriptLoopStarts[index] = scriptLoopStart;
        emit ScriptComponentModified(ScriptComponent.LoopStart, index);
    }

    /// @notice Sets a script loop end component
    /// @param index The index of the script loop end component
    /// @param scriptLoopEnd The script loop end component
    function setScriptLoopEnd(
        uint index,
        string memory scriptLoopEnd
    ) public onlyOwner {
        if (index == nScriptLoopEnds) {
            nScriptLoopEnds++;
        }
        scriptLoopEnds[index] = scriptLoopEnd;
        emit ScriptComponentModified(ScriptComponent.LoopEnd, index);
    }

    /// @notice Sets the default script component indices
    /// @param indices The default script component indices
    /// @dev The indices are in the following order: library, font, extra1, body, UI, extra2, loopStart, loopEnd
    function setDefaultScriptComponentIndices(
        uint256[8] memory indices
    ) public onlyOwner {
        defaultScriptComponentIndices = indices;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface ISatellite {
    function isBroadcasting() external view returns (bool);

    function capture(uint256) external;

    function getBroadcast(uint256) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

import {Status} from "../lib/Types.sol";

interface ITerraforms {
    function dreamers() external view returns (uint256);

    function ownerOf(uint256) external view returns (address);

    function tokenToDreamer(uint256) external view returns (address);

    function tokenToPlacement(uint256) external view returns (uint256);

    function tokenToStatus(uint256) external view returns (Status);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.0;

interface ITerraformsCharacters {
    function font(uint) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import {Initializable} from "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.2;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * The initialization functions use a version number. Once a version number is used, it is consumed and cannot be
 * reused. This mechanism prevents re-execution of each "step" but allows the creation of new initialization steps in
 * case an upgrade adds a module that needs to be initialized.
 *
 * For example:
 *
 * [.hljs-theme-light.nopadding]
 * ```solidity
 * contract MyToken is ERC20Upgradeable {
 *     function initialize() initializer public {
 *         __ERC20_init("MyToken", "MTK");
 *     }
 * }
 *
 * contract MyTokenV2 is MyToken, ERC20PermitUpgradeable {
 *     function initializeV2() reinitializer(2) public {
 *         __ERC20Permit_init("MyToken");
 *     }
 * }
 * ```
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To prevent the implementation contract from being used, you should invoke
 * the {_disableInitializers} function in the constructor to automatically lock it when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() {
 *     _disableInitializers();
 * }
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     * @custom:oz-retyped-from bool
     */
    uint8 private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Triggered when the contract has been initialized or reinitialized.
     */
    event Initialized(uint8 version);

    /**
     * @dev A modifier that defines a protected initializer function that can be invoked at most once. In its scope,
     * `onlyInitializing` functions can be used to initialize parent contracts.
     *
     * Similar to `reinitializer(1)`, except that functions marked with `initializer` can be nested in the context of a
     * constructor.
     *
     * Emits an {Initialized} event.
     */
    modifier initializer() {
        bool isTopLevelCall = !_initializing;
        require(
            (isTopLevelCall && _initialized < 1) || (!AddressUpgradeable.isContract(address(this)) && _initialized == 1),
            "Initializable: contract is already initialized"
        );
        _initialized = 1;
        if (isTopLevelCall) {
            _initializing = true;
        }
        _;
        if (isTopLevelCall) {
            _initializing = false;
            emit Initialized(1);
        }
    }

    /**
     * @dev A modifier that defines a protected reinitializer function that can be invoked at most once, and only if the
     * contract hasn't been initialized to a greater version before. In its scope, `onlyInitializing` functions can be
     * used to initialize parent contracts.
     *
     * A reinitializer may be used after the original initialization step. This is essential to configure modules that
     * are added through upgrades and that require initialization.
     *
     * When `version` is 1, this modifier is similar to `initializer`, except that functions marked with `reinitializer`
     * cannot be nested. If one is invoked in the context of another, execution will revert.
     *
     * Note that versions can jump in increments greater than 1; this implies that if multiple reinitializers coexist in
     * a contract, executing them in the right order is up to the developer or operator.
     *
     * WARNING: setting the version to 255 will prevent any future reinitialization.
     *
     * Emits an {Initialized} event.
     */
    modifier reinitializer(uint8 version) {
        require(!_initializing && _initialized < version, "Initializable: contract is already initialized");
        _initialized = version;
        _initializing = true;
        _;
        _initializing = false;
        emit Initialized(version);
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} and {reinitializer} modifiers, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    /**
     * @dev Locks the contract, preventing any future reinitialization. This cannot be part of an initializer call.
     * Calling this in the constructor of a contract will prevent that contract from being initialized or reinitialized
     * to any version. It is recommended to use this to lock implementation contracts that are designed to be called
     * through proxies.
     *
     * Emits an {Initialized} event the first time it is successfully executed.
     */
    function _disableInitializers() internal virtual {
        require(!_initializing, "Initializable: contract is initializing");
        if (_initialized != type(uint8).max) {
            _initialized = type(uint8).max;
            emit Initialized(type(uint8).max);
        }
    }

    /**
     * @dev Returns the highest version that has been initialized. See {reinitializer}.
     */
    function _getInitializedVersion() internal view returns (uint8) {
        return _initialized;
    }

    /**
     * @dev Returns `true` if the contract is currently initializing. See {onlyInitializing}.
     */
    function _isInitializing() internal view returns (bool) {
        return _initializing;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/utils/UUPSUpgradeable.sol)

pragma solidity ^0.8.0;

import "../../interfaces/draft-IERC1822Upgradeable.sol";
import "../ERC1967/ERC1967UpgradeUpgradeable.sol";
import {Initializable} from "./Initializable.sol";

/**
 * @dev An upgradeability mechanism designed for UUPS proxies. The functions included here can perform an upgrade of an
 * {ERC1967Proxy}, when this contract is set as the implementation behind such a proxy.
 *
 * A security mechanism ensures that an upgrade does not turn off upgradeability accidentally, although this risk is
 * reinstated if the upgrade retains upgradeability but removes the security mechanism, e.g. by replacing
 * `UUPSUpgradeable` with a custom implementation of upgrades.
 *
 * The {_authorizeUpgrade} function must be overridden to include access restriction to the upgrade mechanism.
 *
 * _Available since v4.1._
 */
abstract contract UUPSUpgradeable is Initializable, IERC1822ProxiableUpgradeable, ERC1967UpgradeUpgradeable {
    /// @custom:oz-upgrades-unsafe-allow state-variable-immutable state-variable-assignment
    address private immutable __self = address(this);

    /**
     * @dev Check that the execution is being performed through a delegatecall call and that the execution context is
     * a proxy contract with an implementation (as defined in ERC1967) pointing to self. This should only be the case
     * for UUPS and transparent proxies that are using the current contract as their implementation. Execution of a
     * function through ERC1167 minimal proxies (clones) would not normally pass this test, but is not guaranteed to
     * fail.
     */
    modifier onlyProxy() {
        require(address(this) != __self, "Function must be called through delegatecall");
        require(_getImplementation() == __self, "Function must be called through active proxy");
        _;
    }

    /**
     * @dev Check that the execution is not being performed through a delegate call. This allows a function to be
     * callable on the implementing contract but not through proxies.
     */
    modifier notDelegated() {
        require(address(this) == __self, "UUPSUpgradeable: must not be called through delegatecall");
        _;
    }

    function __UUPSUpgradeable_init() internal onlyInitializing {
    }

    function __UUPSUpgradeable_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev Implementation of the ERC1822 {proxiableUUID} function. This returns the storage slot used by the
     * implementation. It is used to validate the implementation's compatibility when performing an upgrade.
     *
     * IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
     * bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
     * function revert if invoked through a proxy. This is guaranteed by the `notDelegated` modifier.
     */
    function proxiableUUID() external view virtual override notDelegated returns (bytes32) {
        return _IMPLEMENTATION_SLOT;
    }

    /**
     * @dev Upgrade the implementation of the proxy to `newImplementation`.
     *
     * Calls {_authorizeUpgrade}.
     *
     * Emits an {Upgraded} event.
     *
     * @custom:oz-upgrades-unsafe-allow-reachable delegatecall
     */
    function upgradeTo(address newImplementation) public virtual onlyProxy {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallUUPS(newImplementation, new bytes(0), false);
    }

    /**
     * @dev Upgrade the implementation of the proxy to `newImplementation`, and subsequently execute the function call
     * encoded in `data`.
     *
     * Calls {_authorizeUpgrade}.
     *
     * Emits an {Upgraded} event.
     *
     * @custom:oz-upgrades-unsafe-allow-reachable delegatecall
     */
    function upgradeToAndCall(address newImplementation, bytes memory data) public payable virtual onlyProxy {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallUUPS(newImplementation, data, true);
    }

    /**
     * @dev Function that should revert when `msg.sender` is not authorized to upgrade the contract. Called by
     * {upgradeTo} and {upgradeToAndCall}.
     *
     * Normally, this function will use an xref:access.adoc[access control] modifier such as {Ownable-onlyOwner}.
     *
     * ```solidity
     * function _authorizeUpgrade(address) internal override onlyOwner {}
     * ```
     */
    function _authorizeUpgrade(address newImplementation) internal virtual;

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * _Available since v4.1 for `address`, `bool`, `bytes32`, `uint256`._
 * _Available since v4.9 for `string`, `bytes`._
 */
library StorageSlotUpgradeable {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC1967.sol)

pragma solidity ^0.8.0;

/**
 * @dev ERC-1967: Proxy Storage Slots. This interface contains the events defined in the ERC.
 *
 * _Available since v4.8.3._
 */
interface IERC1967Upgradeable {
    /**
     * @dev Emitted when the implementation is upgraded.
     */
    event Upgraded(address indexed implementation);

    /**
     * @dev Emitted when the admin account has changed.
     */
    event AdminChanged(address previousAdmin, address newAdmin);

    /**
     * @dev Emitted when the beacon is changed.
     */
    event BeaconUpgraded(address indexed beacon);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (proxy/beacon/IBeacon.sol)

pragma solidity ^0.8.0;

/**
 * @dev This is the interface that {BeaconProxy} expects of its beacon.
 */
interface IBeaconUpgradeable {
    /**
     * @dev Must return an address that can be used as a delegate call target.
     *
     * {BeaconProxy} will check that this address is a contract.
     */
    function implementation() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (interfaces/draft-IERC1822.sol)

pragma solidity ^0.8.0;

/**
 * @dev ERC1822: Universal Upgradeable Proxy Standard (UUPS) documents a method for upgradeability through a simplified
 * proxy whose upgrades are fully controlled by the current implementation.
 */
interface IERC1822ProxiableUpgradeable {
    /**
     * @dev Returns the storage slot that the proxiable contract assumes is being used to store the implementation
     * address.
     *
     * IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
     * bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
     * function revert if invoked through a proxy.
     */
    function proxiableUUID() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (proxy/ERC1967/ERC1967Upgrade.sol)

pragma solidity ^0.8.2;

import "../beacon/IBeaconUpgradeable.sol";
import "../../interfaces/IERC1967Upgradeable.sol";
import "../../interfaces/draft-IERC1822Upgradeable.sol";
import "../../utils/AddressUpgradeable.sol";
import "../../utils/StorageSlotUpgradeable.sol";
import {Initializable} from "../utils/Initializable.sol";

/**
 * @dev This abstract contract provides getters and event emitting update functions for
 * https://eips.ethereum.org/EIPS/eip-1967[EIP1967] slots.
 *
 * _Available since v4.1._
 */
abstract contract ERC1967UpgradeUpgradeable is Initializable, IERC1967Upgradeable {
    // This is the keccak-256 hash of "eip1967.proxy.rollback" subtracted by 1
    bytes32 private constant _ROLLBACK_SLOT = 0x4910fdfa16fed3260ed0e7147f7cc6da11a60208b5b9406d12a635614ffd9143;

    /**
     * @dev Storage slot with the address of the current implementation.
     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1, and is
     * validated in the constructor.
     */
    bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;

    function __ERC1967Upgrade_init() internal onlyInitializing {
    }

    function __ERC1967Upgrade_init_unchained() internal onlyInitializing {
    }
    /**
     * @dev Returns the current implementation address.
     */
    function _getImplementation() internal view returns (address) {
        return StorageSlotUpgradeable.getAddressSlot(_IMPLEMENTATION_SLOT).value;
    }

    /**
     * @dev Stores a new address in the EIP1967 implementation slot.
     */
    function _setImplementation(address newImplementation) private {
        require(AddressUpgradeable.isContract(newImplementation), "ERC1967: new implementation is not a contract");
        StorageSlotUpgradeable.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
    }

    /**
     * @dev Perform implementation upgrade
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeTo(address newImplementation) internal {
        _setImplementation(newImplementation);
        emit Upgraded(newImplementation);
    }

    /**
     * @dev Perform implementation upgrade with additional setup call.
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeToAndCall(address newImplementation, bytes memory data, bool forceCall) internal {
        _upgradeTo(newImplementation);
        if (data.length > 0 || forceCall) {
            AddressUpgradeable.functionDelegateCall(newImplementation, data);
        }
    }

    /**
     * @dev Perform implementation upgrade with security checks for UUPS proxies, and additional setup call.
     *
     * Emits an {Upgraded} event.
     */
    function _upgradeToAndCallUUPS(address newImplementation, bytes memory data, bool forceCall) internal {
        // Upgrades from old implementations will perform a rollback test. This test requires the new
        // implementation to upgrade back to the old, non-ERC1822 compliant, implementation. Removing
        // this special case will break upgrade paths from old UUPS implementation to new ones.
        if (StorageSlotUpgradeable.getBooleanSlot(_ROLLBACK_SLOT).value) {
            _setImplementation(newImplementation);
        } else {
            try IERC1822ProxiableUpgradeable(newImplementation).proxiableUUID() returns (bytes32 slot) {
                require(slot == _IMPLEMENTATION_SLOT, "ERC1967Upgrade: unsupported proxiableUUID");
            } catch {
                revert("ERC1967Upgrade: new implementation is not UUPS");
            }
            _upgradeToAndCall(newImplementation, data, forceCall);
        }
    }

    /**
     * @dev Storage slot with the admin of the contract.
     * This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1, and is
     * validated in the constructor.
     */
    bytes32 internal constant _ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;

    /**
     * @dev Returns the current admin.
     */
    function _getAdmin() internal view returns (address) {
        return StorageSlotUpgradeable.getAddressSlot(_ADMIN_SLOT).value;
    }

    /**
     * @dev Stores a new address in the EIP1967 admin slot.
     */
    function _setAdmin(address newAdmin) private {
        require(newAdmin != address(0), "ERC1967: new admin is the zero address");
        StorageSlotUpgradeable.getAddressSlot(_ADMIN_SLOT).value = newAdmin;
    }

    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {AdminChanged} event.
     */
    function _changeAdmin(address newAdmin) internal {
        emit AdminChanged(_getAdmin(), newAdmin);
        _setAdmin(newAdmin);
    }

    /**
     * @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
     * This is bytes32(uint256(keccak256('eip1967.proxy.beacon')) - 1)) and is validated in the constructor.
     */
    bytes32 internal constant _BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;

    /**
     * @dev Returns the current beacon.
     */
    function _getBeacon() internal view returns (address) {
        return StorageSlotUpgradeable.getAddressSlot(_BEACON_SLOT).value;
    }

    /**
     * @dev Stores a new beacon in the EIP1967 beacon slot.
     */
    function _setBeacon(address newBeacon) private {
        require(AddressUpgradeable.isContract(newBeacon), "ERC1967: new beacon is not a contract");
        require(
            AddressUpgradeable.isContract(IBeaconUpgradeable(newBeacon).implementation()),
            "ERC1967: beacon implementation is not a contract"
        );
        StorageSlotUpgradeable.getAddressSlot(_BEACON_SLOT).value = newBeacon;
    }

    /**
     * @dev Perform beacon upgrade with additional setup call. Note: This upgrades the address of the beacon, it does
     * not upgrade the implementation contained in the beacon (see {UpgradeableBeacon-_setImplementation} for that).
     *
     * Emits a {BeaconUpgraded} event.
     */
    function _upgradeBeaconToAndCall(address newBeacon, bytes memory data, bool forceCall) internal {
        _setBeacon(newBeacon);
        emit BeaconUpgraded(newBeacon);
        if (data.length > 0 || forceCall) {
            AddressUpgradeable.functionDelegateCall(IBeaconUpgradeable(newBeacon).implementation(), data);
        }
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}