Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import "@openzeppelin/contracts/access/Ownable.sol";
import "@openzeppelin/contracts/utils/math/Math.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";


interface ICMLE {
    function balanceOf(address _address) external view returns (uint256);
}

/**
 * @title PrivateSale Phase for VSTR
 * @dev A contract for managing a private token sale with vesting.
 */
contract PrivateSale is Ownable, ReentrancyGuard {
    using SafeERC20 for IERC20;
    using Math for uint256;

    event Deposit(address indexed account, uint256 amount);
    event Claim(address indexed account, uint256 amount);
    event Refund(
        address indexed account,
        address indexed sender,
        uint256 amount
    );
    event WithdrawUsdt(address indexed owner, uint256 usdt);
    event WithdrawToken(address indexed owner, uint256 token);
    event Whitelisted(address account, bool status);
    // Modifiers
    modifier onlyWhiteList() {
        require(
            whiteListStatus(_msgSender()),
            "WHITELIST:You are not in the Whitelist"
        );
        _;
    }

    // Constants
    uint256 internal constant RATE = 1e10;
    uint256 internal constant TOKEN_DECIMALS = 1e18;
    uint256 internal constant USDT_DECIMALS = 1e6;

    uint256 internal constant MIN_PURCHASE = 500 * USDT_DECIMALS;
    uint256 internal constant MAX_PURCHASE = 100_000 * USDT_DECIMALS;
    uint256 internal constant TOKEN_PRICE = 500; // 0.0005 USDT
    uint256 internal constant TOTAL_ALLOCATION = 2_000_000_000 * TOKEN_DECIMALS;
    uint256 internal constant TOTAL_EXPECTATION = 1_000_000 * USDT_DECIMALS;
    uint256 internal constant TGE_RELEASE_PERCENTAGE = 10;
    uint256 internal constant MONTHLY_RELEASE_PERCENTAGE = 5;

    // Vesting variables
    uint256 internal immutable START_TIME;
    uint256 internal immutable END_TIME;
    uint256 internal immutable START_VESTING_TIME;
    uint256 internal immutable WAITING_TIME;
    uint256 internal immutable UNLOCK_PERIODS;

    // State variables
    IERC20 public token;
    IERC20 public usdt;
    ICMLE public nft;

    uint256 public withdrawUsdtAmount;
    bool public isWithdrawToken;
    uint256 internal _totalParticipants;
    uint256 internal _totalInvestment;
    uint256 internal _refundedUserCount;
    uint256 internal _totalDistribution;

    struct AccountInfo{
        uint256 deposit;
        uint256 amountRequested;
        uint256 amountReceivedPool;
        uint256 refund;
        uint256 totalClaim;
        uint256 unlockedAmount;
        uint256 restAmount;
        uint256 nextUnlockAmount;
        uint256 nextUnlockTime;
        uint256 lastClaimTime;
        bool isCompleted;
        bool isRefunded;
    }

    struct VestingData {
        uint256 totalAmount;
        uint256 totalClaim;
        uint256 maturityReceived;
        uint256 lastClaimedTime;
        bool isRefunded;
    }

    mapping(address => bool) internal _whitelist;
    mapping(address => uint256) internal _deposits;
    mapping(address => VestingData) internal _vestings;


    /**
     * @dev Constructor to initialize the PrivateSale contract.
     * @param initialOwner The initial owner of the contract.
     * @param usdtAddress The address of the USDT token contract.
     * @param tokenAddress The address of the token contract.
     * @param nftAddress The address of the NFT contract.
     * @param startTime The start time of the private sale.
     * @param endTime The end time of the private sale.
     * @param startVestingTime The start time of vesting.
     * @param waitingTime The waiting period after the first unlock.
     * @param unlockPeriods The duration of each vesting period.
     */
    constructor(
        address initialOwner,
        address usdtAddress,
        address tokenAddress,
        address nftAddress,
        uint256 startTime,
        uint256 endTime,
        uint256 startVestingTime,
        uint256 waitingTime,
        uint256 unlockPeriods
    ) Ownable(initialOwner) {
        require(
            initialOwner != address(0),
            "PSALE:Owner's address cannot be zero"
        );
        require(usdtAddress != address(0), "PSALE:USDT address cannot be zero");
        require(
            tokenAddress != address(0),
            "PSALE:Token address cannot be zero"
        );
        require(nftAddress != address(0), "PSALE:NFT address cannot be zero");
        uint64 currentTime = uint64(block.timestamp);
        require(
            startTime > currentTime,
            "PSALE:Starting Private Sale Time must be in the future"
        );
        require(
            endTime > startTime,
            "PSALE:End time must be after the starting private sale time."
        );
        require(
            startVestingTime > endTime,
            "PSALE:Start Vesting Time must be after the end time."
        );

        token = IERC20(tokenAddress);
        usdt = IERC20(usdtAddress);
        nft = ICMLE(nftAddress);

        START_TIME = startTime; // start private sale
        END_TIME = endTime; // end private sale

        WAITING_TIME = waitingTime;
        UNLOCK_PERIODS = unlockPeriods;
        START_VESTING_TIME = startVestingTime;
    }


    /**
     * @notice Allows whitelisted users to deposit USDT and participate in the private sale.
     * @param usdtAmount The amount of USDT to deposit.
     */
    function buy(uint256 usdtAmount) external onlyWhiteList nonReentrant {
        require(
            block.timestamp >= START_TIME,
            "PSALE:Private Sale is not started"
        );
        require(block.timestamp <= END_TIME, "PSALE:Private Sale completed");
        address account = _msgSender();
        require(
            usdtAmount >= MIN_PURCHASE || _deposits[account] > 0,
            "PSALE:Purchasing amount must be minimum 500 USDT."
        );
        require(
            (_deposits[account] + usdtAmount) <= MAX_PURCHASE,
            "PSALE:You have exceeded the maximum purchase amount"
        );

        usdt.safeTransferFrom(account, address(this), usdtAmount);

        if (_deposits[account] == 0) {
            _totalParticipants++;
        }
        _deposits[account] += usdtAmount;
        _totalInvestment += usdtAmount;
        emit Deposit(account, usdtAmount);
    }

    /**
     * @notice Allows whitelisted users to deposit USDT and participate in the private sale.
     * @param account The address of USDT to deposit.
     */
    function deposit(address account) public view returns (uint256) {
        return _deposits[account];
    }

    /**
     * @notice Allows whitelisted users to claim their vested tokens.
     */
    function claim() external onlyWhiteList nonReentrant {
        uint256 currentTime = block.timestamp;
        require(
            currentTime >= START_VESTING_TIME,
            "PSALE:Distributions have not started yet"
        );
        address account = _msgSender();
        
        VestingData storage user = _vestings[account];
        require(
            user.totalAmount == 0 || user.totalAmount > user.totalClaim,
            "PSALE:All tokens have been claimed"
        );

        if (user.totalAmount == 0) {
            _sendRefund(account);
        }

        (uint256 amount, uint256 maturity) = _calculateClaim(
            user.totalAmount,
            user.lastClaimedTime,
            user.maturityReceived,
            currentTime
        );
        require(amount > 0, "PSALE:No tokens available for claim");

        user.totalClaim += amount;
        user.maturityReceived = maturity;
        user.lastClaimedTime = currentTime;

        token.safeTransfer(account, amount);
        emit Claim(account, amount);
    }


    function refundClaim() external onlyWhiteList nonReentrant {
        require(block.timestamp > END_TIME, "PSALE:Refund time is not started.");
        require(!_vestings[_msgSender()].isRefunded, "PSALE:Refund paid already.");
        _sendRefund(_msgSender());
    }
    
    function _sendRefund(address account) private {
        uint256 userDeposit = _deposits[account];
        require(
            userDeposit > 0,
            "PSALE:You did not participate in the private sale"
        );

        uint256 refundAmount = _refundedUsdt(userDeposit);
        if (refundAmount > 0) {
            usdt.safeTransfer(account, refundAmount);
            emit Refund(account, address(this), refundAmount);
        }
        uint256 calcTotalAmount = _poolAllocation(userDeposit, refundAmount);

        _vestings[account].totalAmount = calcTotalAmount;
        _vestings[account].isRefunded = true;

        _totalDistribution += calcTotalAmount; 
        _refundedUserCount ++;
    }

    function _poolAllocation(uint256 userDeposit, uint256 refundAmount) internal pure returns(uint256){
        return ((userDeposit - refundAmount) * TOKEN_DECIMALS) / TOKEN_PRICE; 
    }
    /**
     * @notice Retrieves information about the specified account.
     * @param account The address of the account.
     */
    function accountInfo(address account) public view returns(
        AccountInfo memory
        ){
            VestingData memory user = _vestings[account];
            AccountInfo memory i;

            uint256 userDeposit = deposit(account);
            uint256 totalAmount;
            if(user.totalAmount > 0){
                totalAmount = user.totalAmount;
            }else{
                uint256 refundAmount = _refundedUsdt(userDeposit);
                totalAmount = _poolAllocation(userDeposit, refundAmount);
            }

            (uint256 amount, uint256 maturity) = _calculateClaim(totalAmount, user.lastClaimedTime, user.maturityReceived, block.timestamp);
            
            i.deposit = userDeposit; // The deposited amount of USDT.          
            i.amountRequested = TOKEN_DECIMALS * (userDeposit / TOKEN_PRICE); // The total amount of tokens requested by the account.           
            i.amountReceivedPool = totalAmount;// The total amount of tokens received from the pool.            
            i.refund = _refundedUsdt(userDeposit); // The amount of USDT to be refunded.            
            i.totalClaim = user.totalClaim;// The total amount of tokens claimed by the account.
            i.unlockedAmount = amount; // The amount of tokens ready to be claimed.
            i.restAmount = (i.amountReceivedPool - user.totalClaim - amount); //The remaining amount of tokens to be unlocked.
            i.nextUnlockAmount = _nextUnlockAmount(i.amountReceivedPool); // The amount of tokens to be unlocked next.
            i.nextUnlockTime = userDeposit > 0 ? _nextUnlockTime(maturity) : 0; // The time of the next token unlock.
            i.lastClaimTime = user.lastClaimedTime; // The time of the last token claim.
            i.isCompleted =  user.totalClaim < i.amountReceivedPool ? false : true; // A boolean indicating whether all tokens have been claimed.
            i.isRefunded = user.isRefunded;
            return i;

    }

    /**
     * @notice Retrieves information about the PrivateSale contract.
     * @return startSaleTime The start time of the private sale.
     * @return endSaleTime The end time of the private sale.
     * @return startVestingTime The start time of vesting.
     * @return waitingTime The waiting time after the first unlock.
     * @return periodsTime The duration of each vesting period.
     * @return totalParticipants The total number of participants.
     * @return totalInvestment The total investment (in USDT).
     */
    function info() public view returns(
        uint256 startSaleTime,
        uint256 endSaleTime,
        uint256 startVestingTime,
        uint256 waitingTime,
        uint256 periodsTime,
        uint256 totalParticipants,
        uint256 totalInvestment
    ){
        return (
            START_TIME,
            END_TIME,
            START_VESTING_TIME,
            WAITING_TIME,
            UNLOCK_PERIODS,
            _totalParticipants,
            _totalInvestment
            );
    }


    /**
     * @notice Withdraw USDT and left tokens from poolsize. only by Owner
     * @param usdtAmount The amount of USDT to withdraw.
     */
    function withdrawUsdt(uint256 usdtAmount) external onlyOwner nonReentrant {
        require(
            block.timestamp > END_TIME,
            "PSALE:withdrawUsdt:Private sale process is still continue."
        );

        require(
            withdrawUsdtAmount + usdtAmount <= TOTAL_EXPECTATION - (TOKEN_PRICE * _totalParticipants),
            "PSALE:withdrawUsdt:Withdraw amount cannot exceed total expectation."
        );

        usdt.safeTransfer(owner(), usdtAmount);

        withdrawUsdtAmount += usdtAmount;

        emit WithdrawUsdt(owner(), usdtAmount);
    }

    /**
     * @notice Withdraw Token only by Owner
     */
    function withdrawToken() external onlyOwner nonReentrant {
        require(
            block.timestamp > END_TIME,
            "PSALE:withdrawToken:Private sale process is still continue."
        );
        require(!isWithdrawToken, "PSALE:You have withdrawn already");

        uint256 rmPoolToken;

        if(_totalInvestment >= TOTAL_EXPECTATION){
            require (_refundedUserCount == _totalParticipants, "PSALE:There is still user that is not claim.");
            rmPoolToken = TOTAL_ALLOCATION - _totalDistribution; 
        }else{
            rmPoolToken = TOTAL_ALLOCATION - (TOKEN_DECIMALS * (_totalInvestment / TOKEN_PRICE)); 
        } 

        // Token transfer process
        token.safeTransfer(owner(), rmPoolToken);

        isWithdrawToken = true;

        emit WithdrawToken(owner(), rmPoolToken);
    }

    /**
     * @notice Adds multiple addresses to the whitelist.
     * @param accounts The addresses to add to the whitelist.
     */
    function whiteListAdd(address[] memory accounts) external onlyOwner {
        for (uint256 i = 0; i < accounts.length; i++) {
            _whitelist[accounts[i]] = true;
            emit Whitelisted(accounts[i], true);
        }
    }

    /**
     * @notice Removes an address from the whitelist.
     * @param account The address to remove from the whitelist.
     */
    function whiteListRemove(address account) external onlyOwner {
        _whitelist[account] = false;
        emit Whitelisted(account, false);
    }

    /**
     * @notice Checks the whitelist status of an account.
     * @param account The address of the account.
     * @return status The whitelist status.
     */
    function whiteListStatus(address account) public view returns (bool) {
        return
            _whitelist[account]
                ? true
                : nft.balanceOf(account) > 0
                    ? true
                    : false;
    }

    /**
     * @dev Returns the next unlock amount based on the total amount and current time.
     * @param totalAmount Total amount to unlock.
     * @return uint256 The next unlock amount.
     */
    function _nextUnlockAmount(
        uint256 totalAmount
    ) internal view returns (uint256) {
        uint256 currentTime = block.timestamp;
        if (currentTime < START_VESTING_TIME) {
            // Return the amount to be claimed first
            return _tgeUnlockAmount(totalAmount);
        } else if (
            currentTime >= START_VESTING_TIME && currentTime < _endVestingTime()
        ) {
            // If the current time is after vesting start and before the end of TGE waiting period, return the next unlock amount.
            return _monthlyUnlockAmount(totalAmount);
        } else {
            return 0;
        }
    }

    /**
     * @dev Returns the next unlock time based on the maturity.
     * @param maturity The maturity period.
     * @return uint256 The next unlock time.
     */
    function _nextUnlockTime(uint256 maturity) internal view returns (uint256) {
        uint256 currentTime = block.timestamp;
        uint256 firstMaturity = _firstPeriodTime(); // First installment time
        if (currentTime < START_VESTING_TIME) {
            // If the current time is before vesting start, return the vesting date
            return START_VESTING_TIME;
        } else if (
            currentTime >= START_VESTING_TIME && currentTime < firstMaturity
        ) {
            // If the current time is after vesting start and before the first installment time, return the first maturity
            return firstMaturity;
        } else if (
            currentTime >= firstMaturity && currentTime < _endVestingTime()
        ) {
            // If the current time is after the first maturity and before the end of vesting, calculate the next unlock time
            return firstMaturity + (maturity * UNLOCK_PERIODS);
        } else {
            return 0;
        }
    }

    /**
     * @dev Calculates the claimable amount and maturity based on the total amount, last claimed time, maturity received, and current time.
     * @param totalAmount Total amount to calculate claim from.
     * @param lastClaimedTime Last time claimed.
     * @param maturityReceived Maturity already received.
     * @param currentTime Current time.
     * @return uint256 The claimable amount.
     * @return uint256 The maturity.
     */
    function _calculateClaim(
        uint256 totalAmount,
        uint256 lastClaimedTime,
        uint256 maturityReceived,
        uint256 currentTime
    ) internal view returns (uint256, uint256) {
        uint256 amount;
        uint256 maturity = _currentMaturity(currentTime);

        if (lastClaimedTime == 0 && currentTime >= START_VESTING_TIME) {
            amount += _tgeUnlockAmount(totalAmount);
        }

        amount +=
            (maturity - maturityReceived) *
            _monthlyUnlockAmount(totalAmount);

        return (amount, maturity);
    }

    /**
     * @dev Returns the current maturity based on the current time.
     * @param currentTime Current time.
     * @return uint256 The current maturity.
     */
    function _currentMaturity(
        uint256 currentTime
    ) internal view returns (uint256) {
        uint256 firstPeriodTime = _firstPeriodTime();

        if (currentTime < firstPeriodTime) {
            return 0;
        }

        (, uint256 _gapTime) = Math.trySub(currentTime, firstPeriodTime);
        (, uint256 _maturity) = Math.tryDiv(_gapTime, UNLOCK_PERIODS);
        return Math.min(_maturity + 1, _totalPeriods());
    }

    /**
     * @dev Calculates the refunded USDT amount based on the deposit and the amount.
     * @param _deposit The deposit amount.
     */
    function _refundedUsdt(
        uint256 _deposit
    ) internal view returns (uint256) {
        if (_totalInvestment > TOTAL_EXPECTATION) {
            uint256 poolRate = TOTAL_EXPECTATION * ((_deposit * RATE) / _totalInvestment);
            return (_deposit - (poolRate / RATE));
        }else{
            (, uint256 _refund) = Math.tryMod(_deposit, TOKEN_PRICE);
            return _refund; 
        }
    }


    /**
     * @dev Returns the TGE unlock amount.
     * @param amount The total amount.
     * @return uint256 The TGE unlock amount.
     */
    function _tgeUnlockAmount(uint256 amount) internal pure returns (uint256) {
        return Math.mulDiv(amount, TGE_RELEASE_PERCENTAGE, 100);
    }

    /**
     * @dev Returns the monthly unlock amount.
     * @param amount The total amount.
     * @return uint256 The monthly unlock amount.
     */
    function _monthlyUnlockAmount(
        uint256 amount
    ) internal pure returns (uint256) {
        return Math.mulDiv(amount, MONTHLY_RELEASE_PERCENTAGE, 100);
    }

    /**
     * @dev Returns the first period time.
     * @return uint256 The first period time.
     */
    function _firstPeriodTime() internal view returns (uint256) {
        return START_VESTING_TIME + WAITING_TIME;
    }

    /**
     * @dev Returns the end vesting time.
     * @return uint256 The end vesting time.
     */
    function _endVestingTime() internal view returns (uint256) {
        return
            START_VESTING_TIME +
            WAITING_TIME +
            (UNLOCK_PERIODS * (_totalPeriods() - 1));
    }

    /**
     * @dev Returns the total number of periods.
     * @return uint256 The total number of periods.
     */
    function _totalPeriods() internal pure returns (uint256) {
        return ((100 - TGE_RELEASE_PERCENTAGE) / MONTHLY_RELEASE_PERCENTAGE);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/Address.sol)

pragma solidity ^0.8.20;

/**
 * @dev Collection of functions related to the address type
 */
library Address {
    /**
     * @dev The ETH balance of the account is not enough to perform the operation.
     */
    error AddressInsufficientBalance(address account);

    /**
     * @dev There's no code at `target` (it is not a contract).
     */
    error AddressEmptyCode(address target);

    /**
     * @dev A call to an address target failed. The target may have reverted.
     */
    error FailedInnerCall();

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://consensys.net/diligence/blog/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.8.20/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        if (address(this).balance < amount) {
            revert AddressInsufficientBalance(address(this));
        }

        (bool success, ) = recipient.call{value: amount}("");
        if (!success) {
            revert FailedInnerCall();
        }
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason or custom error, it is bubbled
     * up by this function (like regular Solidity function calls). However, if
     * the call reverted with no returned reason, this function reverts with a
     * {FailedInnerCall} error.
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     */
    function functionCallWithValue(address target, bytes memory data, uint256 value) internal returns (bytes memory) {
        if (address(this).balance < value) {
            revert AddressInsufficientBalance(address(this));
        }
        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a delegate call.
     */
    function functionDelegateCall(address target, bytes memory data) internal returns (bytes memory) {
        (bool success, bytes memory returndata) = target.delegatecall(data);
        return verifyCallResultFromTarget(target, success, returndata);
    }

    /**
     * @dev Tool to verify that a low level call to smart-contract was successful, and reverts if the target
     * was not a contract or bubbling up the revert reason (falling back to {FailedInnerCall}) in case of an
     * unsuccessful call.
     */
    function verifyCallResultFromTarget(
        address target,
        bool success,
        bytes memory returndata
    ) internal view returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            // only check if target is a contract if the call was successful and the return data is empty
            // otherwise we already know that it was a contract
            if (returndata.length == 0 && target.code.length == 0) {
                revert AddressEmptyCode(target);
            }
            return returndata;
        }
    }

    /**
     * @dev Tool to verify that a low level call was successful, and reverts if it wasn't, either by bubbling the
     * revert reason or with a default {FailedInnerCall} error.
     */
    function verifyCallResult(bool success, bytes memory returndata) internal pure returns (bytes memory) {
        if (!success) {
            _revert(returndata);
        } else {
            return returndata;
        }
    }

    /**
     * @dev Reverts with returndata if present. Otherwise reverts with {FailedInnerCall}.
     */
    function _revert(bytes memory returndata) private pure {
        // Look for revert reason and bubble it up if present
        if (returndata.length > 0) {
            // The easiest way to bubble the revert reason is using memory via assembly
            /// @solidity memory-safe-assembly
            assembly {
                let returndata_size := mload(returndata)
                revert(add(32, returndata), returndata_size)
            }
        } else {
            revert FailedInnerCall();
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/math/Math.sol)

pragma solidity ^0.8.20;

/**
 * @dev Standard math utilities missing in the Solidity language.
 */
library Math {
    /**
     * @dev Muldiv operation overflow.
     */
    error MathOverflowedMulDiv();

    enum Rounding {
        Floor, // Toward negative infinity
        Ceil, // Toward positive infinity
        Trunc, // Toward zero
        Expand // Away from zero
    }

    /**
     * @dev Returns the addition of two unsigned integers, with an overflow flag.
     */
    function tryAdd(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            uint256 c = a + b;
            if (c < a) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the subtraction of two unsigned integers, with an overflow flag.
     */
    function trySub(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b > a) return (false, 0);
            return (true, a - b);
        }
    }

    /**
     * @dev Returns the multiplication of two unsigned integers, with an overflow flag.
     */
    function tryMul(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            // Gas optimization: this is cheaper than requiring 'a' not being zero, but the
            // benefit is lost if 'b' is also tested.
            // See: https://github.com/OpenZeppelin/openzeppelin-contracts/pull/522
            if (a == 0) return (true, 0);
            uint256 c = a * b;
            if (c / a != b) return (false, 0);
            return (true, c);
        }
    }

    /**
     * @dev Returns the division of two unsigned integers, with a division by zero flag.
     */
    function tryDiv(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a / b);
        }
    }

    /**
     * @dev Returns the remainder of dividing two unsigned integers, with a division by zero flag.
     */
    function tryMod(uint256 a, uint256 b) internal pure returns (bool, uint256) {
        unchecked {
            if (b == 0) return (false, 0);
            return (true, a % b);
        }
    }

    /**
     * @dev Returns the largest of two numbers.
     */
    function max(uint256 a, uint256 b) internal pure returns (uint256) {
        return a > b ? a : b;
    }

    /**
     * @dev Returns the smallest of two numbers.
     */
    function min(uint256 a, uint256 b) internal pure returns (uint256) {
        return a < b ? a : b;
    }

    /**
     * @dev Returns the average of two numbers. The result is rounded towards
     * zero.
     */
    function average(uint256 a, uint256 b) internal pure returns (uint256) {
        // (a + b) / 2 can overflow.
        return (a & b) + (a ^ b) / 2;
    }

    /**
     * @dev Returns the ceiling of the division of two numbers.
     *
     * This differs from standard division with `/` in that it rounds towards infinity instead
     * of rounding towards zero.
     */
    function ceilDiv(uint256 a, uint256 b) internal pure returns (uint256) {
        if (b == 0) {
            // Guarantee the same behavior as in a regular Solidity division.
            return a / b;
        }

        // (a + b - 1) / b can overflow on addition, so we distribute.
        return a == 0 ? 0 : (a - 1) / b + 1;
    }

    /**
     * @notice Calculates floor(x * y / denominator) with full precision. Throws if result overflows a uint256 or
     * denominator == 0.
     * @dev Original credit to Remco Bloemen under MIT license (https://xn--2-umb.com/21/muldiv) with further edits by
     * Uniswap Labs also under MIT license.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator) internal pure returns (uint256 result) {
        unchecked {
            // 512-bit multiply [prod1 prod0] = x * y. Compute the product mod 2^256 and mod 2^256 - 1, then use
            // use the Chinese Remainder Theorem to reconstruct the 512 bit result. The result is stored in two 256
            // variables such that product = prod1 * 2^256 + prod0.
            uint256 prod0 = x * y; // Least significant 256 bits of the product
            uint256 prod1; // Most significant 256 bits of the product
            assembly {
                let mm := mulmod(x, y, not(0))
                prod1 := sub(sub(mm, prod0), lt(mm, prod0))
            }

            // Handle non-overflow cases, 256 by 256 division.
            if (prod1 == 0) {
                // Solidity will revert if denominator == 0, unlike the div opcode on its own.
                // The surrounding unchecked block does not change this fact.
                // See https://docs.soliditylang.org/en/latest/control-structures.html#checked-or-unchecked-arithmetic.
                return prod0 / denominator;
            }

            // Make sure the result is less than 2^256. Also prevents denominator == 0.
            if (denominator <= prod1) {
                revert MathOverflowedMulDiv();
            }

            ///////////////////////////////////////////////
            // 512 by 256 division.
            ///////////////////////////////////////////////

            // Make division exact by subtracting the remainder from [prod1 prod0].
            uint256 remainder;
            assembly {
                // Compute remainder using mulmod.
                remainder := mulmod(x, y, denominator)

                // Subtract 256 bit number from 512 bit number.
                prod1 := sub(prod1, gt(remainder, prod0))
                prod0 := sub(prod0, remainder)
            }

            // Factor powers of two out of denominator and compute largest power of two divisor of denominator.
            // Always >= 1. See https://cs.stackexchange.com/q/138556/92363.

            uint256 twos = denominator & (0 - denominator);
            assembly {
                // Divide denominator by twos.
                denominator := div(denominator, twos)

                // Divide [prod1 prod0] by twos.
                prod0 := div(prod0, twos)

                // Flip twos such that it is 2^256 / twos. If twos is zero, then it becomes one.
                twos := add(div(sub(0, twos), twos), 1)
            }

            // Shift in bits from prod1 into prod0.
            prod0 |= prod1 * twos;

            // Invert denominator mod 2^256. Now that denominator is an odd number, it has an inverse modulo 2^256 such
            // that denominator * inv = 1 mod 2^256. Compute the inverse by starting with a seed that is correct for
            // four bits. That is, denominator * inv = 1 mod 2^4.
            uint256 inverse = (3 * denominator) ^ 2;

            // Use the Newton-Raphson iteration to improve the precision. Thanks to Hensel's lifting lemma, this also
            // works in modular arithmetic, doubling the correct bits in each step.
            inverse *= 2 - denominator * inverse; // inverse mod 2^8
            inverse *= 2 - denominator * inverse; // inverse mod 2^16
            inverse *= 2 - denominator * inverse; // inverse mod 2^32
            inverse *= 2 - denominator * inverse; // inverse mod 2^64
            inverse *= 2 - denominator * inverse; // inverse mod 2^128
            inverse *= 2 - denominator * inverse; // inverse mod 2^256

            // Because the division is now exact we can divide by multiplying with the modular inverse of denominator.
            // This will give us the correct result modulo 2^256. Since the preconditions guarantee that the outcome is
            // less than 2^256, this is the final result. We don't need to compute the high bits of the result and prod1
            // is no longer required.
            result = prod0 * inverse;
            return result;
        }
    }

    /**
     * @notice Calculates x * y / denominator with full precision, following the selected rounding direction.
     */
    function mulDiv(uint256 x, uint256 y, uint256 denominator, Rounding rounding) internal pure returns (uint256) {
        uint256 result = mulDiv(x, y, denominator);
        if (unsignedRoundsUp(rounding) && mulmod(x, y, denominator) > 0) {
            result += 1;
        }
        return result;
    }

    /**
     * @dev Returns the square root of a number. If the number is not a perfect square, the value is rounded
     * towards zero.
     *
     * Inspired by Henry S. Warren, Jr.'s "Hacker's Delight" (Chapter 11).
     */
    function sqrt(uint256 a) internal pure returns (uint256) {
        if (a == 0) {
            return 0;
        }

        // For our first guess, we get the biggest power of 2 which is smaller than the square root of the target.
        //
        // We know that the "msb" (most significant bit) of our target number `a` is a power of 2 such that we have
        // `msb(a) <= a < 2*msb(a)`. This value can be written `msb(a)=2**k` with `k=log2(a)`.
        //
        // This can be rewritten `2**log2(a) <= a < 2**(log2(a) + 1)`
        // → `sqrt(2**k) <= sqrt(a) < sqrt(2**(k+1))`
        // → `2**(k/2) <= sqrt(a) < 2**((k+1)/2) <= 2**(k/2 + 1)`
        //
        // Consequently, `2**(log2(a) / 2)` is a good first approximation of `sqrt(a)` with at least 1 correct bit.
        uint256 result = 1 << (log2(a) >> 1);

        // At this point `result` is an estimation with one bit of precision. We know the true value is a uint128,
        // since it is the square root of a uint256. Newton's method converges quadratically (precision doubles at
        // every iteration). We thus need at most 7 iteration to turn our partial result with one bit of precision
        // into the expected uint128 result.
        unchecked {
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            result = (result + a / result) >> 1;
            return min(result, a / result);
        }
    }

    /**
     * @notice Calculates sqrt(a), following the selected rounding direction.
     */
    function sqrt(uint256 a, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = sqrt(a);
            return result + (unsignedRoundsUp(rounding) && result * result < a ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 2 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log2(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 128;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 64;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 32;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 16;
            }
            if (value >> 8 > 0) {
                value >>= 8;
                result += 8;
            }
            if (value >> 4 > 0) {
                value >>= 4;
                result += 4;
            }
            if (value >> 2 > 0) {
                value >>= 2;
                result += 2;
            }
            if (value >> 1 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 2, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log2(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log2(value);
            return result + (unsignedRoundsUp(rounding) && 1 << result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 10 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     */
    function log10(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >= 10 ** 64) {
                value /= 10 ** 64;
                result += 64;
            }
            if (value >= 10 ** 32) {
                value /= 10 ** 32;
                result += 32;
            }
            if (value >= 10 ** 16) {
                value /= 10 ** 16;
                result += 16;
            }
            if (value >= 10 ** 8) {
                value /= 10 ** 8;
                result += 8;
            }
            if (value >= 10 ** 4) {
                value /= 10 ** 4;
                result += 4;
            }
            if (value >= 10 ** 2) {
                value /= 10 ** 2;
                result += 2;
            }
            if (value >= 10 ** 1) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 10, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log10(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log10(value);
            return result + (unsignedRoundsUp(rounding) && 10 ** result < value ? 1 : 0);
        }
    }

    /**
     * @dev Return the log in base 256 of a positive value rounded towards zero.
     * Returns 0 if given 0.
     *
     * Adding one to the result gives the number of pairs of hex symbols needed to represent `value` as a hex string.
     */
    function log256(uint256 value) internal pure returns (uint256) {
        uint256 result = 0;
        unchecked {
            if (value >> 128 > 0) {
                value >>= 128;
                result += 16;
            }
            if (value >> 64 > 0) {
                value >>= 64;
                result += 8;
            }
            if (value >> 32 > 0) {
                value >>= 32;
                result += 4;
            }
            if (value >> 16 > 0) {
                value >>= 16;
                result += 2;
            }
            if (value >> 8 > 0) {
                result += 1;
            }
        }
        return result;
    }

    /**
     * @dev Return the log in base 256, following the selected rounding direction, of a positive value.
     * Returns 0 if given 0.
     */
    function log256(uint256 value, Rounding rounding) internal pure returns (uint256) {
        unchecked {
            uint256 result = log256(value);
            return result + (unsignedRoundsUp(rounding) && 1 << (result << 3) < value ? 1 : 0);
        }
    }

    /**
     * @dev Returns whether a provided rounding mode is considered rounding up for unsigned integers.
     */
    function unsignedRoundsUp(Rounding rounding) internal pure returns (bool) {
        return uint8(rounding) % 2 == 1;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC20Permit} from "../extensions/IERC20Permit.sol";
import {Address} from "../../../utils/Address.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    using Address for address;

    /**
     * @dev An operation with an ERC20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We use {Address-functionCall} to perform this call, which verifies that
        // the target address contains contract code and also asserts for success in the low-level call.

        bytes memory returndata = address(token).functionCall(data);
        if (returndata.length != 0 && !abi.decode(returndata, (bool))) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silents catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        // We need to perform a low level call here, to bypass Solidity's return data size checking mechanism, since
        // we're implementing it ourselves. We cannot use {Address-functionCall} here since this should return false
        // and not revert is the subcall reverts.

        (bool success, bytes memory returndata) = address(token).call(data);
        return success && (returndata.length == 0 || abi.decode(returndata, (bool))) && address(token).code.length > 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (token/ERC20/extensions/IERC20Permit.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC20 Permit extension allowing approvals to be made via signatures, as defined in
 * https://eips.ethereum.org/EIPS/eip-2612[EIP-2612].
 *
 * Adds the {permit} method, which can be used to change an account's ERC20 allowance (see {IERC20-allowance}) by
 * presenting a message signed by the account. By not relying on {IERC20-approve}, the token holder account doesn't
 * need to send a transaction, and thus is not required to hold Ether at all.
 *
 * ==== Security Considerations
 *
 * There are two important considerations concerning the use of `permit`. The first is that a valid permit signature
 * expresses an allowance, and it should not be assumed to convey additional meaning. In particular, it should not be
 * considered as an intention to spend the allowance in any specific way. The second is that because permits have
 * built-in replay protection and can be submitted by anyone, they can be frontrun. A protocol that uses permits should
 * take this into consideration and allow a `permit` call to fail. Combining these two aspects, a pattern that may be
 * generally recommended is:
 *
 * ```solidity
 * function doThingWithPermit(..., uint256 value, uint256 deadline, uint8 v, bytes32 r, bytes32 s) public {
 *     try token.permit(msg.sender, address(this), value, deadline, v, r, s) {} catch {}
 *     doThing(..., value);
 * }
 *
 * function doThing(..., uint256 value) public {
 *     token.safeTransferFrom(msg.sender, address(this), value);
 *     ...
 * }
 * ```
 *
 * Observe that: 1) `msg.sender` is used as the owner, leaving no ambiguity as to the signer intent, and 2) the use of
 * `try/catch` allows the permit to fail and makes the code tolerant to frontrunning. (See also
 * {SafeERC20-safeTransferFrom}).
 *
 * Additionally, note that smart contract wallets (such as Argent or Safe) are not able to produce permit signatures, so
 * contracts should have entry points that don't rely on permit.
 */
interface IERC20Permit {
    /**
     * @dev Sets `value` as the allowance of `spender` over ``owner``'s tokens,
     * given ``owner``'s signed approval.
     *
     * IMPORTANT: The same issues {IERC20-approve} has related to transaction
     * ordering also apply here.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     * - `deadline` must be a timestamp in the future.
     * - `v`, `r` and `s` must be a valid `secp256k1` signature from `owner`
     * over the EIP712-formatted function arguments.
     * - the signature must use ``owner``'s current nonce (see {nonces}).
     *
     * For more information on the signature format, see the
     * https://eips.ethereum.org/EIPS/eip-2612#specification[relevant EIP
     * section].
     *
     * CAUTION: See Security Considerations above.
     */
    function permit(
        address owner,
        address spender,
        uint256 value,
        uint256 deadline,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) external;

    /**
     * @dev Returns the current nonce for `owner`. This value must be
     * included whenever a signature is generated for {permit}.
     *
     * Every successful call to {permit} increases ``owner``'s nonce by one. This
     * prevents a signature from being used multiple times.
     */
    function nonces(address owner) external view returns (uint256);

    /**
     * @dev Returns the domain separator used in the encoding of the signature for {permit}, as defined by {EIP712}.
     */
    // solhint-disable-next-line func-name-mixedcase
    function DOMAIN_SEPARATOR() external view returns (bytes32);
}