Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.24;

import "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
import "@openzeppelin/contracts/token/ERC721/extensions/IERC721Metadata.sol";
import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC721/IERC721.sol";
import "@openzeppelin/contracts/utils/ReentrancyGuard.sol";
import "@openzeppelin/contracts/token/ERC721/IERC721Receiver.sol";

interface IFactory {
    function getArtworks() external view returns (address[] memory);
}

contract WeiRui is ReentrancyGuard, IERC721Receiver {
    event UpdateToken(address tokenAddr, uint256 decimal);
    event UpdateCollector(uint16 artworkId, address collector);
    event AddArtwork(address artworkAddr, uint16 artworkId);
    event UpdateArtworkAddress(uint16 artworkId, address newAddr);
    event UpdateStatus(uint16 artworkId, Status status);
    event ActivateArtwork(uint16 artworkId, bool isActive);
    event Request(uint16 artworkId);
    event Confirm(uint16 artworkId);
    event Redeem(uint16 artworkId);
    event List(uint16 artworkId, uint64 amount);
    event PlaceBid(uint16 artworkId, uint64 amount);
    event AcceptBid(uint16 artworkId, address bidder, uint64 amount);
    event Buy(uint16 artworkId, uint64 amount);
    event Fee(uint256 fee);

    address public owner;
    address public factoryAddr;
    uint16 public nextArtworkId;
    mapping(address => bool) public isArtwork;
    mapping(uint16 => Artwork) public artworks;

    uint64 public totalBalance;
    mapping(address => uint64) public balanceOf;
    mapping(uint16 => mapping(address => uint64)) public bids; // Keep track of collector deposit for each bid
    mapping(uint16 => mapping(address => bool)) public isBid; // This will return true if the bidder bid is in the topBids
    mapping(uint16 => Bid[]) public topBids;

    IERC20 public token;
    uint256 public decimals;

    enum Status {
        COLLECTORHOLDING, 
        TRANSPORTINGFROM, 
        ARTISTREVIEWING, 
        TRANSPORTINGTO, 
        INVAULT
    }

    struct Artwork {
        uint16 id;
        address artwork;
        address collector;
        Status status;
        uint64 listingPriceInEth;
        bool isActive; // In case someone lost his private key
    }

    struct Bid {
        address from;
        uint64 price;
    }

    modifier isOwner() {
        require(msg.sender == owner, "Not owner");
        _;
    }

    constructor(
        address _tokenAddr, 
        uint256 _decimals
    ) {
        owner = msg.sender;
        nextArtworkId = 1;
        token = IERC20(_tokenAddr);
        decimals = _decimals;
    }

    function initiateFactory(address _factoryAddr) public isOwner {
        require(factoryAddr == address(0), "Updated");
        factoryAddr = _factoryAddr;
    }

    function updateToken(address _tokenAddr, uint256 _decimals) public isOwner {
        require(totalBalance == 0, "Account has balance");
        require(_decimals <= 18, "Exceed max bound");
        token = IERC20(_tokenAddr);
        decimals = _decimals;
        emit UpdateToken(_tokenAddr, _decimals);
    }

    function getTokenSymbol() public view returns (string memory) {
        address _tokenAddr = address(token);
        IERC20Metadata tokenMeta = IERC20Metadata(_tokenAddr);
        return tokenMeta.symbol();
    }

    function DECIMALS() public view returns (uint256) {
        return 10 ** decimals;
    }

    /// Update the current real holder of the artwork
    function updateCollector(uint16 _artworkId, address _collector) public isOwner {
        require(artworks[_artworkId].listingPriceInEth == 0, "Is listing");
        artworks[_artworkId].collector = _collector;
        emit UpdateCollector(_artworkId, _collector);
    }

    function getAllActiveArtworks() public view returns (Artwork[] memory artworksInfo) {
        uint256 _count;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            if (artworks[i].isActive == true) {
                _count++;
            }
        }
        artworksInfo = new Artwork[](_count);
        uint256 _index;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            if (artworks[i].isActive == true) {
                artworksInfo[_index] = artworks[i];
                _index++;
            }
        }
    }

    function addArtwork(address _artworkAddr, address _collector) public isOwner {
        require(_isArtwork(_artworkAddr), "Not from Weirui");
        require(!isArtwork[_artworkAddr], "Already registered");
        isArtwork[_artworkAddr] = true;
        artworks[nextArtworkId].id = nextArtworkId;
        artworks[nextArtworkId].artwork = _artworkAddr;
        artworks[nextArtworkId].collector = _collector;
        artworks[nextArtworkId].status = Status.COLLECTORHOLDING;
        artworks[nextArtworkId].listingPriceInEth = 0;
        artworks[nextArtworkId].isActive = true;
        nextArtworkId++;
        emit AddArtwork(_artworkAddr, nextArtworkId - 1);
    }

    function updateArtworkAddress(uint16 _artworkId, address _newArtworkAddr) public isOwner {
        require(_isArtwork(_newArtworkAddr), "Not from Weirui");
        require(!isArtwork[_newArtworkAddr], "Already registered");
        require(artworks[_artworkId].isActive == false, "Artwork active");
        address _oldArtworkAddr = artworks[_artworkId].artwork;
        isArtwork[_oldArtworkAddr] = false;
        isArtwork[_newArtworkAddr] = true;
        artworks[_artworkId].isActive = true;
        artworks[_artworkId].artwork = _newArtworkAddr;
        emit UpdateArtworkAddress(_artworkId, _newArtworkAddr);
    }

    /// Check the artwork address is created from the factory contract
    function _isArtwork(address _artwork) internal view returns (bool) {
        IFactory factory = IFactory(factoryAddr);
        address[] memory _artworks = factory.getArtworks();
        for (uint256 i = 0; i < _artworks.length; i++) {
            if (_artworks[i] == _artwork) {
                return true;
            }
        }
        return false;
    }

    function getArtworkName(uint16 _artworkId) public view returns (string memory name) {
        address _artworkAddr = artworks[_artworkId].artwork;
        IERC721Metadata _artwork = IERC721Metadata(_artworkAddr);
        return _artwork.name();
    }

    function getArtworkOwner(uint16 _artworkId) public view returns (address collector) {
        address _artworkAddr = artworks[_artworkId].artwork;
        IERC721 _artwork = IERC721(_artworkAddr);
        return _artwork.ownerOf(0);
    }

    function getArtworkTokenURI(uint16 _artworkId) public view returns (string memory) {
        address _artworkAddr = artworks[_artworkId].artwork;
        IERC721Metadata _artwork = IERC721Metadata(_artworkAddr);
        return _artwork.tokenURI(0);
    }

    function updateStatus(uint16 _artworkId, Status _status) public isOwner {
        require(_artworkId > 0 || _artworkId < nextArtworkId, "Out of bound");
        if (Status(_status) != Status.INVAULT) {
            if (artworks[_artworkId].listingPriceInEth != 0) {
                revert artworkIsListing(_artworkId); // If change to status other than INVAULT, the listing price must be 0;
            }
        }
        artworks[_artworkId].status = _status;
        if (_status == Status.COLLECTORHOLDING || _status == Status.INVAULT) {
            emit UpdateStatus(_artworkId, _status);
        }
    }

    /// The artwork is active or not, only affects if it can list and show on the frontend
    function activateArtwork(uint16 _artworkId, bool _toActive) public isOwner {
        if (_toActive) {
            artworks[_artworkId].isActive = true;
        } else {
            artworks[_artworkId].isActive = false;
        }
        emit ActivateArtwork(_artworkId, _toActive);
    }

    /// Collectors can still check all their collections including those got deactivated
    function getCollectorCollections(address _collector) public view returns (Artwork[] memory artworksInfo) {
        uint256 _count;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            address _artworkCollector = artworks[i].collector;
            if (_artworkCollector == _collector) {
                _count++;
            }
        }
        artworksInfo = new Artwork[](_count);
        uint256 _index;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            address _artworkCollector = artworks[i].collector;
            if (_artworkCollector == _collector) {
                artworksInfo[_index] = artworks[i];
                _index++;
            }
        }
    }

    function getCollectorOrders(address _collector) public view returns (Artwork[] memory collectorArtworks) {
        uint256 _count;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            if (
                artworks[i].collector == _collector && 
                artworks[i].status != Status.COLLECTORHOLDING && 
                artworks[i].status != Status.INVAULT
            ) {
                _count++;
            }
        }
        collectorArtworks = new Artwork[](_count);
        uint256 _index;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            if (
                artworks[i].collector == _collector && 
                artworks[i].status != Status.COLLECTORHOLDING && 
                artworks[i].status != Status.INVAULT
            ) {
                collectorArtworks[_index] = artworks[i];
                _index++;
            }
        }
    }

    function requestVault(uint16 _artworkId) public nonReentrant {
        require(artworks[_artworkId].collector == msg.sender, "Not authorized");
        emit Request(_artworkId);
    }

    /// Transfer artwork to vault
    function sendVault(uint16 _artworkId) public isOwner nonReentrant {
        bool _isActive = artworks[_artworkId].isActive;
        require(_isActive, "Not active");
        Status _status = artworks[_artworkId].status;
        require(_status != Status.COLLECTORHOLDING, "Not yet");
        address _artworkAddr = artworks[_artworkId].artwork;
        address _collector = artworks[_artworkId].collector;
        IERC721(_artworkAddr).safeTransferFrom(address(this), _collector, 0);
        emit Confirm(_artworkId);
    }

    /// Transfer artwork from vault
    function redeemArtwork(uint16 _artworkId) public nonReentrant {
        address _owner = getArtworkOwner(_artworkId);
        require(msg.sender == _owner, "Not authorized");
        require(artworks[_artworkId].status == Status.COLLECTORHOLDING, "Not arrived yet");
        address _artworkAddr = artworks[_artworkId].artwork;
        IERC721(_artworkAddr).safeTransferFrom(_owner, address(this), 0);
        emit Redeem(_artworkId);
    }

    function listArtwork(uint16 _artworkId, uint64 _amount) public nonReentrant {
        address _owner = getArtworkOwner(_artworkId);
        require(_owner == msg.sender, "Not authorized");
        require(artworks[_artworkId].status == Status.INVAULT, "Not in vault");
        require(artworks[_artworkId].isActive == true, "Invalid id");
        artworks[_artworkId].listingPriceInEth = _amount;
        emit List(_artworkId, _amount);
    }

    function delist(uint16 _artworkId) public nonReentrant {
        address _owner = getArtworkOwner(_artworkId);
        require(_owner == msg.sender, "Not authorized");
        require(artworks[_artworkId].listingPriceInEth != 0, "Artwork not listed");
        artworks[_artworkId].listingPriceInEth = 0;
    }

    /// Only the top 10 bidding price will be kept
    /// Bidders whose bids have been forced out, need to either bid with higher price or withdraw bid manually
    /// Bidders who wish to bid higher, can input the desired amount and only the extra part will be charged
    function bid(uint16 _artworkId, uint64 _amount) public nonReentrant {
        require(artworks[_artworkId].isActive, "Not active");
        uint64 _pastBid = bids[_artworkId][msg.sender];
        bool higherBid = true;
        uint64 _bidGap;
        if (_amount > _pastBid) {
            _bidGap = _amount - _pastBid;
        } else {
            _bidGap = _pastBid - _amount;
            higherBid = false;
        }
        if (higherBid) {
            if (token.balanceOf(msg.sender) < uint256(_bidGap) * DECIMALS()) {
                revert insufficientBalance(_bidGap);
            }
        }
        bool outbid = true;
        if (topBids[_artworkId].length == 10) {
            outbid = _removeLowestBid(_artworkId, msg.sender, _amount);
        }
        require(outbid, "Need outbid top ten");
        if (isBid[_artworkId][msg.sender] == false) { // when topBids length less than 10
            isBid[_artworkId][msg.sender] = true;
            topBids[_artworkId].push(Bid({
                from: msg.sender,
                price: _amount
            }));
        } else { // when topBids length less than 10 but bid price changed
            for (uint256 i = 0; i < topBids[_artworkId].length; i++) {
                if (topBids[_artworkId][i].from == msg.sender) {
                    topBids[_artworkId][i].price = _amount;
                    break;
                }
            }
        }
        bids[_artworkId][msg.sender] = _amount;
        if (higherBid) {
            totalBalance += _bidGap;
            balanceOf[msg.sender] += _bidGap;
            token.transferFrom(msg.sender, address(this), uint256(_bidGap) * DECIMALS());
        } else {
            totalBalance -= _bidGap;
            balanceOf[msg.sender] -= _bidGap;
            token.transfer(msg.sender, uint256(_bidGap) * DECIMALS());
        }
        emit PlaceBid(_artworkId, _amount);
    }

    function _removeLowestBid(uint16 _artworkId, address _bidder, uint64 _bidderPrice) internal returns (bool) {
        address _lowestBidder;
        uint64 _lowestBid = topBids[_artworkId][0].price;
        uint256 _index;
        for (uint256 i = 0; i < topBids[_artworkId].length; i++) {
            if (topBids[_artworkId][i].from == _bidder) {
                topBids[_artworkId][i].price = _bidderPrice;
                return true; // bidder outbid himself
            }
            if (topBids[_artworkId][i].price < _bidderPrice) {
                if (topBids[_artworkId][i].price < _lowestBid) {
                    _lowestBidder = topBids[_artworkId][i].from;
                    _lowestBid = topBids[_artworkId][i].price;
                    _index = i;
                }
            }
            if (i == topBids[_artworkId].length -1) {
                if (_lowestBidder == address(0)) {
                    return false; // bidder outbid no one
                } else {
                    address _removedAddr = topBids[_artworkId][_index].from;
                    isBid[_artworkId][_removedAddr] = false;
                    topBids[_artworkId][_index].from = _bidder;
                    topBids[_artworkId][_index].price = _bidderPrice;
                    isBid[_artworkId][_bidder] = true;
                    return true;
                }
            }
        }
        return false;
    }

    function withdrawBid(uint16 _artworkId) public nonReentrant {
        uint64 _bid = bids[_artworkId][msg.sender];
        require(_bid != 0, "Did not bid");
        require(balanceOf[msg.sender] >= _bid, "insufficient balance");
        _removeFromTopBids(_artworkId, msg.sender);
        totalBalance -= _bid;
        balanceOf[msg.sender] -= _bid;
        bids[_artworkId][msg.sender] = 0;
        token.transfer(msg.sender, uint256(_bid) * DECIMALS());
    }

    function acceptBid(uint16 _artworkId, address _bidder) public nonReentrant {
        address _owner = getArtworkOwner(_artworkId);
        require(_owner == msg.sender, "Not authorized");
        require(artworks[_artworkId].isActive, "Not active");
        require(Status(artworks[_artworkId].status) == Status.INVAULT, "Not in vault");
        require(bids[_artworkId][_bidder] != 0, "Not a bidder");
        _removeFromTopBids(_artworkId, _bidder);
        artworks[_artworkId].listingPriceInEth = 0;
        uint64 _acceptedBid = bids[_artworkId][_bidder];
        bids[_artworkId][_bidder] = 0;
        totalBalance -= _acceptedBid;
        balanceOf[_bidder] -= _acceptedBid;
        artworks[_artworkId].collector = _bidder;
        IERC721(artworks[_artworkId].artwork).safeTransferFrom(msg.sender, _bidder, 0);
        uint256 _acceptedBidInWei = uint256(_acceptedBid) * DECIMALS();
        uint256 _fee = _acceptedBidInWei * 5 / 1000;
        _acceptedBidInWei -= _fee;
        token.transfer(msg.sender, _acceptedBidInWei);
        token.transfer(owner, _fee);
        emit AcceptBid(_artworkId, _bidder, _acceptedBid);
        uint256 _feeInEth = _fee / DECIMALS();
        emit Fee(_feeInEth);
    }

    function _removeFromTopBids(uint16 _artworkId, address _bidder) internal {
        if (isBid[_artworkId][_bidder]) {
            isBid[_artworkId][_bidder] = false;
            uint256 _tobeRemovedBidderIndex;
            for (uint256 i = 0; i < topBids[_artworkId].length; i++) {
                if (topBids[_artworkId][i].from == _bidder) {
                    _tobeRemovedBidderIndex = i;
                    break;
                }
            }
            topBids[_artworkId][_tobeRemovedBidderIndex] = topBids[_artworkId][topBids[_artworkId].length - 1];
            topBids[_artworkId].pop();
        }
    }

    function getAllBids(uint16 _artworkId) public view returns (Bid[] memory) {
        return topBids[_artworkId];
    }

    /// Bidders can use this function to check their bids on all artworks
    function getBidderAllBids(address _bidder) public view returns (uint16[] memory bidArtwork, uint64[] memory bidPrice) {
        uint256 _count;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            if (bids[i][_bidder] != 0) {
                _count++;
            }
        }
        bidArtwork = new uint16[](_count);
        bidPrice = new uint64[](_count);
        uint256 _index;
        for (uint16 i = 1; i < nextArtworkId; i++) {
            if (bids[i][_bidder] != 0) {
                bidArtwork[_index] = i;
                bidPrice[_index] = bids[i][_bidder];
                _index++;
            }
        }
    }

    function buyArtwork(uint16 _artworkId) public nonReentrant {
        Status _status = artworks[_artworkId].status;
        require(Status(_status) == Status.INVAULT, "Not in vault");
        require(artworks[_artworkId].isActive, "Not active");
        require(artworks[_artworkId].listingPriceInEth != 0, "Not listing");
        require(token.balanceOf(msg.sender) >= artworks[_artworkId].listingPriceInEth * DECIMALS(), "Insufficient balance");
        uint64 _acceptedPrice = artworks[_artworkId].listingPriceInEth;
        artworks[_artworkId].listingPriceInEth = 0;
        address _originalOwner = getArtworkOwner(_artworkId);
        IERC721(artworks[_artworkId].artwork).safeTransferFrom(_originalOwner, msg.sender, 0);
        artworks[_artworkId].collector = msg.sender;
        uint256 _acceptedPriceInWei = uint256(_acceptedPrice) * DECIMALS();
        token.transferFrom(msg.sender, address(this), _acceptedPriceInWei);
        uint256 _fee = _acceptedPriceInWei * 5 / 1000;
        _acceptedPriceInWei -= _fee;
        token.transfer(_originalOwner, _acceptedPriceInWei);
        token.transfer(owner, _fee);
        emit Buy(_artworkId, _acceptedPrice);
        uint256 _feeInEth = _fee / DECIMALS();
        emit Fee(_feeInEth);
    }

    function onERC721Received(
        address /*operator*/,
        address /*from*/,
        uint256 /*tokenId*/,
        bytes calldata /*data*/
    ) external pure override returns (bytes4) {
        return IERC721Receiver.onERC721Received.selector;
    }

    error artworkIsListing(uint16 artworkId);
    error insufficientBalance(uint64 requiredAmount);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC721/IERC721Receiver.sol)

