Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

interface IAnkrProtocol {

    // tier lifecycle events
    event TierLevelCreated(uint8 level);
    event TierLevelChanged(uint8 level);
    event TierLevelRemoved(uint8 level);

    // jwt token issue
    event TierAssigned(address indexed sender, uint256 amount, uint8 tier, uint256 roles, uint64 expires, bytes32 publicKey);

    // balance management
    event FundsLocked(address indexed sender, uint256 amount);
    event FundsUnlocked(address indexed sender, uint256 amount);
    event FeeCharged(address indexed sender, uint256 fee);

    function deposit(uint256 amount, uint64 timeout, bytes32 publicKey) external;

    function withdraw(uint256 amount) external;
}

interface IRequestFormat {

    function requestWithdrawal(address sender, uint256 amount) external;
}

interface ITransportLayer {

    event ProviderRequest(
        bytes32 id,
        address sender,
        uint256 fee,
        address callback,
        bytes data,
        uint64 expires
    );

    function handleChargeFee(address[] calldata users, uint256[] calldata fees) external;

    function handleWithdraw(address[] calldata users, uint256[] calldata amounts, uint256[] calldata fees) external;
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

import "@openzeppelin/contracts-upgradeable/token/ERC20/IERC20Upgradeable.sol";

interface IERC20Mintable {

    function mint(address account, uint256 amount) external;

    function burn(address account, uint256 amount) external;
}

interface IERC20Extra {

    function name() external returns (string memory);

    function decimals() external returns (uint8);

    function symbol() external returns (string memory);
}

interface IERC20Pegged {

    function getOrigin() external view returns (uint256, address);
}

interface IERC20InternetBond {

    function ratio() external view returns (uint256);
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

interface IGovernable {

    function getGovernanceAddress() external view returns (address);
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

import "./IStakingConfig.sol";

interface IStaking {

    function getStakingConfig() external view returns (IStakingConfig);

    function getValidators() external view returns (address[] memory);

    function isValidatorActive(address validator) external view returns (bool);

    function isValidator(address validator) external view returns (bool);

    function getValidatorStatus(address validator) external view returns (
        address ownerAddress,
        uint8 status,
        uint256 totalDelegated,
        uint32 slashesCount,
        uint64 changedAt,
        uint64 jailedBefore,
        uint64 claimedAt,
        uint16 commissionRate,
        uint96 totalRewards
    );

    function getValidatorStatusAtEpoch(address validator, uint64 epoch) external view returns (
        address ownerAddress,
        uint8 status,
        uint256 totalDelegated,
        uint32 slashesCount,
        uint64 changedAt,
        uint64 jailedBefore,
        uint64 claimedAt,
        uint16 commissionRate,
        uint96 totalRewards
    );

    function getValidatorByOwner(address owner) external view returns (address);

    function registerValidator(address validator, uint16 commissionRate) payable external;

    function addValidator(address validator) external;

    function removeValidator(address validator) external;

    function activateValidator(address validator) external;

    function disableValidator(address validator) external;

    function releaseValidatorFromJail(address validator) external;

    function changeValidatorCommissionRate(address validator, uint16 commissionRate) external;

    function changeValidatorOwner(address validator, address newOwner) external;

    function getValidatorDelegation(address validator, address delegator) external view returns (
        uint256 delegatedAmount,
        uint64 atEpoch
    );

    function delegate(address validator, uint256 amount) payable external;

    function undelegate(address validator, uint256 amount) external;

    function getValidatorFee(address validator) external view returns (uint256);

    function getPendingValidatorFee(address validator) external view returns (uint256);

    function claimValidatorFee(address validator) external;

    function getDelegatorFee(address validator, address delegator) external view returns (uint256);

    function getPendingDelegatorFee(address validator, address delegator) external view returns (uint256);

    function claimDelegatorFee(address validator) external;

    function claimStakingRewards(address validatorAddress) external;

    function claimPendingUndelegates(address validator) external;

