Forkchoice Ethereum Mainnet

/* SPDX-License-Identifier: UNLICENSED */
pragma solidity ^0.8.20;

import './ITBContract.sol';

interface ILoanManager {
    struct LoanConfig {
        address supplyAddress;
        address borrowAddress;
        uint minHealthFactor;
    }

    function getConfig() external view returns (LoanConfig memory);

    function setConfig(address supplyAddress, address borrowAddress, uint minHealthFactor) external;

    function supply(uint amount) external;

    function borrow(uint amount) external;

    function repay(uint256 _amount) external;

    function repayAll() external;

    function withdrawSupply(uint256 _amount) external;

    function withdrawSupplyAll() external;

    function repayAllAndWithdrawSupplyAll() external returns (uint256);

    function getPrices() external view returns (uint256, uint256);

    function getHealthFactor() external view returns (uint256);

    function getLiquidityAndShortFall() external view returns (uint256, uint256);

    function getSupply() external view returns (uint256);

    function getBorrow() external view returns (uint256);

    function getSupplyRate() external view returns (uint256);

    function getBorrowRate() external view returns (uint256);

    function getPositionDataSnapshot() external view returns (uint256, uint256, uint256, uint256, uint256, uint256, uint256);

    function claimRewards() external returns (address[] memory, uint256[] memory);

    function getMarketsData() external returns (uint256, uint256, uint256, uint256, uint256, uint256);

    function getLiquidationThreshold(address _collateral) external view returns (uint256);
}

/* SPDX-License-Identifier: UNLICENSED */
pragma solidity ^0.8.20;

import './utils/Withdrawable.sol';
import './utils/IWETH.sol';


/// @title ITBContract contract that implements common owner only functions accros all strategies
/// @author IntoTheBlock Corp
/// @dev Abstract
abstract contract ITBContract is Withdrawable {
    using SafeERC20 for IERC20;
    event ApproveToken(address indexed token, address guy, uint256 wad);
    address payable immutable public WNATIVE;

    uint constant ONE = 1e18;

    /// @param _executors Executor addresses
    constructor(address[] memory _executors, address payable _wnative) Executable(_executors) {
        WNATIVE = _wnative;
    }

    function _percentageAmount(uint _amount, uint _percentage) internal pure returns (uint) {
        return _amount * _percentage / ONE;
    }

    /// @notice Set allowance for a given token, amount and spender
    /// @param _token Token to spend
    /// @param _guy Spender
    /// @param _wad Max amount to spend
    function _approveToken(address _token, address _guy, uint256 _wad) internal {
        if (_wad != 0)
            IERC20(_token).forceApprove(_guy, _wad);
        else
            IERC20(_token).approve(_guy, _wad);
        emit ApproveToken(_token, _guy, _wad);
    }

    /// @notice For a given token, amount and spender, check if contract can spend amount and, if necessary, set the allowance to amount
    /// @param _token Token to spend
    /// @param _guy Spender
    /// @param _amount Amount to spend
    function _checkAllowanceAndApprove(address _token, address _guy, uint256 _amount) internal {
        _checkAllowanceAndApprove(_token, _guy, _amount, _amount);
    }

    /// @notice For a given token, amount and spender, check if contract can spend amount and, if necessary, set the allowance to approval amount
    /// @param _token Token to spend
    /// @param _guy Spender
    /// @param _amount Amount to spend
    /// @param _approval_amount Amount to approve
    function _checkAllowanceAndApprove(address _token, address _guy, uint256 _amount, uint256 _approval_amount) internal {
        if (IERC20(_token).allowance(address(this), _guy) < _amount)
            _approveToken(_token, _guy, _approval_amount);
    }

    /// @notice Only owner. Set allowance for a given token, amount and spender
    /// @param _token Token to spend
    /// @param _guy Spender
    /// @param _wad Max amount to spend
    function approveToken(address _token, address _guy, uint256 _wad) external onlyOwner {
        _approveToken(_token, _guy, _wad);
    }

    /// @notice Only owner. Revoke allowance for a given token and spender
    /// @param _token Token to spend
    /// @param _guy Spender
    function revokeToken(address _token, address _guy) external onlyOwner {
        _approveToken(_token, _guy, 0);
    }

    /// @notice Only owner. Execute an arbitrary call
    /// @param _to Target address
    /// @param _value Value (i. e. msg.value)
    /// @param _data Invocation data
    function execute(address _to, uint256 _value, bytes calldata _data) external payable onlyOwner {
        (bool success, bytes memory returnData) = _to.call{ value: _value }(_data);
        require(success, string(returnData));
    }

    /// @notice Only owner. Execute multiple arbitrary calls in order
    /// @param _tos Target address for each call
    /// @param _values Value for each call (i. e. msg.value)
    /// @param _datas Invocation data for each call
    function batchExecute(address[] calldata _tos, uint256[] calldata _values, bytes[] calldata _datas) external payable onlyOwner {
        require(_tos.length == _values.length && _tos.length == _datas.length, "Arguments length mismatch");
        for (uint256 i = 0; i < _tos.length; i++) {
            (bool success, bytes memory returnData) = _tos[i].call{ value: _values[i] }(_datas[i]);
            require(success, string(returnData));
        }
    }

    function wrapNative(uint256 _amount) public onlyExecutor {
        IWETH(WNATIVE).deposit{ value: _amount }();
    }

    function unwrapNative(uint256 _amount) public onlyExecutor {
        IWETH(WNATIVE).withdraw(_amount);
    }
}

/* SPDX-License-Identifier: UNLICENSED */
pragma solidity ^0.8.20;

import './ITBContract.sol';

interface IYieldStrategy {
    function assemble() external;
    
    function assemble(uint256 _min_lpts_out) external returns (uint256);

    function disassemble(uint _percent) external;

    function disassemble(uint _percent, uint256[] memory _min_coins_out) external returns (uint256[] memory);

    function fullDisassemble() external;
    
    function fullDisassemble(uint256[] memory min_coins_out) external returns (uint256[] memory);

    function getPositionAssets() external view returns (address [] memory);

    function getUnderlyings() external view returns (address[] memory, uint256[] memory);

    function claimRewards() external returns (address[] memory, uint256[] memory);
    