pragma solidity >=0.5.0;

/**
 * @title ERC-721 token receiver interface
 * @dev Interface for any contract that wants to support safeTransfers
 * from ERC-721 asset contracts.
 */
interface IERC721Receiver {
    /**
     * @dev Whenever an {IERC721} `tokenId` token is transferred to this contract via {IERC721-safeTransferFrom}
     * by `operator` from `from`, this function is called.
     *
     * It must return its Solidity selector to confirm the token transfer.
     * If any other value is returned or the interface is not implemented by the recipient, the transfer will be
     * reverted.
     *
     * The selector can be obtained in Solidity with `IERC721Receiver.onERC721Received.selector`.
     */
    function onERC721Received(
        address operator,
        address from,
        uint256 tokenId,
        bytes calldata data
    ) external returns (bytes4);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC721/IERC721.sol)

pragma solidity >=0.6.2;

import {IERC165} from "../../utils/introspection/IERC165.sol";

/**
 * @dev Required interface of an ERC-721 compliant contract.
 */
interface IERC721 is IERC165 {
    /**
     * @dev Emitted when `tokenId` token is transferred from `from` to `to`.
     */
    event Transfer(address indexed from, address indexed to, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables `approved` to manage the `tokenId` token.
     */
    event Approval(address indexed owner, address indexed approved, uint256 indexed tokenId);

    /**
     * @dev Emitted when `owner` enables or disables (`approved`) `operator` to manage all of its assets.
     */
    event ApprovalForAll(address indexed owner, address indexed operator, bool approved);

    /**
     * @dev Returns the number of tokens in ``owner``'s account.
     */
    function balanceOf(address owner) external view returns (uint256 balance);

    /**
     * @dev Returns the owner of the `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function ownerOf(uint256 tokenId) external view returns (address owner);

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId, bytes calldata data) external;

    /**
     * @dev Safely transfers `tokenId` token from `from` to `to`, checking first that contract recipients
     * are aware of the ERC-721 protocol to prevent tokens from being forever locked.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must exist and be owned by `from`.
     * - If the caller is not `from`, it must have been allowed to move this token by either {approve} or
     *   {setApprovalForAll}.
     * - If `to` refers to a smart contract, it must implement {IERC721Receiver-onERC721Received}, which is called upon
     *   a safe transfer.
     *
     * Emits a {Transfer} event.
     */
    function safeTransferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Transfers `tokenId` token from `from` to `to`.
     *
     * WARNING: Note that the caller is responsible to confirm that the recipient is capable of receiving ERC-721
     * or else they may be permanently lost. Usage of {safeTransferFrom} prevents loss, though the caller must
     * understand this adds an external call which potentially creates a reentrancy vulnerability.
     *
     * Requirements:
     *
     * - `from` cannot be the zero address.
     * - `to` cannot be the zero address.
     * - `tokenId` token must be owned by `from`.
     * - If the caller is not `from`, it must be approved to move this token by either {approve} or {setApprovalForAll}.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 tokenId) external;

