Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {Clones} from "@oz/proxy/Clones.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";
import {SafeERC20} from "@oz/token/ERC20/utils/SafeERC20.sol";
import {IATPFactory, ATPFactory} from "./ATPFactory.sol";
import {ILATP, RevokableParams} from "./atps/linear/ILATP.sol";
import {LATP} from "./atps/linear/LATP.sol";
import {IMATP, MilestoneId} from "./atps/milestone/IMATP.sol";
import {MATP} from "./atps/milestone/MATP.sol";
import {INCATP} from "./atps/noclaim/INCATP.sol";
import {NCATP} from "./atps/noclaim/NCATP.sol";
import {Nonces} from "./Nonces.sol";

interface IATPFactoryNonces is IATPFactory {
    function predictLATPAddressWithNonce(
        address _beneficiary,
        uint256 _allocation,
        RevokableParams memory _revokableParams,
        uint256 _nonce
    ) external view returns (address);

    function predictNCATPAddressWithNonce(
        address _beneficiary,
        uint256 _allocation,
        RevokableParams memory _revokableParams,
        uint256 _nonce
    ) external view returns (address);

    function predictMATPAddressWithNonce(
        address _beneficiary,
        uint256 _allocation,
        MilestoneId _milestoneId,
        uint256 _nonce
    ) external view returns (address);
}

contract ATPFactoryNonces is IATPFactoryNonces, ATPFactory, Nonces {
    using SafeERC20 for IERC20;

    constructor(address __owner, IERC20 _token, uint256 _unlockCliffDuration, uint256 _unlockLockDuration)
        ATPFactory(__owner, _token, _unlockCliffDuration, _unlockLockDuration)
    {}

    /**
     * @notice  Predict the address of an LATP
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the LATP
     * @param _revokableParams The parameters for the accumulation lock and revoke beneficiary, if the LATPs are revokable
     *
     * @return  The address of the LATP
     */
    function predictLATPAddress(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        view
        override(IATPFactory, ATPFactory)
        returns (address)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));

        uint256 nonce = nonces(salt);
        salt = keccak256(abi.encode(salt, nonce));
        return Clones.predictDeterministicAddress(address(LATP_IMPLEMENTATION), salt, address(this));
    }

    /**
     * @notice  Predict the address of an LATP with a given nonce
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the LATP
     * @param _revokableParams The parameters for the accumulation lock and revoke beneficiary, if the LATPs are revokable
     * @param _nonce   The nonce to use for the prediction
     *
     * @return  The address of the LATP
     */
    function predictLATPAddressWithNonce(
        address _beneficiary,
        uint256 _allocation,
        RevokableParams memory _revokableParams,
        uint256 _nonce
    ) external view override(IATPFactoryNonces) returns (address) {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));
        salt = keccak256(abi.encode(salt, _nonce));
        return Clones.predictDeterministicAddress(address(LATP_IMPLEMENTATION), salt, address(this));
    }

    /// @inheritdoc IATPFactory
    function predictNCATPAddress(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        view
        override(IATPFactory, ATPFactory)
        returns (address)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));

        uint256 nonce = nonces(salt);
        salt = keccak256(abi.encode(salt, nonce));
        return Clones.predictDeterministicAddress(address(NCATP_IMPLEMENTATION), salt, address(this));
    }

    /**
     * @notice  Predict the address of an NCATP with a given nonce
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the NCATP
     * @param _revokableParams The parameters for the accumulation lock and revoke beneficiary, if the NCATP is revokable
     * @param _nonce   The nonce to use for the prediction
     *
     * @return  The address of the NCATP
     */
    function predictNCATPAddressWithNonce(
        address _beneficiary,
        uint256 _allocation,
        RevokableParams memory _revokableParams,
        uint256 _nonce
    ) external view override(IATPFactoryNonces) returns (address) {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));
        salt = keccak256(abi.encode(salt, _nonce));
        return Clones.predictDeterministicAddress(address(NCATP_IMPLEMENTATION), salt, address(this));
    }

    /// @inheritdoc IATPFactory
    function predictMATPAddress(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId)
        external
        view
        virtual
        override(IATPFactory, ATPFactory)
        returns (address)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _milestoneId));

        uint256 nonce = nonces(salt);
        salt = keccak256(abi.encode(salt, nonce));
        return Clones.predictDeterministicAddress(address(MATP_IMPLEMENTATION), salt, address(this));
    }

    function predictMATPAddressWithNonce(
        address _beneficiary,
        uint256 _allocation,
        MilestoneId _milestoneId,
        uint256 _nonce
    ) external view override(IATPFactoryNonces) returns (address) {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _milestoneId));
        salt = keccak256(abi.encode(salt, _nonce));
        return Clones.predictDeterministicAddress(address(MATP_IMPLEMENTATION), salt, address(this));
    }

    /**
     * @notice  Create and funds a new LATP
     *          The LATP is created using the `Clones` library and then initialized.
     *          We deploy deterministically using the initialization params as the salt.
     *          When created, the LATP is funded with the `_allocation` amount of tokens.
     *
     *          This setup is done to keep gas costs low.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the LATP
     * @param _revokableParams   The parameters for the accumulation lock, if the LATP is revokable
     *
     * @return  The LATP
     */
    function createLATP(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        public
        override(IATPFactory, ATPFactory)
        onlyMinter
        returns (ILATP)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));

        uint256 nonce = useNonce(salt);
        salt = keccak256(abi.encode(salt, nonce));

        LATP atp = LATP(Clones.cloneDeterministic(address(LATP_IMPLEMENTATION), salt));
        atp.initialize(_beneficiary, _allocation, _revokableParams);
        TOKEN.safeTransfer(address(atp), _allocation);
        emit ATPCreated(_beneficiary, address(atp), _allocation);
        return ILATP(address(atp));
    }

    /**
     * @notice  Create and funds a new NCATP (Non-Claimable ATP)
     *          The NCATP is created using the `Clones` library and then initialized.
     *          We deploy deterministically using the initialization params as the salt.
     *          When created, the NCATP is funded with the `_allocation` amount of tokens.
     *
     *          This setup is done to keep gas costs low.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the NCATP
     * @param _revokableParams   The parameters for the accumulation lock, if the NCATP is revokable
     *
     * @return  The NCATP
     */
    function createNCATP(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        public
        override(IATPFactory, ATPFactory)
        onlyMinter
        returns (INCATP)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));

        uint256 nonce = useNonce(salt);
        salt = keccak256(abi.encode(salt, nonce));

        NCATP atp = NCATP(Clones.cloneDeterministic(address(NCATP_IMPLEMENTATION), salt));
        atp.initialize(_beneficiary, _allocation, _revokableParams);
        TOKEN.safeTransfer(address(atp), _allocation);
        emit ATPCreated(_beneficiary, address(atp), _allocation);
        return INCATP(address(atp));
    }

    /**
     * @notice  Create and funds a new MATP
     *          The MATP is created using the `Clones` library and then initialized.
     *          We deploy deterministically using the initialization params as the salt.
     *          When created, the MATP is funded with the `_allocation` amount of tokens.
     *
     *          This setup is done to keep gas costs low.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the MATP
     * @param _milestoneId   The milestone ID for the MATP
     *
     * @return  The MATP
     */
    function createMATP(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId)
        public
        override(IATPFactory, ATPFactory)
        onlyMinter
        returns (IMATP)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _milestoneId));

        uint256 nonce = useNonce(salt);
        salt = keccak256(abi.encode(salt, nonce));

        MATP atp = MATP(Clones.cloneDeterministic(address(MATP_IMPLEMENTATION), salt));
        atp.initialize(_beneficiary, _allocation, _milestoneId);
        TOKEN.safeTransfer(address(atp), _allocation);
        emit ATPCreated(_beneficiary, address(atp), _allocation);
        return IMATP(address(atp));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (proxy/Clones.sol)

pragma solidity ^0.8.20;

import {Create2} from "../utils/Create2.sol";
import {Errors} from "../utils/Errors.sol";

/**
 * @dev https://eips.ethereum.org/EIPS/eip-1167[ERC-1167] is a standard for
 * deploying minimal proxy contracts, also known as "clones".
 *
 * > To simply and cheaply clone contract functionality in an immutable way, this standard specifies
 * > a minimal bytecode implementation that delegates all calls to a known, fixed address.
 *
 * The library includes functions to deploy a proxy using either `create` (traditional deployment) or `create2`
 * (salted deterministic deployment). It also includes functions to predict the addresses of clones deployed using the
 * deterministic method.
 */
