Forkchoice Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/draft-IERC6093.sol)
pragma solidity >=0.8.4;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /// @inheritdoc IERC20
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /// @inheritdoc IERC20
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /// @inheritdoc IERC20
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
pragma solidity 0.8.28;

import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";

contract BTCR is ERC20, ReentrancyGuard {
    uint256 public constant ENTRY_FEE = 0.001 ether;
    uint256 public constant DECIMALS_MULTIPLIER = 1e18;
    uint256 public constant REWARD_PRECISION = 1e12;
    uint256 public constant HALF_BLOCK_NUM = 210000;
    uint256 public constant BLOCK_TIME = 600;
    uint256 public constant NEWBEE_TIME = 180;
    uint256 public constant INITIAL_BLOCK_PROFIT = 50 * 1e18;
    uint256 public constant NEWBEE_THRESHOLD = 30;
    uint256 public constant DIVIDEND_THRESHOLD = 80;
    uint256 public constant MAX_ENTRY_COUNT = 100;
    uint256 public constant MAX_ROUND = 6;
    address public constant devAddress = 0x5f1eab5dDA8f3A053e65E625B7325b006C28404E;

    error InvalidEntryFee();
    error AlreadyJoined();
    error OnlyNewbiesAllowed();
    error AmountMustBeGreaterThanZero();
    error InsufficientBalance();
    error PriceNotSet();
    error InsufficientBurnFee();
    error ETHTransferFailed();
    error NoPlayersInBlock();
    error EpochNotFinalized();
    error DevFeeTransferFailed();

    struct EpochResult {
        uint128 tokenPerShare;
        uint128 ethPerPlayer;
        bool finalized;
    }

    struct UserInfo {
        uint128 epochId;
        uint128 share;
        bool claimed;
    }

    uint256 public round = 1;
    uint256 public currentEpochId = 1;

    uint256 public blockNum;
    uint256 public blockProfit = INITIAL_BLOCK_PROFIT;
    uint256 public lastBlockTimestamp;

    uint256 public entryCount;
    uint256 public shareSum;

    mapping(uint256 => EpochResult) public epochResults;
    mapping(address => UserInfo) public userInfo;

    uint256 public allocateNum = 3;
    uint256 public price;
    uint256 public burnFee;
    uint256 public poolFee;
    uint256 public devFee;
    uint256 public totalBurned;

    event Played(address indexed player, uint256 share, uint256 entryCount, uint256 epochId);
    event BlockMined(
        uint256 indexed epochId,
        uint256 blockNum,
        uint256 blockPercent,
        uint256 totalProfit
    );
    event DividendDistributed(uint256 indexed epochId, uint256 playerCount, uint256 totalReward);
    event Halved(uint256 newRound, uint256 newBlockProfit);
    event Burned(address indexed user, uint256 amount, uint256 ethReturned);
    event DevFeeWithdrawn(address indexed dev, uint256 amount);
    event Claimed(address indexed user, uint256 tokenAmount, uint256 ethAmount, uint256 epochId);
    event UnexpectedETHReceived(address indexed sender, uint256 amount);

    constructor() ERC20("BTC Reborn", "BTCR") {
        lastBlockTimestamp = block.timestamp;
    }

    receive() external payable {
        if (msg.value > 0) {
            unchecked {
                burnFee += msg.value;
            }
            emit UnexpectedETHReceived(msg.sender, msg.value);
        }
    }

    fallback() external payable {
        if (msg.value > 0) {
            unchecked {
                burnFee += msg.value;
            }
            emit UnexpectedETHReceived(msg.sender, msg.value);
        }
    }

    function play() external payable nonReentrant {
        if (msg.value != ENTRY_FEE) revert InvalidEntryFee();

        uint256 _currentEpochId = currentEpochId;
        UserInfo storage user = userInfo[msg.sender];

        if (user.epochId == _currentEpochId) revert AlreadyJoined();

        if (user.epochId > 0 && !user.claimed) {
            _claim(msg.sender);
        }

        uint256 _entryCount = entryCount;
        uint256 _timestamp = block.timestamp;
        uint256 _lastBlockTimestamp = lastBlockTimestamp;

        bool inNewbeePeriod = _timestamp - _lastBlockTimestamp < NEWBEE_TIME;
        bool shouldCheckNewbee = inNewbeePeriod && _entryCount < NEWBEE_THRESHOLD;

        if (shouldCheckNewbee) {
            if (balanceOf(msg.sender) != 0) revert OnlyNewbiesAllowed();
        }

        _register(_currentEpochId, _entryCount, _timestamp);
    }

    function claim() external nonReentrant {
        _claim(msg.sender);
    }

    function burn(uint256 amount) external nonReentrant {
        if (amount == 0) revert AmountMustBeGreaterThanZero();
        if (balanceOf(msg.sender) < amount) revert InsufficientBalance();

        uint256 _price = price;
        if (_price == 0) revert PriceNotSet();

        uint256 ethReturned = (amount * _price) / DECIMALS_MULTIPLIER;

        uint256 _burnFee = burnFee;
        if (ethReturned > _burnFee) revert InsufficientBurnFee();

        unchecked {
            burnFee = _burnFee - ethReturned;
        }

        _burn(msg.sender, amount);

        unchecked {
            totalBurned += amount;
        }

        (bool success, ) = msg.sender.call{ value: ethReturned }("");
        if (!success) revert ETHTransferFailed();

        emit Burned(msg.sender, amount, ethReturned);
    }

    function _claim(address player) internal {
        UserInfo storage user = userInfo[player];

        uint256 _currentEpochId = currentEpochId;

        if (user.claimed) return;
        if (user.epochId == 0 || user.epochId == _currentEpochId) return;

        uint256 userEpochId = user.epochId;
        EpochResult memory result = epochResults[userEpochId];
        if (!result.finalized) revert EpochNotFinalized();

        uint256 tokenReward = (uint256(user.share) * uint256(result.tokenPerShare)) /
            REWARD_PRECISION;
        uint256 ethReward = uint256(result.ethPerPlayer);

        user.claimed = true;

        if (tokenReward > 0) {
            _mint(player, tokenReward);
        }
        if (ethReward > 0) {
            (bool success, ) = player.call{ value: ethReward }("");
            if (!success) revert ETHTransferFailed();
        }

        emit Claimed(player, tokenReward, ethReward, userEpochId);
    }

    function _register(uint256 _currentEpochId, uint256 _entryCount, uint256 _timestamp) internal {
        uint256 _lastBlockTimestamp = lastBlockTimestamp;
        uint256 _allocateNum = allocateNum;

        bool shouldMineBlock = (_entryCount + 1 >= MAX_ENTRY_COUNT) ||
            (_timestamp - _lastBlockTimestamp >= BLOCK_TIME);

        uint256 shareMultiplier = shouldMineBlock ? 2 : 1;
        uint256 balance = balanceOf(msg.sender) / DECIMALS_MULTIPLIER;
        uint256 balanceShare = balance > 40 ? 40 : balance;
        uint256 share = shareMultiplier * (10 + balanceShare);

        userInfo[msg.sender] = UserInfo({
            epochId: uint128(_currentEpochId),
            share: uint128(share),
            claimed: false
        });

        unchecked {
            shareSum += share;
        }

        uint256 feeType = _entryCount % _allocateNum;
        uint256 newEntryCount;
        unchecked {
            if (feeType == 0) {
                burnFee += ENTRY_FEE;
            } else if (feeType == 1) {
                poolFee += ENTRY_FEE;
            } else {
                devFee += ENTRY_FEE;
            }
            newEntryCount = _entryCount + 1;
            entryCount = newEntryCount;
        }

        emit Played(msg.sender, share, newEntryCount, _currentEpochId);

        if (shouldMineBlock) {
            _mineBlock(_timestamp);
        }
    }

    function _mineBlock(uint256 _timestamp) internal {
        uint256 _entryCount = entryCount;
        if (_entryCount == 0) revert NoPlayersInBlock();

        uint256 _currentEpochId = currentEpochId;
        uint256 _lastBlockTimestamp = lastBlockTimestamp;
        uint256 _blockProfit = blockProfit;
        uint256 _shareSum = shareSum;
        uint256 _blockNum = blockNum;

        uint256 timeDiff = _timestamp - _lastBlockTimestamp;
        uint256 blockPercent = (timeDiff * DECIMALS_MULTIPLIER) / BLOCK_TIME;

        if (blockPercent > DECIMALS_MULTIPLIER) {
            uint256 excess = blockPercent - DECIMALS_MULTIPLIER;
            blockPercent = DECIMALS_MULTIPLIER + excess / 5;
        }

        uint256 totalProfit = (_blockProfit * blockPercent) / DECIMALS_MULTIPLIER;

        uint128 tokenPerShare = 0;
        if (_shareSum > 0) {
            tokenPerShare = uint128((totalProfit * REWARD_PRECISION) / _shareSum);
        }

        uint128 ethPerPlayer = 0;
        uint256 totalEthDistributed = 0;

        if (_entryCount >= DIVIDEND_THRESHOLD) {
            uint256 _poolFee = poolFee;
            uint256 totalReward = _poolFee / 3;
            ethPerPlayer = uint128(totalReward / _entryCount);
            totalEthDistributed = uint256(ethPerPlayer) * _entryCount;

            if (totalEthDistributed > 0) {
                unchecked {
                    poolFee = _poolFee - totalEthDistributed;
                }
                emit DividendDistributed(_currentEpochId, _entryCount, totalEthDistributed);
            }
        }

        epochResults[_currentEpochId] = EpochResult({
            tokenPerShare: tokenPerShare,
            ethPerPlayer: ethPerPlayer,
            finalized: true
        });

        emit BlockMined(_currentEpochId, _blockNum, blockPercent, totalProfit);

        unchecked {
            blockNum = _blockNum + blockPercent;
        }

        if (totalProfit > 0) {
            uint256 numerator = _entryCount * ENTRY_FEE * DECIMALS_MULTIPLIER;
            price = numerator / totalProfit;
        }

        unchecked {
            ++currentEpochId;
        }
        entryCount = 0;
        shareSum = 0;
        lastBlockTimestamp = _timestamp;

        _checkHalving();
    }

    function _checkHalving() internal {
        uint256 halfBlockThreshold = HALF_BLOCK_NUM * DECIMALS_MULTIPLIER;
        if (blockNum >= halfBlockThreshold) {
            unchecked {
                round++;
            }
            blockNum = 0;
            blockProfit /= 2;

            emit Halved(round, blockProfit);

            if (round < MAX_ROUND) {
                _withdrawDevFee();
                if (round == MAX_ROUND - 1) {
                    allocateNum = 2;
                }
            }
        }
    }

    function _withdrawDevFee() internal {
        uint256 _devFee = devFee;
        address _devAddress = devAddress;
        if (_devFee > 0 && _devAddress != address(0)) {
            devFee = 0;
            (bool success, ) = _devAddress.call{ value: _devFee }("");
            if (!success) revert DevFeeTransferFailed();
            emit DevFeeWithdrawn(_devAddress, _devFee);
        }
    }

    function getPlayerCount() external view returns (uint256) {
        return entryCount;
    }

    function getBlockNumValue() external view returns (uint256) {
        return blockNum / DECIMALS_MULTIPLIER;
    }

    function isNewbeeTime() external view returns (bool) {
        return block.timestamp - lastBlockTimestamp < NEWBEE_TIME;
    }

    function canMineBlock() external view returns (bool) {
        return
            (entryCount >= MAX_ENTRY_COUNT) || (block.timestamp - lastBlockTimestamp >= BLOCK_TIME);
    }

    function getPendingReward(
        address player
    ) external view returns (uint256 tokenReward, uint256 ethReward) {
        UserInfo memory user = userInfo[player];
        uint256 _currentEpochId = currentEpochId;
        if (user.epochId == 0 || user.epochId == _currentEpochId || user.claimed) {
            return (0, 0);
        }

        EpochResult memory result = epochResults[user.epochId];
        if (!result.finalized) {
            return (0, 0);
        }

        tokenReward = (uint256(user.share) * uint256(result.tokenPerShare)) / REWARD_PRECISION;
        ethReward = uint256(result.ethPerPlayer);
    }
}