Cryo Explorer Ethereum Mainnet

// File: @openzeppelin/contracts/security/ReentrancyGuard.sol


// OpenZeppelin Contracts (last updated v4.9.0) (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    constructor() {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be _NOT_ENTERED
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == _ENTERED;
    }
}

// File: @openzeppelin/contracts/token/ERC20/IERC20.sol


// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// File: @openzeppelin/contracts/interfaces/IERC20.sol


// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC20.sol)

pragma solidity ^0.8.20;


// File: @openzeppelin/contracts/utils/introspection/IERC165.sol


// OpenZeppelin Contracts (last updated v5.1.0) (utils/introspection/IERC165.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

// File: @openzeppelin/contracts/interfaces/IERC165.sol


// OpenZeppelin Contracts (last updated v5.0.0) (interfaces/IERC165.sol)

pragma solidity ^0.8.20;


// File: @openzeppelin/contracts/interfaces/IERC1363.sol


// OpenZeppelin Contracts (last updated v5.1.0) (interfaces/IERC1363.sol)

pragma solidity ^0.8.20;



/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// File: @openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol


// OpenZeppelin Contracts (last updated v5.2.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;



/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// File: contracts/GGTest3.sol


pragma solidity ^0.8.0;




// Enum to specify DEX type for sell operations
enum DexType { 
    UNISWAP_V2,      // Includes SushiSwap V2 and ShibaSwap
    UNISWAP_V3,      // Includes SushiSwap V3
    PANCAKESWAP_V3,  // Uses IPancakeV3Router interface
    BALANCER,
    CURVE
}

// Interface for Uniswap V2 style routers
interface IUniswapV2Router {
    function swapExactTokensForTokens(
        uint256 amountIn,
        uint256 amountOutMin,
        address[] calldata path,
        address to,
        uint256 deadline
    ) external returns (uint256[] memory amounts);
}

// Interface for Uniswap V3 style routers
interface IUniswapV3Router {
    struct ExactInputSingleParams {
        address tokenIn;
        address tokenOut;
        uint24 fee;
        address recipient;
        uint256 deadline;
        uint256 amountIn;
        uint256 amountOutMinimum;
        uint160 sqrtPriceLimitX96;
    }
    
    function exactInputSingle(ExactInputSingleParams calldata params) 
        external returns (uint256 amountOut);
}

// Interface for Uniswap V3 Swap Callback Interface (for Uniswap V3, SushiSwap V3, and PancakeSwap V3)
interface IUniswapV3SwapCallback {
    function uniswapV3SwapCallback(
        int256 amount0Delta,
        int256 amount1Delta,
        bytes calldata data
    ) external;
}

// Interface for PancakeSwap V3 router
interface IPancakeV3Router {
    struct ExactInputParams {
        bytes path;
        address recipient;
        uint256 deadline;
        uint256 amountIn;
        uint256 amountOutMinimum;
    }
    
    function exactInput(ExactInputParams calldata params) 
        external payable returns (uint256 amountOut);
}

// Interface for Balancer Vault
interface IBalancerVault {
    struct SingleSwap {
        bytes32 poolId;
        uint8 kind;
        address assetIn;
        address assetOut;
        uint256 amount;
        bytes userData;
    }
    
    struct FundManagement {
        address sender;
        bool fromInternalBalance;
        address payable recipient;
        bool toInternalBalance;
    }
    
    function swap(
        SingleSwap memory singleSwap,
        FundManagement memory funds,
        uint256 limit,
        uint256 deadline
    ) external payable returns (uint256);
}

// Interface for Curve pools
interface ICurvePool {
    function exchange(
        int128 i,
        int128 j,
        uint256 dx,
        uint256 min_dy
    ) external;
}

// Interface for IWrappedTokenGatewayV3
interface IWrappedTokenGatewayV3 {
    function withdrawETH(
        address asset,  // WETH address
        uint256 amount,
        address to
    ) external;
}

// Interface for AavePoolV3
interface IAavePoolV3 {
    function flashLoanSimple(
        address receiverAddress,
        address asset,
        uint256 amount,
        bytes calldata params,
        uint16 referralCode
    ) external;
}

// Interface for Flash Loan Receiver to implement flash loan logic
interface IFlashLoanReceiver {
    function executeOperation(
        address asset,
        uint256 amount,
        uint256 premium,
        address initiator,
        bytes calldata params
    ) external returns (bool);
}

