Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;


/* solhint-disable reason-string */

import "@openzeppelin/contracts/access/Ownable.sol";
import "../interfaces/IPaymaster.sol";
import "../interfaces/IEntryPoint.sol";
import "./Helpers.sol";

/**
 * Helper class for creating a paymaster.
 * provides helper methods for staking.
 * validates that the postOp is called only by the entryPoint
 */
abstract contract BasePaymaster is IPaymaster, Ownable {

    IEntryPoint immutable public entryPoint;

    constructor(IEntryPoint _entryPoint) {
        entryPoint = _entryPoint;
    }

    /// @inheritdoc IPaymaster
    function validatePaymasterUserOp(UserOperation calldata userOp, bytes32 userOpHash, uint256 maxCost)
    external override returns (bytes memory context, uint256 validationData) {
         _requireFromEntryPoint();
        return _validatePaymasterUserOp(userOp, userOpHash, maxCost);
    }

    function _validatePaymasterUserOp(UserOperation calldata userOp, bytes32 userOpHash, uint256 maxCost)
    internal virtual returns (bytes memory context, uint256 validationData);

    /// @inheritdoc IPaymaster
    function postOp(PostOpMode mode, bytes calldata context, uint256 actualGasCost) external override {
        _requireFromEntryPoint();
        _postOp(mode, context, actualGasCost);
    }

    /**
     * post-operation handler.
     * (verified to be called only through the entryPoint)
     * @dev if subclass returns a non-empty context from validatePaymasterUserOp, it must also implement this method.
     * @param mode enum with the following options:
     *      opSucceeded - user operation succeeded.
     *      opReverted  - user op reverted. still has to pay for gas.
     *      postOpReverted - user op succeeded, but caused postOp (in mode=opSucceeded) to revert.
     *                       Now this is the 2nd call, after user's op was deliberately reverted.
     * @param context - the context value returned by validatePaymasterUserOp
     * @param actualGasCost - actual gas used so far (without this postOp call).
     */
    function _postOp(PostOpMode mode, bytes calldata context, uint256 actualGasCost) internal virtual {

        (mode,context,actualGasCost); // unused params
        // subclass must override this method if validatePaymasterUserOp returns a context
        revert("must override");
    }

    /**
     * add a deposit for this paymaster, used for paying for transaction fees
     */
    function deposit() public payable {
        entryPoint.depositTo{value : msg.value}(address(this));
    }

    /**
     * withdraw value from the deposit
     * @param withdrawAddress target to send to
     * @param amount to withdraw
     */
    function withdrawTo(address payable withdrawAddress, uint256 amount) public onlyOwner {
        entryPoint.withdrawTo(withdrawAddress, amount);
    }
    /**
     * add stake for this paymaster.
     * This method can also carry eth value to add to the current stake.
     * @param unstakeDelaySec - the unstake delay for this paymaster. Can only be increased.
     */
    function addStake(uint32 unstakeDelaySec) external payable onlyOwner {
        entryPoint.addStake{value : msg.value}(unstakeDelaySec);
    }

    /**
     * return current paymaster's deposit on the entryPoint.
     */
    function getDeposit() public view returns (uint256) {
        return entryPoint.balanceOf(address(this));
    }

    /**
     * unlock the stake, in order to withdraw it.
     * The paymaster can't serve requests once unlocked, until it calls addStake again
     */
    function unlockStake() external onlyOwner {
        entryPoint.unlockStake();
    }

    /**
     * withdraw the entire paymaster's stake.
     * stake must be unlocked first (and then wait for the unstakeDelay to be over)
     * @param withdrawAddress the address to send withdrawn value.
     */
    function withdrawStake(address payable withdrawAddress) external onlyOwner {
        entryPoint.withdrawStake(withdrawAddress);
    }

    /// validate the call is made from a valid entrypoint
    function _requireFromEntryPoint() internal virtual {
        require(msg.sender == address(entryPoint), "Sender not EntryPoint");
    }
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;

/* solhint-disable no-inline-assembly */

/**
 * returned data from validateUserOp.
 * validateUserOp returns a uint256, with is created by `_packedValidationData` and parsed by `_parseValidationData`
 * @param aggregator - address(0) - the account validated the signature by itself.
 *              address(1) - the account failed to validate the signature.
 *              otherwise - this is an address of a signature aggregator that must be used to validate the signature.
 * @param validAfter - this UserOp is valid only after this timestamp.
 * @param validaUntil - this UserOp is valid only up to this timestamp.
 */
    struct ValidationData {
        address aggregator;
        uint48 validAfter;
        uint48 validUntil;
    }

//extract sigFailed, validAfter, validUntil.
// also convert zero validUntil to type(uint48).max
    function _parseValidationData(uint validationData) pure returns (ValidationData memory data) {
        address aggregator = address(uint160(validationData));
        uint48 validUntil = uint48(validationData >> 160);
        if (validUntil == 0) {
            validUntil = type(uint48).max;
        }
        uint48 validAfter = uint48(validationData >> (48 + 160));
        return ValidationData(aggregator, validAfter, validUntil);
    }

// intersect account and paymaster ranges.
    function _intersectTimeRange(uint256 validationData, uint256 paymasterValidationData) pure returns (ValidationData memory) {
        ValidationData memory accountValidationData = _parseValidationData(validationData);
        ValidationData memory pmValidationData = _parseValidationData(paymasterValidationData);
        address aggregator = accountValidationData.aggregator;
        if (aggregator == address(0)) {
            aggregator = pmValidationData.aggregator;
        }
        uint48 validAfter = accountValidationData.validAfter;
        uint48 validUntil = accountValidationData.validUntil;
        uint48 pmValidAfter = pmValidationData.validAfter;
        uint48 pmValidUntil = pmValidationData.validUntil;

        if (validAfter < pmValidAfter) validAfter = pmValidAfter;
        if (validUntil > pmValidUntil) validUntil = pmValidUntil;
        return ValidationData(aggregator, validAfter, validUntil);
    }

/**
 * helper to pack the return value for validateUserOp
 * @param data - the ValidationData to pack
 */
    function _packValidationData(ValidationData memory data) pure returns (uint256) {
        return uint160(data.aggregator) | (uint256(data.validUntil) << 160) | (uint256(data.validAfter) << (160 + 48));
    }

/**
 * helper to pack the return value for validateUserOp, when not using an aggregator
 * @param sigFailed - true for signature failure, false for success
 * @param validUntil last timestamp this UserOperation is valid (or zero for infinite)
 * @param validAfter first timestamp this UserOperation is valid
 */
    function _packValidationData(bool sigFailed, uint48 validUntil, uint48 validAfter) pure returns (uint256) {
        return (sigFailed ? 1 : 0) | (uint256(validUntil) << 160) | (uint256(validAfter) << (160 + 48));
    }

/**
 * keccak function over calldata.
 * @dev copy calldata into memory, do keccak and drop allocated memory. Strangely, this is more efficient than letting solidity do it.
 */
    function calldataKeccak(bytes calldata data) pure returns (bytes32 ret) {
        assembly {
            let mem := mload(0x40)
            let len := data.length
            calldatacopy(mem, data.offset, len)
            ret := keccak256(mem, len)
        }
    }

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;

import "./UserOperation.sol";

/**
 * Aggregated Signatures validator.
 */
interface IAggregator {

    /**
     * validate aggregated signature.
     * revert if the aggregated signature does not match the given list of operations.
     */
    function validateSignatures(UserOperation[] calldata userOps, bytes calldata signature) external view;

    /**
     * validate signature of a single userOp
     * This method is should be called by bundler after EntryPoint.simulateValidation() returns (reverts) with ValidationResultWithAggregation
     * First it validates the signature over the userOp. Then it returns data to be used when creating the handleOps.
     * @param userOp the userOperation received from the user.
     * @return sigForUserOp the value to put into the signature field of the userOp when calling handleOps.
     *    (usually empty, unless account and aggregator support some kind of "multisig"
     */
    function validateUserOpSignature(UserOperation calldata userOp)
    external view returns (bytes memory sigForUserOp);

    /**
     * aggregate multiple signatures into a single value.
     * This method is called off-chain to calculate the signature to pass with handleOps()
     * bundler MAY use optimized custom code perform this aggregation
     * @param userOps array of UserOperations to collect the signatures from.
     * @return aggregatedSignature the aggregated signature
     */
    function aggregateSignatures(UserOperation[] calldata userOps) external view returns (bytes memory aggregatedSignature);
}

/**
 ** Account-Abstraction (EIP-4337) singleton EntryPoint implementation.
 ** Only one instance required on each chain.
 **/
// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;

/* solhint-disable avoid-low-level-calls */
/* solhint-disable no-inline-assembly */
/* solhint-disable reason-string */

import "./UserOperation.sol";
import "./IStakeManager.sol";
import "./IAggregator.sol";
import "./INonceManager.sol";

interface IEntryPoint is IStakeManager, INonceManager {

    /***
     * An event emitted after each successful request
     * @param userOpHash - unique identifier for the request (hash its entire content, except signature).
     * @param sender - the account that generates this request.
     * @param paymaster - if non-null, the paymaster that pays for this request.
     * @param nonce - the nonce value from the request.
     * @param success - true if the sender transaction succeeded, false if reverted.
     * @param actualGasCost - actual amount paid (by account or paymaster) for this UserOperation.
     * @param actualGasUsed - total gas used by this UserOperation (including preVerification, creation, validation and execution).
     */
    event UserOperationEvent(bytes32 indexed userOpHash, address indexed sender, address indexed paymaster, uint256 nonce, bool success, uint256 actualGasCost, uint256 actualGasUsed);

    /**
     * account "sender" was deployed.
     * @param userOpHash the userOp that deployed this account. UserOperationEvent will follow.
     * @param sender the account that is deployed
     * @param factory the factory used to deploy this account (in the initCode)
     * @param paymaster the paymaster used by this UserOp
     */
    event AccountDeployed(bytes32 indexed userOpHash, address indexed sender, address factory, address paymaster);

    /**
     * An event emitted if the UserOperation "callData" reverted with non-zero length
     * @param userOpHash the request unique identifier.
     * @param sender the sender of this request
     * @param nonce the nonce used in the request
     * @param revertReason - the return bytes from the (reverted) call to "callData".
     */
    event UserOperationRevertReason(bytes32 indexed userOpHash, address indexed sender, uint256 nonce, bytes revertReason);

    /**
     * an event emitted by handleOps(), before starting the execution loop.
     * any event emitted before this event, is part of the validation.
     */
    event BeforeExecution();

    /**
     * signature aggregator used by the following UserOperationEvents within this bundle.
     */
    event SignatureAggregatorChanged(address indexed aggregator);

    /**
     * a custom revert error of handleOps, to identify the offending op.
     *  NOTE: if simulateValidation passes successfully, there should be no reason for handleOps to fail on it.
     *  @param opIndex - index into the array of ops to the failed one (in simulateValidation, this is always zero)
     *  @param reason - revert reason
     *      The string starts with a unique code "AAmn", where "m" is "1" for factory, "2" for account and "3" for paymaster issues,
     *      so a failure can be attributed to the correct entity.
     *   Should be caught in off-chain handleOps simulation and not happen on-chain.
     *   Useful for mitigating DoS attempts against batchers or for troubleshooting of factory/account/paymaster reverts.
     */
    error FailedOp(uint256 opIndex, string reason);

    /**
     * error case when a signature aggregator fails to verify the aggregated signature it had created.
     */
    error SignatureValidationFailed(address aggregator);

    /**
     * Successful result from simulateValidation.
     * @param returnInfo gas and time-range returned values
     * @param senderInfo stake information about the sender
     * @param factoryInfo stake information about the factory (if any)
     * @param paymasterInfo stake information about the paymaster (if any)
     */
    error ValidationResult(ReturnInfo returnInfo,
        StakeInfo senderInfo, StakeInfo factoryInfo, StakeInfo paymasterInfo);

    /**
     * Successful result from simulateValidation, if the account returns a signature aggregator
     * @param returnInfo gas and time-range returned values
     * @param senderInfo stake information about the sender
     * @param factoryInfo stake information about the factory (if any)
     * @param paymasterInfo stake information about the paymaster (if any)
     * @param aggregatorInfo signature aggregation info (if the account requires signature aggregator)
     *      bundler MUST use it to verify the signature, or reject the UserOperation
     */
    error ValidationResultWithAggregation(ReturnInfo returnInfo,
        StakeInfo senderInfo, StakeInfo factoryInfo, StakeInfo paymasterInfo,
        AggregatorStakeInfo aggregatorInfo);

    /**
     * return value of getSenderAddress
     */
    error SenderAddressResult(address sender);

    /**
     * return value of simulateHandleOp
     */
    error ExecutionResult(uint256 preOpGas, uint256 paid, uint48 validAfter, uint48 validUntil, bool targetSuccess, bytes targetResult);

    //UserOps handled, per aggregator
    struct UserOpsPerAggregator {
        UserOperation[] userOps;

        // aggregator address
        IAggregator aggregator;
        // aggregated signature
        bytes signature;
    }

    /**
     * Execute a batch of UserOperation.
     * no signature aggregator is used.
     * if any account requires an aggregator (that is, it returned an aggregator when
     * performing simulateValidation), then handleAggregatedOps() must be used instead.
     * @param ops the operations to execute
     * @param beneficiary the address to receive the fees
     */
    function handleOps(UserOperation[] calldata ops, address payable beneficiary) external;

    /**
     * Execute a batch of UserOperation with Aggregators
     * @param opsPerAggregator the operations to execute, grouped by aggregator (or address(0) for no-aggregator accounts)
     * @param beneficiary the address to receive the fees
     */
    function handleAggregatedOps(
        UserOpsPerAggregator[] calldata opsPerAggregator,
        address payable beneficiary
    ) external;

    /**
     * generate a request Id - unique identifier for this request.
     * the request ID is a hash over the content of the userOp (except the signature), the entrypoint and the chainid.
     */
    function getUserOpHash(UserOperation calldata userOp) external view returns (bytes32);

    /**
     * Simulate a call to account.validateUserOp and paymaster.validatePaymasterUserOp.
     * @dev this method always revert. Successful result is ValidationResult error. other errors are failures.
     * @dev The node must also verify it doesn't use banned opcodes, and that it doesn't reference storage outside the account's data.
     * @param userOp the user operation to validate.
     */
    function simulateValidation(UserOperation calldata userOp) external;

    /**
     * gas and return values during simulation
     * @param preOpGas the gas used for validation (including preValidationGas)
     * @param prefund the required prefund for this operation
     * @param sigFailed validateUserOp's (or paymaster's) signature check failed
     * @param validAfter - first timestamp this UserOp is valid (merging account and paymaster time-range)
     * @param validUntil - last timestamp this UserOp is valid (merging account and paymaster time-range)
     * @param paymasterContext returned by validatePaymasterUserOp (to be passed into postOp)
     */
    struct ReturnInfo {
        uint256 preOpGas;
        uint256 prefund;
        bool sigFailed;
        uint48 validAfter;
        uint48 validUntil;
        bytes paymasterContext;
    }

    /**
     * returned aggregated signature info.
     * the aggregator returned by the account, and its current stake.
     */
    struct AggregatorStakeInfo {
        address aggregator;
        StakeInfo stakeInfo;
    }

    /**
     * Get counterfactual sender address.
     *  Calculate the sender contract address that will be generated by the initCode and salt in the UserOperation.
     * this method always revert, and returns the address in SenderAddressResult error
     * @param initCode the constructor code to be passed into the UserOperation.
     */
    function getSenderAddress(bytes memory initCode) external;


    /**
     * simulate full execution of a UserOperation (including both validation and target execution)
     * this method will always revert with "ExecutionResult".
     * it performs full validation of the UserOperation, but ignores signature error.
     * an optional target address is called after the userop succeeds, and its value is returned
     * (before the entire call is reverted)
     * Note that in order to collect the the success/failure of the target call, it must be executed
     * with trace enabled to track the emitted events.
     * @param op the UserOperation to simulate
     * @param target if nonzero, a target address to call after userop simulation. If called, the targetSuccess and targetResult
     *        are set to the return from that call.
     * @param targetCallData callData to pass to target address
     */
    function simulateHandleOp(UserOperation calldata op, address target, bytes calldata targetCallData) external;
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;

interface INonceManager {

    /**
     * Return the next nonce for this sender.
     * Within a given key, the nonce values are sequenced (starting with zero, and incremented by one on each userop)
     * But UserOp with different keys can come with arbitrary order.
     *
     * @param sender the account address
     * @param key the high 192 bit of the nonce
     * @return nonce a full nonce to pass for next UserOp with this sender.
     */
    function getNonce(address sender, uint192 key)
    external view returns (uint256 nonce);

    /**
     * Manually increment the nonce of the sender.
     * This method is exposed just for completeness..
     * Account does NOT need to call it, neither during validation, nor elsewhere,
     * as the EntryPoint will update the nonce regardless.
     * Possible use-case is call it with various keys to "initialize" their nonces to one, so that future
     * UserOperations will not pay extra for the first transaction with a given key.
     */
    function incrementNonce(uint192 key) external;
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;

import "./UserOperation.sol";

/**
 * the interface exposed by a paymaster contract, who agrees to pay the gas for user's operations.
 * a paymaster must hold a stake to cover the required entrypoint stake and also the gas for the transaction.
 */
interface IPaymaster {

    enum PostOpMode {
        opSucceeded, // user op succeeded
        opReverted, // user op reverted. still has to pay for gas.
        postOpReverted //user op succeeded, but caused postOp to revert. Now it's a 2nd call, after user's op was deliberately reverted.
    }

    /**
     * payment validation: check if paymaster agrees to pay.
     * Must verify sender is the entryPoint.
     * Revert to reject this request.
     * Note that bundlers will reject this method if it changes the state, unless the paymaster is trusted (whitelisted)
     * The paymaster pre-pays using its deposit, and receive back a refund after the postOp method returns.
     * @param userOp the user operation
     * @param userOpHash hash of the user's request data.
     * @param maxCost the maximum cost of this transaction (based on maximum gas and gas price from userOp)
     * @return context value to send to a postOp
     *      zero length to signify postOp is not required.
     * @return validationData signature and time-range of this operation, encoded the same as the return value of validateUserOperation
     *      <20-byte> sigAuthorizer - 0 for valid signature, 1 to mark signature failure,
     *         otherwise, an address of an "authorizer" contract.
     *      <6-byte> validUntil - last timestamp this operation is valid. 0 for "indefinite"
     *      <6-byte> validAfter - first timestamp this operation is valid
     *      Note that the validation code cannot use block.timestamp (or block.number) directly.
     */
    function validatePaymasterUserOp(UserOperation calldata userOp, bytes32 userOpHash, uint256 maxCost)
    external returns (bytes memory context, uint256 validationData);

    /**
     * post-operation handler.
     * Must verify sender is the entryPoint
     * @param mode enum with the following options:
     *      opSucceeded - user operation succeeded.
     *      opReverted  - user op reverted. still has to pay for gas.
     *      postOpReverted - user op succeeded, but caused postOp (in mode=opSucceeded) to revert.
     *                       Now this is the 2nd call, after user's op was deliberately reverted.
     * @param context - the context value returned by validatePaymasterUserOp
     * @param actualGasCost - actual gas used so far (without this postOp call).
     */
    function postOp(PostOpMode mode, bytes calldata context, uint256 actualGasCost) external;
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.12;

/**
 * manage deposits and stakes.
 * deposit is just a balance used to pay for UserOperations (either by a paymaster or an account)
 * stake is value locked for at least "unstakeDelay" by the staked entity.
 */
interface IStakeManager {

    event Deposited(
        address indexed account,
        uint256 totalDeposit
    );

    event Withdrawn(
        address indexed account,
        address withdrawAddress,
        uint256 amount
    );

    /// Emitted when stake or unstake delay are modified
    event StakeLocked(
        address indexed account,
        uint256 totalStaked,
        uint256 unstakeDelaySec
    );

    /// Emitted once a stake is scheduled for withdrawal
    event StakeUnlocked(
        address indexed account,
        uint256 withdrawTime
    );

    event StakeWithdrawn(
        address indexed account,
        address withdrawAddress,
        uint256 amount
    );

    /**
     * @param deposit the entity's deposit
     * @param staked true if this entity is staked.
     * @param stake actual amount of ether staked for this entity.
     * @param unstakeDelaySec minimum delay to withdraw the stake.
     * @param withdrawTime - first block timestamp where 'withdrawStake' will be callable, or zero if already locked
     * @dev sizes were chosen so that (deposit,staked, stake) fit into one cell (used during handleOps)
     *    and the rest fit into a 2nd cell.
     *    112 bit allows for 10^15 eth
     *    48 bit for full timestamp
     *    32 bit allows 150 years for unstake delay
     */
    struct DepositInfo {
        uint112 deposit;
        bool staked;
        uint112 stake;
        uint32 unstakeDelaySec;
        uint48 withdrawTime;
    }

    //API struct used by getStakeInfo and simulateValidation
    struct StakeInfo {
        uint256 stake;
        uint256 unstakeDelaySec;
    }

    /// @return info - full deposit information of given account
    function getDepositInfo(address account) external view returns (DepositInfo memory info);

    /// @return the deposit (for gas payment) of the account
    function balanceOf(address account) external view returns (uint256);

    /**
     * add to the deposit of the given account
     */
    function depositTo(address account) external payable;

    /**
     * add to the account's stake - amount and delay
     * any pending unstake is first cancelled.
     * @param _unstakeDelaySec the new lock duration before the deposit can be withdrawn.
     */
    function addStake(uint32 _unstakeDelaySec) external payable;

    /**
     * attempt to unlock the stake.
     * the value can be withdrawn (using withdrawStake) after the unstake delay.
     */
    function unlockStake() external;

    /**
     * withdraw from the (unlocked) stake.
     * must first call unlockStake and wait for the unstakeDelay to pass
     * @param withdrawAddress the address to send withdrawn value.
     */
    function withdrawStake(address payable withdrawAddress) external;

    /**
     * withdraw from the deposit.
     * @param withdrawAddress the address to send withdrawn value.
     * @param withdrawAmount the amount to withdraw.
     */
    function withdrawTo(address payable withdrawAddress, uint256 withdrawAmount) external;
}

// SPDX-License-Identifier: GPL-3.0
pragma solidity ^0.8.12;

/* solhint-disable no-inline-assembly */

import {calldataKeccak} from "../core/Helpers.sol";

/**
 * User Operation struct
 * @param sender the sender account of this request.
     * @param nonce unique value the sender uses to verify it is not a replay.
     * @param initCode if set, the account contract will be created by this constructor/
     * @param callData the method call to execute on this account.
     * @param callGasLimit the gas limit passed to the callData method call.
     * @param verificationGasLimit gas used for validateUserOp and validatePaymasterUserOp.
     * @param preVerificationGas gas not calculated by the handleOps method, but added to the gas paid. Covers batch overhead.
     * @param maxFeePerGas same as EIP-1559 gas parameter.
     * @param maxPriorityFeePerGas same as EIP-1559 gas parameter.
     * @param paymasterAndData if set, this field holds the paymaster address and paymaster-specific data. the paymaster will pay for the transaction instead of the sender.
     * @param signature sender-verified signature over the entire request, the EntryPoint address and the chain ID.
     */
    struct UserOperation {

        address sender;
        uint256 nonce;
        bytes initCode;
        bytes callData;
        uint256 callGasLimit;
        uint256 verificationGasLimit;
        uint256 preVerificationGas;
        uint256 maxFeePerGas;
        uint256 maxPriorityFeePerGas;
        bytes paymasterAndData;
        bytes signature;
    }

/**
 * Utility functions helpful when working with UserOperation structs.
 */
library UserOperationLib {

    function getSender(UserOperation calldata userOp) internal pure returns (address) {
        address data;
        //read sender from userOp, which is first userOp member (saves 800 gas...)
        assembly {data := calldataload(userOp)}
        return address(uint160(data));
    }

    //relayer/block builder might submit the TX with higher priorityFee, but the user should not
    // pay above what he signed for.
    function gasPrice(UserOperation calldata userOp) internal view returns (uint256) {
    unchecked {
        uint256 maxFeePerGas = userOp.maxFeePerGas;
        uint256 maxPriorityFeePerGas = userOp.maxPriorityFeePerGas;
        if (maxFeePerGas == maxPriorityFeePerGas) {
            //legacy mode (for networks that don't support basefee opcode)
            return maxFeePerGas;
        }
        return min(maxFeePerGas, maxPriorityFeePerGas + block.basefee);
    }
    }

    function pack(UserOperation calldata userOp) internal pure returns (bytes memory ret) {
        address sender = getSender(userOp);
        uint256 nonce = userOp.nonce;
        bytes32 hashInitCode = calldataKeccak(userOp.initCode);
        bytes32 hashCallData = calldataKeccak(userOp.callData);
        uint256 callGasLimit = userOp.callGasLimit;
        uint256 verificationGasLimit = userOp.verificationGasLimit;
        uint256 preVerificationGas = userOp.preVerificationGas;
        uint256 maxFeePerGas = userOp.maxFeePerGas;
        uint256 maxPriorityFeePerGas = userOp.maxPriorityFeePerGas;
        bytes32 hashPaymasterAndData = calldataKeccak(userOp.paymasterAndData);

        return abi.encode(
            sender, nonce,
            hashInitCode, hashCallData,
            callGasLimit, verificationGasLimit, preVerificationGas,
            maxFeePerGas, maxPriorityFeePerGas,
            hashPaymasterAndData
        );
    }

    function hash(UserOperation calldata userOp) internal pure returns (bytes32) {
        return keccak256(pack(userOp));
    }

    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.0;

import "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        require(pendingOwner() == sender, "Ownable2Step: caller is not the new owner");
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (interfaces/IERC5267.sol)

pragma solidity ^0.8.0;

interface IERC5267 {
    /**
     * @dev MAY be emitted to signal that the domain could have changed.
     */
    event EIP712DomainChanged();

    /**
     * @dev returns the fields and values that describe the domain separator used by this contract for EIP-712
     * signature.
     */
    function eip712Domain()
        external
        view
        returns (
            bytes1 fields,
            string memory name,
            string memory version,
            uint256 chainId,
            address verifyingContract,
            bytes32 salt,
            uint256[] memory extensions
        );
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 amount) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.3) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.0;

import "../IERC20.sol";
import "../extensions/IERC20Permit.sol";
import "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transfer.selector, to, value));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeWithSelector(token.transferFrom.selector, from, to, value));
    }

    /**
     * @dev Deprecated. This function has issues similar to the ones found in
     * {IERC20-approve}, and its usage is discouraged.
     *
     * Whenever possible, use {safeIncreaseAllowance} and
     * {safeDecreaseAllowance} instead.
     */
    function safeApprove(IERC20 token, address spender, uint256 value) internal {
        // safeApprove should only be called when setting an initial allowance,
        // or when resetting it to zero. To increase and decrease it, use
        // 'safeIncreaseAllowance' and 'safeDecreaseAllowance'
        require(
            (value == 0) || (token.allowance(address(this), spender) == 0),
            "SafeERC20: approve from non-zero to non-zero allowance"
        );
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, value));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance + value));
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        unchecked {
            uint256 oldAllowance = token.allowance(address(this), spender);
            require(oldAllowance >= value, "SafeERC20: decreased allowance below zero");
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, oldAllowance - value));
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeWithSelector(token.approve.selector, spender, value);

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeWithSelector(token.approve.selector, spender, 0));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Use a ERC-2612 signature to set the `owner` approval toward `spender` on `token`.
     * Revert on invalid signature.
     */
    function safePermit(
        IERC20Permit token,
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal {
        uint256 nonceBefore = token.nonces(owner);
        token.permit(owner, spender, value, deadline, v, r, s);
        uint256 nonceAfter = token.nonces(owner);
        require(nonceAfter == nonceBefore + 1, "SafeERC20: permit did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data, "SafeERC20: low-level call failed");
        require(returndata.length == 0 || abi.decode(returndata, (bool)), "SafeERC20: ERC20 operation did not succeed");
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return
            success && (returndata.length == 0 || abi.decode(returndata, (bool))) && Address.isContract(address(token));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     *
     * Furthermore, `isContract` will also return true if the target contract within
     * the same transaction is already scheduled for destruction by `SELFDESTRUCT`,
     * which only has an effect at the end of a transaction.
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.0/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionDelegateCall(target, data, "Address: low-level delegate call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a delegate call.
     *
     * _Available since v3.4._
     */
    function functionDelegateCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and revert (either by bubbling
     * the revert reason or using the provided one) in case of unsuccessful call or if target was not a contract.
     *
     * _Available since v4.8._
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        if (success) {
            if (returndata.length == 0) {
                // only check isContract if the call was successful and the return data is empty
                // otherwise we already know that it was a contract
                require(isContract(target), "Address: call to non-contract");
            }
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason or using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            _revert(returndata, errorMessage);
        }
    }

    function _revert(bytes memory returndata, string memory errorMessage) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert(errorMessage);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.4) (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/ShortStrings.sol)

pragma solidity ^0.8.8;

import "./StorageSlot.sol";

// | string  | 0xAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA   |
// | length  | 0x                                                              BB |
type ShortString is bytes32;

/**
 * @dev This library provides functions to convert short memory strings
 * into a `ShortString` type that can be used as an immutable variable.
 *
 * Strings of arbitrary length can be optimized using this library if
 * they are short enough (up to 31 bytes) by packing them with their
 * length (1 byte) in a single EVM word (32 bytes). Additionally, a
 * fallback mechanism can be used for every other case.
 *
 * Usage example:
 *
 * ```solidity
 * contract Named {
 *     using ShortStrings for *;
 *
 *     ShortString private immutable _name;
 *     string private _nameFallback;
 *
 *     constructor(string memory contractName) {
 *         _name = contractName.toShortStringWithFallback(_nameFallback);
 *     }
 *
 *     function name() external view returns (string memory) {
 *         return _name.toStringWithFallback(_nameFallback);
 *     }
 * }
 * ```
 */
library ShortStrings {
    // Used as an identifier for strings longer than 31 bytes.
    bytes32 private constant _FALLBACK_SENTINEL = 0x00000000000000000000000000000000000000000000000000000000000000FF;

    error StringTooLong(string str);
    error InvalidShortString();

    /**
     * @dev Encode a string of at most 31 chars into a `ShortString`.
     *
     * This will trigger a `StringTooLong` error is the input string is too long.
     */
    function toShortString(string memory str) internal pure returns (ShortString) {
        bytes memory bstr = bytes(str);
        if (bstr.length > 31) {
            revert StringTooLong(str);
        }
        return ShortString.wrap(bytes32(uint256(bytes32(bstr)) | bstr.length));
    }

    /**
     * @dev Decode a `ShortString` back to a "normal" string.
     */
    function toString(ShortString sstr) internal pure returns (string memory) {
        uint256 len = byteLength(sstr);
        // using `new string(len)` would work locally but is not memory safe.
        string memory str = new string(32);
        /// @solidity memory-safe-assembly
        assembly {
            mstore(str, len)
            mstore(add(str, 0x20), sstr)
        }
        return str;
    }

    /**
     * @dev Return the length of a `ShortString`.
     */
    function byteLength(ShortString sstr) internal pure returns (uint256) {
        uint256 result = uint256(ShortString.unwrap(sstr)) & 0xFF;
        if (result > 31) {
            revert InvalidShortString();
        }
        return result;
    }

    /**
     * @dev Encode a string into a `ShortString`, or write it to storage if it is too long.
     */
    function toShortStringWithFallback(string memory value, string storage store) internal returns (ShortString) {
        if (bytes(value).length < 32) {
            return toShortString(value);
        } else {
            StorageSlot.getStringSlot(store).value = value;
            return ShortString.wrap(_FALLBACK_SENTINEL);
        }
    }

    /**
     * @dev Decode a string that was encoded to `ShortString` or written to storage using {setWithFallback}.
     */
    function toStringWithFallback(ShortString value, string storage store) internal pure returns (string memory) {
        if (ShortString.unwrap(value) != _FALLBACK_SENTINEL) {
            return toString(value);
        } else {
            return store;
        }
    }

    /**
     * @dev Return the length of a string that was encoded to `ShortString` or written to storage using {setWithFallback}.
     *
     * WARNING: This will return the "byte length" of the string. This may not reflect the actual length in terms of
     * actual characters as the UTF-8 encoding of a single character can span over multiple bytes.
     */
    function byteLengthWithFallback(ShortString value, string storage store) internal view returns (uint256) {
        if (ShortString.unwrap(value) != _FALLBACK_SENTINEL) {
            return byteLength(value);
        } else {
            return bytes(store).length;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.0;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(Address.isContract(newImplementation), "ERC1967: new implementation is not a contract");
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * _Available since v4.1 for `address`, `bool`, `bytes32`, `uint256`._
 * _Available since v4.9 for `string`, `bytes`._
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        /// @solidity memory-safe-assembly
        assembly {
            r.slot := store.slot
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/Strings.sol)

pragma solidity ^0.8.0;

import "./math/Math.sol";
import "./math/SignedMath.sol";

/**
 * @dev String operations.
 */
library Strings {
    bytes16 private constant _SYMBOLS = "0123456789abcdef";
    uint8 private constant _ADDRESS_LENGTH = 20;

    /**
     * @dev Converts a `uint256` to its ASCII `string` decimal representation.
     */
    function toString(uint256 value) internal pure returns (string memory) {
        unchecked {
            uint256 length = Math.log10(value) + 1;
            string memory buffer = new string(length);
            uint256 ptr;
            /// @solidity memory-safe-assembly
            assembly {
                ptr := add(buffer, add(32, length))
            }
            while (true) {
                ptr--;
                /// @solidity memory-safe-assembly
                assembly {
                    mstore8(ptr, byte(mod(value, 10), _SYMBOLS))
                }
                value /= 10;
                if (value == 0) break;
            }
            return buffer;
        }
    }

    /**
     * @dev Converts a `int256` to its ASCII `string` decimal representation.
     */
    function toString(int256 value) internal pure returns (string memory) {
        return string(abi.encodePacked(value < 0 ? "-" : "", toString(SignedMath.abs(value))));
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation.
     */
    function toHexString(uint256 value) internal pure returns (string memory) {
        unchecked {
            return toHexString(value, Math.log256(value) + 1);
        }
    }

    /**
     * @dev Converts a `uint256` to its ASCII `string` hexadecimal representation with fixed length.
     */
    function toHexString(uint256 value, uint256 length) internal pure returns (string memory) {
        bytes memory buffer = new bytes(2 * length + 2);
        buffer[0] = "0";
        buffer[1] = "x";
        for (uint256 i = 2 * length + 1; i > 1; --i) {
            buffer[i] = _SYMBOLS[value & 0xf];
            value >>= 4;
        }
        require(value == 0, "Strings: hex length insufficient");
        return string(buffer);
    }

    /**
     * @dev Converts an `address` with fixed length of 20 bytes to its not checksummed ASCII `string` hexadecimal representation.
     */
    function toHexString(address addr) internal pure returns (string memory) {
        return toHexString(uint256(uint160(addr)), _ADDRESS_LENGTH);
    }

    /**
     * @dev Returns true if the two strings are equal.
     */
    function equal(string memory a, string memory b) internal pure returns (bool) {
        return keccak256(bytes(a)) == keccak256(bytes(b));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.0;

import "../Strings.sol";

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS,
        InvalidSignatureV // Deprecated in v4.8
    }

    function _throwError(RecoverError error) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert("ECDSA: invalid signature");
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert("ECDSA: invalid signature length");
        } else if (error == RecoverError.InvalidSignatureS) {
            revert("ECDSA: invalid signature 's' value");
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature` or error string. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes memory signature) internal pure returns (address, RecoverError) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            /// @solidity memory-safe-assembly
            assembly {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength);
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM opcode allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, signature);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[EIP-2098 short signatures]
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address, RecoverError) {
        bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
        uint8 v = uint8((uint256(vs) >> 255) + 27);
        return tryRecover(hash, v, r, s);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     *
     * _Available since v4.2._
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, r, vs);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     *
     * _Available since v4.3._
     */
    function tryRecover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address, RecoverError) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature);
        }

        return (signer, RecoverError.NoError);
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error) = tryRecover(hash, v, r, s);
        _throwError(error);
        return recovered;
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from a `hash`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes32 hash) internal pure returns (bytes32 message) {
        // 32 is the length in bytes of hash,
        // enforced by the type signature above
        /// @solidity memory-safe-assembly
        assembly {
            mstore(0x00, "\x19Ethereum Signed Message:\n32")
            mstore(0x1c, hash)
            message := keccak256(0x00, 0x3c)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Message, created from `s`. This
     * produces hash corresponding to the one signed with the
     * https://eth.wiki/json-rpc/API#eth_sign[`eth_sign`]
     * JSON-RPC method as part of EIP-191.
     *
     * See {recover}.
     */
    function toEthSignedMessageHash(bytes memory s) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19Ethereum Signed Message:\n", Strings.toString(s.length), s));
    }

    /**
     * @dev Returns an Ethereum Signed Typed Data, created from a
     * `domainSeparator` and a `structHash`. This produces hash corresponding
     * to the one signed with the
     * https://eips.ethereum.org/EIPS/eip-712[`eth_signTypedData`]
     * JSON-RPC method as part of EIP-712.
     *
     * See {recover}.
     */
    function toTypedDataHash(bytes32 domainSeparator, bytes32 structHash) internal pure returns (bytes32 data) {
        /// @solidity memory-safe-assembly
        assembly {
            let ptr := mload(0x40)
            mstore(ptr, "\x19\x01")
            mstore(add(ptr, 0x02), domainSeparator)
            mstore(add(ptr, 0x22), structHash)
            data := keccak256(ptr, 0x42)
        }
    }

    /**
     * @dev Returns an Ethereum Signed Data with intended validator, created from a
     * `validator` and `data` according to the version 0 of EIP-191.
     *
     * See {recover}.
     */
    function toDataWithIntendedValidatorHash(address validator, bytes memory data) internal pure returns (bytes32) {
        return keccak256(abi.encodePacked("\x19\x00", validator, data));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/cryptography/EIP712.sol)

pragma solidity ^0.8.8;

import "./ECDSA.sol";
import "../ShortStrings.sol";
import "../../interfaces/IERC5267.sol";

/**
 * @dev https://eips.ethereum.org/EIPS/eip-712[EIP 712] is a standard for hashing and signing of typed structured data.
 *
 * The encoding specified in the EIP is very generic, and such a generic implementation in Solidity is not feasible,
 * thus this contract does not implement the encoding itself. Protocols need to implement the type-specific encoding
 * they need in their contracts using a combination of `abi.encode` and `keccak256`.
 *
 * This contract implements the EIP 712 domain separator ({_domainSeparatorV4}) that is used as part of the encoding
 * scheme, and the final step of the encoding to obtain the message digest that is then signed via ECDSA
 * ({_hashTypedDataV4}).
 *
 * The implementation of the domain separator was designed to be as efficient as possible while still properly updating
 * the chain id to protect against replay attacks on an eventual fork of the chain.
 *
 * NOTE: This contract implements the version of the encoding known as "v4", as implemented by the JSON RPC method
 * https://docs.metamask.io/guide/signing-data.html[`eth_signTypedDataV4` in MetaMask].
 *
 * NOTE: In the upgradeable version of this contract, the cached values will correspond to the address, and the domain
 * separator of the implementation contract. This will cause the `_domainSeparatorV4` function to always rebuild the
 * separator from the immutable values, which is cheaper than accessing a cached version in cold storage.
 *
 * _Available since v3.4._
 *
 * @custom:oz-upgrades-unsafe-allow state-variable-immutable state-variable-assignment
 */
abstract contract EIP712 is IERC5267 {
    using ShortStrings for *;

    bytes32 private constant _TYPE_HASH =
        keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)");

    // Cache the domain separator as an immutable value, but also store the chain id that it corresponds to, in order to
    // invalidate the cached domain separator if the chain id changes.
    bytes32 private immutable _cachedDomainSeparator;
    uint256 private immutable _cachedChainId;
    address private immutable _cachedThis;

    bytes32 private immutable _hashedName;
    bytes32 private immutable _hashedVersion;

    ShortString private immutable _name;
    ShortString private immutable _version;
    string private _nameFallback;
    string private _versionFallback;

    /**
     * @dev Initializes the domain separator and parameter caches.
     *
     * The meaning of `name` and `version` is specified in
     * https://eips.ethereum.org/EIPS/eip-712#definition-of-domainseparator[EIP 712]:
     *
     * - `name`: the user readable name of the signing domain, i.e. the name of the DApp or the protocol.
     * - `version`: the current major version of the signing domain.
     *
     * NOTE: These parameters cannot be changed except through a xref:learn::upgrading-smart-contracts.adoc[smart
     * contract upgrade].
     */
    constructor(string memory name, string memory version) {
        _name = name.toShortStringWithFallback(_nameFallback);
        _version = version.toShortStringWithFallback(_versionFallback);
        _hashedName = keccak256(bytes(name));
        _hashedVersion = keccak256(bytes(version));

        _cachedChainId = block.chainid;
        _cachedDomainSeparator = _buildDomainSeparator();
        _cachedThis = address(this);
    }

    /**
     * @dev Returns the domain separator for the current chain.
     */
    function _domainSeparatorV4() internal view returns (bytes32) {
        if (address(this) == _cachedThis && block.chainid == _cachedChainId) {
            return _cachedDomainSeparator;
        } else {
            return _buildDomainSeparator();
        }
    }

    function _buildDomainSeparator() private view returns (bytes32) {
        return keccak256(abi.encode(_TYPE_HASH, _hashedName, _hashedVersion, block.chainid, address(this)));
    }

    /**
     * @dev Given an already https://eips.ethereum.org/EIPS/eip-712#definition-of-hashstruct[hashed struct], this
     * function returns the hash of the fully encoded EIP712 message for this domain.
     *
     * This hash can be used together with {ECDSA-recover} to obtain the signer of a message. For example:
     *
     * ```solidity
     * bytes32 digest = _hashTypedDataV4(keccak256(abi.encode(
     *     keccak256("Mail(address to,string contents)"),
     *     mailTo,
     *     keccak256(bytes(mailContents))
     * )));
     * address signer = ECDSA.recover(digest, signature);
     * ```
     */
    function _hashTypedDataV4(bytes32 structHash) internal view virtual returns (bytes32) {
        return ECDSA.toTypedDataHash(_domainSeparatorV4(), structHash);
    }

    /**
     * @dev See {EIP-5267}.
     *
     * _Available since v4.9._
     */
    function eip712Domain()
        public
        view
        virtual
        override
        returns (
            bytes1 fields,
            string memory name,
            string memory version,
            uint256 chainId,
            address verifyingContract,
            bytes32 salt,
            uint256[] memory extensions
        )
    {
        return (
            hex"0f", // 01111
            _name.toStringWithFallback(_nameFallback),
            _version.toStringWithFallback(_versionFallback),
            block.chainid,
            address(this),
            bytes32(0),
            new uint256[](0)
        );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (utils/math/Math.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Down, // Toward negative infinity
        Up, // Toward infinity
        Zero // Toward zero
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds up instead
     * of rounding down.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or denominator == 0
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv)
     * with further edits by Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod0 := mul(x, y)
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            require(denominator > prod1, "Math: mulDiv overflow");

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator. Always >= 1.
            // See https://cs.stackexchange.com/q/138556/92363.

            // Does not overflow because the denominator cannot be zero at this stage in the function.
            uint256 twos = denominator & (~denominator + 1);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also works
            // in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (rounding == Rounding.Up && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded down.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (rounding == Rounding.Up && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (rounding == Rounding.Up && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10, rounded down, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (rounding == Rounding.Up && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256, rounded down, of a positive value.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (rounding == Rounding.Up && 1 << (result << 3) < value ? 1 : 0);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.8.0) (utils/math/SignedMath.sol)

pragma solidity ^0.8.0;

/**
 * @dev Standard signed math utilities missing in the Solidity language.
 */
library SignedMath {
    /**
     * @dev Returns the largest of two signed numbers.
     */
    function max(int256 a, int256 b) internal pure returns (int256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two signed numbers.
     */
    function min(int256 a, int256 b) internal pure returns (int256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two signed numbers without overflow.
     * The result is rounded towards zero.
     */
    function average(int256 a, int256 b) internal pure returns (int256) {
        // Formula from the book "Hacker's Delight"
        int256 x = (a & b) + ((a ^ b) >> 1);
        return x + (int256(uint256(x) >> 255) & (a ^ b));
    }

    /**
     * @dev Returns the absolute unsigned value of a signed value.
     */
    function abs(int256 n) internal pure returns (uint256) {
        unchecked {
            // must be unchecked in order to support `n = type(int256).min`
            return uint256(n >= 0 ? n : -n);
        }
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import {IEntryPoint} from "@account-abstraction/contracts/interfaces/IEntryPoint.sol";
import {IPaymaster} from "@account-abstraction/contracts/interfaces/IPaymaster.sol";
import {UserOperation} from "@account-abstraction/contracts/interfaces/UserOperation.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

import {
    BridgeParams,
    LiquidityRouterInterface,
    RouterState,
    SwapParams,
    TransferOut
} from "./interfaces/LiquidityRouterInterface.sol";
import {LiquidityRouterEventsAndErrors} from "./interfaces/LiquidityRouterEventsAndErrors.sol";
import {InspectablePaymasterInterface} from "./interfaces/InspectablePaymasterInterface.sol";
import {OrderPaymaster} from "./paymaster/OrderPaymaster.sol";
import {GuardianOwnable} from "./utils/GuardianOwnable.sol";
import {WETH9Interface} from "./interfaces/WETH9Interface.sol";
import {EncodeLib} from "./utils/EncodeLib.sol";

contract LiquidityRouter is GuardianOwnable, LiquidityRouterInterface, LiquidityRouterEventsAndErrors {
    using SafeERC20 for IERC20;
    using EncodeLib for RouterState;

    uint256 public timelockDuration = 1 days;

    IEntryPoint public immutable ENTRY_POINT;
    WETH9Interface public immutable WRAPPED_NATIVE_TOKEN;
    address public immutable NATIVE_TOKEN = address(0xEeeeeEeeeEeEeeEeEeEeeEEEeeeeEeeeeeeeEEeE);
    address public immutable USDT_TOKEN = address(0xdAC17F958D2ee523a2206206994597C13D831ec7);

    uint256 constant BPS = 10000; // 1% = 100 basis points
    uint256 public _REFUND_CUT_BPS_ = 5; // 0.05%

    bool public _ALLOW_ALL_;
    mapping(address target => bool isAllowed) public override _ALLOWED_SWAP_TARGETS_;
    mapping(address target => bool isAllowed) public override _ALLOWED_BRIDGE_TARGETS_;
    mapping(address operator => bool isAllowed) public override _ALLOWED_OPERATORS_;
    mapping(uint256 chainId => bool isAllowed) public override _ALLOWED_CHAIN_IDS_;
    mapping(address asset => uint256 excessAmount) public override _POOL_EXCESS_;
    mapping(bytes32 => uint256) public override _TIMELOCK_EXPIRATION_;
    mapping(address allowedContracts => bool isAllowed) public override _ALLOWED_CONTRACTS_;

    /// @dev Active order accounts.
    mapping(address depositAddress => bytes32 orderHash) internal _ORDERS_;

    modifier allowedSwapTarget(address target) {
        if (!(_ALLOW_ALL_ || _ALLOWED_SWAP_TARGETS_[target])) {
            revert SwapTargetNotAllowed(target);
        }
        _;
    }

    modifier allowedBridgeTarget(address target) {
        if (!(_ALLOW_ALL_ || _ALLOWED_BRIDGE_TARGETS_[target])) {
            revert BridgeTargetNotAllowed(target);
        }
        _;
    }

    modifier refundIfExpired(address depositAddress, RouterState memory order) {
        if (block.timestamp >= order.params.expiration) {
            if (order.params.refundAddress == bytes32(0)) {
                revert OrderExpired();
            }
            delete _ORDERS_[depositAddress];
            _refundFunds(order);
            emit RefundDispatched(depositAddress, order.heldAsset, order.heldAmount);
            return;
        }
        _;
    }

    modifier Timelock() {
        bytes32 hash = getCallHash(msg.sender, msg.data);
        uint256 expiration = _TIMELOCK_EXPIRATION_[hash];
        if (expiration == 0) {
            _TIMELOCK_EXPIRATION_[hash] = block.timestamp + timelockDuration;
        } else if (block.timestamp < expiration) {
            revert TimelockNotExpired(hash, expiration);
        } else {
            delete _TIMELOCK_EXPIRATION_[hash];
            _;
        }
    }

    modifier onlyOperator() {
        if (!_ALLOWED_OPERATORS_[msg.sender]) {
            revert OnlyOperatorsAllowed(msg.sender);
        }
        _;
    }

    modifier withVerifiedOrder(RouterState memory order, address depositAddress) {
        if (_ORDERS_[depositAddress] != order.hash()) {
            revert OrderNotVerified(depositAddress, _ORDERS_[depositAddress], order.hash());
        }
        _;
    }

    receive() external payable {}

    constructor(address guardian, IEntryPoint entryPoint, address wrappedNativeToken) {
        _transferOwnership(guardian);
        ENTRY_POINT = entryPoint;
        WRAPPED_NATIVE_TOKEN = WETH9Interface(wrappedNativeToken);
    }

    function setAllowAll(bool isAllowed) external onlyOwner {
        _ALLOW_ALL_ = isAllowed;
    }

    function setTimelockDuration(uint256 duration) external onlyOwner {
        timelockDuration = duration;
    }

    function setRefundCut(uint256 cut) external onlyOwner {
        require (cut <= BPS, RefundCutTooHigh());
        _REFUND_CUT_BPS_ = cut;
    }

    function addAllowedSwapTargets(address[] calldata targets) external onlyOwner Timelock {
        _updateAllowedSwapTargets(targets, true);
    }

    function addAllowedBridgeTargets(address[] calldata targets) external onlyOwner Timelock {
        _updateAllowedBridgeTargets(targets, true);
    }

    function addAllowedChainIds(uint256[] calldata chainIds) external onlyOwner Timelock {
        _updateAllowedChainIds(chainIds, true);
    }

    function addOperators(address[] calldata operators) external onlyOwner {
        _updateAllowedOperators(operators, true);
    }

    function addAllowedContracts(address[] calldata contracts) external onlyOwner {
        _updateAllowedContracts(contracts, true);
    }

    function removeAllowedSwapTargets(address[] calldata targets) external onlyOwner {
        _updateAllowedSwapTargets(targets, false);
    }

    function removeAllowedBridgeTargets(address[] calldata targets) external onlyOwner {
        _updateAllowedBridgeTargets(targets, false);
    }

    function removeAllowedChainIds(uint256[] calldata chainIds) external onlyOwner {
        _updateAllowedChainIds(chainIds, false);
    }

    function removeOperators(address[] calldata operators) external onlyOwner {
        _updateAllowedOperators(operators, false);
    }

    function removeAllowedContracts(address[] calldata contracts) external onlyOwner {
        _updateAllowedContracts(contracts, false);
    }

    function withdrawFunds(address asset, uint256 amount) external onlyOwner {
        if (asset == NATIVE_TOKEN) {
            uint256 balance = address(this).balance - _POOL_EXCESS_[asset];
            require(balance >= amount, InsufficientTokensToWithdraw(asset, amount, balance));
            (bool success,) = payable(owner()).call{value: amount}("");
            require(success, NativeTokenTransferFailed());
        } else {
            uint256 balance = IERC20(asset).balanceOf(address(this)) - _POOL_EXCESS_[asset];
            require(balance >= amount, InsufficientTokensToWithdraw(asset, amount, balance));
            IERC20(asset).safeTransfer(owner(), amount);
        }
    }

    function setOperator(address operator, bool isAllowed) external onlyOwner {
        _ALLOWED_OPERATORS_[operator] = isAllowed;
    }

    function addExcessToPool(address asset, uint256 amount) external payable {
        if (asset == NATIVE_TOKEN) {
            require(msg.value == amount, IncorrectAmountOfNativeToken(amount, msg.value));
        } else {
            IERC20(asset).safeTransferFrom(msg.sender, address(this), amount);
        }

        _POOL_EXCESS_[asset] += amount;

        emit ExcessAdded(asset, amount);
    }

    function removeExcessFromPool(address asset, uint256 amount) external onlyOwner {
        // Will revert if amount is greater than excess balance.
        _POOL_EXCESS_[asset] -= amount;

        if (asset == NATIVE_TOKEN) {
            (bool success,) = payable(msg.sender).call{value: amount}("");
            require(success, NativeTokenTransferFailed());
        } else {
            IERC20(asset).safeTransfer(msg.sender, amount);
        }

        emit ExcessRemoved(asset, amount);
    }

    /**
     * @notice Deposit funds to create a order account.
     */
    function deposit(RouterState calldata order) external {
        if (order.params.expiration <= block.timestamp) {
            order.heldAsset.safeTransferFrom(msg.sender, address(this), order.heldAmount);        
            if (order.params.refundAddress == bytes32(0)) {
                emit ExpiredOrder(msg.sender);
                return;
            } else {
                _refundFunds(order);
                return;
            }
        }

        address depositAddress = msg.sender;

        order.heldAsset.safeTransferFrom(depositAddress, address(this), order.heldAmount);

        _ORDERS_[depositAddress] = order.hash();

        emit Deposited(depositAddress, order.heldAsset, order.heldAmount);
    }

    function swap(address depositAddress, SwapParams calldata swapParams, RouterState memory order)
        external
        withVerifiedOrder(order, depositAddress)
        refundIfExpired(depositAddress, order)
        allowedSwapTarget(swapParams.target)
        onlyOperator
    {
        // Write order state to storage.
        (order.heldAsset, order.heldAmount) = _swap(swapParams, order);
        _ORDERS_[depositAddress] = order.hash();

        emit Swapped(depositAddress, swapParams.target, order.heldAsset, order.heldAmount);
    }

    function swapAndForward(address depositAddress, SwapParams calldata swapParams, RouterState memory order)
        external
        withVerifiedOrder(order, depositAddress)
        refundIfExpired(depositAddress, order)
        allowedSwapTarget(swapParams.target)
        onlyOperator
    {

        (order.heldAsset, order.heldAmount) = _swap(swapParams, order);
        
        _forward(depositAddress, order);
    }

    function bridge(address depositAddress, BridgeParams calldata bridgeParams, RouterState calldata order)
        external
        withVerifiedOrder(order, depositAddress)
        refundIfExpired(depositAddress, order)
        allowedBridgeTarget(bridgeParams.target)
        onlyOperator
    {
        // Read order state from storage.
        // Note: Read the whole thing into memory since we use it later.
        IERC20 heldAsset = order.heldAsset;
        uint256 heldAmount = order.heldAmount;
        uint256 targetChainId = order.params.targetChainId;

        // Sanity check that we are not already on the target chain.
        if (targetChainId == block.chainid) {
            revert BridgeAlreadyOnTargetChain();
        }

        // Require that the chain ID is allowed/supported.
        if (!(_ALLOW_ALL_ || _ALLOWED_CHAIN_IDS_[targetChainId])) {
            revert BridgeChainIdNotAllowed(targetChainId);
        }

        // Set the allowance on the bridge spender.
        //
        // Note: Using approve() instead of safeIncreaseAllowance() or forceApprove() under the
        // assumption that all allowances from this contract will be zero in between transactions.
        if (block.chainid == 1 && address(heldAsset) == USDT_TOKEN) {
            heldAsset.safeApprove(bridgeParams.spender, heldAmount);
        } else {
            heldAsset.approve(bridgeParams.spender, heldAmount);
        }

        // Deduct the funds from the excess pool.
        _recordUseExcessPoolFunds(NATIVE_TOKEN, bridgeParams.valueFromExcessPool);

        // ute the bridge call.
        _bridgeToRecipient(bridgeParams.target, bridgeParams.callData, bridgeParams.valueFromExcessPool);

        // Require that the full allowance was spent.
        //
        // IMPORTANT NOTE: We assume the bridge contract supports spending an exact amount.
        uint256 remainingAllowance = heldAsset.allowance(address(this), bridgeParams.spender);
        if (remainingAllowance != 0) {
            revert BridgeDidNotSpendExactAmount(remainingAllowance);
        }

        // Delete the order from storage.
        delete _ORDERS_[depositAddress];

        emit Bridged(
            depositAddress,
            bridgeParams.target,
            bridgeParams.bridgeReceivedAsset,
            bridgeParams.minBridgeReceivedAmount,
            bridgeParams.valueFromExcessPool
        );
    }

    /**
     * @dev Execute a contract call with the given calldata to the recipient.
     */
    function executeCalldata(address depositAddress, RouterState memory order)
        external
        withVerifiedOrder(order, depositAddress)
        refundIfExpired(depositAddress, order)
        onlyOperator
    {
        if (block.chainid != order.params.targetChainId) {
            revert ExecuteCalldataChainNotReady(block.chainid);
        }

        if (order.params.recipient == bytes32(0)) {
            revert ExecuteCalldataRecipientNotSet();
        }

        if (address(uint160(uint256(order.params.recipient))).code.length == 0) {
            revert ExecuteCalldataRecipientNotContract();
        }

        _executeCalldata(depositAddress, order);
    }

    function swapAndExecuteCalldata(
        address depositAddress,
        SwapParams calldata swapParams,
        RouterState memory order
    ) external withVerifiedOrder(order, depositAddress) refundIfExpired(depositAddress, order) onlyOperator {
        (order.heldAsset, order.heldAmount) = _swap(swapParams, order);
        _executeCalldata(depositAddress, order);
    }

    // apply to non userOp execution cases
    function forwardFund(address depositAddress, RouterState memory order)
        external
        withVerifiedOrder(order, depositAddress)
        refundIfExpired(depositAddress, order)
        onlyOperator
    {
        if (block.chainid != order.params.targetChainId) {
            revert ForwardFundChainNotReady(block.chainid);
        }

        if (order.params.recipient == bytes32(0)) {
            revert ForwardFundRecipientNotSet();
        }

        _forward(depositAddress, order);
    }

    function getOrderHash(address depositAddress) external view returns (bytes32) {
        return _getOrderHash(depositAddress);
    }

    function _refundFunds(RouterState memory order) internal {
        address refundAddr = address(uint160(uint256(order.params.refundAddress)));
        uint256 refundAmount = order.heldAmount * (BPS - _REFUND_CUT_BPS_) / BPS; // Deduct 0.05%
        _POOL_EXCESS_[address(order.heldAsset)] += order.heldAmount - refundAmount;
        if (order.heldAsset == IERC20(NATIVE_TOKEN)) {
            (bool success,) = payable(refundAddr).call{value: refundAmount}("");
            require(success, RefundTransferFailed(address(order.heldAsset), refundAmount));
        } else {
            order.heldAsset.safeTransfer(refundAddr, refundAmount);
        }
    }

    function _forward(address depositAddress, RouterState memory order) internal {
        IERC20 heldAsset = order.heldAsset;
        uint256 heldAmount = order.heldAmount;

        uint256 forwardAmount = order.params.targetAmount;
        if (forwardAmount < heldAmount) {
            _POOL_EXCESS_[address(heldAsset)] += heldAmount - forwardAmount;
        } else if (forwardAmount <= heldAmount * (1 + order.params.slippage * 100 / BPS)) {
            _recordUseExcessPoolFunds(address(heldAsset), forwardAmount - heldAmount);
        } else {
            revert ExecuteInvalidAmount(heldAmount, forwardAmount);
        }

        address targetAssetAddr = address(uint160(uint256(order.params.targetAsset)));
        address recipientAddr = address(uint160(uint256(order.params.recipient)));
        if (targetAssetAddr == NATIVE_TOKEN) {
            if (heldAsset != WRAPPED_NATIVE_TOKEN) {
                revert ForwardFundAssetNotReady(heldAsset);
            } else {
                WRAPPED_NATIVE_TOKEN.withdraw(forwardAmount);
                (bool success, bytes memory returnData) = payable(recipientAddr).call{value: forwardAmount}("");
                if (!success) {
                    revert ForwardFundReverted(returnData);
                }
            }
        } else if (heldAsset != IERC20(targetAssetAddr)) {
            revert ForwardFundAssetNotReady(heldAsset);
        } else if (heldAsset == IERC20(targetAssetAddr)) {
            heldAsset.safeTransfer(recipientAddr, forwardAmount);
        } else {
            revert ForwardFundAssetNotReady(heldAsset);
        }

        // Delete the order from storage.
        delete _ORDERS_[depositAddress];

        emit FundForwarded(depositAddress, forwardAmount, order.params.recipient);
    }

    function _swap(SwapParams calldata swapParams, RouterState memory order) internal returns (IERC20, uint256) {
        // Read order state from storage.
        IERC20 heldAsset = order.heldAsset;
        uint256 heldAmount = order.heldAmount;

        // Get starting balance of the asset to receive from the swap.
        uint256 balanceBefore;
        if (address(swapParams.receivedAsset) == NATIVE_TOKEN) {
            balanceBefore = address(this).balance;
        } else {
            balanceBefore = IERC20(swapParams.receivedAsset).balanceOf(address(this));
        }

        {
            // Deduct the funds from the excess pool.
            uint256 valueFromExcessPool = swapParams.valueFromExcessPool;
            _recordUseExcessPoolFunds(NATIVE_TOKEN, valueFromExcessPool);

            bool success;
            bytes memory returnData;
            // Execute the swap.
            if (swapParams.isETHSwap) {
                if (heldAsset != WRAPPED_NATIVE_TOKEN) {
                    revert HeldAssetNotWETH(address(heldAsset));
                }
                WETH9Interface(WRAPPED_NATIVE_TOKEN).withdraw(heldAmount);
                (success, returnData) =
                    swapParams.target.call{value: heldAmount + valueFromExcessPool}(swapParams.callData);
            } else {
                // Set the allowance on the swap spender.
                //
                // Note: Using approve() instead of safeIncreaseAllowance() or forceApprove() under the
                // assumption that all allowances from this contract will be zero in between transactions.
                if (block.chainid == 1 && address(heldAsset) == USDT_TOKEN) {
                    heldAsset.safeApprove(swapParams.spender, heldAmount);
                } else {
                    heldAsset.approve(swapParams.spender, heldAmount);
                }

                (success, returnData) = swapParams.target.call{value: valueFromExcessPool}(swapParams.callData);
            }
            if (!success) {
                revert SwapReverted(returnData);
            }
        }
        uint256 receivedAmount;
        IERC20 receivedAsset;
        if (address(swapParams.receivedAsset) == NATIVE_TOKEN) {
            // Note: The tx will revert if the received asset balance decreased.
            receivedAmount = address(this).balance - balanceBefore;
            WRAPPED_NATIVE_TOKEN.deposit{value: receivedAmount}();
            receivedAsset = WRAPPED_NATIVE_TOKEN;
        } else {
            uint256 balanceAfter = IERC20(swapParams.receivedAsset).balanceOf(address(this));
            // Note: The tx will revert if the received asset balance decreased.
            receivedAmount = balanceAfter - balanceBefore;
            receivedAsset = IERC20(swapParams.receivedAsset);
        }

        if (receivedAmount < swapParams.minReceivedAmount) {
            revert SwapDidNotReceiveMinAmount(receivedAmount);
        }

        // Revokes the remaining allowance.
        //
        // IMPORTANT NOTE: We don't assume the swap contract supports spending an exact amount.
        //
        // Note: This check will fail with some ERC-20 implementations in the case
        // where heldAmount = type(uint256).max. We assume that this is impossible in practice.
        if (!swapParams.isETHSwap) {
            uint256 remainingAllowance = heldAsset.allowance(address(this), swapParams.spender);
            if (remainingAllowance != 0) {
                IERC20(heldAsset).safeApprove(swapParams.spender, 0);
            }   
        }

        return (receivedAsset, receivedAmount);
    }

    function _executeCalldata(address depositAddress, RouterState memory order) internal {
        address recipientAddr = address(uint160(uint256(order.params.recipient)));

        if (!_ALLOWED_CONTRACTS_[recipientAddr]) {
            revert OnlyContractsAllowed(recipientAddr);
        }

        IERC20 heldAsset = order.heldAsset;
        uint256 heldAmount = order.heldAmount;

        uint256 forwardAmount = order.params.targetAmount;
        order.params.targetAmount = 0;
        if (forwardAmount < heldAmount) {
            _POOL_EXCESS_[address(heldAsset)] += heldAmount - forwardAmount;
        } else if (forwardAmount <= heldAmount * (1 + order.params.slippage * 100 / BPS)) {
            _recordUseExcessPoolFunds(address(heldAsset), forwardAmount - heldAmount);
        } else {
            revert ExecuteInvalidAmount(heldAmount, forwardAmount);
        }

        uint256[] memory _balancesBefore = new uint256[](order.params.transferOut.length);

        for (uint256 i = 0; i < order.params.transferOut.length;) {
            if (order.params.transferOut[i].token == NATIVE_TOKEN) {
                _balancesBefore[i] = address(this).balance;
            } else {
                _balancesBefore[i] = IERC20(order.params.transferOut[i].token).balanceOf(address(this));
            }
            unchecked {
                ++i;
            }
        }

        address targetAssetAddr = address(uint160(uint256(order.params.targetAsset)));

        if (targetAssetAddr == NATIVE_TOKEN) {
            if (heldAsset != WRAPPED_NATIVE_TOKEN) {
                revert ExecuteAssetNotReady(heldAsset);
            } else {
                WRAPPED_NATIVE_TOKEN.withdraw(forwardAmount);
                {
                    (bool success, bytes memory returnData) =
                        payable(recipientAddr).call{value: forwardAmount}(order.params.targetCalldata);
                    if (!success) {
                        revert ExecuteReverted(returnData);
                    }
                }
                for (uint256 i; i < order.params.transferOut.length;) {
                    if (order.params.transferOut[i].token == NATIVE_TOKEN) {
                        uint256 balanceAfter = address(this).balance;
                        uint256 receivedAmount = balanceAfter - _balancesBefore[i];
                        if (receivedAmount > 0) {
                            payable(order.params.transferOut[i].recipient).transfer(receivedAmount);
                        }
                    } else {
                        uint256 balanceAfter = IERC20(order.params.transferOut[i].token).balanceOf(address(this));
                        uint256 receivedAmount = balanceAfter - _balancesBefore[i];
                        if (receivedAmount > 0) {
                            IERC20(order.params.transferOut[i].token).transfer(
                                order.params.transferOut[i].recipient, receivedAmount
                            );
                        }
                    }
                    unchecked {
                        ++i;
                    }
                }
            }
        } else if (heldAsset != IERC20(targetAssetAddr)) {
            revert ExecuteAssetNotReady(heldAsset);
        } else if (heldAsset == IERC20(targetAssetAddr)) {
            if (block.chainid == 1 && address(heldAsset) == USDT_TOKEN) {
                heldAsset.safeApprove(recipientAddr, forwardAmount);
            } else {
                heldAsset.approve(recipientAddr, forwardAmount);
            }

            // Execute the contract call
            {
                (bool success, bytes memory returnData) = recipientAddr.call(order.params.targetCalldata);
                if (!success) {
                    revert ExecuteReverted(returnData);
                }
            }

            // Require that the full allowance was spent.
            //
            // IMPORTANT NOTE: We assume the bridge contract supports spending an exact amount.
            uint256 remainingAllowance = heldAsset.allowance(address(this), recipientAddr);
            if (remainingAllowance != 0) {
                revert ExecuteDidNotSpendExactAmount(remainingAllowance);
            }

            // Transfer out the received tokens
            for (uint256 i; i < order.params.transferOut.length;) {
                if (order.params.transferOut[i].token == NATIVE_TOKEN) {
                    uint256 balanceAfter = address(this).balance;
                    uint256 receivedAmount = balanceAfter - _balancesBefore[i];
                    if (heldAsset == WRAPPED_NATIVE_TOKEN && order.params.transferOut[i].token == NATIVE_TOKEN) {
                        receivedAmount += forwardAmount;
                    }
                    if (receivedAmount > 0) {
                        payable(order.params.transferOut[i].recipient).transfer(receivedAmount);
                    }
                } else {
                    uint256 balanceAfter = IERC20(order.params.transferOut[i].token).balanceOf(address(this));
                    uint256 receivedAmount = balanceAfter - _balancesBefore[i];
                    if (heldAsset == IERC20(order.params.transferOut[i].token)) {
                        receivedAmount += forwardAmount;
                    }
                    if (receivedAmount > 0) {
                        IERC20(order.params.transferOut[i].token).transfer(
                            order.params.transferOut[i].recipient, receivedAmount
                        );
                    }
                }
                unchecked {
                    ++i;
                }
            }
        } else {
            revert ExecuteCalldataAssetNotReady(heldAsset);
        }

        // Delete the order from storage.
        delete _ORDERS_[depositAddress];

        emit CalldataExecuted(depositAddress, forwardAmount, order.params.recipient);
    }

    function _getOrderHash(address depositAddress) internal view returns (bytes32) {
        bytes32 orderHash = _ORDERS_[depositAddress];
        if (orderHash == bytes32(0)) {
            revert OrderDoesNotExist();
        }
        return orderHash;
    }

    function _updateAllowedSwapTargets(address[] calldata targets, bool isAllowed) internal {
        uint256 n = targets.length;
        for (uint256 i; i < n; ++i) {
            address target = targets[i];
            _ALLOWED_SWAP_TARGETS_[target] = isAllowed;
            emit UpdatedAllowedSwapTarget(target, isAllowed);
        }
    }

    function _updateAllowedBridgeTargets(address[] calldata targets, bool isAllowed) internal {
        uint256 n = targets.length;
        for (uint256 i; i < n; ++i) {
            address target = targets[i];
            _ALLOWED_BRIDGE_TARGETS_[target] = isAllowed;
            emit UpdatedAllowedBridgeTarget(target, isAllowed);
        }
    }

    function _updateAllowedContracts(address[] calldata contracts, bool isAllowed) internal {
        uint256 n = contracts.length;
        for (uint256 i; i < n; ++i) {
            address contractAdd = contracts[i];
            _ALLOWED_CONTRACTS_[contractAdd] = isAllowed;
            emit UpdatedAllowedContracts(contractAdd, isAllowed);
        }
    }

    function _updateAllowedChainIds(uint256[] calldata chainids, bool isAllowed) internal {
        uint256 n = chainids.length;
        for (uint256 i; i < n; ++i) {
            uint256 chainId = chainids[i];
            _ALLOWED_CHAIN_IDS_[chainId] = isAllowed;
            emit UpdatedAllowedChainIds(chainId, isAllowed);
        }
    }

    function _updateAllowedOperators(address[] calldata operators, bool isAllowed) internal {
        uint256 n = operators.length;
        for (uint256 i; i < n; ++i) {
            address operator = operators[i];
            _ALLOWED_OPERATORS_[operator] = isAllowed;
            emit UpdatedAllowedOperator(operator, isAllowed);
        }
    }

    function _bridgeToRecipient(address target, bytes calldata callData, uint256 value) internal {
        // as needed.
        (bool success, bytes memory returnData) = target.call{value: value}(callData);
        if (!success) {
            revert BridgeReverted(returnData);
        }
    }

    function _recordUseExcessPoolFunds(address asset, uint256 value) internal {
        if (value > 0) {
            uint256 excessPoolBalance = _POOL_EXCESS_[asset];
            require(excessPoolBalance >= value, InsufficientTokensInExcessPoolForCall(asset, value, excessPoolBalance));
            _POOL_EXCESS_[asset] -= value;
            emit ExcessPoolFundsUsedForCall(asset, value);
        }
    }

    function getCallHash(address sender, bytes calldata callData) internal pure returns (bytes32) {
        return keccak256(abi.encode(sender, callData));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {IPaymaster} from "@account-abstraction/contracts/interfaces/IPaymaster.sol";

interface InspectablePaymasterInterface {
    function getLastOpMode() external view returns (IPaymaster.PostOpMode);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {IPaymaster} from "@account-abstraction/contracts/interfaces/IPaymaster.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface LiquidityRouterEventsAndErrors {
    error OrderDoesNotExist();
    error OrderExpired();
    error SwapTargetNotAllowed(address target);
    error SwapDidNotSpendExactAmount(uint256 remainingAllowance);
    error SwapDidNotReceiveMinAmount(uint256 remainingBalance);
    error SwapReverted(bytes errorData);
    error HeldAssetNotWETH(address heldAsset);
    error BridgeChainIdNotAllowed(uint256 chainId);
    error BridgeTargetNotAllowed(address target);
    error BridgeAlreadyOnTargetChain();
    error BridgeDidNotSpendExactAmount(uint256 remainingAllowance);
    error BridgeReverted(bytes errorData);
    error ExecuteReverted(bytes errorData);
    error ExecuteInvalidOpsLength();
    error ExecuteChainNotReady(uint256 chainId);
    error ExecuteAssetNotReady(IERC20 heldAsset);
    error ExecuteInsufficientExcessBalance(uint256 oldExcessAmount, uint256 executionAmount, uint256 heldAmount);
    error ExecuteInvalidUserOp(bytes32 calculatedUserOpHash);
    error ExecuteUserOpReverted(IPaymaster.PostOpMode userOpMode);
    error ExecuteInvalidAmount(uint256 heldAmount, uint256 executeAmount);
    error ExecuteDidNotSpendExactAmount(uint256 remainingAllowance);
    error TimelockNotExpired(bytes32 callHash, uint256 expiration);
    error OnlyOperatorsAllowed(address caller);
    error OnlyPaymasterAllowed(address caller, address paymaster);
    error OnlyContractsAllowed(address contractAdd);
    error ForwardFundChainNotReady(uint256 chainId);
    error ForwardFundUserOpHashIsSet(bytes32);
    error ForwardFundAssetNotReady(IERC20 asset);
    error ForwardFundRecipientNotSet();
    error ForwardFundReverted(bytes errorData);
    error OrderNotVerified(address depositAddress, bytes32 orderHashExpected, bytes32 orderHashActual);
    error IncorrectAmountOfNativeToken(uint256 expected, uint256 actual);
    error NativeTokenTransferFailed();
    error InsufficientTokensInExcessPoolForCall(address asset, uint256 required, uint256 available);
    error InsufficientTokensToWithdraw(address asset, uint256 required, uint256 available);

    error ExecuteCalldataChainNotReady(uint256 chainId);
    error ExecuteCalldataUserOpHashIsSet(bytes32);
    error ExecuteCalldataAssetNotReady(IERC20 asset);
    error ExecuteCalldataRecipientNotSet();
    error ExecuteCalldataRecipientNotContract();
    error RefundCutTooHigh();
    error RefundTransferFailed(address refundAsset, uint256 refundAmount);

    event ExpiredOrder(address indexed depositAddress);
    event UpdatedAllowedSwapTarget(address indexed target, bool isAllowed);
    event UpdatedAllowedBridgeTarget(address indexed target, bool isAllowed);
    event UpdatedAllowedChainIds(uint256 indexed chainId, bool isAllowed);
    event UpdatedAllowedOperator(address indexed operator, bool isAllowed);
    event UpdatedAllowedContracts(address indexed contractAdd, bool isAllowed);
    event ExcessPoolFundsUsedForCall(address indexed asset, uint256 amount);

    event ExcessAdded(address indexed asset, uint256 amount);
    event ExcessRemoved(address indexed asset, uint256 amount);

    event Deposited(address indexed depositAddress, IERC20 receivedAsset, uint256 receivedAmount);

    event Bridged(
        address indexed depositAddress,
        address indexed bridgeTarget,
        IERC20 receivedAsset,
        uint256 minReceivedAmount,
        uint256 nativeValueFromExcessPool
    );

    event Swapped(
        address indexed depositAddress, address indexed swapTarget, IERC20 receivedAsset, uint256 receivedAmount
    );

    event Executed(address indexed depositAddress, uint256 executionAmount);
    event FundForwarded(address indexed depositAddress, uint256 forwardAmount, bytes32 indexed recipient);

    event CalldataExecuted(address indexed depositAddress, uint256 forwardAmount, bytes32 indexed recipient);
    event RefundDispatched(address indexed depositAddress, IERC20 refundAsset, uint256 refundAmount);
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {UserOperation} from "@account-abstraction/contracts/interfaces/UserOperation.sol";
import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

struct RouterStateWithNonce {
    RouterState state;
    uint256 nonce;
}

struct RouterState {
    RouterParams params;
    IERC20 heldAsset;
    uint256 heldAmount;
}

/// @dev Immutable parameters of an order.
struct RouterParams {
    bytes32 userOpHash;
    bytes32 targetAsset;
    uint96 targetChainId;
    uint128 targetAmount;
    uint128 expiration;
    bytes targetCalldata;
    TransferOut[] transferOut;
    bytes32 recipient;
    uint32 slippage;
    bytes32 refundAddress;
}

/// @notice A token and how to distribute it
struct TransferOut {
    address token;
    address recipient;
}

struct SwapParams {
    address target;
    address spender;
    bytes callData;
    IERC20 receivedAsset;
    uint256 minReceivedAmount;
    bool isETHSwap;
    uint256 valueFromExcessPool;
}

struct BridgeParams {
    address target;
    address spender;
    bytes callData;
    IERC20 bridgeReceivedAsset;
    uint256 minBridgeReceivedAmount;
    uint256 valueFromExcessPool;
}

interface LiquidityRouterInterface {
    function timelockDuration() external view returns (uint256);

    function _ALLOWED_OPERATORS_(address operator) external view returns (bool);

    function _ALLOWED_CONTRACTS_(address allowedContract) external view returns (bool);

    function _ALLOWED_CHAIN_IDS_(uint256 chainId) external view returns (bool);

    function _ALLOWED_SWAP_TARGETS_(address target) external view returns (bool);

    function _ALLOWED_BRIDGE_TARGETS_(address target) external view returns (bool);

    function _POOL_EXCESS_(address asset) external view returns (uint256);

    function _TIMELOCK_EXPIRATION_(bytes32 callHash) external view returns (uint256);

    function NATIVE_TOKEN() external view returns (address);

    function _REFUND_CUT_BPS_() external view returns (uint256);

    function deposit(RouterState calldata routerState) external;

    function swap(address depositAddress, SwapParams calldata swapParams, RouterState memory order) external;

    function swapAndForward(address depositAddress, SwapParams calldata swapParams, RouterState memory order) external;

    function bridge(address depositAddress, BridgeParams calldata bridgeParams, RouterState memory order) external;

    function getOrderHash(address depositAddress) external view returns (bytes32);

    function forwardFund(address depositAddress, RouterState memory order) external;

    function setOperator(address operator, bool isAllowed) external;

    function setRefundCut(uint256 cut) external;

    function addAllowedContracts(address[] calldata contracts) external;

    function executeCalldata(address depositAddress, RouterState calldata order) external;

    function swapAndExecuteCalldata(
        address depositAddress,
        SwapParams calldata swapParams,
        RouterState calldata order
    ) external;

    function removeAllowedContracts(address[] calldata contracts) external;

    function addOperators(address[] calldata operators) external;

    function removeOperators(address[] calldata operators) external;

    function withdrawFunds(address asset, uint256 amount) external;

    function addAllowedChainIds(uint256[] calldata chainIds) external;

    function removeAllowedChainIds(uint256[] calldata chainIds) external;

    function addExcessToPool(address asset, uint256 amount) external payable;

    function removeExcessFromPool(address asset, uint256 amount) external;

    function addAllowedSwapTargets(address[] calldata targets) external;

    function addAllowedBridgeTargets(address[] calldata targets) external;

    function removeAllowedSwapTargets(address[] calldata targets) external;

    function removeAllowedBridgeTargets(address[] calldata targets) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface WETH9Interface is IERC20 {
    function deposit() external payable;

    function withdraw(uint256) external;
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import {BasePaymaster} from "@account-abstraction/contracts/core/BasePaymaster.sol";
import {IEntryPoint} from "@account-abstraction/contracts/interfaces/IEntryPoint.sol";
import {UserOperation} from "@account-abstraction/contracts/interfaces/UserOperation.sol";
import {ECDSA} from "@openzeppelin/contracts/utils/cryptography/ECDSA.sol";
import {EIP712} from "@openzeppelin/contracts/utils/cryptography/EIP712.sol";

import {InspectablePaymasterInterface} from "../interfaces/InspectablePaymasterInterface.sol";
import {OrderPaymasterEventsAndErrors} from "./OrderPaymasterEventsAndErrors.sol";

enum ActiveState {
    UNSPECIFIED, // 0
    INACTIVE, // 1
    ACTIVE // 2

}

/**
 * @title OrderPaymaster
 */
contract OrderPaymaster is BasePaymaster, InspectablePaymasterInterface, EIP712, OrderPaymasterEventsAndErrors {
    string public constant EIP712_NAME = "OrderPaymaster";
    string public constant VERSION = "2"; // Note: Was a uint256 in version 1.

    bytes32 private constant SPONSOR_USER_OP_TYPEHASH =
        keccak256("SponsorUserOp(" "bytes32 userOpHash," "uint64 deadline" ")");
    bytes1 private constant CONTEXT_ACTIVE = bytes1(uint8(0));
    bytes1 private constant CONTEXT_INACTIVE = bytes1(uint8(1));

    ActiveState internal _ACTIVE_STATE_;
    PostOpMode internal _LAST_OP_MODE_;

    mapping(address => bool) internal _OPERATORS_;
    mapping(address => bool) internal _SIGNERS_;
    mapping(bytes32 => bool) internal _SPONSORED_USER_OP_HASHES_;

    modifier onlyOperator() {
        if (!_OPERATORS_[msg.sender]) {
            revert OperatorNotAllowed(msg.sender);
        }
        _;
    }

    modifier activate() {
        _ACTIVE_STATE_ = ActiveState.ACTIVE;
        _;
        _ACTIVE_STATE_ = ActiveState.INACTIVE;
    }

    constructor(IEntryPoint entryPoint) BasePaymaster(entryPoint) EIP712(EIP712_NAME, VERSION) {
        _ACTIVE_STATE_ = ActiveState.INACTIVE;
    }

    function setOperators(address[] calldata operators, bool isAllowed) external onlyOwner {
        uint256 n = operators.length;
        for (uint256 i; i < n; ++i) {
            address operator = operators[i];
            _OPERATORS_[operator] = isAllowed;
            emit OperatorSet(operator, isAllowed);
        }
    }

    function setSigners(address[] calldata signers, bool isAllowed) external onlyOwner {
        uint256 n = signers.length;
        for (uint256 i; i < n; ++i) {
            address signer = signers[i];
            _SIGNERS_[signer] = isAllowed;
            emit SignerSet(signer, isAllowed);
        }
    }

    function activateAndCall(address target, bytes calldata callData)
        external
        payable
        onlyOperator
        activate
        returns (bytes memory)
    {
        (bool success, bytes memory returnData) = payable(target).call{value: msg.value}(callData);
        if (!success) {
            assembly {
                revert(add(returnData, 32), mload(returnData))
            }
        }
        return returnData;
    }

    function getLastOpMode() external view returns (PostOpMode) {
        return _LAST_OP_MODE_;
    }

    function isOperatorAllowed(address operator) external view returns (bool) {
        return _OPERATORS_[operator];
    }

    function isSignerAllowed(address signer) external view returns (bool) {
        return _SIGNERS_[signer];
    }

    function DOMAIN_SEPARATOR() external view virtual returns (bytes32) {
        return _domainSeparatorV4();
    }

    /**
     * @notice Validate a user operation that is using this paymaster.
     *
     * @param userOp ERC-4337 UserOperation.
     *
     * @return context The context containing the sponsor, spender, gasPriceUserOp, and opHash.
     * @return validationData The validation result.
     */
    function _validatePaymasterUserOp(UserOperation calldata userOp, bytes32, /* opHash */ uint256 /* maxCost */ )
        internal
        override
        returns (bytes memory context, uint256 validationData)
    {
        // Assume paymasterAndData.length >= 20 based on reasonable EntryPoint behavior.
        uint256 len = userOp.paymasterAndData.length;
        if (len > 20) {
            // Format of paymasterAndData:
            //   -  [0:20]  address paymaster
            //   - [20:40]  address signer
            //   - [40:48]  uint64  deadline
            //   - [48:113] bytes   signature
            if (len != 113) {
                revert InvalidPaymasterAndDataLength(len);
            }

            address expectedSigner = address(bytes20(userOp.paymasterAndData[20:40]));
            uint64 deadline = uint64(bytes8(userOp.paymasterAndData[40:48]));
            bytes memory signature = userOp.paymasterAndData[48:];

            _validateSponsoredUserOp(signature, expectedSigner, deadline, userOp);

            context = abi.encodePacked(CONTEXT_ACTIVE);
        } else {
            context = abi.encodePacked(CONTEXT_INACTIVE);
        }
        validationData = 0;
    }

    /**
     * @notice Post-operation handler.
     * @dev Records the result of the user operation (e.g. success or revert).
     *
     *      Also, reverts if the paymaster was not active, ensuring that only allowed
     *      operators can make use of this paymaster.
     *
     * @param mode The mode enum representing the operation result.
     */
    function _postOp(PostOpMode mode, bytes calldata context, uint256 /* actualGasCost */ ) internal override {
        if (context[0] == CONTEXT_INACTIVE || _ACTIVE_STATE_ != ActiveState.ACTIVE) {
            revert Inactive();
        }
        _LAST_OP_MODE_ = mode;
    }

    function _validateSponsoredUserOp(
        bytes memory signature,
        address expectedSigner,
        uint64 deadline,
        UserOperation calldata userOp
    ) internal {
        if (block.timestamp > deadline) {
            revert SignatureExpired(deadline);
        }

        if (!_SIGNERS_[expectedSigner]) {
            revert SignerNotAllowed(expectedSigner);
        }

        // Zero-out paymasterAndData before hashing the userOp.
        UserOperation memory userOpClone = userOp;
        userOpClone.paymasterAndData = bytes("");
        userOpClone.signature = bytes("");
        bytes32 userOpHash = entryPoint.getUserOpHash(userOpClone);

        bytes32 structHash = keccak256(abi.encode(SPONSOR_USER_OP_TYPEHASH, userOpHash, deadline));

        bytes32 digest = _hashTypedDataV4(structHash);

        address recoveredSigner = ECDSA.recover(digest, signature);
        if (recoveredSigner != expectedSigner) {
            revert SignatureInvalid(recoveredSigner, expectedSigner);
        }

        if (_SPONSORED_USER_OP_HASHES_[userOpHash]) {
            revert SponsoredUserOpRepeated(userOpHash);
        }

        _SPONSORED_USER_OP_HASHES_[userOpHash] = true;

        emit UserOpSponsored(userOpHash);
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

interface OrderPaymasterEventsAndErrors {
    error Inactive();
    error InvalidPaymasterAndDataLength(uint256 length);
    error OperatorNotAllowed(address operator);
    error SignerNotAllowed(address signer);
    error SignatureExpired(uint256 deadline);
    error SignatureInvalid(address recoveredSigner, address expectedSigner);
    error SponsoredUserOpRepeated(bytes32 userOpHash);

    event OperatorSet(address indexed operator, bool isAllowed);
    event SignerSet(address indexed signer, bool isAllowed);

    /// @dev Intentionally not indexed to save gas since most clients won't need this.
    event UserOpSponsored(bytes32 userOpHash);
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import {
    RouterStateWithNonce, RouterState, RouterParams, TransferOut
} from "../interfaces/LiquidityRouterInterface.sol";

library EncodeLib {
    function encode(RouterStateWithNonce memory rswn) internal pure returns (bytes memory) {
        return abi.encode(rswn);
    }

    function hash(RouterStateWithNonce memory rswn) internal pure returns (bytes32) {
        return keccak256(encode(rswn));
    }

    function encode(RouterState memory rs) internal pure returns (bytes memory) {
        return abi.encode(rs);
    }

    function hash(RouterState memory rs) internal pure returns (bytes32) {
        return keccak256(encode(rs));
    }

    function encode(RouterParams memory rp) internal pure returns (bytes memory) {
        return abi.encode(rp);
    }

    function hash(RouterParams memory rp) internal pure returns (bytes32) {
        return keccak256(encode(rp));
    }

    function encode(TransferOut[] memory tos) internal pure returns (bytes memory) {
        return abi.encode(tos);
    }

    function hash(TransferOut[] memory tos) internal pure returns (bytes32) {
        return keccak256(encode(tos));
    }

    function encode(TransferOut memory to) internal pure returns (bytes memory) {
        return abi.encode(to);
    }

    function hash(TransferOut memory to) internal pure returns (bytes32) {
        return keccak256(encode(to));
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import {Ownable2Step} from "@openzeppelin/contracts/access/Ownable2Step.sol";
import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";

import {GuardianRescuable} from "./GuardianRescuable.sol";

/**
 * @title GuardianOwnable
 */
abstract contract GuardianOwnable is Ownable2Step, GuardianRescuable {
    error RenounceDisabled();

    function guardian() public view override returns (address) {
        return owner();
    }

    function renounceOwnership() public view override onlyOwner {
        revert RenounceDisabled();
    }
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.28;

import {IERC20} from "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";

/**
 * @title GuardianRescuable
 */
abstract contract GuardianRescuable {
    using SafeERC20 for IERC20;

    error NotGuardian(address sender);

    modifier onlyGuardian() {
        if (msg.sender != guardian()) {
            revert NotGuardian(msg.sender);
        }
        _;
    }

    function guardian() public virtual returns (address);

    function withdrawNative(address payable recipient, uint256 amount) external onlyGuardian {
        recipient.transfer(amount);
    }

    function withdrawErc20(IERC20 token, address recipient, uint256 amount) external onlyGuardian {
        token.safeTransfer(recipient, amount);
    }

    function withdrawAllNative(address payable recipient) external onlyGuardian {
        recipient.transfer(address(this).balance);
    }

    function withdrawAllErc20(IERC20 token, address recipient) external onlyGuardian {
        uint256 balance = token.balanceOf(address(this));
        token.safeTransfer(recipient, balance);
    }
}