    function calcAvailableForRedelegateAmount(address validator, address delegator) external view returns (uint256 amountToStake, uint256 rewardsDust);

    function redelegateDelegatorFee(address validator) external;

    function currentEpoch() external view returns (uint64);

    function nextEpoch() external view returns (uint64);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (utils/Context.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract ContextUpgradeable is Initializable {
    function __Context_init() internal onlyInitializing {
    }

    function __Context_init_unchained() internal onlyInitializing {
    }
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[50] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20 {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";

import "./IStaking.sol";

interface ITokenStaking is IStaking {

    function getErc20Token() external view returns (IERC20);

    function distributeRewards(address validatorAddress, uint256 amount) external;
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

import "./IGovernable.sol";

interface IEarnConfig is IGovernable {

    function getConsensusAddress() external view returns (address);

    function setConsensusAddress(address newValue) external;

    function getGovernanceAddress() external view override returns (address);

    function setGovernanceAddress(address newValue) external;

    function getTreasuryAddress() external view returns (address);

    function setTreasuryAddress(address newValue) external;

    function getSwapFeeRatio() external view returns (uint16);

    function setSwapFeeRatio(uint16 newValue) external;

    function pauseBondStaking() external;

    function unpauseBondStaking() external;

    function isBondStakingPaused() external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (access/Ownable.sol)

pragma solidity ^0.8.0;

import "../utils/ContextUpgradeable.sol";
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * By default, the owner account will be the one that deploys the contract. This
 * can later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract OwnableUpgradeable is Initializable, ContextUpgradeable {
    address private _owner;

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the deployer as the initial owner.
     */
    function __Ownable_init() internal onlyInitializing {
        __Ownable_init_unchained();
    }

    function __Ownable_init_unchained() internal onlyInitializing {
        _transferOwnership(_msgSender());
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        require(owner() == _msgSender(), "Ownable: caller is not the owner");
        _;
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions anymore. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby removing any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        require(newOwner != address(0), "Ownable: new owner is the zero address");
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

import "@openzeppelin/contracts-upgradeable/access/OwnableUpgradeable.sol";
import "@openzeppelin/contracts-upgradeable/security/ReentrancyGuardUpgradeable.sol";

import "../interfaces/IAnkrProtocol.sol";
import "../interfaces/IERC20.sol";
import "../interfaces/IStakingConfig.sol";
import "../interfaces/IEarnConfig.sol";
import "../interfaces/ITokenStaking.sol";

contract PayAsYouGo is ReentrancyGuardUpgradeable, IAnkrProtocol, ITransportLayer {

    uint256 internal constant BALANCE_COMPACT_PRECISION = 1e8;
    uint256 internal constant DEPOSIT_WITHDRAW_PRECISION = 1e15;

    event MinWithdrawAmountSet(uint256 amount);
    event InstantlyChargeCollectedFee(uint256 amount);
    event ManuallyFeedCollectedFee(uint256 amount);

    struct UserBalance {
        uint80 available;
        uint80 pending;
    }

    IERC20Upgradeable internal _ankrToken;
    IEarnConfig internal _earnConfig;
    mapping(address => UserBalance) internal _userDeposits;
    mapping(address => uint64) internal _requestNonce;
    uint256 internal _collectedFee;
    uint256 internal _minWithdrawAmount;

    function initialize(IEarnConfig earnConfig, IERC20Upgradeable ankrToken) external initializer {
        __ReentrancyGuard_init();
        __AnkrProtocol_init(earnConfig, ankrToken);
    }

    function __AnkrProtocol_init(IEarnConfig earnConfig, IERC20Upgradeable ankrToken) internal {
        _ankrToken = ankrToken;
        _earnConfig = earnConfig;
    }

    modifier onlyGovernance() {
        require(msg.sender == address(_earnConfig.getGovernanceAddress()), "PayAsYouGo: only governance");
        _;
    }

    modifier onlyConsensus() {
        require(msg.sender == address(_earnConfig.getConsensusAddress()), "PayAsYouGo: only consensus");
        _;
    }

    modifier onlyTreasury() {
        require(msg.sender == address(_earnConfig.getTreasuryAddress()), "PayAsYouGo: only treasury");
        _;
    }

    function getUserBalance(address user) external view returns (
        uint256 available,
        uint256 pending
    ) {
        UserBalance memory userDeposit = _userDeposits[user];
        return (
        uint256(userDeposit.available) * BALANCE_COMPACT_PRECISION,
        uint256(userDeposit.pending) * BALANCE_COMPACT_PRECISION
        );
    }

    function deposit(uint256 amount, uint64 timeout, bytes32 publicKey) external nonReentrant override {
        require(amount % BALANCE_COMPACT_PRECISION == 0, "PayAsYouGo: remainder is not allowed");
        require(amount % DEPOSIT_WITHDRAW_PRECISION == 0, "PayAsYouGo: too high precision");
        _lockDepositForUser(msg.sender, amount, timeout, msg.sender, publicKey);
    }

    function depositForUser(uint256 amount, uint64 timeout, address user, bytes32 publicKey) external nonReentrant {
        require(amount % BALANCE_COMPACT_PRECISION == 0, "PayAsYouGo: remainder is not allowed");
        require(amount % DEPOSIT_WITHDRAW_PRECISION == 0, "PayAsYouGo: too high precision");
        _lockDepositForUser(msg.sender, amount, timeout, user, publicKey);
    }

    // function _lockDeposit(address sender, uint256 amount, uint64 timeout, bytes32 publicKey) internal {
    //     if (amount > 0) {
    //         require(_ankrToken.transferFrom(msg.sender, address(this), amount), "PayAsYouGo: can't transfer");
    //     }
    //     // obtain user's lock and match next tier level
    //     UserBalance memory userDeposit = _userDeposits[sender];
    //     userDeposit.available += uint80(amount / BALANCE_COMPACT_PRECISION);
    //     _userDeposits[sender] = userDeposit;
    //     emit FundsLocked(sender, amount);
    //     // emit event for JWT token
    //     emit TierAssigned(sender, amount, 0, 0, uint64(block.timestamp + timeout), publicKey);
    // }

    function _lockDepositForUser(address sender, uint256 amount, uint64 timeout, address user, bytes32 publicKey) internal {
        if (amount > 0) {
            require(_ankrToken.transferFrom(sender, address(this), amount), "PayAsYouGo: can't transfer");
        }
        // obtain user's lock and match next tier level
        UserBalance memory userDeposit = _userDeposits[user];
        userDeposit.available += uint80(amount / BALANCE_COMPACT_PRECISION);
        _userDeposits[user] = userDeposit;
        emit FundsLocked(user, amount);
        // emit event for JWT token
        emit TierAssigned(user, amount, 0, 0, uint64(block.timestamp + timeout), publicKey);
    }

    function withdraw(uint256 amount) external nonReentrant override {
        require(amount >= _minWithdrawAmount, "PayAsYouGo: amount too low");
        require(amount % BALANCE_COMPACT_PRECISION == 0, "PayAsYouGo: remainder is not allowed");
        require(amount % DEPOSIT_WITHDRAW_PRECISION == 0, "PayAsYouGo: too high precision");
        _createWithdrawal(msg.sender, amount);
    }

    function _createWithdrawal(address sender, uint256 amount) internal {
        uint80 amount80 = uint80(amount / BALANCE_COMPACT_PRECISION);
        UserBalance memory userDeposit = _userDeposits[sender];
        require(userDeposit.available >= amount80, "PayAsYouGo: insufficient balance");
        require(userDeposit.pending == 0, "PayAsYouGo: already have pending withdrawal");
        userDeposit.available -= amount80;
        userDeposit.pending += amount80;
        _userDeposits[sender] = userDeposit;
        // trigger withdraw request
        bytes memory input = abi.encodeWithSelector(IRequestFormat.requestWithdrawal.selector, sender, amount);
        _triggerRequestEvent(sender, 0, input);
    }

    function handleChargeFee(address[] calldata users, uint256[] calldata fees) external onlyConsensus override {
        require(users.length == fees.length);
        for (uint256 i = 0; i < users.length; i++) {
            _chargeAnkrFor(users[i], fees[i]);
        }
    }

    function _chargeAnkrFor(address sender, uint256 fee) internal {
        uint80 fee80 = uint80(fee / BALANCE_COMPACT_PRECISION);
        UserBalance memory userDeposit = _userDeposits[sender];
        require((userDeposit.pending + userDeposit.available) >= fee80, "PayAsYouGo: insufficient balance");
        if (userDeposit.available >= fee80) {
            userDeposit.available -= fee80;
        } else {
            userDeposit.pending -= (fee80 - userDeposit.available);
            userDeposit.available = 0;
        }
        _userDeposits[sender] = userDeposit;
        _collectedFee += fee;
        emit FeeCharged(sender, fee);
    }

    function handleWithdraw(address[] calldata users, uint256[] calldata amounts, uint256[] calldata fees) external onlyConsensus override {
        require(users.length == amounts.length && amounts.length == fees.length, "PayAsYouGo: corrupted data");
        for (uint256 i = 0; i < users.length; i++) {
            _doWithdraw(users[i], amounts[i], fees[i]);
        }
    }

    function _doWithdraw(address user, uint256 amount, uint256 fee) internal {
        uint80 amount80 = uint80(amount / BALANCE_COMPACT_PRECISION);
        uint80 fee80 = uint80(fee / BALANCE_COMPACT_PRECISION);
        // decrease user's balance
        UserBalance memory userDeposit = _userDeposits[user];
        require(userDeposit.pending >= amount80, "PayAsYouGo: wrong withdraw amount");
        require((userDeposit.pending + userDeposit.available) >= (amount80 + fee80), "PayAsYouGo: insufficient balance");
        userDeposit.available += userDeposit.pending - amount80;
        userDeposit.pending = 0;
        _userDeposits[user] = userDeposit;
        // if we have specified fee then charge it from user's account
        if (fee > 0) {
            _chargeAnkrFor(user, fee);
        }
        // transfer funds to user
        require(_ankrToken.transfer(user, amount), "PayAsYouGo: can't transfer");
        // emit event
        emit FundsUnlocked(user, amount);
    }

    function _triggerRequestEvent(address sender, uint64 lifetime, bytes memory input) internal {
        // increase nonce
        uint64 nonce = _requestNonce[sender];
        _requestNonce[sender]++;
        // calc request id
        bytes32 id = keccak256(abi.encodePacked(sender, nonce, block.chainid, input));
        // request expiration time (default lifetime is 1 week)
        if (lifetime == 0) {
            lifetime = 604800;
        }
        uint64 expires = uint64(block.timestamp) + lifetime;
        // emit as event to provider
        emit ProviderRequest(id, sender, 0, address(this), input, expires);
    }

    function setMinWithdrawAmount(uint256 minWithdrawalAmount) external onlyGovernance {
        require(minWithdrawalAmount % BALANCE_COMPACT_PRECISION == 0, "PayAsYouGo: remainder is not allowed");
        _minWithdrawAmount = minWithdrawalAmount;
        emit MinWithdrawAmountSet(minWithdrawalAmount);
    }

    function getMinWithdrawAmount() external view returns (uint256) {
        return _minWithdrawAmount;
    }

    function getCollectedFee() external view returns (uint256) {
        return _collectedFee;
    }

    function instantlyChargeCollectedFee(uint256 amount) external onlyGovernance {
        _collectedFee -= amount;
        emit InstantlyChargeCollectedFee(amount);
    }

    function manuallyFeedCollectedFee(uint256 amount) external {
        require(_ankrToken.transferFrom(msg.sender, address(this), amount), "PayAsYoGo: failed to transfer");
        _collectedFee += amount;
        emit ManuallyFeedCollectedFee(amount);
    }

    function deliverReward(address stakingContract, address validatorAddress, uint256 amount) external onlyConsensus {
        require(amount <= _collectedFee, "PayAsYouGo: insufficient fee");
        _collectedFee -= amount;
        require(_ankrToken.approve(stakingContract, amount), "PayAsYouGo: can't increase allowance");
        ITokenStaking(stakingContract).distributeRewards(validatorAddress, amount);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (proxy/utils/Initializable.sol)

pragma solidity ^0.8.0;

import "../../utils/AddressUpgradeable.sol";

/**
 * @dev This is a base contract to aid in writing upgradeable contracts, or any kind of contract that will be deployed
 * behind a proxy. Since proxied contracts do not make use of a constructor, it's common to move constructor logic to an
 * external initializer function, usually called `initialize`. It then becomes necessary to protect this initializer
 * function so it can only be called once. The {initializer} modifier provided by this contract will have this effect.
 *
 * TIP: To avoid leaving the proxy in an uninitialized state, the initializer function should be called as early as
 * possible by providing the encoded function call as the `_data` argument to {ERC1967Proxy-constructor}.
 *
 * CAUTION: When used with inheritance, manual care must be taken to not invoke a parent initializer twice, or to ensure
 * that all initializers are idempotent. This is not verified automatically as constructors are by Solidity.
 *
 * [CAUTION]
 * ====
 * Avoid leaving a contract uninitialized.
 *
 * An uninitialized contract can be taken over by an attacker. This applies to both a proxy and its implementation
 * contract, which may impact the proxy. To initialize the implementation contract, you can either invoke the
 * initializer manually, or you can include a constructor to automatically mark it as initialized when it is deployed:
 *
 * [.hljs-theme-light.nopadding]
 * ```
 * /// @custom:oz-upgrades-unsafe-allow constructor
 * constructor() initializer {}
 * ```
 * ====
 */
abstract contract Initializable {
    /**
     * @dev Indicates that the contract has been initialized.
     */
    bool private _initialized;

    /**
     * @dev Indicates that the contract is in the process of being initialized.
     */
    bool private _initializing;

    /**
     * @dev Modifier to protect an initializer function from being invoked twice.
     */
    modifier initializer() {
        // If the contract is initializing we ignore whether _initialized is set in order to support multiple
        // inheritance patterns, but we only do this in the context of a constructor, because in other contexts the
        // contract may have been reentered.
        require(_initializing ? _isConstructor() : !_initialized, "Initializable: contract is already initialized");

        bool isTopLevelCall = !_initializing;
        if (isTopLevelCall) {
            _initializing = true;
            _initialized = true;
        }

        _;

        if (isTopLevelCall) {
            _initializing = false;
        }
    }

    /**
     * @dev Modifier to protect an initialization function so that it can only be invoked by functions with the
     * {initializer} modifier, directly or indirectly.
     */
    modifier onlyInitializing() {
        require(_initializing, "Initializable: contract is not initializing");
        _;
    }

    function _isConstructor() private view returns (bool) {
        return !AddressUpgradeable.isContract(address(this));
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts v4.4.1 (security/ReentrancyGuard.sol)

pragma solidity ^0.8.0;
import "../proxy/utils/Initializable.sol";

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuardUpgradeable is Initializable {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant _NOT_ENTERED = 1;
    uint256 private constant _ENTERED = 2;

    uint256 private _status;

    function __ReentrancyGuard_init() internal onlyInitializing {
        __ReentrancyGuard_init_unchained();
    }

    function __ReentrancyGuard_init_unchained() internal onlyInitializing {
        _status = _NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        // On the first call to nonReentrant, _notEntered will be true
        require(_status != _ENTERED, "ReentrancyGuard: reentrant call");

        // Any calls to nonReentrant after this point will fail
        _status = _ENTERED;

        _;

        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = _NOT_ENTERED;
    }

    /**
     * @dev This empty reserved space is put in place to allow future versions to add new
     * variables without shifting down storage in the inheritance chain.
     * See https://docs.openzeppelin.com/contracts/4.x/upgradeable#storage_gaps
     */
    uint256[49] private __gap;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.0;

/**
 * @dev Interface of the ERC20 standard as defined in the EIP.
 */
interface IERC20Upgradeable {
    /**
     * @dev Returns the amount of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the amount of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves `amount` tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 amount) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets `amount` as the allowance of `spender` over the caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 amount) external returns (bool);

    /**
     * @dev Moves `amount` tokens from `from` to `to` using the
     * allowance mechanism. `amount` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(
        address from,
        address to,
        uint256 amount
    ) external returns (bool);

    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v4.5.0) (utils/Address.sol)

pragma solidity ^0.8.1;

/**
 * @dev Collection of functions related to the address type
 */
library AddressUpgradeable {
    /**
     * @dev Returns true if `account` is a contract.
     *
     * [IMPORTANT]
     * ====
     * It is unsafe to assume that an address for which this function returns
     * false is an externally-owned account (EOA) and not a contract.
     *
     * Among others, `isContract` will return false for the following
     * types of addresses:
     *
     *  - an externally-owned account
     *  - a contract in construction
     *  - an address where a contract will be created
     *  - an address where a contract lived, but was destroyed
     * ====
     *
     * [IMPORTANT]
     * ====
     * You shouldn't rely on `isContract` to protect against flash loan attacks!
     *
     * Preventing calls from contracts is highly discouraged. It breaks composability, breaks support for smart wallets
     * like Gnosis Safe, and does not provide security since it can be circumvented by calling from a contract
     * constructor.
     * ====
     */
    function isContract(address account) internal view returns (bool) {
        // This method relies on extcodesize/address.code.length, which returns 0
        // for contracts in construction, since the code is only stored at the end
        // of the constructor execution.

        return account.code.length > 0;
    }

    /**
     * @dev Replacement for Solidity's `transfer`: sends `amount` wei to
     * `recipient`, forwarding all available gas and reverting on errors.
     *
     * https://eips.ethereum.org/EIPS/eip-1884[EIP1884] increases the gas cost
     * of certain opcodes, possibly making contracts go over the 2300 gas limit
     * imposed by `transfer`, making them unable to receive funds via
     * `transfer`. {sendValue} removes this limitation.
     *
     * https://diligence.consensys.net/posts/2019/09/stop-using-soliditys-transfer-now/[Learn more].
     *
     * IMPORTANT: because control is transferred to `recipient`, care must be
     * taken to not create reentrancy vulnerabilities. Consider using
     * {ReentrancyGuard} or the
     * https://solidity.readthedocs.io/en/v0.5.11/security-considerations.html#use-the-checks-effects-interactions-pattern[checks-effects-interactions pattern].
     */
    function sendValue(address payable recipient, uint256 amount) internal {
        require(address(this).balance >= amount, "Address: insufficient balance");

        (bool success, ) = recipient.call{value: amount}("");
        require(success, "Address: unable to send value, recipient may have reverted");
    }

    /**
     * @dev Performs a Solidity function call using a low level `call`. A
     * plain `call` is an unsafe replacement for a function call: use this
     * function instead.
     *
     * If `target` reverts with a revert reason, it is bubbled up by this
     * function (like regular Solidity function calls).
     *
     * Returns the raw returned data. To convert to the expected return value,
     * use https://solidity.readthedocs.io/en/latest/units-and-global-variables.html?highlight=abi.decode#abi-encoding-and-decoding-functions[`abi.decode`].
     *
     * Requirements:
     *
     * - `target` must be a contract.
     * - calling `target` with `data` must not revert.
     *
     * _Available since v3.1._
     */
    function functionCall(address target, bytes memory data) internal returns (bytes memory) {
        return functionCall(target, data, "Address: low-level call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`], but with
     * `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, 0, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but also transferring `value` wei to `target`.
     *
     * Requirements:
     *
     * - the calling contract must have an ETH balance of at least `value`.
     * - the called Solidity function must be `payable`.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value
    ) internal returns (bytes memory) {
        return functionCallWithValue(target, data, value, "Address: low-level call with value failed");
    }

    /**
     * @dev Same as {xref-Address-functionCallWithValue-address-bytes-uint256-}[`functionCallWithValue`], but
     * with `errorMessage` as a fallback revert reason when `target` reverts.
     *
     * _Available since v3.1._
     */
    function functionCallWithValue(
        address target,
        bytes memory data,
        uint256 value,
        string memory errorMessage
    ) internal returns (bytes memory) {
        require(address(this).balance >= value, "Address: insufficient balance for call");
        require(isContract(target), "Address: call to non-contract");

        (bool success, bytes memory returndata) = target.call{value: value}(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(address target, bytes memory data) internal view returns (bytes memory) {
        return functionStaticCall(target, data, "Address: low-level static call failed");
    }

    /**
     * @dev Same as {xref-Address-functionCall-address-bytes-string-}[`functionCall`],
     * but performing a static call.
     *
     * _Available since v3.3._
     */
    function functionStaticCall(
        address target,
        bytes memory data,
        string memory errorMessage
    ) internal view returns (bytes memory) {
        require(isContract(target), "Address: static call to non-contract");

        (bool success, bytes memory returndata) = target.staticcall(data);
        return verifyCallResult(success, returndata, errorMessage);
    }

    /**
     * @dev Tool to verifies that a low level call was successful, and revert if it wasn't, either by bubbling the
     * revert reason using the provided one.
     *
     * _Available since v4.3._
     */
    function verifyCallResult(
        bool success,
        bytes memory returndata,
        string memory errorMessage
    ) internal pure returns (bytes memory) {
        if (success) {
            return returndata;
        } else {
            // Look for revert reason and bubble it up if present
            if (returndata.length > 0) {
                // The easiest way to bubble the revert reason is using memory via assembly

                assembly {
                    let returndata_size := mload(returndata)
                    revert(add(32, returndata), returndata_size)
                }
            } else {
                revert(errorMessage);
            }
        }
    }
}

// SPDX-License-Identifier: GPL-3.0-only
pragma solidity ^0.8.7;

import "./IGovernable.sol";

interface IStakingConfig is IGovernable {

    function getActiveValidatorsLength() external view returns (uint32);

    function setActiveValidatorsLength(uint32 newValue) external;

    function getEpochBlockInterval() external view returns (uint32);

    function setEpochBlockInterval(uint32 newValue) external;

    function getMisdemeanorThreshold() external view returns (uint32);

    function setMisdemeanorThreshold(uint32 newValue) external;

    function getFelonyThreshold() external view returns (uint32);

    function setFelonyThreshold(uint32 newValue) external;

    function getValidatorJailEpochLength() external view returns (uint32);

    function setValidatorJailEpochLength(uint32 newValue) external;

    function getUndelegatePeriod() external view returns (uint32);

    function setUndelegatePeriod(uint32 newValue) external;

    function getMinValidatorStakeAmount() external view returns (uint256);

    function setMinValidatorStakeAmount(uint256 newValue) external;

    function getMinStakingAmount() external view returns (uint256);

    function setMinStakingAmount(uint256 newValue) external;

    function getGovernanceAddress() external view override returns (address);

    function setGovernanceAddress(address newValue) external;

    function getTreasuryAddress() external view returns (address);

    function setTreasuryAddress(address newValue) external;

    function getLockPeriod() external view returns (uint64);

    function setLockPeriod(uint64 newValue) external;
}