    function VERSION() external view returns (string memory);
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/access/Ownable2Step.sol";

/// @title Base contract that implements executor related functions
/// @author IntoTheBlock Corp
/// @dev Abstract
abstract contract Executable is Ownable2Step {
    mapping(address => bool) public executors;

    event ExecutorUpdated(address indexed executor, bool enabled);

    /// @param _executors Initial whitelisted executor addresses
    constructor(address[] memory _executors) Ownable(msg.sender) {
        for (uint256 i = 0; i < _executors.length; i++) {
            addExecutor(_executors[i]);
        }
    }

    /// @notice Revert if call is not being made from the owner or an executor
    modifier onlyExecutor() {
        require(owner() == msg.sender || executors[msg.sender], "Executable: caller is not the executor");
        _;
    }

    /// @notice Only owner. Add an executor
    /// @param _executor New executor address
    function addExecutor(address _executor) public onlyOwner {
        emit ExecutorUpdated(_executor, true);
        executors[_executor] = true;
    }

    /// @notice Only owner. Remove an executor
    /// @param _executor Executor address to remove
    function removeExecutor(address _executor) external onlyOwner {
        emit ExecutorUpdated(_executor, false);
        executors[_executor] = false;
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;

interface IWETH {
    function name() external view returns (string memory);
    function symbol() external view returns (string memory);
    function decimals() external view returns (uint8);

    event Approval(address indexed src, address indexed guy, uint256 wad);
    event Transfer(address indexed src, address indexed dst, uint256 wad);
    event Deposit(address indexed dst, uint256 wad);
    event Withdrawal(address indexed src, uint256 wad);

    function balanceOf(address) external view returns (uint256);
    function allowance(address, address) external view returns (uint256);

    fallback() external payable;
    receive() external payable;
    function deposit() external payable;
    function withdraw(uint256 wad) external;
    function totalSupply() external view returns (uint256);
    function approve(address guy, uint256 wad) external returns (bool);
    function transfer(address dst, uint256 wad) external returns (bool);
    function transferFrom(address src, address dst, uint256 wad) external returns (bool);
}

/* SPDX-License-Identifier: UNLICENSED */
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/access/Ownable2Step.sol";

abstract contract Ownable2StepWithShortcut is Ownable2Step {
    function transferOwnership1Step(address newOwner) public onlyOwner {
        require(newOwner != address(0), "ITBOwnable: zero address");
        _transferOwnership(newOwner);
    }
}

// SPDX-License-Identifier: UNLICENSED
pragma solidity ^0.8.20;

import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
import './Executable.sol';

/**
    Ensures that any contract that inherits from this contract is able to
    withdraw funds that are accidentally received or stuck.
 */

/// @title Base contract that implements withdrawal related functions
/// @author IntoTheBlock Corp
/// @dev Abstract
abstract contract Withdrawable is Executable {
    using SafeERC20 for IERC20;
    address constant ETHER = address(0);

    event LogWithdraw(
        address indexed _to,
        address indexed _asset_address,
        uint256 amount
    );

    receive() external payable {}

    
    /// @notice ERC20 or ETH balance of this contract given a token address
    /// @param _asset_address Token address or address(0) for ETH
    /// @return Balance    
    function _erc20OrNativeBalance(address _asset_address) internal view returns (uint256) {
        return _asset_address == ETHER ? _nativeBalance() : _erc20Balance(_asset_address);
    }
    
    function _erc20Balance(address _asset_address) internal view returns (uint256) {
        return IERC20(_asset_address).balanceOf(address(this));
    }

    function _nativeBalance() internal view returns (uint256) {
        return address(this).balance;
    }
    
    /// @notice ERC20 balance of given account
    /// @param _asset_address Token address 
    /// @param _account Account address 
    /// @return Balance  
    function balanceOf(address _asset_address, address _account) public view returns (uint256) {
        return IERC20(_asset_address).balanceOf(_account);
    }

    /// @notice Send the given amount of the given token or ETH to the given receiver
    /// @param _asset_address Token address or address(0) for ETH
    /// @param _amount Amount to send
    /// @param _to Receiver address
    function _withdraw_to(address _asset_address, uint256 _amount, address payable _to) internal {
        require(_to != address(0), 'Invalid address');
        uint256 balance = _erc20OrNativeBalance(_asset_address);
        require(balance >= _amount, 'Insufficient funds');
        if (_asset_address == ETHER) {
            (bool success, ) = _to.call{value: _amount}(''); /* carry gas over so it works with contracts with custom fallback, we dont care about reentrancy on onlyOwner */
            require(success, 'Native transfer failed.');
        } else
            IERC20(_asset_address).safeTransfer(_to, _amount);
        emit LogWithdraw(_to, _asset_address, _amount);
    }

    /// @notice Only owner. Send the given amount of the given token or ETH to the caller
    /// @param _asset_address Token address or address(0) for ETH
    /// @param _amount Amount to send
    function withdraw(address _asset_address, uint256 _amount) external onlyOwner {
        _withdraw_to(_asset_address, _amount, payable(msg.sender));
    }

    /// @notice Only owner. Send the given amount of the given token or ETH to the given receiver
    /// @param _asset_address Token address or address(0) for ETH
    /// @param _amount Amount to send
    /// @param _to Receiver address
    function withdrawTo(address _asset_address, uint256 _amount, address payable _to) external onlyOwner {
        _withdraw_to(_asset_address, _amount, _to);
    }

    /// @notice Only owner. Send its entire balance of the given token or ETH to the caller
    /// @param _asset_address Token address or address(0) for ETH
    function withdrawAll(address _asset_address) external onlyOwner {
        uint256 balance = _erc20OrNativeBalance(_asset_address);
        _withdraw_to(_asset_address, balance, payable(msg.sender));
    }

    /// @notice Only owner. Send its entire balance of the given token or ETH to the given receiver
    /// @param _asset_address Token address or address(0) for ETH
    /// @param _to Receiver address
    function withdrawAllTo(address _asset_address, address payable _to) external onlyOwner {
        uint256 balance = _erc20OrNativeBalance(_asset_address);
        _withdraw_to(_asset_address, balance, _to);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.0) (access/Ownable.sol)

pragma solidity ^0.8.20;

import {Context} from "../utils/Context.sol";

/**
 * @dev Contract module which provides a basic access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * The initial owner is set to the address provided by the deployer. This can
 * later be changed with {transferOwnership}.
 *
 * This module is used through inheritance. It will make available the modifier
 * `onlyOwner`, which can be applied to your functions to restrict their use to
 * the owner.
 */
abstract contract Ownable is Context {
    address private _owner;

    /**
     * @dev The caller account is not authorized to perform an operation.
     */
    error OwnableUnauthorizedAccount(address account);

    /**
     * @dev The owner is not a valid owner account. (eg. `address(0)`)
     */
    error OwnableInvalidOwner(address owner);

    event OwnershipTransferred(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Initializes the contract setting the address provided by the deployer as the initial owner.
     */
    constructor(address initialOwner) {
        if (initialOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(initialOwner);
    }

    /**
     * @dev Throws if called by any account other than the owner.
     */
    modifier onlyOwner() {
        _checkOwner();
        _;
    }

    /**
     * @dev Returns the address of the current owner.
     */
    function owner() public view virtual returns (address) {
        return _owner;
    }

    /**
     * @dev Throws if the sender is not the owner.
     */
    function _checkOwner() internal view virtual {
        if (owner() != _msgSender()) {
            revert OwnableUnauthorizedAccount(_msgSender());
        }
    }

    /**
     * @dev Leaves the contract without owner. It will not be possible to call
     * `onlyOwner` functions. Can only be called by the current owner.
     *
     * NOTE: Renouncing ownership will leave the contract without an owner,
     * thereby disabling any functionality that is only available to the owner.
     */
    function renounceOwnership() public virtual onlyOwner {
        _transferOwnership(address(0));
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Can only be called by the current owner.
     */
    function transferOwnership(address newOwner) public virtual onlyOwner {
        if (newOwner == address(0)) {
            revert OwnableInvalidOwner(address(0));
        }
        _transferOwnership(newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`).
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual {
        address oldOwner = _owner;
        _owner = newOwner;
        emit OwnershipTransferred(oldOwner, newOwner);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (access/Ownable2Step.sol)

pragma solidity ^0.8.20;

import {Ownable} from "./Ownable.sol";

/**
 * @dev Contract module which provides access control mechanism, where
 * there is an account (an owner) that can be granted exclusive access to
 * specific functions.
 *
 * This extension of the {Ownable} contract includes a two-step mechanism to transfer
 * ownership, where the new owner must call {acceptOwnership} in order to replace the
 * old one. This can help prevent common mistakes, such as transfers of ownership to
 * incorrect accounts, or to contracts that are unable to interact with the
 * permission system.
 *
 * The initial owner is specified at deployment time in the constructor for `Ownable`. This
 * can later be changed with {transferOwnership} and {acceptOwnership}.
 *
 * This module is used through inheritance. It will make available all functions
 * from parent (Ownable).
 */
abstract contract Ownable2Step is Ownable {
    address private _pendingOwner;

    event OwnershipTransferStarted(address indexed previousOwner, address indexed newOwner);

    /**
     * @dev Returns the address of the pending owner.
     */
    function pendingOwner() public view virtual returns (address) {
        return _pendingOwner;
    }

    /**
     * @dev Starts the ownership transfer of the contract to a new account. Replaces the pending transfer if there is one.
     * Can only be called by the current owner.
     *
     * Setting `newOwner` to the zero address is allowed; this can be used to cancel an initiated ownership transfer.
     */
    function transferOwnership(address newOwner) public virtual override onlyOwner {
        _pendingOwner = newOwner;
        emit OwnershipTransferStarted(owner(), newOwner);
    }

    /**
     * @dev Transfers ownership of the contract to a new account (`newOwner`) and deletes any pending owner.
     * Internal function without access restriction.
     */
    function _transferOwnership(address newOwner) internal virtual override {
        delete _pendingOwner;
        super._transferOwnership(newOwner);
    }

    /**
     * @dev The new owner accepts the ownership transfer.
     */
    function acceptOwnership() public virtual {
        address sender = _msgSender();
        if (pendingOwner() != sender) {
            revert OwnableUnauthorizedAccount(sender);
        }
        _transferOwnership(sender);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/draft-IERC6093.sol)
pragma solidity >=0.8.4;

/**
 * @dev Standard ERC-20 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-20 tokens.
 */
interface IERC20Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientBalance(address sender, uint256 balance, uint256 needed);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC20InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC20InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `spender`’s `allowance`. Used in transfers.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     * @param allowance Amount of tokens a `spender` is allowed to operate with.
     * @param needed Minimum amount required to perform a transfer.
     */
    error ERC20InsufficientAllowance(address spender, uint256 allowance, uint256 needed);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC20InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `spender` to be approved. Used in approvals.
     * @param spender Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC20InvalidSpender(address spender);
}

/**
 * @dev Standard ERC-721 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-721 tokens.
 */
interface IERC721Errors {
    /**
     * @dev Indicates that an address can't be an owner. For example, `address(0)` is a forbidden owner in ERC-20.
     * Used in balance queries.
     * @param owner Address of the current owner of a token.
     */
    error ERC721InvalidOwner(address owner);

    /**
     * @dev Indicates a `tokenId` whose `owner` is the zero address.
     * @param tokenId Identifier number of a token.
     */
    error ERC721NonexistentToken(uint256 tokenId);

    /**
     * @dev Indicates an error related to the ownership over a particular token. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param tokenId Identifier number of a token.
     * @param owner Address of the current owner of a token.
     */
    error ERC721IncorrectOwner(address sender, uint256 tokenId, address owner);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC721InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC721InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param tokenId Identifier number of a token.
     */
    error ERC721InsufficientApproval(address operator, uint256 tokenId);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC721InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC721InvalidOperator(address operator);
}

/**
 * @dev Standard ERC-1155 Errors
 * Interface of the https://eips.ethereum.org/EIPS/eip-6093[ERC-6093] custom errors for ERC-1155 tokens.
 */
interface IERC1155Errors {
    /**
     * @dev Indicates an error related to the current `balance` of a `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     * @param balance Current balance for the interacting account.
     * @param needed Minimum amount required to perform a transfer.
     * @param tokenId Identifier number of a token.
     */
    error ERC1155InsufficientBalance(address sender, uint256 balance, uint256 needed, uint256 tokenId);

    /**
     * @dev Indicates a failure with the token `sender`. Used in transfers.
     * @param sender Address whose tokens are being transferred.
     */
    error ERC1155InvalidSender(address sender);

    /**
     * @dev Indicates a failure with the token `receiver`. Used in transfers.
     * @param receiver Address to which tokens are being transferred.
     */
    error ERC1155InvalidReceiver(address receiver);

    /**
     * @dev Indicates a failure with the `operator`’s approval. Used in transfers.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     * @param owner Address of the current owner of a token.
     */
    error ERC1155MissingApprovalForAll(address operator, address owner);

    /**
     * @dev Indicates a failure with the `approver` of a token to be approved. Used in approvals.
     * @param approver Address initiating an approval operation.
     */
    error ERC1155InvalidApprover(address approver);

    /**
     * @dev Indicates a failure with the `operator` to be approved. Used in approvals.
     * @param operator Address that may be allowed to operate on tokens without being their owner.
     */
    error ERC1155InvalidOperator(address operator);

    /**
     * @dev Indicates an array length mismatch between ids and values in a safeBatchTransferFrom operation.
     * Used in batch transfers.
     * @param idsLength Length of the array of token identifiers
     * @param valuesLength Length of the array of token amounts
     */
    error ERC1155InvalidArrayLength(uint256 idsLength, uint256 valuesLength);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC1363.sol)

pragma solidity >=0.6.2;

import {IERC20} from "./IERC20.sol";
import {IERC165} from "./IERC165.sol";

/**
 * @title IERC1363
 * @dev Interface of the ERC-1363 standard as defined in the https://eips.ethereum.org/EIPS/eip-1363[ERC-1363].
 *
 * Defines an extension interface for ERC-20 tokens that supports executing code on a recipient contract
 * after `transfer` or `transferFrom`, or code on a spender contract after `approve`, in a single transaction.
 */
interface IERC1363 is IERC20, IERC165 {
    /*
     * Note: the ERC-165 identifier for this interface is 0xb0202a11.
     * 0xb0202a11 ===
     *   bytes4(keccak256('transferAndCall(address,uint256)')) ^
     *   bytes4(keccak256('transferAndCall(address,uint256,bytes)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256)')) ^
     *   bytes4(keccak256('transferFromAndCall(address,address,uint256,bytes)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256)')) ^
     *   bytes4(keccak256('approveAndCall(address,uint256,bytes)'))
     */

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferAndCall(address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the allowance mechanism
     * and then calls {IERC1363Receiver-onTransferReceived} on `to`.
     * @param from The address which you want to send tokens from.
     * @param to The address which you want to transfer to.
     * @param value The amount of tokens to be transferred.
     * @param data Additional data with no specified format, sent in call to `to`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function transferFromAndCall(address from, address to, uint256 value, bytes calldata data) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value) external returns (bool);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens and then calls {IERC1363Spender-onApprovalReceived} on `spender`.
     * @param spender The address which will spend the funds.
     * @param value The amount of tokens to be spent.
     * @param data Additional data with no specified format, sent in call to `spender`.
     * @return A boolean value indicating whether the operation succeeded unless throwing.
     */
    function approveAndCall(address spender, uint256 value, bytes calldata data) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC165.sol)

pragma solidity >=0.4.16;

import {IERC165} from "../utils/introspection/IERC165.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (interfaces/IERC20.sol)

pragma solidity >=0.4.16;

import {IERC20} from "../token/ERC20/IERC20.sol";

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/ERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "./IERC20.sol";
import {IERC20Metadata} from "./extensions/IERC20Metadata.sol";
import {Context} from "../../utils/Context.sol";
import {IERC20Errors} from "../../interfaces/draft-IERC6093.sol";

/**
 * @dev Implementation of the {IERC20} interface.
 *
 * This implementation is agnostic to the way tokens are created. This means
 * that a supply mechanism has to be added in a derived contract using {_mint}.
 *
 * TIP: For a detailed writeup see our guide
 * https://forum.openzeppelin.com/t/how-to-implement-erc20-supply-mechanisms/226[How
 * to implement supply mechanisms].
 *
 * The default value of {decimals} is 18. To change this, you should override
 * this function so it returns a different value.
 *
 * We have followed general OpenZeppelin Contracts guidelines: functions revert
 * instead returning `false` on failure. This behavior is nonetheless
 * conventional and does not conflict with the expectations of ERC-20
 * applications.
 */
abstract contract ERC20 is Context, IERC20, IERC20Metadata, IERC20Errors {
    mapping(address account => uint256) private _balances;

    mapping(address account => mapping(address spender => uint256)) private _allowances;

    uint256 private _totalSupply;

    string private _name;
    string private _symbol;

    /**
     * @dev Sets the values for {name} and {symbol}.
     *
     * Both values are immutable: they can only be set once during construction.
     */
    constructor(string memory name_, string memory symbol_) {
        _name = name_;
        _symbol = symbol_;
    }

    /**
     * @dev Returns the name of the token.
     */
    function name() public view virtual returns (string memory) {
        return _name;
    }

    /**
     * @dev Returns the symbol of the token, usually a shorter version of the
     * name.
     */
    function symbol() public view virtual returns (string memory) {
        return _symbol;
    }

    /**
     * @dev Returns the number of decimals used to get its user representation.
     * For example, if `decimals` equals `2`, a balance of `505` tokens should
     * be displayed to a user as `5.05` (`505 / 10 ** 2`).
     *
     * Tokens usually opt for a value of 18, imitating the relationship between
     * Ether and Wei. This is the default value returned by this function, unless
     * it's overridden.
     *
     * NOTE: This information is only used for _display_ purposes: it in
     * no way affects any of the arithmetic of the contract, including
     * {IERC20-balanceOf} and {IERC20-transfer}.
     */
    function decimals() public view virtual returns (uint8) {
        return 18;
    }

    /// @inheritdoc IERC20
    function totalSupply() public view virtual returns (uint256) {
        return _totalSupply;
    }

    /// @inheritdoc IERC20
    function balanceOf(address account) public view virtual returns (uint256) {
        return _balances[account];
    }

    /**
     * @dev See {IERC20-transfer}.
     *
     * Requirements:
     *
     * - `to` cannot be the zero address.
     * - the caller must have a balance of at least `value`.
     */
    function transfer(address to, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _transfer(owner, to, value);
        return true;
    }

    /// @inheritdoc IERC20
    function allowance(address owner, address spender) public view virtual returns (uint256) {
        return _allowances[owner][spender];
    }

    /**
     * @dev See {IERC20-approve}.
     *
     * NOTE: If `value` is the maximum `uint256`, the allowance is not updated on
     * `transferFrom`. This is semantically equivalent to an infinite approval.
     *
     * Requirements:
     *
     * - `spender` cannot be the zero address.
     */
    function approve(address spender, uint256 value) public virtual returns (bool) {
        address owner = _msgSender();
        _approve(owner, spender, value);
        return true;
    }

    /**
     * @dev See {IERC20-transferFrom}.
     *
     * Skips emitting an {Approval} event indicating an allowance update. This is not
     * required by the ERC. See {xref-ERC20-_approve-address-address-uint256-bool-}[_approve].
     *
     * NOTE: Does not update the allowance if the current allowance
     * is the maximum `uint256`.
     *
     * Requirements:
     *
     * - `from` and `to` cannot be the zero address.
     * - `from` must have a balance of at least `value`.
     * - the caller must have allowance for ``from``'s tokens of at least
     * `value`.
     */
    function transferFrom(address from, address to, uint256 value) public virtual returns (bool) {
        address spender = _msgSender();
        _spendAllowance(from, spender, value);
        _transfer(from, to, value);
        return true;
    }

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to`.
     *
     * This internal function is equivalent to {transfer}, and can be used to
     * e.g. implement automatic token fees, slashing mechanisms, etc.
     *
     * Emits a {Transfer} event.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _transfer(address from, address to, uint256 value) internal {
        if (from == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        if (to == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(from, to, value);
    }

    /**
     * @dev Transfers a `value` amount of tokens from `from` to `to`, or alternatively mints (or burns) if `from`
     * (or `to`) is the zero address. All customizations to transfers, mints, and burns should be done by overriding
     * this function.
     *
     * Emits a {Transfer} event.
     */
    function _update(address from, address to, uint256 value) internal virtual {
        if (from == address(0)) {
            // Overflow check required: The rest of the code assumes that totalSupply never overflows
            _totalSupply += value;
        } else {
            uint256 fromBalance = _balances[from];
            if (fromBalance < value) {
                revert ERC20InsufficientBalance(from, fromBalance, value);
            }
            unchecked {
                // Overflow not possible: value <= fromBalance <= totalSupply.
                _balances[from] = fromBalance - value;
            }
        }

        if (to == address(0)) {
            unchecked {
                // Overflow not possible: value <= totalSupply or value <= fromBalance <= totalSupply.
                _totalSupply -= value;
            }
        } else {
            unchecked {
                // Overflow not possible: balance + value is at most totalSupply, which we know fits into a uint256.
                _balances[to] += value;
            }
        }

        emit Transfer(from, to, value);
    }

    /**
     * @dev Creates a `value` amount of tokens and assigns them to `account`, by transferring it from address(0).
     * Relies on the `_update` mechanism
     *
     * Emits a {Transfer} event with `from` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead.
     */
    function _mint(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidReceiver(address(0));
        }
        _update(address(0), account, value);
    }

    /**
     * @dev Destroys a `value` amount of tokens from `account`, lowering the total supply.
     * Relies on the `_update` mechanism.
     *
     * Emits a {Transfer} event with `to` set to the zero address.
     *
     * NOTE: This function is not virtual, {_update} should be overridden instead
     */
    function _burn(address account, uint256 value) internal {
        if (account == address(0)) {
            revert ERC20InvalidSender(address(0));
        }
        _update(account, address(0), value);
    }

    /**
     * @dev Sets `value` as the allowance of `spender` over the `owner`'s tokens.
     *
     * This internal function is equivalent to `approve`, and can be used to
     * e.g. set automatic allowances for certain subsystems, etc.
     *
     * Emits an {Approval} event.
     *
     * Requirements:
     *
     * - `owner` cannot be the zero address.
     * - `spender` cannot be the zero address.
     *
     * Overrides to this logic should be done to the variant with an additional `bool emitEvent` argument.
     */
    function _approve(address owner, address spender, uint256 value) internal {
        _approve(owner, spender, value, true);
    }

    /**
     * @dev Variant of {_approve} with an optional flag to enable or disable the {Approval} event.
     *
     * By default (when calling {_approve}) the flag is set to true. On the other hand, approval changes made by
     * `_spendAllowance` during the `transferFrom` operation set the flag to false. This saves gas by not emitting any
     * `Approval` event during `transferFrom` operations.
     *
     * Anyone who wishes to continue emitting `Approval` events on the`transferFrom` operation can force the flag to
     * true using the following override:
     *
     * ```solidity
     * function _approve(address owner, address spender, uint256 value, bool) internal virtual override {
     *     super._approve(owner, spender, value, true);
     * }
     * ```
     *
     * Requirements are the same as {_approve}.
     */
    function _approve(address owner, address spender, uint256 value, bool emitEvent) internal virtual {
        if (owner == address(0)) {
            revert ERC20InvalidApprover(address(0));
        }
        if (spender == address(0)) {
            revert ERC20InvalidSpender(address(0));
        }
        _allowances[owner][spender] = value;
        if (emitEvent) {
            emit Approval(owner, spender, value);
        }
    }

    /**
     * @dev Updates `owner`'s allowance for `spender` based on spent `value`.
     *
     * Does not update the allowance value in case of infinite allowance.
     * Revert if not enough allowance is available.
     *
     * Does not emit an {Approval} event.
     */
    function _spendAllowance(address owner, address spender, uint256 value) internal virtual {
        uint256 currentAllowance = allowance(owner, spender);
        if (currentAllowance < type(uint256).max) {
            if (currentAllowance < value) {
                revert ERC20InsufficientAllowance(spender, currentAllowance, value);
            }
            unchecked {
                _approve(owner, spender, currentAllowance - value, false);
            }
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/extensions/IERC20Metadata.sol)

pragma solidity >=0.6.2;

import {IERC20} from "../IERC20.sol";

/**
 * @dev Interface for the optional metadata functions from the ERC-20 standard.
 */
interface IERC20Metadata is IERC20 {
    /**
     * @dev Returns the name of the token.
     */
    function name() external view returns (string memory);

    /**
     * @dev Returns the symbol of the token.
     */
    function symbol() external view returns (string memory);

    /**
     * @dev Returns the decimals places of the token.
     */
    function decimals() external view returns (uint8);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.3.0) (token/ERC20/utils/SafeERC20.sol)

pragma solidity ^0.8.20;

import {IERC20} from "../IERC20.sol";
import {IERC1363} from "../../../interfaces/IERC1363.sol";

/**
 * @title SafeERC20
 * @dev Wrappers around ERC-20 operations that throw on failure (when the token
 * contract returns false). Tokens that return no value (and instead revert or
 * throw on failure) are also supported, non-reverting calls are assumed to be
 * successful.
 * To use this library you can add a `using SafeERC20 for IERC20;` statement to your contract,
 * which allows you to call the safe operations as `token.safeTransfer(...)`, etc.
 */
library SafeERC20 {
    /**
     * @dev An operation with an ERC-20 token failed.
     */
    error SafeERC20FailedOperation(address token);

    /**
     * @dev Indicates a failed `decreaseAllowance` request.
     */
    error SafeERC20FailedDecreaseAllowance(address spender, uint256 currentAllowance, uint256 requestedDecrease);

    /**
     * @dev Transfer `value` amount of `token` from the calling contract to `to`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     */
    function safeTransfer(IERC20 token, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Transfer `value` amount of `token` from `from` to `to`, spending the approval given by `from` to the
     * calling contract. If `token` returns no value, non-reverting calls are assumed to be successful.
     */
    function safeTransferFrom(IERC20 token, address from, address to, uint256 value) internal {
        _callOptionalReturn(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Variant of {safeTransfer} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransfer(IERC20 token, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transfer, (to, value)));
    }

    /**
     * @dev Variant of {safeTransferFrom} that returns a bool instead of reverting if the operation is not successful.
     */
    function trySafeTransferFrom(IERC20 token, address from, address to, uint256 value) internal returns (bool) {
        return _callOptionalReturnBool(token, abi.encodeCall(token.transferFrom, (from, to, value)));
    }

    /**
     * @dev Increase the calling contract's allowance toward `spender` by `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeIncreaseAllowance(IERC20 token, address spender, uint256 value) internal {
        uint256 oldAllowance = token.allowance(address(this), spender);
        forceApprove(token, spender, oldAllowance + value);
    }

    /**
     * @dev Decrease the calling contract's allowance toward `spender` by `requestedDecrease`. If `token` returns no
     * value, non-reverting calls are assumed to be successful.
     *
     * IMPORTANT: If the token implements ERC-7674 (ERC-20 with temporary allowance), and if the "client"
     * smart contract uses ERC-7674 to set temporary allowances, then the "client" smart contract should avoid using
     * this function. Performing a {safeIncreaseAllowance} or {safeDecreaseAllowance} operation on a token contract
     * that has a non-zero temporary allowance (for that particular owner-spender) will result in unexpected behavior.
     */
    function safeDecreaseAllowance(IERC20 token, address spender, uint256 requestedDecrease) internal {
        unchecked {
            uint256 currentAllowance = token.allowance(address(this), spender);
            if (currentAllowance < requestedDecrease) {
                revert SafeERC20FailedDecreaseAllowance(spender, currentAllowance, requestedDecrease);
            }
            forceApprove(token, spender, currentAllowance - requestedDecrease);
        }
    }

    /**
     * @dev Set the calling contract's allowance toward `spender` to `value`. If `token` returns no value,
     * non-reverting calls are assumed to be successful. Meant to be used with tokens that require the approval
     * to be set to zero before setting it to a non-zero value, such as USDT.
     *
     * NOTE: If the token implements ERC-7674, this function will not modify any temporary allowance. This function
     * only sets the "standard" allowance. Any temporary allowance will remain active, in addition to the value being
     * set here.
     */
    function forceApprove(IERC20 token, address spender, uint256 value) internal {
        bytes memory approvalCall = abi.encodeCall(token.approve, (spender, value));

        if (!_callOptionalReturnBool(token, approvalCall)) {
            _callOptionalReturn(token, abi.encodeCall(token.approve, (spender, 0)));
            _callOptionalReturn(token, approvalCall);
        }
    }

    /**
     * @dev Performs an {ERC1363} transferAndCall, with a fallback to the simple {ERC20} transfer if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            safeTransfer(token, to, value);
        } else if (!token.transferAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} transferFromAndCall, with a fallback to the simple {ERC20} transferFrom if the target
     * has no code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * Reverts if the returned value is other than `true`.
     */
    function transferFromAndCallRelaxed(
        IERC1363 token,
        address from,
        address to,
        uint256 value,
        bytes memory data
    ) internal {
        if (to.code.length == 0) {
            safeTransferFrom(token, from, to, value);
        } else if (!token.transferFromAndCall(from, to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Performs an {ERC1363} approveAndCall, with a fallback to the simple {ERC20} approve if the target has no
     * code. This can be used to implement an {ERC721}-like safe transfer that rely on {ERC1363} checks when
     * targeting contracts.
     *
     * NOTE: When the recipient address (`to`) has no code (i.e. is an EOA), this function behaves as {forceApprove}.
     * Opposedly, when the recipient address (`to`) has code, this function only attempts to call {ERC1363-approveAndCall}
     * once without retrying, and relies on the returned value to be true.
     *
     * Reverts if the returned value is other than `true`.
     */
    function approveAndCallRelaxed(IERC1363 token, address to, uint256 value, bytes memory data) internal {
        if (to.code.length == 0) {
            forceApprove(token, to, value);
        } else if (!token.approveAndCall(to, value, data)) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturnBool} that reverts if call fails to meet the requirements.
     */
    function _callOptionalReturn(IERC20 token, bytes memory data) private {
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            let success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            // bubble errors
            if iszero(success) {
                let ptr := mload(0x40)
                returndatacopy(ptr, 0, returndatasize())
                revert(ptr, returndatasize())
            }
            returnSize := returndatasize()
            returnValue := mload(0)
        }

        if (returnSize == 0 ? address(token).code.length == 0 : returnValue != 1) {
            revert SafeERC20FailedOperation(address(token));
        }
    }

    /**
     * @dev Imitates a Solidity high-level call (i.e. a regular function call to a contract), relaxing the requirement
     * on the return value: the return value is optional (but if data is returned, it must not be false).
     * @param token The token targeted by the call.
     * @param data The call data (encoded using abi.encode or one of its variants).
     *
     * This is a variant of {_callOptionalReturn} that silently catches all reverts and returns a bool instead.
     */
    function _callOptionalReturnBool(IERC20 token, bytes memory data) private returns (bool) {
        bool success;
        uint256 returnSize;
        uint256 returnValue;
        assembly ("memory-safe") {
            success := call(gas(), token, 0, add(data, 0x20), mload(data), 0, 0x20)
            returnSize := returndatasize()
            returnValue := mload(0)
        }
        return success && (returnSize == 0 ? address(token).code.length > 0 : returnValue == 1);
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.0.1) (utils/Context.sol)

pragma solidity ^0.8.20;

/**
 * @dev Provides information about the current execution context, including the
 * sender of the transaction and its data. While these are generally available
 * via msg.sender and msg.data, they should not be accessed in such a direct
 * manner, since when dealing with meta-transactions the account sending and
 * paying for execution may not be the actual sender (as far as an application
 * is concerned).
 *
 * This contract is only required for intermediate, library-like contracts.
 */
abstract contract Context {
    function _msgSender() internal view virtual returns (address) {
        return msg.sender;
    }

    function _msgData() internal view virtual returns (bytes calldata) {
        return msg.data;
    }

    function _contextSuffixLength() internal view virtual returns (uint256) {
        return 0;
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (utils/introspection/IERC165.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-165 standard, as defined in the
 * https://eips.ethereum.org/EIPS/eip-165[ERC].
 *
 * Implementers can declare support of contract interfaces, which can then be
 * queried by others ({ERC165Checker}).
 *
 * For an implementation, see {ERC165}.
 */
interface IERC165 {
    /**
     * @dev Returns true if this contract implements the interface defined by
     * `interfaceId`. See the corresponding
     * https://eips.ethereum.org/EIPS/eip-165#how-interfaces-are-identified[ERC section]
     * to learn more about how these ids are created.
     *
     * This function call must use less than 30 000 gas.
     */
    function supportsInterface(bytes4 interfaceId) external view returns (bool);
}

/* SPDX-License-Identifier: UNLICENSED */
pragma solidity ^0.8.0;

import '@itb/quant-common/contracts/solidity8/ITBContract.sol';
import '@itb/quant-common/contracts/solidity8/ILoanManager.sol';
import '@itb/quant-common/contracts/solidity8/IYieldStrategy.sol';
import '@openzeppelin/contracts/token/ERC20/ERC20.sol';

/// @title SupervisedLoanPositionManager
/// @author IntoTheBlock Corp
contract SupervisedLoanPositionManager is ITBContract {
    using SafeERC20 for IERC20;

    struct SupervisedConfig {
        uint256 targetHealthFactor;
        bool yieldStrategyUseNativeAssets;
    }

    event FullDisassemble(uint supply_amount, uint borrow_amount);
    event Assemble(uint supply_amount, uint borrow_amount);
    event WithdrawSupplyAndAssemble(uint supply_amount);
    event UnwindAndSupply(uint supply_amount);
    event UnwindAndRepay(uint borrow_amount);
    event UnwindRepayAndWithdraw();
    event Supply(uint supply_amount);
    event WithdrawSupply(uint supply_amount);
    event Borrow(uint borrow_amount);
    event Repay(uint borrow_amount);
    event UpdateSupervisedConfig(SupervisedConfig old_config, SupervisedConfig new_config);
    event UpdateLoanManager(ILoanManager old_loan_manager, ILoanManager new_loan_manager);
    event UpdateYieldStrategy(IYieldStrategy old_yield_strategy, IYieldStrategy new_yield_strategy);

    ILoanManager public loanManager;
    IYieldStrategy public yieldStrategy;
    SupervisedConfig supervisedConfig;

    /// @param _executors Array of executors addresses.
    /// @param _wnative Native token address.
    /// @param _loanManager Loan Manager address.
    /// @param _yieldStrategy Yield Strategy Position Manager address.
    /// @param _targetHealthFactor Target health factor.
    constructor(address[] memory _executors, address payable _wnative, ILoanManager _loanManager, IYieldStrategy _yieldStrategy, uint256 _targetHealthFactor, bool _yieldStrategyUseNativeAssets) ITBContract(_executors, _wnative) {
        setConfig(_targetHealthFactor, _yieldStrategyUseNativeAssets);
        updateLoanManager(_loanManager);
        updateYieldStrategy(_yieldStrategy);
    }

    function setConfig(uint256 _targetHealthFactor, bool _yieldStrategyUseNativeAssets) public onlyOwner {
        SupervisedConfig memory new_config = SupervisedConfig(_targetHealthFactor, _yieldStrategyUseNativeAssets);
        emit UpdateSupervisedConfig(supervisedConfig, new_config);
        supervisedConfig = new_config;
    }

    function getConfig() public view returns (SupervisedConfig memory) {
        return supervisedConfig;
    }

    function getLoanManagerConfig() external view returns (ILoanManager.LoanConfig memory) {
        return loanManager.getConfig();
    }

    /// @notice Only owner. Updates LoanManager address.
    /// @param _address New Loan Manager address.
    function updateLoanManager(ILoanManager _address) public onlyOwner {
        emit UpdateLoanManager(loanManager, _address);
        loanManager = _address;
    }

    /// @notice Only owner. Updates Yield Strategy Position Manager address.
    /// @param _address New Yield Strategy Position Manager address.
    function updateYieldStrategy(IYieldStrategy _address) public onlyOwner {
        emit UpdateYieldStrategy(yieldStrategy, _address);
        yieldStrategy = _address;
    }

    function _balanceOfLoan(address _asset) internal view returns (uint) {
        return balanceOf(_asset, address(loanManager));
    }

    function _balanceOfYield(address _asset) internal view returns (uint) {
        if (supervisedConfig.yieldStrategyUseNativeAssets && _asset == WNATIVE)
            return address(yieldStrategy).balance;
        return balanceOf(_asset, address(yieldStrategy));
    }

    function _getYieldAssets() internal view returns (address[] memory positionAssets) {
        positionAssets = yieldStrategy.getPositionAssets();
        if (supervisedConfig.yieldStrategyUseNativeAssets)
            for (uint i = 0; i < positionAssets.length; i++)
                if (positionAssets[i] == address(0))
                    positionAssets[i] = WNATIVE;
    }

    function _transferAllAssetsFromYield() internal {
        address[] memory positionAssets = _getYieldAssets();
        for (uint i = 0; i < positionAssets.length; i++)
            transferAssetsFromYieldStrategy(positionAssets[i], _balanceOfYield(positionAssets[i]));
    }

    /// @notice Supplies collateral to the loan.
    /// @param _amount Amount to supply.
    function _supply(uint256 _amount) internal {
        transferAssetsToLoanManager(loanManager.getConfig().supplyAddress, _amount);
        loanManager.supply(_amount);
    }

    /// @notice Withdraw supply from the loan.
    /// @param _amount Amount to withdraw.
    function _withdrawSupply(uint256 _amount) internal {
        loanManager.withdrawSupply(_amount);
        transferAssetsFromLoanManager(loanManager.getConfig().supplyAddress, _amount);
        emit WithdrawSupply(_amount);
    }

    /// @notice Borrows from the loan.
    /// @param _amount Amount to borrow.
    function _borrow(uint256 _amount) internal {
        loanManager.borrow(_amount);
        transferAssetsFromLoanManager(loanManager.getConfig().borrowAddress, _amount);
    }

    /// @notice Repays part of the loan.
    /// @param _amount Amount to repay.
    function _repay(uint256 _amount) internal {
        address borrowedAsset = loanManager.getConfig().borrowAddress;
        uint256 borrowed = loanManager.getBorrow();
        if (_amount > borrowed)
            _amount = borrowed;
        transferAssetsToLoanManager(borrowedAsset, _amount);
        loanManager.repay(_amount);
    }

    /// @notice Withdraw all available supply to reach the desired HF.
    function _withdrawSupplyAvailable() internal returns (uint256) {
        uint256 withdrawAmount = getAvailableWithdraw();
        if (withdrawAmount == 0)
            return 0;
        _withdrawSupply(withdrawAmount);
        return withdrawAmount;
    }

    /// @notice Assembles a supervised loan position.
    /// @param _supplyAmount Amount of token to deposit and use as collateral.
    /// @param _borrowAmount Amount of token to borrow from the lending protocol.
    /// @param _min_lpt_out Min lpts out.
    /// @param _before_assemble_data Data to be used with custom logic before assembling the yield strategy.
    /// @return lpt_amount Amount out of LPT token from yield_strategy.
    function _assemble(uint256 _supplyAmount, uint256 _borrowAmount, uint256 _min_lpt_out, bytes memory _before_assemble_data) internal virtual returns (uint256) {
        if (_supplyAmount != 0)
            _supply(_supplyAmount);
        if (_borrowAmount != 0)
            _borrow(_borrowAmount);

        _beforeYieldStrategyAssemble(_before_assemble_data);
        address[] memory positionAssets = _getYieldAssets();
        for (uint i = 0; i < positionAssets.length; i++)
            transferAssetsToYieldStrategy(positionAssets[i], _erc20Balance(positionAssets[i]));
        emit Assemble(_supplyAmount, _borrowAmount);
        return _yieldStrategyAssemble(_min_lpt_out);
    }

    function _unwind(address _asset, uint _percentage, uint256[] memory _min_yield_outs, bytes memory _after_disassemble_data) internal virtual returns (uint256[] memory yield_outs, uint256 amount_out) {
        uint256 previousBalance = _erc20Balance(_asset);
        yield_outs = _yieldStrategyDisassemble(_percentage, _min_yield_outs);
        _afterYieldStrategyDisassemble(_after_disassemble_data);
        _transferAllAssetsFromYield();
        uint256 newBalance = _erc20Balance(_asset);
        amount_out = newBalance - previousBalance;
    }

    /// @notice Unwinds a percentage of the yield position and uses it to repay part of the loan.
    /// @param _percentage Amount to unwind expressed as percentage. 1e18 is equivalent to 100%.
    /// @param _min_yield_outs Min coin amounts out of yield_strategy.
    /// @param _after_disassemble_data Data to be used with custom logic after disassembling the yield strategy.
    /// @return yield_outs Coin amounts out of yield_strategy.
    function _unwindAndRepay(uint _percentage, uint256[] memory _min_yield_outs, bytes memory _after_disassemble_data) internal virtual returns (uint256[] memory) {
        (uint256[] memory yield_outs, uint256 repay_amount) = _unwind(loanManager.getConfig().borrowAddress, _percentage, _min_yield_outs, _after_disassemble_data);
        _repay(repay_amount);
        emit UnwindAndRepay(repay_amount);
        return yield_outs;
    }

    function _unwindRepayAndWithdraw(uint _percentage, uint _withdraw_supply_amount, uint256[] memory _min_yield_outs, bytes memory _after_disassemble_data) internal virtual returns (uint256[] memory) {
        uint256[] memory yield_outs = _unwindAndRepay(_percentage, _min_yield_outs, _after_disassemble_data);
        _withdrawSupply(_withdraw_supply_amount);
        emit UnwindRepayAndWithdraw();
        return yield_outs;
    }

    function _unwindRepayAndWithdrawAvailable(uint _percentage, uint256[] memory _min_yield_outs, bytes memory _after_disassemble_data) internal virtual returns (uint256[] memory) {
        uint256[] memory yield_outs = _unwindAndRepay(_percentage, _min_yield_outs, _after_disassemble_data);
        _withdrawSupplyAvailable();
        emit UnwindRepayAndWithdraw();
        return yield_outs;
    }

    /// @notice Completely disassembles a supervised loan position.
    /// @param _min_yield_outs Min coin amounts out of yield_strategy.
    /// @param _after_disassemble_data Data to be used with custom logic after disassembling the yield strategy.
    /// @return yields_out Coin amounts out of yield_strategy.
    function _fullDisassemble(uint256[] memory _min_yield_outs, bytes memory _after_disassemble_data) internal virtual returns (uint256[] memory yields_out) {
        yields_out = _yieldStrategyFullDisassemble(_min_yield_outs);
        emit FullDisassemble(loanManager.getSupply(), loanManager.getBorrow());
        _afterYieldStrategyDisassemble(_after_disassemble_data);
        _finishFullDisassemble();
    }

    function _finishFullDisassemble() internal {
        ILoanManager.LoanConfig memory loanConfig = loanManager.getConfig();
        _transferAllAssetsFromYield();
        transferAssetsToLoanManager(loanConfig.borrowAddress, _erc20Balance(loanConfig.borrowAddress));
        (uint256 supplyMarketDeposits, uint256 supplyMarketDebt, , , , ) = loanManager.getMarketsData();
        uint256 liquidity = supplyMarketDeposits - supplyMarketDebt;
        if (liquidity < loanManager.getSupply()) {
            loanManager.repayAll();
            loanManager.withdrawSupply(liquidity);
        }
        else
            loanManager.repayAllAndWithdrawSupplyAll();
        uint256 withdrawAmount = _balanceOfLoan(loanConfig.supplyAddress);
        transferAssetsFromLoanManager(loanConfig.supplyAddress, withdrawAmount);
        uint256 remainingBorrowAsset = _balanceOfLoan(loanConfig.borrowAddress);
        if (remainingBorrowAsset > 0)
            transferAssetsFromLoanManager(loanConfig.borrowAddress, remainingBorrowAsset);
    }

    function _maxBorrow(uint256 targetHealthFactor) internal view returns (uint256) {
        uint256 supplied = loanManager.getSupply();
        if (supplied == 0)
            return 0;

        ILoanManager.LoanConfig memory loanConfig = loanManager.getConfig();
        uint256 supplyExp = 10 ** ERC20(loanConfig.supplyAddress).decimals();
        uint256 borrowExp = 10 ** ERC20(loanConfig.borrowAddress).decimals();

        uint256 collateralFactor = loanManager.getLiquidationThreshold(loanConfig.supplyAddress);
        (uint256 supplyTokenPrice, uint256 borrowTokenPrice) = loanManager.getPrices();

        uint256 supplyAsBase = supplied * supplyTokenPrice;
        uint256 supplyPowerAsBase = supplyAsBase * collateralFactor;
        return supplyPowerAsBase * borrowExp / (supplyExp * borrowTokenPrice * targetHealthFactor);
    }

    function _minSupply(uint256 targetHealthFactor) internal view returns (uint256) {
        uint256 borrowed = loanManager.getBorrow();
        if (borrowed == 0)
            return 0;

        ILoanManager.LoanConfig memory loanConfig = loanManager.getConfig();
        uint256 supplyExp = 10 ** ERC20(loanConfig.supplyAddress).decimals();
        uint256 borrowExp = 10 ** ERC20(loanConfig.borrowAddress).decimals();

        uint256 collateralFactor = loanManager.getLiquidationThreshold(loanConfig.supplyAddress);
        (uint256 supplyTokenPrice, uint256 borrowTokenPrice) = loanManager.getPrices();

        uint256 borrowAsBase = borrowed * borrowTokenPrice;
        uint256 minSupplyPowerAsBase = borrowAsBase * targetHealthFactor;
        return minSupplyPowerAsBase * supplyExp / (borrowExp * supplyTokenPrice * collateralFactor);
    }

    function _beforeTransferFromYieldStrategy(address asset, uint amount) internal {
        if (supervisedConfig.yieldStrategyUseNativeAssets && asset == WNATIVE)
            ITBContract(payable(address(yieldStrategy))).wrapNative(amount);
    }
    
    function _afterTransferToYieldStrategy(address asset, uint amount) internal {
        if (supervisedConfig.yieldStrategyUseNativeAssets && asset == WNATIVE)
            ITBContract(payable(address(yieldStrategy))).unwrapNative(amount);
    }

    function _beforeYieldStrategyAssemble(bytes memory) internal virtual {
        address borrowAddress = loanManager.getConfig().borrowAddress;
        address[] memory positionAssets = _getYieldAssets();

        bool borrowNeeded;
        for (uint i = 0; i < positionAssets.length; i++)
            if (positionAssets[i] == borrowAddress) {
                borrowNeeded = true;
                break;
            }
        require(borrowNeeded, "Configured borrow token must be used in strategy");
    }

    function _afterYieldStrategyDisassemble(bytes memory) internal virtual {}

    /// @notice Assembles the yield position.
    /// @param _min_lpt_out Min LPT amount increase from assembling the yield position.
    /// @return lpt_out LPT amount obtained from assembling the yield position.
    function _yieldStrategyAssemble(uint256 _min_lpt_out) internal virtual returns (uint256) {
        return yieldStrategy.assemble(_min_lpt_out);
    }

    /// @notice Unwinds a percentage of the yield position.
    /// @param _percentage Amount to unwind expressed as percentage. 1e18 is equivalent to 100%.
    /// @param _min_yield_outs Min coin amounts out of yield_strategy.
    /// @return yield_outs Coin amounts out of yield_strategy.
    function _yieldStrategyDisassemble(uint256 _percentage, uint256[] memory _min_yield_outs) internal virtual returns (uint256[] memory) {
        return yieldStrategy.disassemble(_percentage, _min_yield_outs);
    }

    /// @notice Unwinds the yield position.
    /// @param _min_yield_outs Min coin amounts out of yield_strategy.
    /// @return yield_outs Coin amounts out of yield_strategy.
    function _yieldStrategyFullDisassemble(uint256[] memory _min_yield_outs) internal virtual returns (uint256[] memory) {
        return yieldStrategy.disassemble(1e18, _min_yield_outs);
    }

    function getBorrow() external view returns (uint256) {
        return loanManager.getBorrow();
    }

    function getAvailableBorrow() public view returns (uint256) {
        uint256 targetHealthFactor = supervisedConfig.targetHealthFactor;
        uint256 healthFactor = loanManager.getHealthFactor();
        if (healthFactor <= targetHealthFactor)
            return 0;
        
        uint256 maxBorrow = _maxBorrow(targetHealthFactor);
        uint256 borrowed = loanManager.getBorrow();
        return maxBorrow - borrowed;
    }

    function getRequiredRepay() public view returns (uint256) {
        uint256 targetHealthFactor = supervisedConfig.targetHealthFactor;
        uint256 healthFactor = loanManager.getHealthFactor();
        if (healthFactor >= targetHealthFactor)
            return 0;

        uint256 maxBorrow = _maxBorrow(targetHealthFactor);
        uint256 borrowed = loanManager.getBorrow();
        return borrowed - maxBorrow;
    }

    function getAvailableBorrowOrRequiredRepay() external view returns (uint256 availableBorrow, uint256 requiredRepay) {
        return (getAvailableBorrow(), getRequiredRepay());
    }

    function getAvailableWithdraw() public view returns (uint256) {
        uint256 targetHealthFactor = supervisedConfig.targetHealthFactor;
        uint256 healthFactor = loanManager.getHealthFactor();
        if (healthFactor <= targetHealthFactor)
            return 0;
        
        uint256 minSupply = _minSupply(targetHealthFactor);
        uint256 supplied = loanManager.getSupply();
        return supplied - minSupply;
    }

    function getRequiredSupply() public view returns (uint256) {
        uint256 targetHealthFactor = supervisedConfig.targetHealthFactor;
        uint256 healthFactor = loanManager.getHealthFactor();
        if (healthFactor >= targetHealthFactor)
            return 0;

        uint256 minSupply = _minSupply(targetHealthFactor);
        uint256 supplied = loanManager.getSupply();
        return minSupply - supplied;
    }

    function getAvailableWithdrawOrRequiredSupply() external view returns (uint256 availableWithdraw, uint256 requiredSupply) {
        return (getAvailableWithdraw(), getRequiredSupply());
    }

    /// @notice Only executor. Receives the specified amount of asset from the loan manager.
    /// @param _assetAddress Address of the asset being received.
    /// @param _amount Amount of asset to be received.
    function transferAssetsFromLoanManager(address _assetAddress, uint256 _amount) public onlyExecutor {
        IERC20(_assetAddress).safeTransferFrom(address(loanManager), address(this), _amount);
    }

    /// @notice Only executor. Sends the specified amount of asset to the loan manager.
    /// @param _assetAddress Address of the asset being sent.
    /// @param _amount Amount of asset to be sent.
    function transferAssetsToLoanManager(address _assetAddress, uint256 _amount) public onlyExecutor {
        IERC20(_assetAddress).safeTransfer(address(loanManager), _amount);
    }

    /// @notice Only executor. Receives the specified amount of asset from the yield strategy.
    /// @param _assetAddress Address of the asset being received.
    /// @param _amount Amount of asset to be received.
    function transferAssetsFromYieldStrategy(address _assetAddress, uint256 _amount) public onlyExecutor {
        _beforeTransferFromYieldStrategy(_assetAddress, _amount);
        IERC20(_assetAddress).safeTransferFrom(address(yieldStrategy), address(this), _amount);
    }

    /// @notice Only executor. Sends the specified amount of asset to the yield strategy.
    /// @param _assetAddress Address of the asset being sent.
    /// @param _amount Amount of asset to be sent.
    function transferAssetsToYieldStrategy(address _assetAddress, uint256 _amount) public onlyExecutor {
        IERC20(_assetAddress).safeTransfer(address(yieldStrategy), _amount);
        _afterTransferToYieldStrategy(_assetAddress, _amount);
    }

    /// @notice Only executor. Supplies collateral to the loan.
    /// @param _amount Amount to supply.
    function supply(uint256 _amount) external onlyExecutor {
        _supply(_amount);
        emit Supply(_amount);
    }

    /// @notice Only executor. Withdraw supply from the loan.
    /// @param _amount Amount to withdraw.
    function withdrawSupply(uint256 _amount) external onlyExecutor {
        _withdrawSupply(_amount);
    }

    /// @notice Only executor. Borrows from the loan.
    /// @param _amount Amount to borrow.
    function borrow(uint256 _amount) external onlyExecutor {
        _borrow(_amount);
        emit Borrow(_amount);
    }

    /// @notice Only executor. Repays part of the loan.
    /// @param _amount Amount to repay.
    function repay(uint256 _amount) external onlyExecutor {
        _repay(_amount);
        emit Repay(_amount);
    }

    /// @notice Only executor. Withdraw all available supply to reach the desired HF.
    function withdrawSupplyAvailable() external onlyExecutor returns (uint256) {
        return _withdrawSupplyAvailable();
    }

    /// @notice Only executor. Assembles a supervised loan position.
    /// @param _supplyAmount Amount of token to deposit and use as collateral.
    /// @param _borrowAmount Amount of token to borrow from the lending protocol.
    /// @param _min_lpt_out Min lpts out.
    /// @return lpt_amount Amount out of LPT token from yield_strategy.
    function assemble(uint256 _supplyAmount, uint256 _borrowAmount, uint256 _min_lpt_out) external virtual onlyExecutor returns (uint256) {
        return _assemble(_supplyAmount, _borrowAmount, _min_lpt_out, new bytes(0));
    }

    function unwind(uint _percentage, uint256[] memory _min_yield_outs) external virtual onlyExecutor returns (uint256[] memory yield_outs, uint256 amount_out) {
        return _unwind(loanManager.getConfig().borrowAddress, _percentage, _min_yield_outs, new bytes(0));
    }

    /// @notice Only executor. Unwinds a percentage of the yield position and uses it to repay part of the loan.
    /// @param _percentage Amount to unwind expressed as percentage. 1e18 is equivalent to 100%.
    /// @param _min_yield_outs Min coin amounts out of yield_strategy.
    /// @return yield_outs Coin amounts out of yield_strategy.
    function unwindAndRepay(uint _percentage, uint256[] memory _min_yield_outs) external virtual onlyExecutor returns (uint256[] memory) {
        return _unwindAndRepay(_percentage, _min_yield_outs, new bytes(0));
    }

    function unwindRepayAndWithdraw(uint _percentage, uint _withdraw_supply_amount, uint256[] memory _min_yield_outs) external virtual onlyExecutor returns (uint256[] memory) {
        return _unwindRepayAndWithdraw(_percentage, _withdraw_supply_amount, _min_yield_outs, new bytes(0));
    }

    function unwindRepayAndWithdrawAvailable(uint _percentage, uint256[] memory _min_yield_outs) external virtual onlyExecutor returns (uint256[] memory) {
        return _unwindRepayAndWithdrawAvailable(_percentage, _min_yield_outs, new bytes(0));
    }

    /// @notice Completely disassembles a supervised loan position.
    /// @param _min_yield_outs Min coin amounts out of yield_strategy.
    /// @return yields_out Coin amounts out of yield_strategy.
    function fullDisassemble(uint256[] memory _min_yield_outs) external virtual onlyExecutor returns (uint256[] memory yields_out) {
        return _fullDisassemble(_min_yield_outs, new bytes(0));
    }
}

/* SPDX-License-Identifier: UNLICENSED */
pragma solidity ^0.8.0;

import './SupervisedLoanPositionManager.sol';
import '@itb/quant-common/contracts/solidity8/utils/Ownable2StepWithShortcut.sol';

contract SupervisedLoanPositionManagerOwnable2StepWithShortcut is SupervisedLoanPositionManager, Ownable2StepWithShortcut {
    constructor(address[] memory _executors, address payable _wnative, ILoanManager _loanManager, IYieldStrategy _yieldStrategy, uint256 _targetHealthFactor, bool _yieldStrategyUseNativeAssets) SupervisedLoanPositionManager(_executors, _wnative, _loanManager, _yieldStrategy, _targetHealthFactor, _yieldStrategyUseNativeAssets) {}
}