library Clones {
    error CloneArgumentsTooLong();

    /**
     * @dev Deploys and returns the address of a clone that mimics the behavior of `implementation`.
     *
     * This function uses the create opcode, which should never revert.
     */
    function clone(address implementation) internal returns (address instance) {
        return clone(implementation, 0);
    }

    /**
     * @dev Same as {xref-Clones-clone-address-}[clone], but with a `value` parameter to send native currency
     * to the new contract.
     *
     * NOTE: Using a non-zero value at creation will require the contract using this function (e.g. a factory)
     * to always have enough balance for new deployments. Consider exposing this function under a payable method.
     */
    function clone(address implementation, uint256 value) internal returns (address instance) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        assembly ("memory-safe") {
            // Cleans the upper 96 bits of the `implementation` word, then packs the first 3 bytes
            // of the `implementation` address with the bytecode before the address.
            mstore(0x00, or(shr(0xe8, shl(0x60, implementation)), 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000))
            // Packs the remaining 17 bytes of `implementation` with the bytecode after the address.
            mstore(0x20, or(shl(0x78, implementation), 0x5af43d82803e903d91602b57fd5bf3))
            instance := create(value, 0x09, 0x37)
        }
        if (instance == address(0)) {
            revert Errors.FailedDeployment();
        }
    }

    /**
     * @dev Deploys and returns the address of a clone that mimics the behavior of `implementation`.
     *
     * This function uses the create2 opcode and a `salt` to deterministically deploy
     * the clone. Using the same `implementation` and `salt` multiple times will revert, since
     * the clones cannot be deployed twice at the same address.
     */
    function cloneDeterministic(address implementation, bytes32 salt) internal returns (address instance) {
        return cloneDeterministic(implementation, salt, 0);
    }

    /**
     * @dev Same as {xref-Clones-cloneDeterministic-address-bytes32-}[cloneDeterministic], but with
     * a `value` parameter to send native currency to the new contract.
     *
     * NOTE: Using a non-zero value at creation will require the contract using this function (e.g. a factory)
     * to always have enough balance for new deployments. Consider exposing this function under a payable method.
     */
    function cloneDeterministic(
        address implementation,
        bytes32 salt,
        uint256 value
    ) internal returns (address instance) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        assembly ("memory-safe") {
            // Cleans the upper 96 bits of the `implementation` word, then packs the first 3 bytes
            // of the `implementation` address with the bytecode before the address.
            mstore(0x00, or(shr(0xe8, shl(0x60, implementation)), 0x3d602d80600a3d3981f3363d3d373d3d3d363d73000000))
            // Packs the remaining 17 bytes of `implementation` with the bytecode after the address.
            mstore(0x20, or(shl(0x78, implementation), 0x5af43d82803e903d91602b57fd5bf3))
            instance := create2(value, 0x09, 0x37, salt)
        }
        if (instance == address(0)) {
            revert Errors.FailedDeployment();
        }
    }

    /**
     * @dev Computes the address of a clone deployed using {Clones-cloneDeterministic}.
     */
    function predictDeterministicAddress(
        address implementation,
        bytes32 salt,
        address deployer
    ) internal pure returns (address predicted) {
        assembly ("memory-safe") {
            let ptr := mload(0x40)
            mstore(add(ptr, 0x38), deployer)
            mstore(add(ptr, 0x24), 0x5af43d82803e903d91602b57fd5bf3ff)
            mstore(add(ptr, 0x14), implementation)
            mstore(ptr, 0x3d602d80600a3d3981f3363d3d373d3d3d363d73)
            mstore(add(ptr, 0x58), salt)
            mstore(add(ptr, 0x78), keccak256(add(ptr, 0x0c), 0x37))
            predicted := and(keccak256(add(ptr, 0x43), 0x55), 0xffffffffffffffffffffffffffffffffffffffff)
        }
    }

    /**
     * @dev Computes the address of a clone deployed using {Clones-cloneDeterministic}.
     */
    function predictDeterministicAddress(
        address implementation,
        bytes32 salt
    ) internal view returns (address predicted) {
        return predictDeterministicAddress(implementation, salt, address(this));
    }

    /**
     * @dev Deploys and returns the address of a clone that mimics the behavior of `implementation` with custom
     * immutable arguments. These are provided through `args` and cannot be changed after deployment. To
     * access the arguments within the implementation, use {fetchCloneArgs}.
     *
     * This function uses the create opcode, which should never revert.
     */
    function cloneWithImmutableArgs(address implementation, bytes memory args) internal returns (address instance) {
        return cloneWithImmutableArgs(implementation, args, 0);
    }

    /**
     * @dev Same as {xref-Clones-cloneWithImmutableArgs-address-bytes-}[cloneWithImmutableArgs], but with a `value`
     * parameter to send native currency to the new contract.
     *
     * NOTE: Using a non-zero value at creation will require the contract using this function (e.g. a factory)
     * to always have enough balance for new deployments. Consider exposing this function under a payable method.
     */
    function cloneWithImmutableArgs(
        address implementation,
        bytes memory args,
        uint256 value
    ) internal returns (address instance) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        bytes memory bytecode = _cloneCodeWithImmutableArgs(implementation, args);
        assembly ("memory-safe") {
            instance := create(value, add(bytecode, 0x20), mload(bytecode))
        }
        if (instance == address(0)) {
            revert Errors.FailedDeployment();
        }
    }

    /**
     * @dev Deploys and returns the address of a clone that mimics the behavior of `implementation` with custom
     * immutable arguments. These are provided through `args` and cannot be changed after deployment. To
     * access the arguments within the implementation, use {fetchCloneArgs}.
     *
     * This function uses the create2 opcode and a `salt` to deterministically deploy the clone. Using the same
     * `implementation`, `args` and `salt` multiple times will revert, since the clones cannot be deployed twice
     * at the same address.
     */
    function cloneDeterministicWithImmutableArgs(
        address implementation,
        bytes memory args,
        bytes32 salt
    ) internal returns (address instance) {
        return cloneDeterministicWithImmutableArgs(implementation, args, salt, 0);
    }

    /**
     * @dev Same as {xref-Clones-cloneDeterministicWithImmutableArgs-address-bytes-bytes32-}[cloneDeterministicWithImmutableArgs],
     * but with a `value` parameter to send native currency to the new contract.
     *
     * NOTE: Using a non-zero value at creation will require the contract using this function (e.g. a factory)
     * to always have enough balance for new deployments. Consider exposing this function under a payable method.
     */
    function cloneDeterministicWithImmutableArgs(
        address implementation,
        bytes memory args,
        bytes32 salt,
        uint256 value
    ) internal returns (address instance) {
        bytes memory bytecode = _cloneCodeWithImmutableArgs(implementation, args);
        return Create2.deploy(value, salt, bytecode);
    }

    /**
     * @dev Computes the address of a clone deployed using {Clones-cloneDeterministicWithImmutableArgs}.
     */
    function predictDeterministicAddressWithImmutableArgs(
        address implementation,
        bytes memory args,
        bytes32 salt,
        address deployer
    ) internal pure returns (address predicted) {
        bytes memory bytecode = _cloneCodeWithImmutableArgs(implementation, args);
        return Create2.computeAddress(salt, keccak256(bytecode), deployer);
    }

    /**
     * @dev Computes the address of a clone deployed using {Clones-cloneDeterministicWithImmutableArgs}.
     */
    function predictDeterministicAddressWithImmutableArgs(
        address implementation,
        bytes memory args,
        bytes32 salt
    ) internal view returns (address predicted) {
        return predictDeterministicAddressWithImmutableArgs(implementation, args, salt, address(this));
    }

    /**
     * @dev Get the immutable args attached to a clone.
     *
     * - If `instance` is a clone that was deployed using `clone` or `cloneDeterministic`, this
     *   function will return an empty array.
     * - If `instance` is a clone that was deployed using `cloneWithImmutableArgs` or
     *   `cloneDeterministicWithImmutableArgs`, this function will return the args array used at
     *   creation.
     * - If `instance` is NOT a clone deployed using this library, the behavior is undefined. This
     *   function should only be used to check addresses that are known to be clones.
     */
    function fetchCloneArgs(address instance) internal view returns (bytes memory) {
        bytes memory result = new bytes(instance.code.length - 45); // revert if length is too short
        assembly ("memory-safe") {
            extcodecopy(instance, add(result, 32), 45, mload(result))
        }
        return result;
    }

    /**
     * @dev Helper that prepares the initcode of the proxy with immutable args.
     *
     * An assembly variant of this function requires copying the `args` array, which can be efficiently done using
     * `mcopy`. Unfortunately, that opcode is not available before cancun. A pure solidity implementation using
     * abi.encodePacked is more expensive but also more portable and easier to review.
     *
     * NOTE: https://eips.ethereum.org/EIPS/eip-170[EIP-170] limits the length of the contract code to 24576 bytes.
     * With the proxy code taking 45 bytes, that limits the length of the immutable args to 24531 bytes.
     */
    function _cloneCodeWithImmutableArgs(
        address implementation,
        bytes memory args
    ) private pure returns (bytes memory) {
        if (args.length > 24531) revert CloneArgumentsTooLong();
        return
            abi.encodePacked(
                hex"61",
                uint16(args.length + 45),
                hex"3d81600a3d39f3363d3d373d3d3d363d73",
                implementation,
                hex"5af43d82803e903d91602b57fd5bf3",
                args
            );
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {Ownable2Step, Ownable} from "@oz/access/Ownable2Step.sol";
import {Clones} from "@oz/proxy/Clones.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";
import {SafeERC20} from "@oz/token/ERC20/utils/SafeERC20.sol";
import {ILATP, RevokableParams} from "./atps/linear/ILATP.sol";
import {IMATP, MilestoneId} from "./atps/milestone/IMATP.sol";
import {LATP} from "./atps/linear/LATP.sol";
import {MATP} from "./atps/milestone/MATP.sol";
import {INCATP} from "./atps/noclaim/INCATP.sol";
import {NCATP} from "./atps/noclaim/NCATP.sol";
import {Registry, IRegistry} from "./Registry.sol";

import {LATPFactory} from "./deployment-factories/LATPFactory.sol";
import {NCATPFactory} from "./deployment-factories/NCATPFactory.sol";
import {MATPFactory} from "./deployment-factories/MATPFactory.sol";

interface IATPFactory {
    event ATPCreated(address indexed beneficiary, address indexed atp, uint256 allocation);
    event MinterSet(address indexed minter, bool isMinter);

    error InvalidInputLength();
    error NotMinter();

    function createLATP(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        returns (ILATP);

    function createNCATP(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        returns (INCATP);

    function createMATP(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId) external returns (IMATP);

    function createLATPs(
        address[] memory _beneficiaries,
        uint256[] memory _allocations,
        RevokableParams[] memory _revokableParams
    ) external returns (ILATP[] memory);

    function createNCATPs(
        address[] memory _beneficiaries,
        uint256[] memory _allocations,
        RevokableParams[] memory _revokableParams
    ) external returns (INCATP[] memory);

    function createMATPs(
        address[] memory _beneficiaries,
        uint256[] memory _allocations,
        MilestoneId[] memory _milestoneIds
    ) external returns (IMATP[] memory);

    function recoverTokens(address _token, address _to, uint256 _amount) external;

    function setMinter(address _minter, bool _isMinter) external;

    function getRegistry() external view returns (IRegistry);

    function getToken() external view returns (IERC20);

    function predictLATPAddress(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        view
        returns (address);

    function predictNCATPAddress(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        view
        returns (address);

    function predictMATPAddress(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId)
        external
        view
        returns (address);
}

contract ATPFactory is Ownable2Step, IATPFactory {
    using SafeERC20 for IERC20;

    Registry internal immutable REGISTRY;
    IERC20 internal immutable TOKEN;

    LATP internal immutable LATP_IMPLEMENTATION;
    NCATP internal immutable NCATP_IMPLEMENTATION;
    MATP internal immutable MATP_IMPLEMENTATION;

    mapping(address => bool) public minter;

    modifier onlyMinter() {
        require(minter[msg.sender], NotMinter());
        _;
    }

    constructor(address __owner, IERC20 _token, uint256 _unlockCliffDuration, uint256 _unlockLockDuration)
        Ownable(__owner)
    {
        REGISTRY = new Registry(__owner, _unlockCliffDuration, _unlockLockDuration);
        TOKEN = _token;
        LATP_IMPLEMENTATION = LATPFactory.deployImplementation(IRegistry(address(REGISTRY)), TOKEN);
        NCATP_IMPLEMENTATION = NCATPFactory.deployImplementation(IRegistry(address(REGISTRY)), TOKEN);
        MATP_IMPLEMENTATION = MATPFactory.deployImplementation(IRegistry(address(REGISTRY)), TOKEN);

        minter[__owner] = true;
        emit MinterSet(__owner, true);
    }

    /**
     * @notice  Recover any token from the contract
     *
     * @dev     The caller must be the `owner`
     *
     * @dev     Does not support Ether as it is not an ERC20,
     *
     * @param _token   The token to rescue
     * @param _to   The address to rescue the tokens to
     * @param _amount   The amount of tokens to rescue
     */
    function recoverTokens(address _token, address _to, uint256 _amount) external override(IATPFactory) onlyOwner {
        IERC20(_token).safeTransfer(_to, _amount);
    }

    /**
     * @notice  Set the minter status of an address
     *
     * @dev     The caller must be the `owner`
     *
     * @param _minter The address to set the minter status of
     * @param _isMinter The minter status to set
     */
    function setMinter(address _minter, bool _isMinter) external override(IATPFactory) onlyOwner {
        minter[_minter] = _isMinter;
        emit MinterSet(_minter, _isMinter);
    }

    /**
     * @notice  Create and fund multiple LATPs
     *          Creates the LATPs using the `clones` library, initializes it and funds it.
     *
     * @dev     The caller must be a minter
     *
     * @param _beneficiaries The addresses of the beneficiaries
     * @param _allocations The amounts of tokens to allocate to the LATPs
     * @param _revokableParams The parameters for the accumulation lock and revoke beneficiary,
     *                         provide empty `LockParams` and `address(0)` as `revokeBeneficiary`
     *                         if the LATP are not revokable
     *
     * @return The LATPs
     */
    function createLATPs(
        address[] memory _beneficiaries,
        uint256[] memory _allocations,
        RevokableParams[] memory _revokableParams
    ) external virtual override(IATPFactory) onlyMinter returns (ILATP[] memory) {
        require(
            _beneficiaries.length == _allocations.length && _beneficiaries.length == _revokableParams.length,
            InvalidInputLength()
        );
        ILATP[] memory atps = new ILATP[](_beneficiaries.length);
        for (uint256 i = 0; i < _beneficiaries.length; i++) {
            atps[i] = createLATP(_beneficiaries[i], _allocations[i], _revokableParams[i]);
        }
        return atps;
    }

    /**
     * @notice  Create and fund multiple NCATPs
     *          Creates the NCATPs using the `clones` library, initializes it and funds it.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiaries The addresses of the beneficiaries
     * @param _allocations The amounts of tokens to allocate to the NCATPs
     * @param _revokableParams The parameters for the accumulation lock and revoke beneficiary,
     *                         provide empty `LockParams` and `address(0)` as `revokeBeneficiary`
     *                         if the NCATP are not revokable
     *
     * @return The NCATPs
     */
    function createNCATPs(
        address[] memory _beneficiaries,
        uint256[] memory _allocations,
        RevokableParams[] memory _revokableParams
    ) external virtual override(IATPFactory) onlyMinter returns (INCATP[] memory) {
        require(
            _beneficiaries.length == _allocations.length && _beneficiaries.length == _revokableParams.length,
            InvalidInputLength()
        );
        INCATP[] memory atps = new INCATP[](_beneficiaries.length);
        for (uint256 i = 0; i < _beneficiaries.length; i++) {
            atps[i] = createNCATP(_beneficiaries[i], _allocations[i], _revokableParams[i]);
        }
        return atps;
    }

    /**
     * @notice  Create and fund multiple MATPs
     *          Creates the MATPs using the `clones` library, initializes it and funds it.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiaries The addresses of the beneficiaries
     * @param _allocations The amounts of tokens to allocate to the MATPs
     * @param _milestoneIds The milestone IDs for the MATPs
     *
     * @return The MATPs
     */
    function createMATPs(
        address[] memory _beneficiaries,
        uint256[] memory _allocations,
        MilestoneId[] memory _milestoneIds
    ) external virtual override(IATPFactory) onlyMinter returns (IMATP[] memory) {
        require(
            _beneficiaries.length == _allocations.length && _beneficiaries.length == _milestoneIds.length,
            InvalidInputLength()
        );
        IMATP[] memory atps = new IMATP[](_beneficiaries.length);
        for (uint256 i = 0; i < _beneficiaries.length; i++) {
            atps[i] = createMATP(_beneficiaries[i], _allocations[i], _milestoneIds[i]);
        }
        return atps;
    }

    /**
     * @notice  Get the registry
     *
     * @return  The registry
     */
    function getRegistry() external view override(IATPFactory) returns (IRegistry) {
        return IRegistry(address(REGISTRY));
    }

    /**
     * @notice  Get the token
     *
     * @return  The token
     */
    function getToken() external view override(IATPFactory) returns (IERC20) {
        return TOKEN;
    }

    /**
     * @notice  Predict the address of an LATP
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the LATP
     * @param _revokableParams The parameters for the accumulation lock and revoke beneficiary, if the LATPs are revokable
     *
     * @return  The address of the LATP
     */
    function predictLATPAddress(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        view
        virtual
        override(IATPFactory)
        returns (address)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));
        return Clones.predictDeterministicAddress(address(LATP_IMPLEMENTATION), salt, address(this));
    }

    function predictNCATPAddress(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        view
        virtual
        override(IATPFactory)
        returns (address)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));
        return Clones.predictDeterministicAddress(address(NCATP_IMPLEMENTATION), salt, address(this));
    }

    function predictMATPAddress(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId)
        external
        view
        virtual
        override(IATPFactory)
        returns (address)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _milestoneId));
        return Clones.predictDeterministicAddress(address(MATP_IMPLEMENTATION), salt, address(this));
    }

    /**
     * @notice  Create and funds a new LATP
     *          The LATP is created using the `Clones` library and then initialized.
     *          We deploy deterministically using the initialization params as the salt.
     *          When created, the LATP is funded with the `_allocation` amount of tokens.
     *
     *          This setup is done to keep gas costs low.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the LATP
     * @param _revokableParams   The parameters for the accumulation lock, if the LATP is revokable
     *
     * @return  The LATP
     */
    function createLATP(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        public
        virtual
        override(IATPFactory)
        onlyMinter
        returns (ILATP)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));
        LATP atp = LATP(Clones.cloneDeterministic(address(LATP_IMPLEMENTATION), salt));
        atp.initialize(_beneficiary, _allocation, _revokableParams);
        TOKEN.safeTransfer(address(atp), _allocation);
        emit ATPCreated(_beneficiary, address(atp), _allocation);
        return ILATP(address(atp));
    }

    /**
     * @notice  Create and funds a new NCATP (Non-Claimable ATP)
     *          The NCATP is created using the `Clones` library and then initialized.
     *          We deploy deterministically using the initialization params as the salt.
     *          When created, the NCATP is funded with the `_allocation` amount of tokens.
     *
     *          This setup is done to keep gas costs low.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the NCATP
     * @param _revokableParams   The parameters for the accumulation lock, if the NCATP is revokable
     *
     * @return  The NCATP
     */
    function createNCATP(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        public
        virtual
        override(IATPFactory)
        onlyMinter
        returns (INCATP)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _revokableParams));
        NCATP atp = NCATP(Clones.cloneDeterministic(address(NCATP_IMPLEMENTATION), salt));
        atp.initialize(_beneficiary, _allocation, _revokableParams);
        TOKEN.safeTransfer(address(atp), _allocation);
        emit ATPCreated(_beneficiary, address(atp), _allocation);
        return INCATP(address(atp));
    }

    /**
     * @notice  Create and funds a new MATP
     *          The MATP is created using the `Clones` library and then initialized.
     *          We deploy deterministically using the initialization params as the salt.
     *          When created, the MATP is funded with the `_allocation` amount of tokens.
     *
     *          This setup is done to keep gas costs low.
     *
     * @dev     The caller must be a `minter`
     *
     * @param _beneficiary   The address of the beneficiary
     * @param _allocation    The amount of tokens to allocate to the MATP
     * @param _milestoneId   The milestone ID for the MATP
     *
     * @return  The MATP
     */
    function createMATP(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId)
        public
        virtual
        override(IATPFactory)
        onlyMinter
        returns (IMATP)
    {
        bytes32 salt = keccak256(abi.encode(_beneficiary, _allocation, _milestoneId));
        MATP atp = MATP(Clones.cloneDeterministic(address(MATP_IMPLEMENTATION), salt));
        atp.initialize(_beneficiary, _allocation, _milestoneId);
        TOKEN.safeTransfer(address(atp), _allocation);
        emit ATPCreated(_beneficiary, address(atp), _allocation);
        return IMATP(address(atp));
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {Lock, LockParams} from "./../../libraries/LockLib.sol";
import {IATPCore, IATPPeriphery} from "./../base/IATP.sol";

struct LATPStorage {
    uint32 accumulationStartTime;
    uint32 accumulationCliffDuration;
    uint32 accumulationLockDuration;
    bool isRevokable;
    address revokeBeneficiary;
}

struct RevokableParams {
    address revokeBeneficiary;
    LockParams lockParams;
}

interface ILATPCore is IATPCore {
    error InsufficientStakeable(uint256 stakeable, uint256 allowance);
    error LockParamsMustBeEmpty();

    function initialize(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams) external;

    function getAccumulationLock() external view returns (Lock memory);
    function getRevokableAmount() external view returns (uint256);
    function getStakeableAmount() external view returns (uint256);
}

interface ILATPPeriphery is IATPPeriphery {
    function getStore() external view returns (LATPStorage memory);
    function getRevokeBeneficiary() external view returns (address);
}

interface ILATP is ILATPCore, ILATPPeriphery {}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {ATPType} from "./../base/IATP.sol";
import {ILATP, ILATPPeriphery, IATPPeriphery, LATPStorage} from "./ILATP.sol";
import {LATPCore, IERC20, IRegistry, IBaseStaker} from "./LATPCore.sol";

/**
 * @title   Linear Aztec Token Position
 * @notice  Linear Aztec Token Position with additional helper view functions
 *          This is a helper contract to make it easier to use the LATP contract
 *          Will not include any state mutating extensions, just easier access to the data
 *          I might be kinda strange doing this, but I just find it simpler when looking at the state mutating
 *          functions, as I don't need to skip functions etc.
 *
 *          It is also a neat way to make sure that all of the getters follow a similar pattern, as we like using
 *          different naming conventions for different types of data, e.g., constant vs mutable.
 */
contract LATP is ILATP, LATPCore {
    constructor(IRegistry _registry, IERC20 _token) LATPCore(_registry, _token) {}

    function getToken() external view override(IATPPeriphery) returns (IERC20) {
        return TOKEN;
    }

    function getRegistry() external view override(IATPPeriphery) returns (IRegistry) {
        return REGISTRY;
    }

    function getStaker() external view override(IATPPeriphery) returns (IBaseStaker) {
        return staker;
    }

    function getExecuteAllowedAt() external view override(IATPPeriphery) returns (uint256) {
        return REGISTRY.getExecuteAllowedAt();
    }

    function getClaimed() external view override(IATPPeriphery) returns (uint256) {
        return claimed;
    }

    function getRevoker() external view override(IATPPeriphery) returns (address) {
        return REGISTRY.getRevoker();
    }

    function getIsRevokable() external view override(IATPPeriphery) returns (bool) {
        return store.isRevokable;
    }

    function getAllocation() external view override(IATPPeriphery) returns (uint256) {
        return allocation;
    }

    function getStore() external view override(ILATPPeriphery) returns (LATPStorage memory) {
        return store;
    }

    function getRevokeBeneficiary() external view override(ILATPPeriphery) returns (address) {
        return store.revokeBeneficiary;
    }

    function getType() external pure virtual override(IATPPeriphery) returns (ATPType) {
        return ATPType.Linear;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {MilestoneId} from "./../../Registry.sol";

import {IATPCore, IATPPeriphery} from "./../base/IATP.sol";

interface IMATPCore is IATPCore {
    error RevokedOrFailed();

    function initialize(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId) external;
}

interface IMATPPeriphery is IATPPeriphery {
    function getMilestoneId() external view returns (MilestoneId);
    function getIsRevoked() external view returns (bool);
}

interface IMATP is IMATPCore, IMATPPeriphery {}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {ATPType} from "./../base/IATP.sol";
import {IMATP, IMATPPeriphery, IATPPeriphery} from "./IMATP.sol";
import {MATPCore, MilestoneId, IRegistry, IERC20, IBaseStaker} from "./MATPCore.sol";

contract MATP is IMATP, MATPCore {
    constructor(IRegistry _registry, IERC20 _token) MATPCore(_registry, _token) {}

    function getToken() external view override(IATPPeriphery) returns (IERC20) {
        return TOKEN;
    }

    function getRegistry() external view override(IATPPeriphery) returns (IRegistry) {
        return REGISTRY;
    }

    function getStaker() external view override(IATPPeriphery) returns (IBaseStaker) {
        return staker;
    }

    function getExecuteAllowedAt() external view override(IATPPeriphery) returns (uint256) {
        return REGISTRY.getExecuteAllowedAt();
    }

    function getClaimed() external view override(IATPPeriphery) returns (uint256) {
        return claimed;
    }

    function getRevoker() external view override(IATPPeriphery) returns (address) {
        return REGISTRY.getRevoker();
    }

    function getIsRevokable() external view override(IATPPeriphery) returns (bool) {
        return !isRevoked;
    }

    function getAllocation() external view override(IATPPeriphery) returns (uint256) {
        return allocation;
    }

    function getMilestoneId() external view override(IMATPPeriphery) returns (MilestoneId) {
        return milestoneId;
    }

    function getIsRevoked() external view override(IMATPPeriphery) returns (bool) {
        return isRevoked;
    }

    function getType() external pure override(IATPPeriphery) returns (ATPType) {
        return ATPType.Milestone;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {LockParams} from "./../../libraries/LockLib.sol";
import {IATPPeriphery} from "./../base/IATP.sol";

import {ILATPCore} from "./../linear/ILATP.sol";

struct NCATPStorage {
    uint32 accumulationStartTime;
    uint32 accumulationCliffDuration;
    uint32 accumulationLockDuration;
    bool isRevokable;
    address revokeBeneficiary;
}

struct RevokableParams {
    address revokeBeneficiary;
    LockParams lockParams;
}

interface INCATPCore is ILATPCore {}

interface INCATPPeriphery is IATPPeriphery {
    function getStore() external view returns (NCATPStorage memory);
    function getRevokeBeneficiary() external view returns (address);
}

interface INCATP is INCATPCore, INCATPPeriphery {}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {ATPType, IATPCore} from "./../base/IATP.sol";
import {LATP} from "./../linear/LATP.sol";
import {LATPCore, IERC20, IRegistry} from "./../linear/LATPCore.sol";

/**
 * @title   Non Claimable Linear Aztec Position
 * @notice  An override of the LATP contract to make it non-claimable.
 */
contract NCATP is LATP {
    uint256 public immutable CREATED_AT_TIMESTAMP;

    constructor(IRegistry _registry, IERC20 _token) LATP(_registry, _token) {
        CREATED_AT_TIMESTAMP = block.timestamp;
    }

    function claim() external override(IATPCore, LATPCore) onlyBeneficiary returns (uint256) {
        revert NoClaimable();
    }

    function getType() external pure override(LATP) returns (ATPType) {
        return ATPType.NonClaim;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

/**
 * @title Track hash Nonces
 * @dev See OpenZeppelin's Nonces.sol
 */
abstract contract Nonces {
    mapping(bytes32 hash => uint256) private _nonces;

    /**
     * @dev Returns the next unused nonce for a hash.
     */
    function nonces(bytes32 _hash) public view virtual returns (uint256) {
        return _nonces[_hash];
    }

    /**
     * @dev Consumes a nonce.
     *
     * Returns the current value and increments nonce.
     */
    function useNonce(bytes32 _hash) internal virtual returns (uint256) {
        // For each hash, the nonce has an initial value of 0, can only be incremented by one, and cannot be
        // decremented or reset. This guarantees that the nonce never overflows.
        unchecked {
            // It is important to do x++ and not ++x here.
            return _nonces[_hash]++;
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Create2.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Helper to make usage of the `CREATE2` EVM opcode easier and safer.
 * `CREATE2` can be used to compute in advance the address where a smart
 * contract will be deployed, which allows for interesting new mechanisms known
 * as 'counterfactual interactions'.
 *
 * See the https://eips.ethereum.org/EIPS/eip-1014#motivation[EIP] for more
 * information.
 */
library Create2 {
    /**
     * @dev There's no code to deploy.
     */
    error Create2EmptyBytecode();

    /**
     * @dev Deploys a contract using `CREATE2`. The address where the contract
     * will be deployed can be known in advance via {computeAddress}.
     *
     * The bytecode for a contract can be obtained from Solidity with
     * `type(contractName).creationCode`.
     *
     * Requirements:
     *
     * - `bytecode` must not be empty.
     * - `salt` must have not been used for `bytecode` already.
     * - the factory must have a balance of at least `amount`.
     * - if `amount` is non-zero, `bytecode` must have a `payable` constructor.
     */
    function deploy(uint256 amount, bytes32 salt, bytes memory bytecode) internal returns (address addr) {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }
        if (bytecode.length == 0) {
            revert Create2EmptyBytecode();
        }
        assembly ("memory-safe") {
            addr := create2(amount, add(bytecode, 0x20), mload(bytecode), salt)
            // if no address was created, and returndata is not empty, bubble revert
            if and(iszero(addr), not(iszero(returndatasize()))) {
                let p := mload(0x40)
                returndatacopy(p, 0, returndatasize())
                revert(p, returndatasize())
            }
        }
        if (addr == address(0)) {
            revert Errors.FailedDeployment();
        }
    }

    /**
     * @dev Returns the address where a contract will be stored if deployed via {deploy}. Any change in the
     * `bytecodeHash` or `salt` will result in a new destination address.
     */
    function computeAddress(bytes32 salt, bytes32 bytecodeHash) internal view returns (address) {
        return computeAddress(salt, bytecodeHash, address(this));
    }

    /**
     * @dev Returns the address where a contract will be stored if deployed via {deploy} from a contract located at
     * `deployer`. If `deployer` is this contract's address, returns the same value as {computeAddress}.
     */
    function computeAddress(bytes32 salt, bytes32 bytecodeHash, address deployer) internal pure returns (address addr) {
        assembly ("memory-safe") {
            let ptr := mload(0x40) // Get free memory pointer

            // |                   | ↓ ptr ...  ↓ ptr + 0x0B (start) ...  ↓ ptr + 0x20 ...  ↓ ptr + 0x40 ...   |
            // |-------------------|---------------------------------------------------------------------------|
            // | bytecodeHash      |                                                        CCCCCCCCCCCCC...CC |
            // | salt              |                                      BBBBBBBBBBBBB...BB                   |
            // | deployer          | 000000...0000AAAAAAAAAAAAAAAAAAA...AA                                     |
            // | 0xFF              |            FF                                                             |
            // |-------------------|---------------------------------------------------------------------------|
            // | memory            | 000000...00FFAAAAAAAAAAAAAAAAAAA...AABBBBBBBBBBBBB...BBCCCCCCCCCCCCC...CC |
            // | keccak(start, 85) |            ↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑ |

            mstore(add(ptr, 0x40), bytecodeHash)
            mstore(add(ptr, 0x20), salt)
            mstore(ptr, deployer) // Right-aligned with 12 preceding garbage bytes
            let start := add(ptr, 0x0b) // The hashed data starts at the final garbage byte which we will set to 0xff
            mstore8(start, 0xff)
            addr := and(keccak256(start, 85), 0xffffffffffffffffffffffffffffffffffffffff)
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Errors.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of common custom errors used in multiple contracts
 *
 * IMPORTANT: Backwards compatibility is not guaranteed in future versions of the library.
 * It is recommended to avoid relying on the error API for critical functionality.
 *
 * _Available since v5.1._
 */
library Errors {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error InsufficientBalance(uint256 balance, uint256 needed);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedCall();

    /**
     * @dev The deployment failed.
     */
    error FailedDeployment();

    /**
     * @dev A necessary precompile is missing.
     */
    error MissingPrecompile(address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This extension of the {Ownable} contract includes a two-step mechanism to transfer
 * ownership, where the new owner must call {acceptOwnership} in order to replace the
 * old one. This can help prevent common mistakes, such as transfers of ownership to
 * incorrect accounts, or to contracts that are unable to interact with the
 * permission system.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     *
     * Setting `newOwner` to the zero address is allowed; this can be used to cancel an initiated ownership transfer.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {Ownable2Step, Ownable} from "@oz/access/Ownable2Step.sol";
import {UUPSUpgradeable, ERC1967Utils} from "@oz/proxy/utils/UUPSUpgradeable.sol";
import {LockParams} from "./libraries/LockLib.sol";
import {BaseStaker} from "./staker/BaseStaker.sol";

type MilestoneId is uint96;

type StakerVersion is uint256;

enum MilestoneStatus {
    Pending,
    Failed,
    Succeeded
}

interface IRegistry {
    event UpdatedRevoker(address revoker);
    event UpdatedRevokerOperator(address revokerOperator);
    event UpdatedExecuteAllowedAt(uint256 executeAllowedAt);
    event UpdatedUnlockStartTime(uint256 unlockStartTime);
    event StakerRegistered(StakerVersion version, address implementation);
    event MilestoneAdded(MilestoneId milestoneId);
    event MilestoneStatusUpdated(MilestoneId milestoneId, MilestoneStatus status);

    error InvalidExecuteAllowedAt(uint256 newExecuteAllowedAt, uint256 currentExecuteAllowedAt);
    error InvalidUnlockStartTime(uint256 newUnlockStartTime, uint256 currentUnlockStartTime);
    error InvalidUnlockDuration();
    error InvalidUnlockCliffDuration();
    error InvalidStakerImplementation(address implementation);

    error UnRegisteredStaker(StakerVersion version);
    error InvalidMilestoneId(MilestoneId milestoneId);
    error InvalidMilestoneStatus(MilestoneId milestoneId);

    function setRevoker(address _revoker) external;
    function setRevokerOperator(address _revokerOperator) external;
    function setExecuteAllowedAt(uint256 _executeAllowedAt) external;
    function setUnlockStartTime(uint256 _unlockStartTime) external;
    function registerStakerImplementation(address _implementation) external;
    function addMilestone() external returns (MilestoneId);
    function setMilestoneStatus(MilestoneId _milestoneId, MilestoneStatus _status) external;

    function getRevoker() external view returns (address);
    function getRevokerOperator() external view returns (address);
    function getExecuteAllowedAt() external view returns (uint256);
    function getUnlockStartTime() external view returns (uint256);
    function getGlobalLockParams() external view returns (LockParams memory);
    function getStakerImplementation(StakerVersion _version) external view returns (address);
    function getNextStakerVersion() external view returns (StakerVersion);
    function getMilestoneStatus(MilestoneId _milestoneId) external view returns (MilestoneStatus);
    function getNextMilestoneId() external view returns (MilestoneId);
}

contract Registry is Ownable2Step, IRegistry {
    uint256 internal immutable UNLOCK_CLIFF_DURATION;
    uint256 internal immutable UNLOCK_LOCK_DURATION;

    // @note An initial value set to be the unix timestamp of 1st of January 2027
    uint256 internal unlockStartTime = 1798761600;
    uint256 internal executeAllowedAt = 1798761600;
    address internal revoker;
    address internal revokerOperator;

    StakerVersion internal nextStakerVersion;
    mapping(StakerVersion version => address implementation) internal stakerImplementations;

    MilestoneId internal nextMilestoneId;
    mapping(MilestoneId milestoneId => MilestoneStatus status) internal milestones;

    constructor(address __owner, uint256 _unlockCliffDuration, uint256 _unlockLockDuration) Ownable(__owner) {
        require(_unlockLockDuration > 0, InvalidUnlockDuration());
        require(_unlockLockDuration >= _unlockCliffDuration, InvalidUnlockCliffDuration());

        UNLOCK_CLIFF_DURATION = _unlockCliffDuration;
        UNLOCK_LOCK_DURATION = _unlockLockDuration;

        // @note Register the base staker implementation
        stakerImplementations[StakerVersion.wrap(0)] = address(new BaseStaker());
        nextStakerVersion = StakerVersion.wrap(1);
    }

    /**
     * @notice  Add a new milestone
     *
     * @dev Only callable by the owner
     *
     * @return  The milestone id
     */
    function addMilestone() external override(IRegistry) onlyOwner returns (MilestoneId) {
        MilestoneId milestoneId = nextMilestoneId;
        nextMilestoneId = MilestoneId.wrap(MilestoneId.unwrap(nextMilestoneId) + 1);
        milestones[milestoneId] = MilestoneStatus.Pending; // To be explicit

        emit MilestoneAdded(milestoneId);
        return milestoneId;
    }

    function setMilestoneStatus(MilestoneId _milestoneId, MilestoneStatus _status)
        external
        override(IRegistry)
        onlyOwner
    {
        require(getMilestoneStatus(_milestoneId) == MilestoneStatus.Pending, InvalidMilestoneStatus(_milestoneId));
        require(_status != MilestoneStatus.Pending, InvalidMilestoneStatus(_milestoneId));
        milestones[_milestoneId] = _status;

        emit MilestoneStatusUpdated(_milestoneId, _status);
    }

    /**
     * @notice  Register a new staker implementation
     *
     * @dev Only callable by the owner
     *
     * @param _implementation   The address of the staker implementation
     */
    function registerStakerImplementation(address _implementation) external override(IRegistry) onlyOwner {
        require(
            UUPSUpgradeable(_implementation).proxiableUUID() == ERC1967Utils.IMPLEMENTATION_SLOT,
            InvalidStakerImplementation(_implementation)
        );

        StakerVersion version = nextStakerVersion;
        nextStakerVersion = StakerVersion.wrap(StakerVersion.unwrap(nextStakerVersion) + 1);
        stakerImplementations[version] = _implementation;

        emit StakerRegistered(version, _implementation);
    }

    /**
     * @notice  Set the revoker address
     *
     * @dev Only callable by the owner
     *
     * @param _revoker   The address of the revoker
     */
    function setRevoker(address _revoker) external override(IRegistry) onlyOwner {
        revoker = _revoker;
        emit UpdatedRevoker(_revoker);
    }

    function setRevokerOperator(address _revokerOperator) external override(IRegistry) onlyOwner {
        revokerOperator = _revokerOperator;
        emit UpdatedRevokerOperator(_revokerOperator);
    }

    /**
     * @notice  Set the execute allowed at timestamp
     *          Can only be decreased to avoid unintentional updates and give some guarantees to LATP beneficiaries
     *
     * @dev Only callable by the owner
     *
     * @param _executeAllowedAt   The timestamp of when the execute is allowed
     */
    function setExecuteAllowedAt(uint256 _executeAllowedAt) external override(IRegistry) onlyOwner {
        require(_executeAllowedAt < executeAllowedAt, InvalidExecuteAllowedAt(_executeAllowedAt, executeAllowedAt));
        executeAllowedAt = _executeAllowedAt;
        emit UpdatedExecuteAllowedAt(_executeAllowedAt);
    }

    /**
     * @notice  Set the unlock start time
     *          Can only be decreased to avoid unintentional updates and give some guarantees to LATP beneficiaries
     *
     * @dev Only callable by the owner
     *
     * @param _unlockStartTime   The timestamp of when the unlock starts
     */
    function setUnlockStartTime(uint256 _unlockStartTime) external override(IRegistry) onlyOwner {
        require(_unlockStartTime < unlockStartTime, InvalidUnlockStartTime(_unlockStartTime, unlockStartTime));
        unlockStartTime = _unlockStartTime;
        emit UpdatedUnlockStartTime(_unlockStartTime);
    }

    /**
     * @notice  Get the revoker address
     *
     * @return  The address of the revoker
     */
    function getRevoker() external view override(IRegistry) returns (address) {
        return revoker;
    }

    function getRevokerOperator() external view override(IRegistry) returns (address) {
        return revokerOperator;
    }

    /**
     * @notice  Get the execute allowed at timestamp
     *
     * @return  The timestamp of when the execute is allowed
     */
    function getExecuteAllowedAt() external view override(IRegistry) returns (uint256) {
        return executeAllowedAt;
    }

    /**
     * @notice  Get the unlock start time
     *
     * @return  The timestamp of when the unlock starts
     */
    function getUnlockStartTime() external view override(IRegistry) returns (uint256) {
        return unlockStartTime;
    }

    /**
     * @notice  Get the lock params for the global unlocking schedule
     *
     * @return  The global lock params
     */
    function getGlobalLockParams() external view override(IRegistry) returns (LockParams memory) {
        return LockParams({
            startTime: unlockStartTime, cliffDuration: UNLOCK_CLIFF_DURATION, lockDuration: UNLOCK_LOCK_DURATION
        });
    }

    /**
     * @notice  Get the implementation for a given staker version
     *
     * @param   _version   The version of the staker
     *
     * @return  The implementation for the given staker version
     */
    function getStakerImplementation(StakerVersion _version) external view override(IRegistry) returns (address) {
        require(StakerVersion.unwrap(_version) < StakerVersion.unwrap(nextStakerVersion), UnRegisteredStaker(_version));
        return stakerImplementations[_version];
    }

    /**
     * @notice  Get the next staker version
     *
     * @return  The next staker version
     */
    function getNextStakerVersion() external view override(IRegistry) returns (StakerVersion) {
        return nextStakerVersion;
    }

    function getNextMilestoneId() external view override(IRegistry) returns (MilestoneId) {
        return nextMilestoneId;
    }

    function getMilestoneStatus(MilestoneId _milestoneId) public view override(IRegistry) returns (MilestoneStatus) {
        require(
            MilestoneId.unwrap(_milestoneId) < MilestoneId.unwrap(nextMilestoneId), InvalidMilestoneId(_milestoneId)
        );
        return milestones[_milestoneId];
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {IRegistry} from "../Registry.sol";
import {LATP} from "../atps/linear/LATP.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";

library LATPFactory {
    /**
     * @notice Deploy the LATP implementation
     * @param _registry The registry
     * @param _token The token
     * @return The LATP implementation
     */
    function deployImplementation(IRegistry _registry, IERC20 _token) external returns (LATP) {
        return new LATP(_registry, _token);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {IRegistry} from "../Registry.sol";
import {NCATP} from "../atps/noclaim/NCATP.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";

library NCATPFactory {
    /**
     * @notice Deploy the NCATP implementation
     * @param _registry The registry
     * @param _token The token
     * @return The NCATP implementation
     */
    function deployImplementation(IRegistry _registry, IERC20 _token) external returns (NCATP) {
        return new NCATP(_registry, _token);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {IRegistry} from "../Registry.sol";
import {MATP} from "../atps/milestone/MATP.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";

library MATPFactory {
    /**
     * @notice Deploy the MATP implementation
     * @param _registry The registry
     * @param _token The token
     * @return The MATP implementation
     */
    function deployImplementation(IRegistry _registry, IERC20 _token) external returns (MATP) {
        return new MATP(_registry, _token);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

/**
 * @notice  The parameters for a lock
 *          The parameters used to derive the actual lock.
 *
 * @param   startTime The timestamp that the lock starts at (0 before this value)
 * @param   cliffDuration Time until the cliff is reached
 * @param   lockDuration Time until the lock is fully unlocked
 */
struct LockParams {
    uint256 startTime;
    uint256 cliffDuration;
    uint256 lockDuration;
}

/**
 * @notice  The lock struct
 * @param   startTime The timestamp that the lock starts at (0 before this value)
 * @param   cliff The timestamp of the cliff of the lock (0 before this value, >= startTime)
 * @param   endTime The timestamp that the lock ends at, >= cliff
 * @param   allocation The amount of tokens that are locked
 */
struct Lock {
    uint256 startTime;
    uint256 cliff;
    uint256 endTime;
    uint256 allocation;
}

/**
 * @title   LockLib
 * @notice  Library for handling "locks" on assets
 *          A lock is in this case, a curve defining the amount available at any given timestamp.
 *          The particular lock is a linear curve with a cliff.
 */
library LockLib {
    error LockDurationMustBeGTZero();
    error LockDurationMustBeGECliffDuration(uint256 lockDuration, uint256 cliffDuration);

    /**
     * @notice  Check if the lock has ended
     *
     * @param _lock   The lock
     * @param _timestamp   The timestamp to check
     *
     * @return  True if the lock has ended
     */
    function hasEnded(Lock memory _lock, uint256 _timestamp) internal pure returns (bool) {
        return _timestamp >= _lock.endTime;
    }

    /**
     * @notice  Get the unlocked value of the lock at a given timestamp
     *
     * @param _lock   The lock
     * @param _timestamp   The timestamp to get the value at
     *
     * @return  The unlocked value at the given timestamp
     */
    function unlockedAt(Lock memory _lock, uint256 _timestamp) internal pure returns (uint256) {
        if (_timestamp < _lock.cliff) {
            return 0;
        }

        if (_timestamp >= _lock.endTime) {
            return _lock.allocation;
        }

        return (_lock.allocation * (_timestamp - _lock.startTime)) / (_lock.endTime - _lock.startTime);
    }

    /**
     * @notice  Create a lock
     *
     * @dev     The caller should make sure that `_allocation` is not zero
     *
     * @param _params   The lock params
     * @param _allocation   The allocation of the lock
     *
     * @return  The lock
     */
    function createLock(LockParams memory _params, uint256 _allocation) internal pure returns (Lock memory) {
        LockLib.assertValid(_params);
        return Lock({
            startTime: _params.startTime,
            cliff: _params.startTime + _params.cliffDuration,
            endTime: _params.startTime + _params.lockDuration,
            allocation: _allocation
        });
    }

    /**
     * @notice  Assert that the lock params are valid
     *
     * @param _params   The lock params
     */
    function assertValid(LockParams memory _params) internal pure {
        require(_params.lockDuration > 0, LockDurationMustBeGTZero());
        require(
            _params.lockDuration >= _params.cliffDuration,
            LockDurationMustBeGECliffDuration(_params.lockDuration, _params.cliffDuration)
        );
    }

    /**
     * @notice  Check if the lock params are empty
     *
     * @param _params   The lock params
     *
     * @return  True if the lock params are empty
     */
    function isEmpty(LockParams memory _params) internal pure returns (bool) {
        return _params.startTime == 0 && _params.cliffDuration == 0 && _params.lockDuration == 0;
    }

    /**
     * @notice  Get an empty lock params
     *
     * @return  An empty lock params
     */
    function empty() internal pure returns (LockParams memory) {
        return LockParams({startTime: 0, cliffDuration: 0, lockDuration: 0});
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {IERC20} from "@oz/token/ERC20/IERC20.sol";
import {Lock} from "../../libraries/LockLib.sol";
import {IRegistry, StakerVersion} from "../../Registry.sol";
import {IBaseStaker} from "./../../staker/BaseStaker.sol";

enum ATPType {
    Linear,
    Milestone,
    NonClaim
}

interface IATPCore {
    event StakerInitialized(IBaseStaker staker);
    event StakerUpgraded(StakerVersion version);
    event StakerOperatorUpdated(address operator);
    event Claimed(uint256 amount);
    event ApprovedStaker(uint256 allowance);
    event Rescued(address asset, address to, uint256 amount);
    event Revoked(uint256 amount);

    error AlreadyInitialized();
    error InvalidBeneficiary(address beneficiary);
    error NotBeneficiary(address caller, address beneficiary);
    error LockHasEnded();
    error InvalidTokenAddress(address token);
    error InvalidRegistry(address registry);
    error AllocationMustBeGreaterThanZero();
    error InvalidAsset(address asset);
    error ExecutionNotAllowedYet(uint256 timestamp, uint256 executeAllowedAt);
    error NotRevokable();
    error NotRevoker(address caller, address revoker);
    error NoClaimable();
    error LockDurationMustBeGTZero(string variant);
    error InvalidUpgrade();

    function upgradeStaker(StakerVersion _version) external;
    function approveStaker(uint256 _allowance) external;
    function updateStakerOperator(address _operator) external;
    function claim() external returns (uint256);
    function rescueFunds(address _asset, address _to) external;
    function revoke() external returns (uint256);
    function getClaimable() external view returns (uint256);
    function getGlobalLock() external view returns (Lock memory);
    function getBeneficiary() external view returns (address);
    function getOperator() external view returns (address);
}

interface IATPPeriphery {
    function getToken() external view returns (IERC20);
    function getRegistry() external view returns (IRegistry);
    function getExecuteAllowedAt() external view returns (uint256);

    function getClaimed() external view returns (uint256);
    function getRevoker() external view returns (address);
    function getIsRevokable() external view returns (bool);
    function getAllocation() external view returns (uint256);

    function getType() external view returns (ATPType);
    function getStaker() external view returns (IBaseStaker);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {ERC1967Proxy} from "@oz/proxy/ERC1967/ERC1967Proxy.sol";
import {UUPSUpgradeable} from "@oz/proxy/utils/UUPSUpgradeable.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";
import {SafeERC20} from "@oz/token/ERC20/utils/SafeERC20.sol";
import {Math} from "@oz/utils/math/Math.sol";
import {SafeCast} from "@oz/utils/math/SafeCast.sol";
import {LockParams, Lock, LockLib} from "./../../libraries/LockLib.sol";
import {IRegistry, StakerVersion} from "./../../Registry.sol";
import {IBaseStaker} from "./../../staker/BaseStaker.sol";
import {ILATPCore, IATPCore, LATPStorage, RevokableParams} from "./ILATP.sol";

/**
 * @title   Linear Aztec Token Position Core
 * @notice  The core logic of the Linear Aztec Token Position
 * @dev     This contract is abstract and cannot be deployed on its own.
 *          It is meant to be inherited by the `LATP` contract.
 *          MUST be deployed using the `ATPFactory` contract.
 */
abstract contract LATPCore is ILATPCore {
    using SafeCast for uint256;
    using SafeERC20 for IERC20;
    using LockLib for Lock;

    IERC20 internal immutable TOKEN;
    IRegistry internal immutable REGISTRY;

    uint256 internal allocation;
    address internal beneficiary;
    IBaseStaker internal staker;
    address internal operator;

    uint256 internal claimed = 0;

    LATPStorage internal store;

    /**
     * @dev     The caller must be the beneficiary
     */
    modifier onlyBeneficiary() {
        require(msg.sender == beneficiary, NotBeneficiary(msg.sender, beneficiary));
        _;
    }

    /**
     * @dev     Since we are using the `Clones` library to create the LATP's to use
     *          we can't use the constructor to initialize the individual ones, but
     *          we can use it to initialize values that will be shared across all the clones.
     *
     * @param _registry   The registry
     * @param _token             The token
     */
    constructor(IRegistry _registry, IERC20 _token) {
        require(address(_registry) != address(0), InvalidRegistry(address(_registry)));
        require(address(_token) != address(0), InvalidTokenAddress(address(_token)));

        TOKEN = _token;
        REGISTRY = _registry;

        staker = IBaseStaker(address(0xdead));
    }

    /**
     * @notice  Initialize the Aztec Token Position
     *          Creates a `Staker`, sets the `beneficiary` and `allocation`
     *          If the LATP is revokable, it will set the `accumulation` lock as well
     *
     * @dev     If run twice, the `staker` will already be set and this will revert
     *          with the `AlreadyInitialized` error
     *
     * @dev     When done by the `ATPFactory` this will happen in the same transaction as LATP creation
     *
     * @param _beneficiary              The address of the beneficiary
     * @param _allocation               The amount of tokens to allocate to the LATP
     * @param _revokableParams          The parameters for the accumulation lock and revoke beneficiary, if the LATP is revokable
     */
    function initialize(address _beneficiary, uint256 _allocation, RevokableParams memory _revokableParams)
        external
        override(ILATPCore)
    {
        require(address(staker) == address(0), AlreadyInitialized());
        require(_beneficiary != address(0), InvalidBeneficiary(address(0)));
        require(_allocation > 0, AllocationMustBeGreaterThanZero());

        beneficiary = _beneficiary;
        allocation = _allocation;

        staker = createStaker();

        if (_revokableParams.revokeBeneficiary != address(0)) {
            LockLib.assertValid(_revokableParams.lockParams);

            store = LATPStorage({
                isRevokable: true,
                accumulationStartTime: _revokableParams.lockParams.startTime.toUint32(),
                accumulationCliffDuration: _revokableParams.lockParams.cliffDuration.toUint32(),
                accumulationLockDuration: _revokableParams.lockParams.lockDuration.toUint32(),
                revokeBeneficiary: _revokableParams.revokeBeneficiary
            });
        } else {
            // If the LATP is non-revokable, the store will be all 0, so we do not need to set storage
            // We will however check that the lock params are empty, to reduce potential for confusion
            require(LockLib.isEmpty(_revokableParams.lockParams), LockParamsMustBeEmpty());
        }
    }

    /**
     * @notice  Upgrade the staker contract to a new version
     *
     * @param _version The version of the staker to upgrade to
     */
    function upgradeStaker(StakerVersion _version) external override(IATPCore) onlyBeneficiary {
        address impl = REGISTRY.getStakerImplementation(_version);
        UUPSUpgradeable(address(staker)).upgradeToAndCall(impl, "");

        require(staker.getATP() == address(this), InvalidUpgrade());

        emit StakerUpgraded(_version);
    }

    /**
     * @notice  Update the operator of the staker contract
     *
     * @param _operator The address of the new operator
     */
    function updateStakerOperator(address _operator) external override(IATPCore) onlyBeneficiary {
        operator = _operator;
        emit StakerOperatorUpdated(_operator);
    }

    /**
     * @notice  Cancel the accumulation of assets
     *
     * @return  The amount of tokens revoked
     */
    function revoke() external override(IATPCore) returns (uint256) {
        require(store.isRevokable, NotRevokable());

        address revoker = REGISTRY.getRevoker();
        require(msg.sender == revoker, NotRevoker(msg.sender, revoker));

        Lock memory accumulationLock = getAccumulationLock();
        require(!accumulationLock.hasEnded(block.timestamp), LockHasEnded());

        uint256 debt = getRevokableAmount();

        store.isRevokable = false;

        TOKEN.safeTransfer(store.revokeBeneficiary, debt);

        emit Revoked(debt);
        return debt;
    }

    /**
     * @notice  Rescue funds that have been sent to the contract by mistake
     *          Allows the beneficiary to transfer funds that are not unlock token from the contract.
     *
     * @param _asset  The asset to rescue
     * @param _to     The address to send the assets to
     */
    function rescueFunds(address _asset, address _to) external override(IATPCore) onlyBeneficiary {
        require(_asset != address(TOKEN), InvalidAsset(_asset));
        IERC20 asset = IERC20(_asset);
        uint256 amount = asset.balanceOf(address(this));
        asset.safeTransfer(_to, amount);

        emit Rescued(_asset, _to, amount);
    }

    /**
     * @notice  Authorizes the staker contract for the specified amount.
     *
     * @param _allowance The amount of tokens to authorize the staker contract for
     */
    function approveStaker(uint256 _allowance) external override(IATPCore) onlyBeneficiary {
        // slither-disable-start block-timestamp
        // As we are not relying on block.timestamp for randomness but merely for when we will toggle
        // the EXECUTE_ALLOWED_AT flag, and time will only ever increase, we can safely ignore the warning.
        uint256 executeAllowedAt = REGISTRY.getExecuteAllowedAt();
        require(block.timestamp >= executeAllowedAt, ExecutionNotAllowedYet(block.timestamp, executeAllowedAt));
        // slither-disable-end block-timestamp

        uint256 stakeable = getStakeableAmount();
        require(stakeable >= _allowance, InsufficientStakeable(stakeable, _allowance));

        TOKEN.approve(address(staker), _allowance);

        emit ApprovedStaker(_allowance);
    }

    /**
     * @notice  Claim the amount of tokens that are available for the owner to claim.
     *
     * @dev     The `caller` must be the `beneficiary`
     *
     * @return  The amount of tokens claimed
     */
    function claim() external virtual override(IATPCore) onlyBeneficiary returns (uint256) {
        uint256 amount = getClaimable();
        require(amount > 0, NoClaimable());

        claimed += amount;

        TOKEN.safeTransfer(msg.sender, amount);

        // @note After the transfer, we need to ensure that the allowance is not too high.
        // Namely, if the allowance is larger than the stakeable amount it should be reduced.
        uint256 stakeable = getStakeableAmount();
        uint256 allowance = TOKEN.allowance(address(this), address(staker));
        if (stakeable < allowance) {
            TOKEN.approve(address(staker), stakeable);
        }

        emit Claimed(amount);
        return amount;
    }

    function getOperator() public view override(IATPCore) returns (address) {
        return operator;
    }

    function getBeneficiary() public view override(IATPCore) returns (address) {
        return beneficiary;
    }

    /**
     * @notice Compute the amount of tokens that can be claimed.
     *
     * @return  The amount of tokens that can be claimed
     */
    function getClaimable() public view override(IATPCore) returns (uint256) {
        Lock memory globalLock = getGlobalLock();
        uint256 unlocked = globalLock.hasEnded(block.timestamp)
            ? type(uint256).max
            : (globalLock.unlockedAt(block.timestamp) - claimed);

        return Math.min(TOKEN.balanceOf(address(this)) - getRevokableAmount(), unlocked);
    }

    /**
     * @notice  Get the global unlock schedule lock
     *
     * @return  The global lock
     */
    function getGlobalLock() public view override(IATPCore) returns (Lock memory) {
        return LockLib.createLock(REGISTRY.getGlobalLockParams(), allocation);
    }

    /**
     * @notice  Get the accumulation lock
     *
     * @return  The accumulation lock or empty if not revokable
     */
    function getAccumulationLock() public view override(ILATPCore) returns (Lock memory) {
        require(store.isRevokable, NotRevokable());
        return LockLib.createLock(
            LockParams({
                startTime: store.accumulationStartTime,
                cliffDuration: store.accumulationCliffDuration,
                lockDuration: store.accumulationLockDuration
            }),
            allocation
        );
    }

    /**
     * @notice  Get the amount of tokens that can be revoked
     *
     * @return  The amount of tokens that can be revoked
     */
    function getRevokableAmount() public view override(ILATPCore) returns (uint256) {
        if (!store.isRevokable) {
            return 0;
        }
        return allocation - getAccumulationLock().unlockedAt(block.timestamp);
    }

    /**
     * @notice  Get the amount of tokens that can be staked
     *
     * @return  The amount of tokens that can be staked
     */
    function getStakeableAmount() public view override(ILATPCore) returns (uint256) {
        if (!store.isRevokable) {
            return type(uint256).max;
        }
        return TOKEN.balanceOf(address(this)) - getRevokableAmount();
    }

    /**
     * @notice  Create a new staker contract with the `ERC1967Proxy`
     *          the initial implementation used will the be `BaseStaker`
     *
     * @return  The new staker contract
     */
    function createStaker() private returns (IBaseStaker) {
        address impl = REGISTRY.getStakerImplementation(StakerVersion.wrap(0));
        ERC1967Proxy proxy = new ERC1967Proxy(impl, abi.encodeCall(IBaseStaker.initialize, address(this)));
        IBaseStaker _staker = IBaseStaker(address(proxy));
        emit StakerInitialized(_staker);
        return _staker;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {ERC1967Proxy} from "@oz/proxy/ERC1967/ERC1967Proxy.sol";
import {UUPSUpgradeable} from "@oz/proxy/utils/UUPSUpgradeable.sol";
import {IERC20} from "@oz/token/ERC20/IERC20.sol";
import {SafeERC20} from "@oz/token/ERC20/utils/SafeERC20.sol";
import {Math} from "@oz/utils/math/Math.sol";
import {SafeCast} from "@oz/utils/math/SafeCast.sol";
import {Lock, LockLib} from "./../../libraries/LockLib.sol";
import {IRegistry, StakerVersion, MilestoneId, MilestoneStatus} from "./../../Registry.sol";
import {IBaseStaker} from "./../../staker/BaseStaker.sol";
import {IMATPCore, IATPCore} from "./IMATP.sol";

/**
 * @title   Milestone Aztec Token Position Core
 * @notice  The core logic of the Milestone Aztec Token Position
 * @dev     This contract is abstract and cannot be deployed on its own.
 *          It is meant to be inherited by the `MATP` contract.
 *          MUST be deployed using the `ATPFactory` contract.
 */
abstract contract MATPCore is IMATPCore {
    using SafeCast for uint256;
    using SafeERC20 for IERC20;
    using LockLib for Lock;

    IERC20 internal immutable TOKEN;
    IRegistry internal immutable REGISTRY;

    uint256 internal allocation;

    // 160 + 96 = 256
    address internal beneficiary;
    MilestoneId internal milestoneId;

    IBaseStaker internal staker;
    address internal operator;

    uint256 internal claimed = 0;
    bool internal isRevoked = false;

    /**
     * @dev     The caller must be the beneficiary, or if the milestone have failed it must be the revoker
     */
    modifier onlyBeneficiary() {
        address _beneficiary = getBeneficiary();
        require(msg.sender == _beneficiary, NotBeneficiary(msg.sender, _beneficiary));
        _;
    }

    /**
     * @dev     Since we are using the `Clones` library to create the ATP's to use
     *          we can't use the constructor to initialize the individual ones, but
     *          we can use it to initialize values that will be shared across all the clones.
     *
     * @param _registry   The registry
     * @param _token      The token
     */
    constructor(IRegistry _registry, IERC20 _token) {
        require(address(_registry) != address(0), InvalidRegistry(address(_registry)));
        require(address(_token) != address(0), InvalidTokenAddress(address(_token)));

        TOKEN = _token;
        REGISTRY = _registry;

        staker = IBaseStaker(address(0xdead));
    }

    /**
     * @notice  Initialize the Aztec Token Position
     *          Creates a `Staker`, sets the `beneficiary` and `allocation`
     *          If the ATP is revokable, it will set the `accumulation` lock as well
     *
     * @dev     If run twice, the `staker` will already be set and this will revert
     *          with the `AlreadyInitialized` error
     *
     * @dev     When done by the `ATPFactory` this will happen in the same transaction as ATP creation
     *
     * @param _beneficiary              The address of the beneficiary
     * @param _allocation               The amount of tokens to allocate to the ATP
     * @param _milestoneId              The milestone id
     */
    function initialize(address _beneficiary, uint256 _allocation, MilestoneId _milestoneId)
        external
        override(IMATPCore)
    {
        require(address(staker) == address(0), AlreadyInitialized());
        require(_beneficiary != address(0), InvalidBeneficiary(address(0)));
        require(_allocation > 0, AllocationMustBeGreaterThanZero());

        require(
            REGISTRY.getMilestoneStatus(_milestoneId) == MilestoneStatus.Pending,
            IRegistry.InvalidMilestoneStatus(_milestoneId)
        );

        beneficiary = _beneficiary;
        milestoneId = _milestoneId;
        allocation = _allocation;
        staker = createStaker();
    }

    /**
     * @notice  Upgrade the staker contract to a new version
     *
     * @param _version The version of the staker to upgrade to
     */
    function upgradeStaker(StakerVersion _version) external override(IATPCore) onlyBeneficiary {
        address impl = REGISTRY.getStakerImplementation(_version);
        UUPSUpgradeable(address(staker)).upgradeToAndCall(impl, "");

        require(staker.getATP() == address(this), InvalidUpgrade());

        emit StakerUpgraded(_version);
    }

    /**
     * @notice  Cancel the accumulation of assets
     *
     * @return  The amount of tokens revoked
     */
    function revoke() external override(IATPCore) returns (uint256) {
        require(!isRevoked, NotRevokable());
        require(REGISTRY.getMilestoneStatus(milestoneId) == MilestoneStatus.Pending, NotRevokable());
        address revoker = REGISTRY.getRevoker();
        require(msg.sender == revoker, NotRevoker(msg.sender, revoker));

        isRevoked = true;

        emit Revoked(allocation);

        return allocation;
    }

    /**
     * @notice  Rescue funds that have been sent to the contract by mistake
     *          Allows the beneficiary to transfer funds that are not unlock token from the contract.
     *
     * @param _asset  The asset to rescue
     * @param _to     The address to send the assets to
     */
    function rescueFunds(address _asset, address _to) external override(IATPCore) {
        require(_asset != address(TOKEN), InvalidAsset(_asset));
        require(msg.sender == beneficiary, NotBeneficiary(msg.sender, beneficiary));
        IERC20 asset = IERC20(_asset);
        uint256 amount = asset.balanceOf(address(this));
        asset.safeTransfer(_to, amount);

        emit Rescued(_asset, _to, amount);
    }

    /**
     * @notice  Authorizes the staker contract for the specified amount.
     *
     * @param _allowance The amount of tokens to authorize the staker contract for
     */
    function approveStaker(uint256 _allowance) external override(IATPCore) onlyBeneficiary {
        // slither-disable-start block-timestamp
        // As we are not relying on block.timestamp for randomness but merely for when we will toggle
        // the EXECUTE_ALLOWED_AT flag, and time will only ever increase, we can safely ignore the warning.
        uint256 executeAllowedAt = REGISTRY.getExecuteAllowedAt();
        require(block.timestamp >= executeAllowedAt, ExecutionNotAllowedYet(block.timestamp, executeAllowedAt));
        // slither-disable-end block-timestamp

        TOKEN.approve(address(staker), _allowance);

        emit ApprovedStaker(_allowance);
    }

    /**
     * @notice  Claim the amount of tokens that are available for the owner to claim.
     *
     * @dev     The `caller` must be the `beneficiary`
     *
     * @return  The amount of tokens claimed
     */
    function claim() external override(IATPCore) onlyBeneficiary returns (uint256) {
        uint256 amount = getClaimable();
        require(amount > 0, NoClaimable());

        claimed += amount;

        TOKEN.safeTransfer(msg.sender, amount);

        emit Claimed(amount);
        return amount;
    }

    /**
     * @notice  Update the operator of the staker contract
     *
     * @param _operator The address of the new operator
     */
    function updateStakerOperator(address _operator) public override(IATPCore) onlyBeneficiary {
        require(!isRevoked && REGISTRY.getMilestoneStatus(milestoneId) != MilestoneStatus.Failed, RevokedOrFailed());

        operator = _operator;
        emit StakerOperatorUpdated(_operator);
    }

    /**
     * @notice Compute the amount of tokens that can be claimed.
     *
     * @return  The amount of tokens that can be claimed
     */
    function getClaimable() public view override(IATPCore) returns (uint256) {
        MilestoneStatus status = REGISTRY.getMilestoneStatus(milestoneId);
        if (isRevoked || status == MilestoneStatus.Failed) {
            // When revoked or milestone failed, the lock is ignored as it is the revoker
            // claiming, and it should be able to bypass these
            return TOKEN.balanceOf(address(this));
        }
        if (status != MilestoneStatus.Succeeded) {
            return 0;
        }

        Lock memory globalLock = getGlobalLock();
        uint256 unlocked = globalLock.hasEnded(block.timestamp)
            ? type(uint256).max
            : (globalLock.unlockedAt(block.timestamp) - claimed);

        return Math.min(TOKEN.balanceOf(address(this)), unlocked);
    }

    /**
     * @notice  Get the global unlock schedule lock
     *
     * @return  The global lock
     */
    function getGlobalLock() public view override(IATPCore) returns (Lock memory) {
        return LockLib.createLock(REGISTRY.getGlobalLockParams(), allocation);
    }

    /**
     * @notice  Get the beneficiary of the ATP
     *          If the milestone has failed or ATP was revoked, the beneficiary is the revoker
     *
     * @return  The beneficiary
     */
    function getBeneficiary() public view override(IATPCore) returns (address) {
        if (isRevoked || REGISTRY.getMilestoneStatus(milestoneId) == MilestoneStatus.Failed) {
            return REGISTRY.getRevoker();
        }
        return beneficiary;
    }

    /**
     * @notice  Get the operator of the staker contract
     *          If the milestone has failed or ATP was revoked, the operator is the revoker operator
     *
     * @return  The operator
     */
    function getOperator() public view override(IATPCore) returns (address) {
        if (isRevoked || REGISTRY.getMilestoneStatus(milestoneId) == MilestoneStatus.Failed) {
            return REGISTRY.getRevokerOperator();
        }
        return operator;
    }

    /**
     * @notice  Create a new staker contract with the `ERC1967Proxy`
     *          the initial implementation used will the be `BaseStaker`
     *
     * @return  The new staker contract
     */
    function createStaker() private returns (IBaseStaker) {
        address impl = REGISTRY.getStakerImplementation(StakerVersion.wrap(0));
        ERC1967Proxy proxy = new ERC1967Proxy(impl, abi.encodeCall(IBaseStaker.initialize, address(this)));
        IBaseStaker _staker = IBaseStaker(address(proxy));
        emit StakerInitialized(_staker);
        return _staker;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (proxy/utils/UUPSUpgradeable.sol)

pragma solidity ^0.8.22;

import {IERC1822Proxiable} from "../../interfaces/draft-IERC1822.sol";
import {ERC1967Utils} from "../ERC1967/ERC1967Utils.sol";

/**
 * @dev An upgradeability mechanism designed for UUPS proxies. The functions included here can perform an upgrade of an
 * {ERC1967Proxy}, when this contract is set as the implementation behind such a proxy.
 *
 * A security mechanism ensures that an upgrade does not turn off upgradeability accidentally, although this risk is
 * reinstated if the upgrade retains upgradeability but removes the security mechanism, e.g. by replacing
 * `UUPSUpgradeable` with a custom implementation of upgrades.
 *
 * The {_authorizeUpgrade} function must be overridden to include access restriction to the upgrade mechanism.
 */
abstract contract UUPSUpgradeable is IERC1822Proxiable {
    /// @custom:oz-upgrades-unsafe-allow state-variable-immutable
    address private immutable __self = address(this);

    /**
     * @dev The version of the upgrade interface of the contract. If this getter is missing, both `upgradeTo(address)`
     * and `upgradeToAndCall(address,bytes)` are present, and `upgradeTo` must be used if no function should be called,
     * while `upgradeToAndCall` will invoke the `receive` function if the second argument is the empty byte string.
     * If the getter returns `"5.0.0"`, only `upgradeToAndCall(address,bytes)` is present, and the second argument must
     * be the empty byte string if no function should be called, making it impossible to invoke the `receive` function
     * during an upgrade.
     */
    string public constant UPGRADE_INTERFACE_VERSION = "5.0.0";

    /**
     * @dev The call is from an unauthorized context.
     */
    error UUPSUnauthorizedCallContext();

    /**
     * @dev The storage `slot` is unsupported as a UUID.
     */
    error UUPSUnsupportedProxiableUUID(bytes32 slot);

    /**
     * @dev Check that the execution is being performed through a delegatecall call and that the execution context is
     * a proxy contract with an implementation (as defined in ERC-1967) pointing to self. This should only be the case
     * for UUPS and transparent proxies that are using the current contract as their implementation. Execution of a
     * function through ERC-1167 minimal proxies (clones) would not normally pass this test, but is not guaranteed to
     * fail.
     */
    modifier onlyProxy() {
        _checkProxy();
        _;
    }

    /**
     * @dev Check that the execution is not being performed through a delegate call. This allows a function to be
     * callable on the implementing contract but not through proxies.
     */
    modifier notDelegated() {
        _checkNotDelegated();
        _;
    }

    /**
     * @dev Implementation of the ERC-1822 {proxiableUUID} function. This returns the storage slot used by the
     * implementation. It is used to validate the implementation's compatibility when performing an upgrade.
     *
     * IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
     * bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
     * function revert if invoked through a proxy. This is guaranteed by the `notDelegated` modifier.
     */
    function proxiableUUID() external view virtual notDelegated returns (bytes32) {
        return ERC1967Utils.IMPLEMENTATION_SLOT;
    }

    /**
     * @dev Upgrade the implementation of the proxy to `newImplementation`, and subsequently execute the function call
     * encoded in `data`.
     *
     * Calls {_authorizeUpgrade}.
     *
     * Emits an {Upgraded} event.
     *
     * @custom:oz-upgrades-unsafe-allow-reachable delegatecall
     */
    function upgradeToAndCall(address newImplementation, bytes memory data) public payable virtual onlyProxy {
        _authorizeUpgrade(newImplementation);
        _upgradeToAndCallUUPS(newImplementation, data);
    }

    /**
     * @dev Reverts if the execution is not performed via delegatecall or the execution
     * context is not of a proxy with an ERC-1967 compliant implementation pointing to self.
     */
    function _checkProxy() internal view virtual {
        if (
            address(this) == __self || // Must be called through delegatecall
            ERC1967Utils.getImplementation() != __self // Must be called through an active proxy
        ) {
            revert UUPSUnauthorizedCallContext();
        }
    }

    /**
     * @dev Reverts if the execution is performed via delegatecall.
     * See {notDelegated}.
     */
    function _checkNotDelegated() internal view virtual {
        if (address(this) != __self) {
            // Must not be called through delegatecall
            revert UUPSUnauthorizedCallContext();
        }
    }

    /**
     * @dev Function that should revert when `msg.sender` is not authorized to upgrade the contract. Called by
     * {upgradeToAndCall}.
     *
     * Normally, this function will use an xref:access.adoc[access control] modifier such as {Ownable-onlyOwner}.
     *
     * ```solidity
     * function _authorizeUpgrade(address) internal onlyOwner {}
     * ```
     */
    function _authorizeUpgrade(address newImplementation) internal virtual;

    /**
     * @dev Performs an implementation upgrade with a security check for UUPS proxies, and additional setup call.
     *
     * As a security check, {proxiableUUID} is invoked in the new implementation, and the return value
     * is expected to be the implementation slot in ERC-1967.
     *
     * Emits an {IERC1967-Upgraded} event.
     */
    function _upgradeToAndCallUUPS(address newImplementation, bytes memory data) private {
        try IERC1822Proxiable(newImplementation).proxiableUUID() returns (bytes32 slot) {
            if (slot != ERC1967Utils.IMPLEMENTATION_SLOT) {
                revert UUPSUnsupportedProxiableUUID(slot);
            }
            ERC1967Utils.upgradeToAndCall(newImplementation, data);
        } catch {
            // The implementation is not UUPS
            revert ERC1967Utils.ERC1967InvalidImplementation(newImplementation);
        }
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.27;

import {ERC1967Utils} from "@oz/proxy/ERC1967/ERC1967Utils.sol";
import {UUPSUpgradeable} from "@oz/proxy/utils/UUPSUpgradeable.sol";
import {IATPCore} from "../atps/base/IATP.sol";

interface IBaseStaker {
    function initialize(address _atp) external;

    function getATP() external view returns (address);
    function getOperator() external view returns (address);
    function getImplementation() external view returns (address);
}

contract BaseStaker is IBaseStaker, UUPSUpgradeable {
    address internal atp;

    error AlreadyInitialized();
    error ZeroATP();
    error NotATP(address caller, address atp);
    error NotOperator(address caller, address operator);
    error UnSupportedOperation();

    modifier onlyOperator() {
        address operator = getOperator();
        require(msg.sender == operator, NotOperator(msg.sender, operator));
        _;
    }

    modifier onlyATP() {
        require(msg.sender == address(atp), NotATP(msg.sender, address(atp)));
        _;
    }

    constructor() {
        atp = address(0xdead);
    }

    function initialize(address _atp) external virtual override(IBaseStaker) {
        require(address(_atp) != address(0), ZeroATP());
        require(address(atp) == address(0), AlreadyInitialized());

        atp = _atp;
    }

    function getImplementation() external view virtual override(IBaseStaker) returns (address) {
        return ERC1967Utils.getImplementation();
    }

    function getATP() public view virtual override(IBaseStaker) returns (address) {
        return atp;
    }

    function getOperator() public view virtual override(IBaseStaker) returns (address) {
        return IATPCore(atp).getOperator();
    }

    function _authorizeUpgrade(address _newImplementation) internal virtual override(UUPSUpgradeable) onlyATP {}
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (proxy/ERC1967/ERC1967Proxy.sol)

pragma solidity ^0.8.22;

import {Proxy} from "../Proxy.sol";
import {ERC1967Utils} from "./ERC1967Utils.sol";

/**
 * @dev This contract implements an upgradeable proxy. It is upgradeable because calls are delegated to an
 * implementation address that can be changed. This address is stored in storage in the location specified by
 * https://eips.ethereum.org/EIPS/eip-1967[ERC-1967], so that it doesn't conflict with the storage layout of the
 * implementation behind the proxy.
 */
contract ERC1967Proxy is Proxy {
    /**
     * @dev Initializes the upgradeable proxy with an initial implementation specified by `implementation`.
     *
     * If `_data` is nonempty, it's used as data in a delegate call to `implementation`. This will typically be an
     * encoded function call, and allows initializing the storage of the proxy like a Solidity constructor.
     *
     * Requirements:
     *
     * - If `data` is empty, `msg.value` must be zero.
     */
    constructor(address implementation, bytes memory _data) payable {
        ERC1967Utils.upgradeToAndCall(implementation, _data);
    }

    /**
     * @dev Returns the current implementation address.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by ERC-1967) using
     * the https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc`
     */
    function _implementation() internal view virtual override returns (address) {
        return ERC1967Utils.getImplementation();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

import {Panic} from "../Panic.sol";
import {SafeCast} from "./SafeCast.sol";

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Return the 512-bit addition of two uint256.
     *
     * The result is stored in two 256 variables such that sum = high * 2²⁵⁶ + low.
     */
    function add512(uint256 a, uint256 b) internal pure returns (uint256 high, uint256 low) {
        assembly ("memory-safe") {
            low := add(a, b)
            high := lt(low, a)
        }
    }

    /**
     * @dev Return the 512-bit multiplication of two uint256.
     *
     * The result is stored in two 256 variables such that product = high * 2²⁵⁶ + low.
     */
    function mul512(uint256 a, uint256 b) internal pure returns (uint256 high, uint256 low) {
        // 512-bit multiply [high low] = x * y. Compute the product mod 2²⁵⁶ and mod 2²⁵⁶ - 1, then use
        // the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
        // variables such that product = high * 2²⁵⁶ + low.
        assembly ("memory-safe") {
            let mm := mulmod(a, b, not(0))
            low := mul(a, b)
            high := sub(sub(mm, low), lt(mm, low))
        }
    }

    /**
     * @dev Returns the addition of two unsigned integers, with a success flag (no overflow).
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool success, uint256 result) {
        unchecked {
            uint256 c = a + b;
            success = c >= a;
            result = c * SafeCast.toUint(success);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with a success flag (no overflow).
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool success, uint256 result) {
        unchecked {
            uint256 c = a - b;
            success = c <= a;
            result = c * SafeCast.toUint(success);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with a success flag (no overflow).
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool success, uint256 result) {
        unchecked {
            uint256 c = a * b;
            assembly ("memory-safe") {
                // Only true when the multiplication doesn't overflow
                // (c / a == b) || (a == 0)
                success := or(eq(div(c, a), b), iszero(a))
            }
            // equivalent to: success ? c : 0
            result = c * SafeCast.toUint(success);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a success flag (no division by zero).
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool success, uint256 result) {
        unchecked {
            success = b > 0;
            assembly ("memory-safe") {
                // The `DIV` opcode returns zero when the denominator is 0.
                result := div(a, b)
            }
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a success flag (no division by zero).
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool success, uint256 result) {
        unchecked {
            success = b > 0;
            assembly ("memory-safe") {
                // The `MOD` opcode returns zero when the denominator is 0.
                result := mod(a, b)
            }
        }
    }

    /**
     * @dev Unsigned saturating addition, bounds to `2²⁵⁶ - 1` instead of overflowing.
     */
    function saturatingAdd(uint256 a, uint256 b) internal pure returns (uint256) {
        (bool success, uint256 result) = tryAdd(a, b);
        return ternary(success, result, type(uint256).max);
    }

    /**
     * @dev Unsigned saturating subtraction, bounds to zero instead of overflowing.
     */
    function saturatingSub(uint256 a, uint256 b) internal pure returns (uint256) {
        (, uint256 result) = trySub(a, b);
        return result;
    }

    /**
     * @dev Unsigned saturating multiplication, bounds to `2²⁵⁶ - 1` instead of overflowing.
     */
    function saturatingMul(uint256 a, uint256 b) internal pure returns (uint256) {
        (bool success, uint256 result) = tryMul(a, b);
        return ternary(success, result, type(uint256).max);
    }

    /**
     * @dev Branchless ternary evaluation for `a ? b : c`. Gas costs are constant.
     *
     * IMPORTANT: This function may reduce bytecode size and consume less gas when used standalone.
     * However, the compiler may optimize Solidity ternary operations (i.e. `a ? b : c`) to only compute
     * one branch when needed, making this function more expensive.
     */
    function ternary(bool condition, uint256 a, uint256 b) internal pure returns (uint256) {
        unchecked {
            // branchless ternary works because:
            // b ^ (a ^ b) == a
            // b ^ 0 == b
            return b ^ ((a ^ b) * SafeCast.toUint(condition));
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return ternary(a > b, a, b);
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return ternary(a < b, a, b);
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            Panic.panic(Panic.DIVISION_BY_ZERO);
        }

        // The following calculation ensures accurate ceiling division without overflow.
        // Since a is non-zero, (a - 1) / b will not overflow.
        // The largest possible result occurs when (a - 1) / b is type(uint256).max,
        // but the largest value we can obtain is type(uint256).max - 1, which happens
        // when a = type(uint256).max and b = 1.
        unchecked {
            return SafeCast.toUint(a > 0) * ((a - 1) / b + 1);
        }
    }

    /**
     * @dev Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     *
     * Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            (uint256 high, uint256 low) = mul512(x, y);

            // Handle non-overflow cases, 256 by 256 division.
            if (high == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return low / denominator;
            }

            // Make sure the result is less than 2²⁵⁶. Also prevents denominator == 0.
            if (denominator <= high) {
                Panic.panic(ternary(denominator == 0, Panic.DIVISION_BY_ZERO, Panic.UNDER_OVERFLOW));
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [high low].
            uint256 remainder;
            assembly ("memory-safe") {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                high := sub(high, gt(remainder, low))
                low := sub(low, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly ("memory-safe") {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [high low] by twos.
                low := div(low, twos)

                // Flip twos such that it is 2²⁵⁶ / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from high into low.
            low |= high * twos;

            // Invert denominator mod 2²⁵⁶. Now that denominator is an odd number, it has an inverse modulo 2²⁵⁶ such
            // that denominator * inv ≡ 1 mod 2²⁵⁶. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv ≡ 1 mod 2⁴.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2⁸
            inverse *= 2 - denominator * inverse; // inverse mod 2¹⁶
            inverse *= 2 - denominator * inverse; // inverse mod 2³²
            inverse *= 2 - denominator * inverse; // inverse mod 2⁶⁴
            inverse *= 2 - denominator * inverse; // inverse mod 2¹²⁸
            inverse *= 2 - denominator * inverse; // inverse mod 2²⁵⁶

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2²⁵⁶. Since the preconditions guarantee that the outcome is
            // less than 2²⁵⁶, this is the final result. We don't need to compute the high bits of the result and high
            // is no longer required.
            result = low * inverse;
            return result;
        }
    }

    /**
     * @dev Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        return mulDiv(x, y, denominator) + SafeCast.toUint(unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0);
    }

    /**
     * @dev Calculates floor(x * y >> n) with full precision. Throws if result overflows a uint256.
     */
    function mulShr(uint256 x, uint256 y, uint8 n) internal pure returns (uint256 result) {
        unchecked {
            (uint256 high, uint256 low) = mul512(x, y);
            if (high >= 1 << n) {
                Panic.panic(Panic.UNDER_OVERFLOW);
            }
            return (high << (256 - n)) | (low >> n);
        }
    }

    /**
     * @dev Calculates x * y >> n with full precision, following the selected rounding direction.
     */
    function mulShr(uint256 x, uint256 y, uint8 n, Rounding rounding) internal pure returns (uint256) {
        return mulShr(x, y, n) + SafeCast.toUint(unsignedRoundsUp(rounding) && mulmod(x, y, 1 << n) > 0);
    }

    /**
     * @dev Calculate the modular multiplicative inverse of a number in Z/nZ.
     *
     * If n is a prime, then Z/nZ is a field. In that case all elements are inversible, except 0.
     * If n is not a prime, then Z/nZ is not a field, and some elements might not be inversible.
     *
     * If the input value is not inversible, 0 is returned.
     *
     * NOTE: If you know for sure that n is (big) a prime, it may be cheaper to use Fermat's little theorem and get the
     * inverse using `Math.modExp(a, n - 2, n)`. See {invModPrime}.
     */
    function invMod(uint256 a, uint256 n) internal pure returns (uint256) {
        unchecked {
            if (n == 0) return 0;

            // The inverse modulo is calculated using the Extended Euclidean Algorithm (iterative version)
            // Used to compute integers x and y such that: ax + ny = gcd(a, n).
            // When the gcd is 1, then the inverse of a modulo n exists and it's x.
            // ax + ny = 1
            // ax = 1 + (-y)n
            // ax ≡ 1 (mod n) # x is the inverse of a modulo n

            // If the remainder is 0 the gcd is n right away.
            uint256 remainder = a % n;
            uint256 gcd = n;

            // Therefore the initial coefficients are:
            // ax + ny = gcd(a, n) = n
            // 0a + 1n = n
            int256 x = 0;
            int256 y = 1;

            while (remainder != 0) {
                uint256 quotient = gcd / remainder;

                (gcd, remainder) = (
                    // The old remainder is the next gcd to try.
                    remainder,
                    // Compute the next remainder.
                    // Can't overflow given that (a % gcd) * (gcd // (a % gcd)) <= gcd
                    // where gcd is at most n (capped to type(uint256).max)
                    gcd - remainder * quotient
                );

                (x, y) = (
                    // Increment the coefficient of a.
                    y,
                    // Decrement the coefficient of n.
                    // Can overflow, but the result is casted to uint256 so that the
                    // next value of y is "wrapped around" to a value between 0 and n - 1.
                    x - y * int256(quotient)
                );
            }

            if (gcd != 1) return 0; // No inverse exists.
            return ternary(x < 0, n - uint256(-x), uint256(x)); // Wrap the result if it's negative.
        }
    }

    /**
     * @dev Variant of {invMod}. More efficient, but only works if `p` is known to be a prime greater than `2`.
     *
     * From https://en.wikipedia.org/wiki/Fermat%27s_little_theorem[Fermat's little theorem], we know that if p is
     * prime, then `a**(p-1) ≡ 1 mod p`. As a consequence, we have `a * a**(p-2) ≡ 1 mod p`, which means that
     * `a**(p-2)` is the modular multiplicative inverse of a in Fp.
     *
     * NOTE: this function does NOT check that `p` is a prime greater than `2`.
     */
    function invModPrime(uint256 a, uint256 p) internal view returns (uint256) {
        unchecked {
            return Math.modExp(a, p - 2, p);
        }
    }

    /**
     * @dev Returns the modular exponentiation of the specified base, exponent and modulus (b ** e % m)
     *
     * Requirements:
     * - modulus can't be zero
     * - underlying staticcall to precompile must succeed
     *
     * IMPORTANT: The result is only valid if the underlying call succeeds. When using this function, make
     * sure the chain you're using it on supports the precompiled contract for modular exponentiation
     * at address 0x05 as specified in https://eips.ethereum.org/EIPS/eip-198[EIP-198]. Otherwise,
     * the underlying function will succeed given the lack of a revert, but the result may be incorrectly
     * interpreted as 0.
     */
    function modExp(uint256 b, uint256 e, uint256 m) internal view returns (uint256) {
        (bool success, uint256 result) = tryModExp(b, e, m);
        if (!success) {
            Panic.panic(Panic.DIVISION_BY_ZERO);
        }
        return result;
    }

    /**
     * @dev Returns the modular exponentiation of the specified base, exponent and modulus (b ** e % m).
     * It includes a success flag indicating if the operation succeeded. Operation will be marked as failed if trying
     * to operate modulo 0 or if the underlying precompile reverted.
     *
     * IMPORTANT: The result is only valid if the success flag is true. When using this function, make sure the chain
     * you're using it on supports the precompiled contract for modular exponentiation at address 0x05 as specified in
     * https://eips.ethereum.org/EIPS/eip-198[EIP-198]. Otherwise, the underlying function will succeed given the lack
     * of a revert, but the result may be incorrectly interpreted as 0.
     */
    function tryModExp(uint256 b, uint256 e, uint256 m) internal view returns (bool success, uint256 result) {
        if (m == 0) return (false, 0);
        assembly ("memory-safe") {
            let ptr := mload(0x40)
            // | Offset    | Content    | Content (Hex)                                                      |
            // |-----------|------------|--------------------------------------------------------------------|
            // | 0x00:0x1f | size of b  | 0x0000000000000000000000000000000000000000000000000000000000000020 |
            // | 0x20:0x3f | size of e  | 0x0000000000000000000000000000000000000000000000000000000000000020 |
            // | 0x40:0x5f | size of m  | 0x0000000000000000000000000000000000000000000000000000000000000020 |
            // | 0x60:0x7f | value of b | 0x<.............................................................b> |
            // | 0x80:0x9f | value of e | 0x<.............................................................e> |
            // | 0xa0:0xbf | value of m | 0x<.............................................................m> |
            mstore(ptr, 0x20)
            mstore(add(ptr, 0x20), 0x20)
            mstore(add(ptr, 0x40), 0x20)
            mstore(add(ptr, 0x60), b)
            mstore(add(ptr, 0x80), e)
            mstore(add(ptr, 0xa0), m)

            // Given the result < m, it's guaranteed to fit in 32 bytes,
            // so we can use the memory scratch space located at offset 0.
            success := staticcall(gas(), 0x05, ptr, 0xc0, 0x00, 0x20)
            result := mload(0x00)
        }
    }

    /**
     * @dev Variant of {modExp} that supports inputs of arbitrary length.
     */
    function modExp(bytes memory b, bytes memory e, bytes memory m) internal view returns (bytes memory) {
        (bool success, bytes memory result) = tryModExp(b, e, m);
        if (!success) {
            Panic.panic(Panic.DIVISION_BY_ZERO);
        }
        return result;
    }

    /**
     * @dev Variant of {tryModExp} that supports inputs of arbitrary length.
     */
    function tryModExp(
        bytes memory b,
        bytes memory e,
        bytes memory m
    ) internal view returns (bool success, bytes memory result) {
        if (_zeroBytes(m)) return (false, new bytes(0));

        uint256 mLen = m.length;

        // Encode call args in result and move the free memory pointer
        result = abi.encodePacked(b.length, e.length, mLen, b, e, m);

        assembly ("memory-safe") {
            let dataPtr := add(result, 0x20)
            // Write result on top of args to avoid allocating extra memory.
            success := staticcall(gas(), 0x05, dataPtr, mload(result), dataPtr, mLen)
            // Overwrite the length.
            // result.length > returndatasize() is guaranteed because returndatasize() == m.length
            mstore(result, mLen)
            // Set the memory pointer after the returned data.
            mstore(0x40, add(dataPtr, mLen))
        }
    }

    /**
     * @dev Returns whether the provided byte array is zero.
     */
    function _zeroBytes(bytes memory byteArray) private pure returns (bool) {
        for (uint256 i = 0; i < byteArray.length; ++i) {
            if (byteArray[i] != 0) {
                return false;
            }
        }
        return true;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * This method is based on Newton's method for computing square roots; the algorithm is restricted to only
     * using integer operations.
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        unchecked {
            // Take care of easy edge cases when a == 0 or a == 1
            if (a <= 1) {
                return a;
            }

            // In this function, we use Newton's method to get a root of `f(x) := x² - a`. It involves building a
            // sequence x_n that converges toward sqrt(a). For each iteration x_n, we also define the error between
            // the current value as `ε_n = | x_n - sqrt(a) |`.
            //
            // For our first estimation, we consider `e` the smallest power of 2 which is bigger than the square root
            // of the target. (i.e. `2**(e-1) ≤ sqrt(a) < 2**e`). We know that `e ≤ 128` because `(2¹²⁸)² = 2²⁵⁶` is
            // bigger than any uint256.
            //
            // By noticing that
            // `2**(e-1) ≤ sqrt(a) < 2**e → (2**(e-1))² ≤ a < (2**e)² → 2**(2*e-2) ≤ a < 2**(2*e)`
            // we can deduce that `e - 1` is `log2(a) / 2`. We can thus compute `x_n = 2**(e-1)` using a method similar
            // to the msb function.
            uint256 aa = a;
            uint256 xn = 1;

            if (aa >= (1 << 128)) {
                aa >>= 128;
                xn <<= 64;
            }
            if (aa >= (1 << 64)) {
                aa >>= 64;
                xn <<= 32;
            }
            if (aa >= (1 << 32)) {
                aa >>= 32;
                xn <<= 16;
            }
            if (aa >= (1 << 16)) {
                aa >>= 16;
                xn <<= 8;
            }
            if (aa >= (1 << 8)) {
                aa >>= 8;
                xn <<= 4;
            }
            if (aa >= (1 << 4)) {
                aa >>= 4;
                xn <<= 2;
            }
            if (aa >= (1 << 2)) {
                xn <<= 1;
            }

            // We now have x_n such that `x_n = 2**(e-1) ≤ sqrt(a) < 2**e = 2 * x_n`. This implies ε_n ≤ 2**(e-1).
            //
            // We can refine our estimation by noticing that the middle of that interval minimizes the error.
            // If we move x_n to equal 2**(e-1) + 2**(e-2), then we reduce the error to ε_n ≤ 2**(e-2).
            // This is going to be our x_0 (and ε_0)
            xn = (3 * xn) >> 1; // ε_0 := | x_0 - sqrt(a) | ≤ 2**(e-2)

            // From here, Newton's method give us:
            // x_{n+1} = (x_n + a / x_n) / 2
            //
            // One should note that:
            // x_{n+1}² - a = ((x_n + a / x_n) / 2)² - a
            //              = ((x_n² + a) / (2 * x_n))² - a
            //              = (x_n⁴ + 2 * a * x_n² + a²) / (4 * x_n²) - a
            //              = (x_n⁴ + 2 * a * x_n² + a² - 4 * a * x_n²) / (4 * x_n²)
            //              = (x_n⁴ - 2 * a * x_n² + a²) / (4 * x_n²)
            //              = (x_n² - a)² / (2 * x_n)²
            //              = ((x_n² - a) / (2 * x_n))²
            //              ≥ 0
            // Which proves that for all n ≥ 1, sqrt(a) ≤ x_n
            //
            // This gives us the proof of quadratic convergence of the sequence:
            // ε_{n+1} = | x_{n+1} - sqrt(a) |
            //         = | (x_n + a / x_n) / 2 - sqrt(a) |
            //         = | (x_n² + a - 2*x_n*sqrt(a)) / (2 * x_n) |
            //         = | (x_n - sqrt(a))² / (2 * x_n) |
            //         = | ε_n² / (2 * x_n) |
            //         = ε_n² / | (2 * x_n) |
            //
            // For the first iteration, we have a special case where x_0 is known:
            // ε_1 = ε_0² / | (2 * x_0) |
            //     ≤ (2**(e-2))² / (2 * (2**(e-1) + 2**(e-2)))
            //     ≤ 2**(2*e-4) / (3 * 2**(e-1))
            //     ≤ 2**(e-3) / 3
            //     ≤ 2**(e-3-log2(3))
            //     ≤ 2**(e-4.5)
            //
            // For the following iterations, we use the fact that, 2**(e-1) ≤ sqrt(a) ≤ x_n:
            // ε_{n+1} = ε_n² / | (2 * x_n) |
            //         ≤ (2**(e-k))² / (2 * 2**(e-1))
            //         ≤ 2**(2*e-2*k) / 2**e
            //         ≤ 2**(e-2*k)
            xn = (xn + a / xn) >> 1; // ε_1 := | x_1 - sqrt(a) | ≤ 2**(e-4.5)  -- special case, see above
            xn = (xn + a / xn) >> 1; // ε_2 := | x_2 - sqrt(a) | ≤ 2**(e-9)    -- general case with k = 4.5
            xn = (xn + a / xn) >> 1; // ε_3 := | x_3 - sqrt(a) | ≤ 2**(e-18)   -- general case with k = 9
            xn = (xn + a / xn) >> 1; // ε_4 := | x_4 - sqrt(a) | ≤ 2**(e-36)   -- general case with k = 18
            xn = (xn + a / xn) >> 1; // ε_5 := | x_5 - sqrt(a) | ≤ 2**(e-72)   -- general case with k = 36
            xn = (xn + a / xn) >> 1; // ε_6 := | x_6 - sqrt(a) | ≤ 2**(e-144)  -- general case with k = 72

            // Because e ≤ 128 (as discussed during the first estimation phase), we know have reached a precision
            // ε_6 ≤ 2**(e-144) < 1. Given we're operating on integers, then we can ensure that xn is now either
            // sqrt(a) or sqrt(a) + 1.
            return xn - SafeCast.toUint(xn > a / xn);
        }
    }

    /**
     * @dev Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + SafeCast.toUint(unsignedRoundsUp(rounding) && result * result < a);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 x) internal pure returns (uint256 r) {
        // If value has upper 128 bits set, log2 result is at least 128
        r = SafeCast.toUint(x > 0xffffffffffffffffffffffffffffffff) << 7;
        // If upper 64 bits of 128-bit half set, add 64 to result
        r |= SafeCast.toUint((x >> r) > 0xffffffffffffffff) << 6;
        // If upper 32 bits of 64-bit half set, add 32 to result
        r |= SafeCast.toUint((x >> r) > 0xffffffff) << 5;
        // If upper 16 bits of 32-bit half set, add 16 to result
        r |= SafeCast.toUint((x >> r) > 0xffff) << 4;
        // If upper 8 bits of 16-bit half set, add 8 to result
        r |= SafeCast.toUint((x >> r) > 0xff) << 3;
        // If upper 4 bits of 8-bit half set, add 4 to result
        r |= SafeCast.toUint((x >> r) > 0xf) << 2;

        // Shifts value right by the current result and use it as an index into this lookup table:
        //
        // | x (4 bits) |  index  | table[index] = MSB position |
        // |------------|---------|-----------------------------|
        // |    0000    |    0    |        table[0] = 0         |
        // |    0001    |    1    |        table[1] = 0         |
        // |    0010    |    2    |        table[2] = 1         |
        // |    0011    |    3    |        table[3] = 1         |
        // |    0100    |    4    |        table[4] = 2         |
        // |    0101    |    5    |        table[5] = 2         |
        // |    0110    |    6    |        table[6] = 2         |
        // |    0111    |    7    |        table[7] = 2         |
        // |    1000    |    8    |        table[8] = 3         |
        // |    1001    |    9    |        table[9] = 3         |
        // |    1010    |   10    |        table[10] = 3        |
        // |    1011    |   11    |        table[11] = 3        |
        // |    1100    |   12    |        table[12] = 3        |
        // |    1101    |   13    |        table[13] = 3        |
        // |    1110    |   14    |        table[14] = 3        |
        // |    1111    |   15    |        table[15] = 3        |
        //
        // The lookup table is represented as a 32-byte value with the MSB positions for 0-15 in the last 16 bytes.
        assembly ("memory-safe") {
            r := or(r, byte(shr(r, x), 0x0000010102020202030303030303030300000000000000000000000000000000))
        }
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + SafeCast.toUint(unsignedRoundsUp(rounding) && 1 << result < value);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + SafeCast.toUint(unsignedRoundsUp(rounding) && 10 ** result < value);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 x) internal pure returns (uint256 r) {
        // If value has upper 128 bits set, log2 result is at least 128
        r = SafeCast.toUint(x > 0xffffffffffffffffffffffffffffffff) << 7;
        // If upper 64 bits of 128-bit half set, add 64 to result
        r |= SafeCast.toUint((x >> r) > 0xffffffffffffffff) << 6;
        // If upper 32 bits of 64-bit half set, add 32 to result
        r |= SafeCast.toUint((x >> r) > 0xffffffff) << 5;
        // If upper 16 bits of 32-bit half set, add 16 to result
        r |= SafeCast.toUint((x >> r) > 0xffff) << 4;
        // Add 1 if upper 8 bits of 16-bit half set, and divide accumulated result by 8
        return (r >> 3) | SafeCast.toUint((x >> r) > 0xff);
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + SafeCast.toUint(unsignedRoundsUp(rounding) && 1 << (result << 3) < value);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/math/SafeCast.sol)
// This file was procedurally generated from scripts/generate/templates/SafeCast.js.

pragma solidity ^0.8.20;

/**
 * @dev Wrappers over Solidity's uintXX/intXX/bool casting operators with added overflow
 * checks.
 *
 * Downcasting from uint256/int256 in Solidity does not revert on overflow. This can
 * easily result in undesired exploitation or bugs, since developers usually
 * assume that overflows raise errors. `SafeCast` restores this intuition by
 * reverting the transaction when such an operation overflows.
 *
 * Using this library instead of the unchecked operations eliminates an entire
 * class of bugs, so it's recommended to use it always.
 */
library SafeCast {
    /**
     * @dev Value doesn't fit in an uint of `bits` size.
     */
    error SafeCastOverflowedUintDowncast(uint8 bits, uint256 value);

    /**
     * @dev An int value doesn't fit in an uint of `bits` size.
     */
    error SafeCastOverflowedIntToUint(int256 value);

    /**
     * @dev Value doesn't fit in an int of `bits` size.
     */
    error SafeCastOverflowedIntDowncast(uint8 bits, int256 value);

    /**
     * @dev An uint value doesn't fit in an int of `bits` size.
     */
    error SafeCastOverflowedUintToInt(uint256 value);

    /**
     * @dev Returns the downcasted uint248 from uint256, reverting on
     * overflow (when the input is greater than largest uint248).
     *
     * Counterpart to Solidity's `uint248` operator.
     *
     * Requirements:
     *
     * - input must fit into 248 bits
     */
    function toUint248(uint256 value) internal pure returns (uint248) {
        if (value > type(uint248).max) {
            revert SafeCastOverflowedUintDowncast(248, value);
        }
        return uint248(value);
    }

    /**
     * @dev Returns the downcasted uint240 from uint256, reverting on
     * overflow (when the input is greater than largest uint240).
     *
     * Counterpart to Solidity's `uint240` operator.
     *
     * Requirements:
     *
     * - input must fit into 240 bits
     */
    function toUint240(uint256 value) internal pure returns (uint240) {
        if (value > type(uint240).max) {
            revert SafeCastOverflowedUintDowncast(240, value);
        }
        return uint240(value);
    }

    /**
     * @dev Returns the downcasted uint232 from uint256, reverting on
     * overflow (when the input is greater than largest uint232).
     *
     * Counterpart to Solidity's `uint232` operator.
     *
     * Requirements:
     *
     * - input must fit into 232 bits
     */
    function toUint232(uint256 value) internal pure returns (uint232) {
        if (value > type(uint232).max) {
            revert SafeCastOverflowedUintDowncast(232, value);
        }
        return uint232(value);
    }

    /**
     * @dev Returns the downcasted uint224 from uint256, reverting on
     * overflow (when the input is greater than largest uint224).
     *
     * Counterpart to Solidity's `uint224` operator.
     *
     * Requirements:
     *
     * - input must fit into 224 bits
     */
    function toUint224(uint256 value) internal pure returns (uint224) {
        if (value > type(uint224).max) {
            revert SafeCastOverflowedUintDowncast(224, value);
        }
        return uint224(value);
    }

    /**
     * @dev Returns the downcasted uint216 from uint256, reverting on
     * overflow (when the input is greater than largest uint216).
     *
     * Counterpart to Solidity's `uint216` operator.
     *
     * Requirements:
     *
     * - input must fit into 216 bits
     */
    function toUint216(uint256 value) internal pure returns (uint216) {
        if (value > type(uint216).max) {
            revert SafeCastOverflowedUintDowncast(216, value);
        }
        return uint216(value);
    }

    /**
     * @dev Returns the downcasted uint208 from uint256, reverting on
     * overflow (when the input is greater than largest uint208).
     *
     * Counterpart to Solidity's `uint208` operator.
     *
     * Requirements:
     *
     * - input must fit into 208 bits
     */
    function toUint208(uint256 value) internal pure returns (uint208) {
        if (value > type(uint208).max) {
            revert SafeCastOverflowedUintDowncast(208, value);
        }
        return uint208(value);
    }

    /**
     * @dev Returns the downcasted uint200 from uint256, reverting on
     * overflow (when the input is greater than largest uint200).
     *
     * Counterpart to Solidity's `uint200` operator.
     *
     * Requirements:
     *
     * - input must fit into 200 bits
     */
    function toUint200(uint256 value) internal pure returns (uint200) {
        if (value > type(uint200).max) {
            revert SafeCastOverflowedUintDowncast(200, value);
        }
        return uint200(value);
    }

    /**
     * @dev Returns the downcasted uint192 from uint256, reverting on
     * overflow (when the input is greater than largest uint192).
     *
     * Counterpart to Solidity's `uint192` operator.
     *
     * Requirements:
     *
     * - input must fit into 192 bits
     */
    function toUint192(uint256 value) internal pure returns (uint192) {
        if (value > type(uint192).max) {
            revert SafeCastOverflowedUintDowncast(192, value);
        }
        return uint192(value);
    }

    /**
     * @dev Returns the downcasted uint184 from uint256, reverting on
     * overflow (when the input is greater than largest uint184).
     *
     * Counterpart to Solidity's `uint184` operator.
     *
     * Requirements:
     *
     * - input must fit into 184 bits
     */
    function toUint184(uint256 value) internal pure returns (uint184) {
        if (value > type(uint184).max) {
            revert SafeCastOverflowedUintDowncast(184, value);
        }
        return uint184(value);
    }

    /**
     * @dev Returns the downcasted uint176 from uint256, reverting on
     * overflow (when the input is greater than largest uint176).
     *
     * Counterpart to Solidity's `uint176` operator.
     *
     * Requirements:
     *
     * - input must fit into 176 bits
     */
    function toUint176(uint256 value) internal pure returns (uint176) {
        if (value > type(uint176).max) {
            revert SafeCastOverflowedUintDowncast(176, value);
        }
        return uint176(value);
    }

    /**
     * @dev Returns the downcasted uint168 from uint256, reverting on
     * overflow (when the input is greater than largest uint168).
     *
     * Counterpart to Solidity's `uint168` operator.
     *
     * Requirements:
     *
     * - input must fit into 168 bits
     */
    function toUint168(uint256 value) internal pure returns (uint168) {
        if (value > type(uint168).max) {
            revert SafeCastOverflowedUintDowncast(168, value);
        }
        return uint168(value);
    }

    /**
     * @dev Returns the downcasted uint160 from uint256, reverting on
     * overflow (when the input is greater than largest uint160).
     *
     * Counterpart to Solidity's `uint160` operator.
     *
     * Requirements:
     *
     * - input must fit into 160 bits
     */
    function toUint160(uint256 value) internal pure returns (uint160) {
        if (value > type(uint160).max) {
            revert SafeCastOverflowedUintDowncast(160, value);
        }
        return uint160(value);
    }

    /**
     * @dev Returns the downcasted uint152 from uint256, reverting on
     * overflow (when the input is greater than largest uint152).
     *
     * Counterpart to Solidity's `uint152` operator.
     *
     * Requirements:
     *
     * - input must fit into 152 bits
     */
    function toUint152(uint256 value) internal pure returns (uint152) {
        if (value > type(uint152).max) {
            revert SafeCastOverflowedUintDowncast(152, value);
        }
        return uint152(value);
    }

    /**
     * @dev Returns the downcasted uint144 from uint256, reverting on
     * overflow (when the input is greater than largest uint144).
     *
     * Counterpart to Solidity's `uint144` operator.
     *
     * Requirements:
     *
     * - input must fit into 144 bits
     */
    function toUint144(uint256 value) internal pure returns (uint144) {
        if (value > type(uint144).max) {
            revert SafeCastOverflowedUintDowncast(144, value);
        }
        return uint144(value);
    }

    /**
     * @dev Returns the downcasted uint136 from uint256, reverting on
     * overflow (when the input is greater than largest uint136).
     *
     * Counterpart to Solidity's `uint136` operator.
     *
     * Requirements:
     *
     * - input must fit into 136 bits
     */
    function toUint136(uint256 value) internal pure returns (uint136) {
        if (value > type(uint136).max) {
            revert SafeCastOverflowedUintDowncast(136, value);
        }
        return uint136(value);
    }

    /**
     * @dev Returns the downcasted uint128 from uint256, reverting on
     * overflow (when the input is greater than largest uint128).
     *
     * Counterpart to Solidity's `uint128` operator.
     *
     * Requirements:
     *
     * - input must fit into 128 bits
     */
    function toUint128(uint256 value) internal pure returns (uint128) {
        if (value > type(uint128).max) {
            revert SafeCastOverflowedUintDowncast(128, value);
        }
        return uint128(value);
    }

    /**
     * @dev Returns the downcasted uint120 from uint256, reverting on
     * overflow (when the input is greater than largest uint120).
     *
     * Counterpart to Solidity's `uint120` operator.
     *
     * Requirements:
     *
     * - input must fit into 120 bits
     */
    function toUint120(uint256 value) internal pure returns (uint120) {
        if (value > type(uint120).max) {
            revert SafeCastOverflowedUintDowncast(120, value);
        }
        return uint120(value);
    }

    /**
     * @dev Returns the downcasted uint112 from uint256, reverting on
     * overflow (when the input is greater than largest uint112).
     *
     * Counterpart to Solidity's `uint112` operator.
     *
     * Requirements:
     *
     * - input must fit into 112 bits
     */
    function toUint112(uint256 value) internal pure returns (uint112) {
        if (value > type(uint112).max) {
            revert SafeCastOverflowedUintDowncast(112, value);
        }
        return uint112(value);
    }

    /**
     * @dev Returns the downcasted uint104 from uint256, reverting on
     * overflow (when the input is greater than largest uint104).
     *
     * Counterpart to Solidity's `uint104` operator.
     *
     * Requirements:
     *
     * - input must fit into 104 bits
     */
    function toUint104(uint256 value) internal pure returns (uint104) {
        if (value > type(uint104).max) {
            revert SafeCastOverflowedUintDowncast(104, value);
        }
        return uint104(value);
    }

    /**
     * @dev Returns the downcasted uint96 from uint256, reverting on
     * overflow (when the input is greater than largest uint96).
     *
     * Counterpart to Solidity's `uint96` operator.
     *
     * Requirements:
     *
     * - input must fit into 96 bits
     */
    function toUint96(uint256 value) internal pure returns (uint96) {
        if (value > type(uint96).max) {
            revert SafeCastOverflowedUintDowncast(96, value);
        }
        return uint96(value);
    }

    /**
     * @dev Returns the downcasted uint88 from uint256, reverting on
     * overflow (when the input is greater than largest uint88).
     *
     * Counterpart to Solidity's `uint88` operator.
     *
     * Requirements:
     *
     * - input must fit into 88 bits
     */
    function toUint88(uint256 value) internal pure returns (uint88) {
        if (value > type(uint88).max) {
            revert SafeCastOverflowedUintDowncast(88, value);
        }
        return uint88(value);
    }

    /**
     * @dev Returns the downcasted uint80 from uint256, reverting on
     * overflow (when the input is greater than largest uint80).
     *
     * Counterpart to Solidity's `uint80` operator.
     *
     * Requirements:
     *
     * - input must fit into 80 bits
     */
    function toUint80(uint256 value) internal pure returns (uint80) {
        if (value > type(uint80).max) {
            revert SafeCastOverflowedUintDowncast(80, value);
        }
        return uint80(value);
    }

    /**
     * @dev Returns the downcasted uint72 from uint256, reverting on
     * overflow (when the input is greater than largest uint72).
     *
     * Counterpart to Solidity's `uint72` operator.
     *
     * Requirements:
     *
     * - input must fit into 72 bits
     */
    function toUint72(uint256 value) internal pure returns (uint72) {
        if (value > type(uint72).max) {
            revert SafeCastOverflowedUintDowncast(72, value);
        }
        return uint72(value);
    }

    /**
     * @dev Returns the downcasted uint64 from uint256, reverting on
     * overflow (when the input is greater than largest uint64).
     *
     * Counterpart to Solidity's `uint64` operator.
     *
     * Requirements:
     *
     * - input must fit into 64 bits
     */
    function toUint64(uint256 value) internal pure returns (uint64) {
        if (value > type(uint64).max) {
            revert SafeCastOverflowedUintDowncast(64, value);
        }
        return uint64(value);
    }

    /**
     * @dev Returns the downcasted uint56 from uint256, reverting on
     * overflow (when the input is greater than largest uint56).
     *
     * Counterpart to Solidity's `uint56` operator.
     *
     * Requirements:
     *
     * - input must fit into 56 bits
     */
    function toUint56(uint256 value) internal pure returns (uint56) {
        if (value > type(uint56).max) {
            revert SafeCastOverflowedUintDowncast(56, value);
        }
        return uint56(value);
    }

    /**
     * @dev Returns the downcasted uint48 from uint256, reverting on
     * overflow (when the input is greater than largest uint48).
     *
     * Counterpart to Solidity's `uint48` operator.
     *
     * Requirements:
     *
     * - input must fit into 48 bits
     */
    function toUint48(uint256 value) internal pure returns (uint48) {
        if (value > type(uint48).max) {
            revert SafeCastOverflowedUintDowncast(48, value);
        }
        return uint48(value);
    }

    /**
     * @dev Returns the downcasted uint40 from uint256, reverting on
     * overflow (when the input is greater than largest uint40).
     *
     * Counterpart to Solidity's `uint40` operator.
     *
     * Requirements:
     *
     * - input must fit into 40 bits
     */
    function toUint40(uint256 value) internal pure returns (uint40) {
        if (value > type(uint40).max) {
            revert SafeCastOverflowedUintDowncast(40, value);
        }
        return uint40(value);
    }

    /**
     * @dev Returns the downcasted uint32 from uint256, reverting on
     * overflow (when the input is greater than largest uint32).
     *
     * Counterpart to Solidity's `uint32` operator.
     *
     * Requirements:
     *
     * - input must fit into 32 bits
     */
    function toUint32(uint256 value) internal pure returns (uint32) {
        if (value > type(uint32).max) {
            revert SafeCastOverflowedUintDowncast(32, value);
        }
        return uint32(value);
    }

    /**
     * @dev Returns the downcasted uint24 from uint256, reverting on
     * overflow (when the input is greater than largest uint24).
     *
     * Counterpart to Solidity's `uint24` operator.
     *
     * Requirements:
     *
     * - input must fit into 24 bits
     */
    function toUint24(uint256 value) internal pure returns (uint24) {
        if (value > type(uint24).max) {
            revert SafeCastOverflowedUintDowncast(24, value);
        }
        return uint24(value);
    }

    /**
     * @dev Returns the downcasted uint16 from uint256, reverting on
     * overflow (when the input is greater than largest uint16).
     *
     * Counterpart to Solidity's `uint16` operator.
     *
     * Requirements:
     *
     * - input must fit into 16 bits
     */
    function toUint16(uint256 value) internal pure returns (uint16) {
        if (value > type(uint16).max) {
            revert SafeCastOverflowedUintDowncast(16, value);
        }
        return uint16(value);
    }

    /**
     * @dev Returns the downcasted uint8 from uint256, reverting on
     * overflow (when the input is greater than largest uint8).
     *
     * Counterpart to Solidity's `uint8` operator.
     *
     * Requirements:
     *
     * - input must fit into 8 bits
     */
    function toUint8(uint256 value) internal pure returns (uint8) {
        if (value > type(uint8).max) {
            revert SafeCastOverflowedUintDowncast(8, value);
        }
        return uint8(value);
    }

    /**
     * @dev Converts a signed int256 into an unsigned uint256.
     *
     * Requirements:
     *
     * - input must be greater than or equal to 0.
     */
    function toUint256(int256 value) internal pure returns (uint256) {
        if (value < 0) {
            revert SafeCastOverflowedIntToUint(value);
        }
        return uint256(value);
    }

    /**
     * @dev Returns the downcasted int248 from int256, reverting on
     * overflow (when the input is less than smallest int248 or
     * greater than largest int248).
     *
     * Counterpart to Solidity's `int248` operator.
     *
     * Requirements:
     *
     * - input must fit into 248 bits
     */
    function toInt248(int256 value) internal pure returns (int248 downcasted) {
        downcasted = int248(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(248, value);
        }
    }

    /**
     * @dev Returns the downcasted int240 from int256, reverting on
     * overflow (when the input is less than smallest int240 or
     * greater than largest int240).
     *
     * Counterpart to Solidity's `int240` operator.
     *
     * Requirements:
     *
     * - input must fit into 240 bits
     */
    function toInt240(int256 value) internal pure returns (int240 downcasted) {
        downcasted = int240(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(240, value);
        }
    }

    /**
     * @dev Returns the downcasted int232 from int256, reverting on
     * overflow (when the input is less than smallest int232 or
     * greater than largest int232).
     *
     * Counterpart to Solidity's `int232` operator.
     *
     * Requirements:
     *
     * - input must fit into 232 bits
     */
    function toInt232(int256 value) internal pure returns (int232 downcasted) {
        downcasted = int232(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(232, value);
        }
    }

    /**
     * @dev Returns the downcasted int224 from int256, reverting on
     * overflow (when the input is less than smallest int224 or
     * greater than largest int224).
     *
     * Counterpart to Solidity's `int224` operator.
     *
     * Requirements:
     *
     * - input must fit into 224 bits
     */
    function toInt224(int256 value) internal pure returns (int224 downcasted) {
        downcasted = int224(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(224, value);
        }
    }

    /**
     * @dev Returns the downcasted int216 from int256, reverting on
     * overflow (when the input is less than smallest int216 or
     * greater than largest int216).
     *
     * Counterpart to Solidity's `int216` operator.
     *
     * Requirements:
     *
     * - input must fit into 216 bits
     */
    function toInt216(int256 value) internal pure returns (int216 downcasted) {
        downcasted = int216(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(216, value);
        }
    }

    /**
     * @dev Returns the downcasted int208 from int256, reverting on
     * overflow (when the input is less than smallest int208 or
     * greater than largest int208).
     *
     * Counterpart to Solidity's `int208` operator.
     *
     * Requirements:
     *
     * - input must fit into 208 bits
     */
    function toInt208(int256 value) internal pure returns (int208 downcasted) {
        downcasted = int208(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(208, value);
        }
    }

    /**
     * @dev Returns the downcasted int200 from int256, reverting on
     * overflow (when the input is less than smallest int200 or
     * greater than largest int200).
     *
     * Counterpart to Solidity's `int200` operator.
     *
     * Requirements:
     *
     * - input must fit into 200 bits
     */
    function toInt200(int256 value) internal pure returns (int200 downcasted) {
        downcasted = int200(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(200, value);
        }
    }

    /**
     * @dev Returns the downcasted int192 from int256, reverting on
     * overflow (when the input is less than smallest int192 or
     * greater than largest int192).
     *
     * Counterpart to Solidity's `int192` operator.
     *
     * Requirements:
     *
     * - input must fit into 192 bits
     */
    function toInt192(int256 value) internal pure returns (int192 downcasted) {
        downcasted = int192(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(192, value);
        }
    }

    /**
     * @dev Returns the downcasted int184 from int256, reverting on
     * overflow (when the input is less than smallest int184 or
     * greater than largest int184).
     *
     * Counterpart to Solidity's `int184` operator.
     *
     * Requirements:
     *
     * - input must fit into 184 bits
     */
    function toInt184(int256 value) internal pure returns (int184 downcasted) {
        downcasted = int184(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(184, value);
        }
    }

    /**
     * @dev Returns the downcasted int176 from int256, reverting on
     * overflow (when the input is less than smallest int176 or
     * greater than largest int176).
     *
     * Counterpart to Solidity's `int176` operator.
     *
     * Requirements:
     *
     * - input must fit into 176 bits
     */
    function toInt176(int256 value) internal pure returns (int176 downcasted) {
        downcasted = int176(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(176, value);
        }
    }

    /**
     * @dev Returns the downcasted int168 from int256, reverting on
     * overflow (when the input is less than smallest int168 or
     * greater than largest int168).
     *
     * Counterpart to Solidity's `int168` operator.
     *
     * Requirements:
     *
     * - input must fit into 168 bits
     */
    function toInt168(int256 value) internal pure returns (int168 downcasted) {
        downcasted = int168(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(168, value);
        }
    }

    /**
     * @dev Returns the downcasted int160 from int256, reverting on
     * overflow (when the input is less than smallest int160 or
     * greater than largest int160).
     *
     * Counterpart to Solidity's `int160` operator.
     *
     * Requirements:
     *
     * - input must fit into 160 bits
     */
    function toInt160(int256 value) internal pure returns (int160 downcasted) {
        downcasted = int160(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(160, value);
        }
    }

    /**
     * @dev Returns the downcasted int152 from int256, reverting on
     * overflow (when the input is less than smallest int152 or
     * greater than largest int152).
     *
     * Counterpart to Solidity's `int152` operator.
     *
     * Requirements:
     *
     * - input must fit into 152 bits
     */
    function toInt152(int256 value) internal pure returns (int152 downcasted) {
        downcasted = int152(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(152, value);
        }
    }

    /**
     * @dev Returns the downcasted int144 from int256, reverting on
     * overflow (when the input is less than smallest int144 or
     * greater than largest int144).
     *
     * Counterpart to Solidity's `int144` operator.
     *
     * Requirements:
     *
     * - input must fit into 144 bits
     */
    function toInt144(int256 value) internal pure returns (int144 downcasted) {
        downcasted = int144(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(144, value);
        }
    }

    /**
     * @dev Returns the downcasted int136 from int256, reverting on
     * overflow (when the input is less than smallest int136 or
     * greater than largest int136).
     *
     * Counterpart to Solidity's `int136` operator.
     *
     * Requirements:
     *
     * - input must fit into 136 bits
     */
    function toInt136(int256 value) internal pure returns (int136 downcasted) {
        downcasted = int136(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(136, value);
        }
    }

    /**
     * @dev Returns the downcasted int128 from int256, reverting on
     * overflow (when the input is less than smallest int128 or
     * greater than largest int128).
     *
     * Counterpart to Solidity's `int128` operator.
     *
     * Requirements:
     *
     * - input must fit into 128 bits
     */
    function toInt128(int256 value) internal pure returns (int128 downcasted) {
        downcasted = int128(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(128, value);
        }
    }

    /**
     * @dev Returns the downcasted int120 from int256, reverting on
     * overflow (when the input is less than smallest int120 or
     * greater than largest int120).
     *
     * Counterpart to Solidity's `int120` operator.
     *
     * Requirements:
     *
     * - input must fit into 120 bits
     */
    function toInt120(int256 value) internal pure returns (int120 downcasted) {
        downcasted = int120(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(120, value);
        }
    }

    /**
     * @dev Returns the downcasted int112 from int256, reverting on
     * overflow (when the input is less than smallest int112 or
     * greater than largest int112).
     *
     * Counterpart to Solidity's `int112` operator.
     *
     * Requirements:
     *
     * - input must fit into 112 bits
     */
    function toInt112(int256 value) internal pure returns (int112 downcasted) {
        downcasted = int112(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(112, value);
        }
    }

    /**
     * @dev Returns the downcasted int104 from int256, reverting on
     * overflow (when the input is less than smallest int104 or
     * greater than largest int104).
     *
     * Counterpart to Solidity's `int104` operator.
     *
     * Requirements:
     *
     * - input must fit into 104 bits
     */
    function toInt104(int256 value) internal pure returns (int104 downcasted) {
        downcasted = int104(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(104, value);
        }
    }

    /**
     * @dev Returns the downcasted int96 from int256, reverting on
     * overflow (when the input is less than smallest int96 or
     * greater than largest int96).
     *
     * Counterpart to Solidity's `int96` operator.
     *
     * Requirements:
     *
     * - input must fit into 96 bits
     */
    function toInt96(int256 value) internal pure returns (int96 downcasted) {
        downcasted = int96(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(96, value);
        }
    }

    /**
     * @dev Returns the downcasted int88 from int256, reverting on
     * overflow (when the input is less than smallest int88 or
     * greater than largest int88).
     *
     * Counterpart to Solidity's `int88` operator.
     *
     * Requirements:
     *
     * - input must fit into 88 bits
     */
    function toInt88(int256 value) internal pure returns (int88 downcasted) {
        downcasted = int88(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(88, value);
        }
    }

    /**
     * @dev Returns the downcasted int80 from int256, reverting on
     * overflow (when the input is less than smallest int80 or
     * greater than largest int80).
     *
     * Counterpart to Solidity's `int80` operator.
     *
     * Requirements:
     *
     * - input must fit into 80 bits
     */
    function toInt80(int256 value) internal pure returns (int80 downcasted) {
        downcasted = int80(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(80, value);
        }
    }

    /**
     * @dev Returns the downcasted int72 from int256, reverting on
     * overflow (when the input is less than smallest int72 or
     * greater than largest int72).
     *
     * Counterpart to Solidity's `int72` operator.
     *
     * Requirements:
     *
     * - input must fit into 72 bits
     */
    function toInt72(int256 value) internal pure returns (int72 downcasted) {
        downcasted = int72(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(72, value);
        }
    }

    /**
     * @dev Returns the downcasted int64 from int256, reverting on
     * overflow (when the input is less than smallest int64 or
     * greater than largest int64).
     *
     * Counterpart to Solidity's `int64` operator.
     *
     * Requirements:
     *
     * - input must fit into 64 bits
     */
    function toInt64(int256 value) internal pure returns (int64 downcasted) {
        downcasted = int64(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(64, value);
        }
    }

    /**
     * @dev Returns the downcasted int56 from int256, reverting on
     * overflow (when the input is less than smallest int56 or
     * greater than largest int56).
     *
     * Counterpart to Solidity's `int56` operator.
     *
     * Requirements:
     *
     * - input must fit into 56 bits
     */
    function toInt56(int256 value) internal pure returns (int56 downcasted) {
        downcasted = int56(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(56, value);
        }
    }

    /**
     * @dev Returns the downcasted int48 from int256, reverting on
     * overflow (when the input is less than smallest int48 or
     * greater than largest int48).
     *
     * Counterpart to Solidity's `int48` operator.
     *
     * Requirements:
     *
     * - input must fit into 48 bits
     */
    function toInt48(int256 value) internal pure returns (int48 downcasted) {
        downcasted = int48(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(48, value);
        }
    }

    /**
     * @dev Returns the downcasted int40 from int256, reverting on
     * overflow (when the input is less than smallest int40 or
     * greater than largest int40).
     *
     * Counterpart to Solidity's `int40` operator.
     *
     * Requirements:
     *
     * - input must fit into 40 bits
     */
    function toInt40(int256 value) internal pure returns (int40 downcasted) {
        downcasted = int40(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(40, value);
        }
    }

    /**
     * @dev Returns the downcasted int32 from int256, reverting on
     * overflow (when the input is less than smallest int32 or
     * greater than largest int32).
     *
     * Counterpart to Solidity's `int32` operator.
     *
     * Requirements:
     *
     * - input must fit into 32 bits
     */
    function toInt32(int256 value) internal pure returns (int32 downcasted) {
        downcasted = int32(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(32, value);
        }
    }

    /**
     * @dev Returns the downcasted int24 from int256, reverting on
     * overflow (when the input is less than smallest int24 or
     * greater than largest int24).
     *
     * Counterpart to Solidity's `int24` operator.
     *
     * Requirements:
     *
     * - input must fit into 24 bits
     */
    function toInt24(int256 value) internal pure returns (int24 downcasted) {
        downcasted = int24(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(24, value);
        }
    }

    /**
     * @dev Returns the downcasted int16 from int256, reverting on
     * overflow (when the input is less than smallest int16 or
     * greater than largest int16).
     *
     * Counterpart to Solidity's `int16` operator.
     *
     * Requirements:
     *
     * - input must fit into 16 bits
     */
    function toInt16(int256 value) internal pure returns (int16 downcasted) {
        downcasted = int16(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(16, value);
        }
    }

    /**
     * @dev Returns the downcasted int8 from int256, reverting on
     * overflow (when the input is less than smallest int8 or
     * greater than largest int8).
     *
     * Counterpart to Solidity's `int8` operator.
     *
     * Requirements:
     *
     * - input must fit into 8 bits
     */
    function toInt8(int256 value) internal pure returns (int8 downcasted) {
        downcasted = int8(value);
        if (downcasted != value) {
            revert SafeCastOverflowedIntDowncast(8, value);
        }
    }

    /**
     * @dev Converts an unsigned uint256 into a signed int256.
     *
     * Requirements:
     *
     * - input must be less than or equal to maxInt256.
     */
    function toInt256(uint256 value) internal pure returns (int256) {
        // Note: Unsafe cast below is okay because `type(int256).max` is guaranteed to be positive
        if (value > uint256(type(int256).max)) {
            revert SafeCastOverflowedUintToInt(value);
        }
        return int256(value);
    }

    /**
     * @dev Cast a boolean (false or true) to a uint256 (0 or 1) with no jump.
     */
    function toUint(bool b) internal pure returns (uint256 u) {
        assembly ("memory-safe") {
            u := iszero(iszero(b))
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/draft-IERC1822.sol)

pragma solidity ^0.8.20;

/**
 * @dev ERC-1822: Universal Upgradeable Proxy Standard (UUPS) documents a method for upgradeability through a simplified
 * proxy whose upgrades are fully controlled by the current implementation.
 */
interface IERC1822Proxiable {
    /**
     * @dev Returns the storage slot that the proxiable contract assumes is being used to store the implementation
     * address.
     *
     * IMPORTANT: A proxy pointing at a proxiable contract should not be considered proxiable itself, because this risks
     * bricking a proxy that upgrades to it, by delegating to itself until out of gas. Thus it is critical that this
     * function revert if invoked through a proxy.
     */
    function proxiableUUID() external view returns (bytes32);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (proxy/ERC1967/ERC1967Utils.sol)

pragma solidity ^0.8.22;

import {IBeacon} from "../beacon/IBeacon.sol";
import {IERC1967} from "../../interfaces/IERC1967.sol";
import {Address} from "../../utils/Address.sol";
import {StorageSlot} from "../../utils/StorageSlot.sol";

/**
 * @dev This library provides getters and event emitting update functions for
 * https://eips.ethereum.org/EIPS/eip-1967[ERC-1967] slots.
 */
library ERC1967Utils {
    /**
     * @dev Storage slot with the address of the current implementation.
     * This is the keccak-256 hash of "eip1967.proxy.implementation" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;

    /**
     * @dev The `implementation` of the proxy is invalid.
     */
    error ERC1967InvalidImplementation(address implementation);

    /**
     * @dev The `admin` of the proxy is invalid.
     */
    error ERC1967InvalidAdmin(address admin);

    /**
     * @dev The `beacon` of the proxy is invalid.
     */
    error ERC1967InvalidBeacon(address beacon);

    /**
     * @dev An upgrade function sees `msg.value > 0` that may be lost.
     */
    error ERC1967NonPayable();

    /**
     * @dev Returns the current implementation address.
     */
    function getImplementation() internal view returns (address) {
        return StorageSlot.getAddressSlot(IMPLEMENTATION_SLOT).value;
    }

    /**
     * @dev Stores a new address in the ERC-1967 implementation slot.
     */
    function _setImplementation(address newImplementation) private {
        if (newImplementation.code.length == 0) {
            revert ERC1967InvalidImplementation(newImplementation);
        }
        StorageSlot.getAddressSlot(IMPLEMENTATION_SLOT).value = newImplementation;
    }

    /**
     * @dev Performs implementation upgrade with additional setup call if data is nonempty.
     * This function is payable only if the setup call is performed, otherwise `msg.value` is rejected
     * to avoid stuck value in the contract.
     *
     * Emits an {IERC1967-Upgraded} event.
     */
    function upgradeToAndCall(address newImplementation, bytes memory data) internal {
        _setImplementation(newImplementation);
        emit IERC1967.Upgraded(newImplementation);

        if (data.length > 0) {
            Address.functionDelegateCall(newImplementation, data);
        } else {
            _checkNonPayable();
        }
    }

    /**
     * @dev Storage slot with the admin of the contract.
     * This is the keccak-256 hash of "eip1967.proxy.admin" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant ADMIN_SLOT = 0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103;

    /**
     * @dev Returns the current admin.
     *
     * TIP: To get this value clients can read directly from the storage slot shown below (specified by ERC-1967) using
     * the https://eth.wiki/json-rpc/API#eth_getstorageat[`eth_getStorageAt`] RPC call.
     * `0xb53127684a568b3173ae13b9f8a6016e243e63b6e8ee1178d6a717850b5d6103`
     */
    function getAdmin() internal view returns (address) {
        return StorageSlot.getAddressSlot(ADMIN_SLOT).value;
    }

    /**
     * @dev Stores a new address in the ERC-1967 admin slot.
     */
    function _setAdmin(address newAdmin) private {
        if (newAdmin == address(0)) {
            revert ERC1967InvalidAdmin(address(0));
        }
        StorageSlot.getAddressSlot(ADMIN_SLOT).value = newAdmin;
    }

    /**
     * @dev Changes the admin of the proxy.
     *
     * Emits an {IERC1967-AdminChanged} event.
     */
    function changeAdmin(address newAdmin) internal {
        emit IERC1967.AdminChanged(getAdmin(), newAdmin);
        _setAdmin(newAdmin);
    }

    /**
     * @dev The storage slot of the UpgradeableBeacon contract which defines the implementation for this proxy.
     * This is the keccak-256 hash of "eip1967.proxy.beacon" subtracted by 1.
     */
    // solhint-disable-next-line private-vars-leading-underscore
    bytes32 internal constant BEACON_SLOT = 0xa3f0ad74e5423aebfd80d3ef4346578335a9a72aeaee59ff6cb3582b35133d50;

    /**
     * @dev Returns the current beacon.
     */
    function getBeacon() internal view returns (address) {
        return StorageSlot.getAddressSlot(BEACON_SLOT).value;
    }

    /**
     * @dev Stores a new beacon in the ERC-1967 beacon slot.
     */
    function _setBeacon(address newBeacon) private {
        if (newBeacon.code.length == 0) {
            revert ERC1967InvalidBeacon(newBeacon);
        }

        StorageSlot.getAddressSlot(BEACON_SLOT).value = newBeacon;

        address beaconImplementation = IBeacon(newBeacon).implementation();
        if (beaconImplementation.code.length == 0) {
            revert ERC1967InvalidImplementation(beaconImplementation);
        }
    }

    /**
     * @dev Change the beacon and trigger a setup call if data is nonempty.
     * This function is payable only if the setup call is performed, otherwise `msg.value` is rejected
     * to avoid stuck value in the contract.
     *
     * Emits an {IERC1967-BeaconUpgraded} event.
     *
     * CAUTION: Invoking this function has no effect on an instance of {BeaconProxy} since v5, since
     * it uses an immutable beacon without looking at the value of the ERC-1967 beacon slot for
     * efficiency.
     */
    function upgradeBeaconToAndCall(address newBeacon, bytes memory data) internal {
        _setBeacon(newBeacon);
        emit IERC1967.BeaconUpgraded(newBeacon);

        if (data.length > 0) {
            Address.functionDelegateCall(IBeacon(newBeacon).implementation(), data);
        } else {
            _checkNonPayable();
        }
    }

    /**
     * @dev Reverts if `msg.value` is not zero. It can be used to avoid `msg.value` stuck in the contract
     * if an upgrade doesn't perform an initialization call.
     */
    function _checkNonPayable() private {
        if (msg.value > 0) {
            revert ERC1967NonPayable();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/Proxy.sol)

pragma solidity ^0.8.20;

/**
 * @dev This abstract contract provides a fallback function that delegates all calls to another contract using the EVM
 * instruction `delegatecall`. We refer to the second contract as the _implementation_ behind the proxy, and it has to
 * be specified by overriding the virtual {_implementation} function.
 *
 * Additionally, delegation to the implementation can be triggered manually through the {_fallback} function, or to a
 * different contract through the {_delegate} function.
 *
 * The success and return data of the delegated call will be returned back to the caller of the proxy.
 */
abstract contract Proxy {
    /**
     * @dev Delegates the current call to `implementation`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _delegate(address implementation) internal virtual {
        assembly {
            // Copy msg.data. We take full control of memory in this inline assembly
            // block because it will not return to Solidity code. We overwrite the
            // Solidity scratch pad at memory position 0.
            calldatacopy(0, 0, calldatasize())

            // Call the implementation.
            // out and outsize are 0 because we don't know the size yet.
            let result := delegatecall(gas(), implementation, 0, calldatasize(), 0, 0)

            // Copy the returned data.
            returndatacopy(0, 0, returndatasize())

            switch result
            // delegatecall returns 0 on error.
            case 0 {
                revert(0, returndatasize())
            }
            default {
                return(0, returndatasize())
            }
        }
    }

    /**
     * @dev This is a virtual function that should be overridden so it returns the address to which the fallback
     * function and {_fallback} should delegate.
     */
    function _implementation() internal view virtual returns (address);

    /**
     * @dev Delegates the current call to the address returned by `_implementation()`.
     *
     * This function does not return to its internal call site, it will return directly to the external caller.
     */
    function _fallback() internal virtual {
        _delegate(_implementation());
    }

    /**
     * @dev Fallback function that delegates calls to the address returned by `_implementation()`. Will run if no other
     * function in the contract matches the call data.
     */
    fallback() external payable virtual {
        _fallback();
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/Panic.sol)

pragma solidity ^0.8.20;

/**
 * @dev Helper library for emitting standardized panic codes.
 *
 * ```solidity
 * contract Example {
 *      using Panic for uint256;
 *
 *      // Use any of the declared internal constants
 *      function foo() { Panic.GENERIC.panic(); }
 *
 *      // Alternatively
 *      function foo() { Panic.panic(Panic.GENERIC); }
 * }
 * ```
 *
 * Follows the list from https://github.com/ethereum/solidity/blob/v0.8.24/libsolutil/ErrorCodes.h[libsolutil].
 *
 * _Available since v5.1._
 */
// slither-disable-next-line unused-state
library Panic {
    /// @dev generic / unspecified error
    uint256 internal constant GENERIC = 0x00;
    /// @dev used by the assert() builtin
    uint256 internal constant ASSERT = 0x01;
    /// @dev arithmetic underflow or overflow
    uint256 internal constant UNDER_OVERFLOW = 0x11;
    /// @dev division or modulo by zero
    uint256 internal constant DIVISION_BY_ZERO = 0x12;
    /// @dev enum conversion error
    uint256 internal constant ENUM_CONVERSION_ERROR = 0x21;
    /// @dev invalid encoding in storage
    uint256 internal constant STORAGE_ENCODING_ERROR = 0x22;
    /// @dev empty array pop
    uint256 internal constant EMPTY_ARRAY_POP = 0x31;
    /// @dev array out of bounds access
    uint256 internal constant ARRAY_OUT_OF_BOUNDS = 0x32;
    /// @dev resource error (too large allocation or too large array)
    uint256 internal constant RESOURCE_ERROR = 0x41;
    /// @dev calling invalid internal function
    uint256 internal constant INVALID_INTERNAL_FUNCTION = 0x51;

    /// @dev Reverts with a panic code. Recommended to use with
    /// the internal constants with predefined codes.
    function panic(uint256 code) internal pure {
        assembly ("memory-safe") {
            mstore(0x00, 0x4e487b71)
            mstore(0x20, code)
            revert(0x1c, 0x24)
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (proxy/beacon/IBeacon.sol)

pragma solidity ^0.8.20;

/**
 * @dev This is the interface that {BeaconProxy} expects of its beacon.
 */
interface IBeacon {
    /**
     * @dev Must return an address that can be used as a delegate call target.
     *
     * {UpgradeableBeacon} will check that this address is a contract.
     */
    function implementation() external view returns (address);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC1967.sol)

pragma solidity ^0.8.20;

/**
 * @dev ERC-1967: Proxy Storage Slots. This interface contains the events defined in the ERC.
 */
interface IERC1967 {
    /**
     * @dev Emitted when the implementation is upgraded.
     */
    event Upgraded(address indexed implementation);

    /**
     * @dev Emitted when the admin account has changed.
     */
    event AdminChanged(address previousAdmin, address newAdmin);

    /**
     * @dev Emitted when the beacon is changed.
     */
    event BeaconUpgraded(address indexed beacon);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.2.0) (utils/Address.sol)

pragma solidity ^0.8.20;

import {Errors} from "./Errors.sol";

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert Errors.InsufficientBalance(address(this).balance, amount);
        }

        (bool success, bytes memory returndata) = recipient.call{value: amount}("");
        if (!success) {
            _revert(returndata);
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {Errors.FailedCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert Errors.InsufficientBalance(address(this).balance, value);
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {Errors.FailedCall}) in case
     * of an unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {Errors.FailedCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {Errors.FailedCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            assembly ("memory-safe") {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert Errors.FailedCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/StorageSlot.sol)
// This file was procedurally generated from scripts/generate/templates/StorageSlot.js.

pragma solidity ^0.8.20;

/**
 * @dev Library for reading and writing primitive types to specific storage slots.
 *
 * Storage slots are often used to avoid storage conflict when dealing with upgradeable contracts.
 * This library helps with reading and writing to such slots without the need for inline assembly.
 *
 * The functions in this library return Slot structs that contain a `value` member that can be used to read or write.
 *
 * Example usage to set ERC-1967 implementation slot:
 * ```solidity
 * contract ERC1967 {
 *     // Define the slot. Alternatively, use the SlotDerivation library to derive the slot.
 *     bytes32 internal constant _IMPLEMENTATION_SLOT = 0x360894a13ba1a3210667c828492db98dca3e2076cc3735a920a3ca505d382bbc;
 *
 *     function _getImplementation() internal view returns (address) {
 *         return StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value;
 *     }
 *
 *     function _setImplementation(address newImplementation) internal {
 *         require(newImplementation.code.length > 0);
 *         StorageSlot.getAddressSlot(_IMPLEMENTATION_SLOT).value = newImplementation;
 *     }
 * }
 * ```
 *
 * TIP: Consider using this library along with {SlotDerivation}.
 */
library StorageSlot {
    struct AddressSlot {
        address value;
    }

    struct BooleanSlot {
        bool value;
    }

    struct Bytes32Slot {
        bytes32 value;
    }

    struct Uint256Slot {
        uint256 value;
    }

    struct Int256Slot {
        int256 value;
    }

    struct StringSlot {
        string value;
    }

    struct BytesSlot {
        bytes value;
    }

    /**
     * @dev Returns an `AddressSlot` with member `value` located at `slot`.
     */
    function getAddressSlot(bytes32 slot) internal pure returns (AddressSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `BooleanSlot` with member `value` located at `slot`.
     */
    function getBooleanSlot(bytes32 slot) internal pure returns (BooleanSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Bytes32Slot` with member `value` located at `slot`.
     */
    function getBytes32Slot(bytes32 slot) internal pure returns (Bytes32Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Uint256Slot` with member `value` located at `slot`.
     */
    function getUint256Slot(bytes32 slot) internal pure returns (Uint256Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `Int256Slot` with member `value` located at `slot`.
     */
    function getInt256Slot(bytes32 slot) internal pure returns (Int256Slot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns a `StringSlot` with member `value` located at `slot`.
     */
    function getStringSlot(bytes32 slot) internal pure returns (StringSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `StringSlot` representation of the string storage pointer `store`.
     */
    function getStringSlot(string storage store) internal pure returns (StringSlot storage r) {
        assembly ("memory-safe") {
            r.slot := store.slot
        }
    }

    /**
     * @dev Returns a `BytesSlot` with member `value` located at `slot`.
     */
    function getBytesSlot(bytes32 slot) internal pure returns (BytesSlot storage r) {
        assembly ("memory-safe") {
            r.slot := slot
        }
    }

    /**
     * @dev Returns an `BytesSlot` representation of the bytes storage pointer `store`.
     */
    function getBytesSlot(bytes storage store) internal pure returns (BytesSlot storage r) {
        assembly ("memory-safe") {
            r.slot := store.slot
        }
    }
}