Forkchoice Ethereum Mainnet

// SPDX-License-Identifier: GPL-3.0
// solhint-disable-next-line
pragma solidity 0.8.12;

import "./interface/IAssetsInteraction.sol";
import "./reduced_interfaces/BAPApesInterface.sol";
import "@openzeppelin/contracts/access/Ownable.sol";

/// @title Bulls and Apes Project - God Minting Contract
/// @author BAP Dev Team
/// @notice Handle the minting of God Apes through the BAP gamification
contract GodMinting is Ownable {
  /// @notice Counter of Gods minted
  uint256 public godCounter;

  /// @notice Apes Contract instance
  BAPApesInterface public bapApes;
  /// @notice Assets Interactions contract instance
  IAssetsInteraction public assetsInteractionContract;

  /// @notice Address of the wallet that signs messages
  address public secret;

  /// @notice Boolean to prevent using the same signature twice
  mapping(bytes => bool) public usedSignatures;

  /// @notice God Minted event
  /// @param element: Element of the God Bull minted, 12 Elements in total (0-11)
  /// @param compass: God is Good (0) or Evil (1)
  event GodBullMinted(
    address user,
    uint256 godId,
    uint256 element,
    uint256 compass
  );

  /// @notice Deploys the contract and sets the instances addresses
  /// @param apesAddress: Address of the Apes Contract
  /// @param assetsInteractionAddress: Address of the Teen Bulls contract
  constructor(address apesAddress, address assetsInteractionAddress) {
    bapApes = BAPApesInterface(apesAddress);
    assetsInteractionContract = IAssetsInteraction(assetsInteractionAddress);
  }

  /// @notice Mint a God Bull
  /// @param recipient: Address of the recipient
  /// @param apeId: ID of the Ape to use
  /// @param element: Element of the God Bull minted, 12 Elements in total (0-11)
  /// @param compass: God is Good (0) or Evil (1)
  /// @param signature: Signature to confirm above parameters
  function mintGodApes(
    address recipient,
    uint256 apeId,
    uint256 element,
    uint256 compass,
    bytes memory signature
  ) external {
    require(godCounter < 1000, "mintGodApes: All Gods minted");
    require(!usedSignatures[signature], "mintGodApes: Signature already used");
    require(
      _verifyHashSignature(
        keccak256(abi.encode(recipient, apeId, element, compass, "God Mint")),
        signature
      ),
      "mintGodApes: Invalid signature"
    );

    usedSignatures[signature] = true;
    godCounter++;

    assetsInteractionContract.resurrectApe(apeId, recipient); // Send the Ape to the user
    bapApes.confirmChange(apeId); // burn-mint Ape to transform it into a God Ape

    emit GodBullMinted(recipient, apeId + 10000, element, compass);
  }

  /// @notice Internal function to set a new signer
  /// @param newSigner: Address of the new signer
  /// @dev Only the owner can set a new signer
  function setSigner(address newSigner) external onlyOwner {
    require(newSigner != address(0), "Invalid address");
    secret = newSigner;
  }

  /// @notice Transfer ownership from external contracts owned by this contract
  /// @param _contract Address of the external contract
  /// @param _newOwner New owner
  /// @dev Only contract owner can call this function
  function transferOwnershipExternalContract(
    address _contract,
    address _newOwner
  ) external onlyOwner {
    Ownable(_contract).transferOwnership(_newOwner);
  }

  /// @notice Set new contracts addresses
  /// @param apesAddress: Address of the Apes Contract
  /// @param assetsInteractionAddress: Address of the Teen Bulls contract
  /// @dev Only contract owner can call this function
  function setContractsAddresses(
    address apesAddress,
    address assetsInteractionAddress
  ) external onlyOwner {
    bapApes = BAPApesInterface(apesAddress);
    assetsInteractionContract = IAssetsInteraction(assetsInteractionAddress);
  }

  /// @notice Internal function to check if a signature is valid
  /// @param freshHash: Hash to check
  /// @param signature: Signature to check
  function _verifyHashSignature(
    bytes32 freshHash,
    bytes memory signature
  ) internal view returns (bool) {
    bytes32 hash = keccak256(
      abi.encodePacked("\x19Ethereum Signed Message:\n32", freshHash)
    );

    bytes32 r;
    bytes32 s;
    uint8 v;

    if (signature.length != 65) {
      return false;
    }
    assembly {
      r := mload(add(signature, 32))
      s := mload(add(signature, 64))
      v := byte(0, mload(add(signature, 96)))
    }

    if (v < 27) {
      v += 27;
    }

    address signer = address(0);
    if (v == 27 || v == 28) {
      // solium-disable-next-line arg-overflow
      signer = ecrecover(hash, v, r, s);
    }
    return secret == signer;
  }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.9.0) (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    constructor() {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: GPL-3.0
// solhint-disable-next-line
pragma solidity 0.8.12;

interface IAssetsInteraction {
    function resurrectApe(uint256 tokenId, address recipient) external;
}

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.12;

interface BAPApesInterface {
    function ownerOf(uint256) external view returns (address);

   function transferFrom(
        address from,
        address to,
        uint256 tokenId
    ) external;

    function confirmChange(uint256 tokenId) external;
}