// Main contract implementing arbitrage strategies using flash loans
contract GGTest3 is ReentrancyGuard, IFlashLoanReceiver, IUniswapV3SwapCallback {
    using SafeERC20 for IERC20;
    // State variables
    address payable private immutable owner;   // Contract owner (payable to allow ETH transfers)
    IAavePoolV3 public pool;                   // AavePoolV3 contract address
    address public immutable weth;             // WETH contract address
    IWrappedTokenGatewayV3 public unwrapWETH;  // Wrapped Token GatewayV3 contract address
    address private botAddress;                // Bot address authorized to interact with the contract
    
    // State minimum profit threshold
    uint256 public minProfitBasisPoints = 100; // 1.0% minimum profit by default

    // Memory struct for flash loan variables
    struct FlashLoanVars {
        address buyDexRouter;
        address sellDexRouter;
        DexType sellDexType;
        bytes buyCalldata;
        bytes sellParams;
        address[] buyPath;
        uint128 dynamicProfitFactor;
        uint128 dynamicSlippageTolerance;
    }

    // Packed struct for execution results to minimize stack usage
    struct ExecutionContext {
        uint256 amountBorrowed;
        uint256 premium;
        uint256 amountOwed;
        uint256 boughtAmount;
    }

    // Restrict certain functions to only be callable by contract owner
    modifier onlyOwner() {
        require(msg.sender == owner, "Not authorized");
        _;
    }

    // Restrict certain functions to only be callable by owner or bot
    modifier onlyOwnerOrBot() {
        require(msg.sender == owner || msg.sender == botAddress, "Not authorized");
        _;
    }

    // Restrict certain functions to only be callable by bot
    modifier onlyBot() {
        require(msg.sender == botAddress, "Not authorized");
        _;
    }   

    // Initialize variables with default values
    constructor(address _botAddress) {
        require(_botAddress != address(0), "Invalid bot address");
        owner = payable(msg.sender);                                            // Set contract owner
        botAddress = _botAddress;                                               // Set bot address
        pool = IAavePoolV3(0x87870Bca3F3fD6335C3F4ce8392D69350B4fA4E2);         // AavePoolV3 contract address
        weth = 0xC02aaA39b223FE8D0A0e5C4F27eAD9083C756Cc2;                      // WETH contract address (not token address)
        unwrapWETH = IWrappedTokenGatewayV3(0xA434D495249abE33E031Fe71a969B81f3c07950D);  // Wrapped Token Gateway contract address
        IERC20(weth).approve(address(pool), type(uint256).max);                 // Set unlimited approval for WETH once during deployment
    }
    
    // Update bot address (only callable by owner)
    function updateBotAddress(address newBotAddress) external onlyOwner {
        require(newBotAddress != address(0), "Invalid bot address");
        botAddress = newBotAddress;
    }

    // Update minimum profit threshold (only callable by owner)
    function updateMinProfitThreshold(uint256 _minProfitBasisPoints) external onlyOwner {
        minProfitBasisPoints = _minProfitBasisPoints;
    }

    // Initiate Arbitrage (uses uint128 for profit/slippage factors instead of uint256)
    function initiateArbitrage(
        uint256 amount,                    // Amount to borrow (WETH is implicit)
        address buyDexRouter,              // Router address for DEX 1
        address sellDexRouter,             // Router address for DEX 2  
        DexType sellDexType,               // Type of DEX for sell operation
        bytes calldata buyCalldata,        // Encoded buy calldata on DEX 1
        bytes calldata sellParams,         // DEX-specific parameters for sell operation
        address[] calldata buyPath,        // Token swap path on DEX 1 (input token to output token)
        uint128 dynamicProfitFactor,       // Dynamic profit factor (in basis points)
        uint128 dynamicSlippageTolerance   // Dynamic slippage tolerance (in basis points)
    ) external onlyBot {        
        require(buyDexRouter != address(0) && sellDexRouter != address(0), "Invalid router");
        require(uint8(sellDexType) <= 4, "Invalid DEX type");

        // Initiate flash loan with packed parameters
        pool.flashLoanSimple(
            address(this),  // Receiver address (this contract)
            weth,           // Asset to borrow (always WETH)
            amount,         // Amount to borrow
            abi.encode(
                buyDexRouter,
                sellDexRouter,
                uint8(sellDexType),
                buyCalldata,
                sellParams,
                buyPath,
                dynamicProfitFactor,
                dynamicSlippageTolerance
            ),
            0              // Referral code (0 for no referral)
        );
    }

    // Execute Operation
    function executeOperation(
        address asset,
        uint256 amount,
        uint256 premium,
        address initiator,
        bytes calldata params
    ) external override returns (bool) {
        require(msg.sender == address(pool), "Invalid caller");
        require(initiator == address(this), "Invalid initiator");
        require(asset == weth, "Only WETH supported");
        require(amount > 0, "Invalid loan amount");

        // Decode params into memory struct (not storage)
        FlashLoanVars memory data = _decodeFlashLoanParams(params);
        
        // Create execution context in memory to track state
        ExecutionContext memory ctx = ExecutionContext({
            amountBorrowed: amount,
            premium: premium,
            amountOwed: amount + premium,
            boughtAmount: 0
        });

        // Execute trades using memory data
        ctx.boughtAmount = _executeBuy(data, amount);
        _executeSell(data, ctx);

        return true;
    }

    // Decode parameters into memory struct
    function _decodeFlashLoanParams(bytes calldata params) 
        private 
        pure 
        returns (FlashLoanVars memory data) 
    {
        uint8 sellDexTypeUint;  // Declare the variable first

        (
            data.buyDexRouter,
            data.sellDexRouter,
            sellDexTypeUint,
            data.buyCalldata,
            data.sellParams,
            data.buyPath,
            data.dynamicProfitFactor,
            data.dynamicSlippageTolerance
        ) = abi.decode(params, (address, address, uint8, bytes, bytes, address[], uint128, uint128));
        
        data.sellDexType = DexType(sellDexTypeUint);
    }

    // Execute buy operation using memory parameters
    function _executeBuy(FlashLoanVars memory data, uint256 amount) 
        private 
        returns (uint256 boughtAmount) 
    {
        // Approve DEX 1 to spend borrowed WETH
        IERC20(weth).approve(data.buyDexRouter, amount);

        // Execute DEX 1 buy swap
        (bool success, bytes memory result) = data.buyDexRouter.call(data.buyCalldata);
        require(success, "Buy failed");

        // Decode swap result and get actual bought amount based on result length
        if (result.length > 32) {
            // V2 returns uint256[] array
            uint256[] memory amounts = abi.decode(result, (uint256[]));
            boughtAmount = amounts[amounts.length - 1];
        } else if (result.length == 32) {
            // V3 and Balancer return single uint256
            boughtAmount = abi.decode(result, (uint256));
        } else {
            // Curve returns nothing - check balance
            boughtAmount = IERC20(data.buyPath[1]).balanceOf(address(this));
        }

        // Verify we received the tokens
        require(
            IERC20(data.buyPath[1]).balanceOf(address(this)) >= boughtAmount,
            "Insufficient balance"
        );
    }

    // Execute sell operation using memory parameters
    function _executeSell(FlashLoanVars memory data, ExecutionContext memory ctx) 
        private 
    {
        // Approve DEX 2 to spend acquired tokens
        IERC20(data.buyPath[1]).approve(data.sellDexRouter, ctx.boughtAmount);

        // Choose profit basis points: dynamic if set, otherwise fallback
        uint256 profitBP = data.dynamicProfitFactor > 0
            ? data.dynamicProfitFactor
            : minProfitBasisPoints;
        
        // Calculate minimum required output for profitability
        uint256 minProfit = (ctx.amountBorrowed * profitBP) / 10000;
        uint256 minRequiredOutput = ctx.amountOwed + minProfit;
        
        // Apply dynamic slippage tolerance (using uint128 is sufficient for basis points)
        uint256 adjustedMinOutput = (minRequiredOutput * data.dynamicSlippageTolerance) / 10000;

        // Build sell calldata from scratch
        bytes memory sellCalldata = _buildSellCalldata(
            data.sellDexType,
            ctx.boughtAmount,
            adjustedMinOutput,
            data.buyPath,
            data.sellParams
        );

        // Execute sell swap
        (bool success, bytes memory resultData) = data.sellDexRouter.call(sellCalldata);
        if (!success) {
            assembly ("memory-safe") {
                let ptr := mload(0x40)
                let size := mload(resultData)
                revert(add(resultData, 0x20), size)
            }
        }

        // Verify profitability
        uint256 balance = IERC20(weth).balanceOf(address(this));
        require(balance >= ctx.amountOwed, "Not enough balance to repay loan");
        require(balance >= minRequiredOutput, "Trade not profitable enough");
    }

    // Consolidated sell calldata builder (single function for 5 DEX types)
    function _buildSellCalldata(
        DexType dexType,
        uint256 amountIn,
        uint256 minOut,
        address[] memory path,
        bytes memory params
    ) private view returns (bytes memory) {
        if (dexType == DexType.UNISWAP_V2) {
            // Build reversed path for Uniswap V2 sell
            address[] memory sellPath = new address[](path.length);
            for (uint256 i = 0; i < path.length; i++) {
                sellPath[i] = path[path.length - 1 - i];
            }
            
            return abi.encodeWithSelector(
                IUniswapV2Router.swapExactTokensForTokens.selector,
                amountIn,
                minOut,
                sellPath,
                address(this),
                block.timestamp + 3600
            );
        } 
        else if (dexType == DexType.UNISWAP_V3) { 
            uint24 fee = abi.decode(params, (uint24));
            
            return abi.encodeWithSelector(
                IUniswapV3Router.exactInputSingle.selector,
                IUniswapV3Router.ExactInputSingleParams({
                    tokenIn: path[1],
                    tokenOut: path[0],
                    fee: fee,
                    recipient: address(this),
                    deadline: block.timestamp + 3600,
                    amountIn: amountIn,
                    amountOutMinimum: minOut,
                    sqrtPriceLimitX96: 0
                })
            );
        } 
        else if (dexType == DexType.PANCAKESWAP_V3) {
            uint24 fee = abi.decode(params, (uint24));
        
            // Encode path for PancakeSwap's exactInput
            bytes memory encodedPath = abi.encodePacked(
                path[1],  // tokenIn (selling this)
                fee,      // fee tier
                path[0]   // tokenOut (want WETH back)
            );
        
            return abi.encodeWithSelector(
                IPancakeV3Router.exactInput.selector,
                IPancakeV3Router.ExactInputParams({
                    path: encodedPath,
                    recipient: address(this),
                    deadline: block.timestamp + 3600,
                    amountIn: amountIn,
                    amountOutMinimum: minOut
                })
            );
        }   
        else if (dexType == DexType.BALANCER) {
            (bytes32 poolId, uint8 kind) = abi.decode(params, (bytes32, uint8));
            
            return abi.encodeWithSelector(
                IBalancerVault.swap.selector,
                IBalancerVault.SingleSwap({
                    poolId: poolId,
                    kind: kind,
                    assetIn: path[1],
                    assetOut: path[0],
                    amount: amountIn,
                    userData: ""
                }),
                IBalancerVault.FundManagement({
                    sender: address(this),
                    fromInternalBalance: false,
                    recipient: payable(address(this)),
                    toInternalBalance: false
                }),
                minOut,
                block.timestamp + 3600
            );
        } 
        else {
            // CURVE
            (int128 i, int128 j) = abi.decode(params, (int128, int128));
            
            return abi.encodeWithSelector(
                ICurvePool.exchange.selector,
                i, j, amountIn, minOut
            );
        }
    }

    // Uniswap V3 swap callback (for Uniswap V3, SushiSwap V3, and PancakeSwap V3)
    function uniswapV3SwapCallback(
        int256 amount0Delta,
        int256 amount1Delta,
        bytes calldata data
    ) external override { 
        // Decode expected pool address from data
        (address expectedPool, address tokenIn, address tokenOut) = abi.decode(data, (address, address, address));
        require(msg.sender == expectedPool, "Callback: invalid pool");
        // Pay whichever token the pool expects
        if (amount0Delta > 0) {
            // token0 is path[1] when buying (WETH > token), so here token0 = WETH
            IERC20(tokenIn).transfer(expectedPool, uint256(amount0Delta));
        } else if (amount1Delta > 0) {
            // token1 is path[1] (the ERC20 token)
            IERC20(tokenOut).transfer(expectedPool, uint256(amount1Delta));
        }
    }   
    
    // Unwrap WETH to ETH using WrappedTokenGatewayV3 contract (can be called manually or automatically)
    function unwrapWETHToETH(uint256 wethAmount) external onlyOwnerOrBot nonReentrant {
        require(address(unwrapWETH) != address(0), "WrappedTokenGatewayV3 contract not set");        
        IERC20(weth).approve(address(unwrapWETH), wethAmount);
        unwrapWETH.withdrawETH(weth, wethAmount, address(this));
    }
 
    // Withdraw ETH to owner wallet (can be called manually or automatically)
    function withdrawETH(uint256 amount) external onlyOwnerOrBot nonReentrant {
        require(address(this).balance >= amount, "Insufficient ETH balance");
        payable(owner).transfer(amount);
    }

    // Manually withdraw ERC-20 tokens (can only be done manually if needed)
    function withdrawERC20(address tokenAddress, uint256 amount) external onlyOwner nonReentrant {
        IERC20 tokenToWithdraw = IERC20(tokenAddress);
        require(tokenToWithdraw.balanceOf(address(this)) >= amount, "Insufficient token balance");
        tokenToWithdraw.safeTransfer(owner, amount);
    }
}