    /**
     * @dev Gives permission to `to` to transfer `tokenId` token to another account.
     * The approval is cleared when the token is transferred.
     *
     * Only a single account can be approved at a time, so approving the zero address clears previous approvals.
     *
     * Requirements:
     *
     * - The caller must own the token or be an approved operator.
     * - `tokenId` must exist.
     *
     * Emits an {Approval} event.
     */
    function approve(address to, uint256 tokenId) external;

    /**
     * @dev Approve or remove `operator` as an operator for the caller.
     * Operators can call {transferFrom} or {safeTransferFrom} for any token owned by the caller.
     *
     * Requirements:
     *
     * - The `operator` cannot be the address zero.
     *
     * Emits an {ApprovalForAll} event.
     */
    function setApprovalForAll(address operator, bool approved) external;

    /**
     * @dev Returns the account approved for `tokenId` token.
     *
     * Requirements:
     *
     * - `tokenId` must exist.
     */
    function getApproved(uint256 tokenId) external view returns (address operator);

    /**
     * @dev Returns if the `operator` is allowed to manage all of the assets of `owner`.
     *
     * See {setApprovalForAll}
     */
    function isApprovedForAll(address owner, address operator) external view returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/IERC20.sol)

pragma solidity ^0.8.20;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC721/extensions/IERC721Metadata.sol)

pragma solidity >=0.6.2;

import {IERC721} from "../IERC721.sol";

/**
 * @title ERC-721 Non-Fungible Token Standard, optional metadata extension
 * @dev See https://eips.ethereum.org/EIPS/eip-721
 */
interface IERC721Metadata is IERC721 {
    /**
     * @dev Returns the token collection name.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the token collection symbol.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the Uniform Resource Identifier (URI) for `tokenId` token.
     */
    function tokenURI(uint256 tokenId) external view returns (string memory);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}