Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: UNLICENSED
// Copyright (c) 2025 Tokemak Foundation. All rights reserved.

pragma solidity ^0.8.27;

//              ██
//              ██
//              ██
//              ██
//              ██
// █████████████████████████████████████████
//                            ██
//                            ██
//                            ██
//                            ██
//                            ██

import { IAccToke } from "src/interfaces/IAccToke.sol";
import { IERC20Mintable } from "src/interfaces/IERC20Mintable.sol";
import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

contract TokenConversion {
    IERC20Mintable public immutable AUTO;
    IERC20 public immutable TOKE;
    address public immutable TREASURY;
    IAccToke public immutable NEW_STAKING;

    error ZeroAddress();
    error ZeroAmount();

    event TokensConverted(address indexed from, address indexed receiver, address indexed finalReceiver, uint256 amount);
    event TokensStaked(address indexed from, address indexed account, uint256 amount, uint256 numOfCycles);

    constructor(
        address autoToken,
        address tokeToken,
        address treasury,
        address newStakingContract
    ) {
        if (autoToken == address(0) || tokeToken == address(0) || treasury == address(0) || newStakingContract == address(0)) {
            revert ZeroAddress();
        }

        AUTO = IERC20Mintable(autoToken);
        TOKE = IERC20(tokeToken);
        TREASURY = treasury;
        NEW_STAKING = IAccToke(newStakingContract);
    }

    /// @notice Convert your TOKE tokens to AUTO 1:1
    /// @param amount Amount of TOKE to convert to AUTO
    /// @param receiver Receiver of the AUTO token
    function tokeToAuto(
        uint256 amount,
        address receiver
    ) external {
        _tokeToAuto(amount, receiver, receiver);
    }

    /// @notice Convert your TOKE tokens to AUTO 1:1 and lock to a different account for `numOfCycles` cycles ->
    /// @notice that account gets resulting accAUTO
    /// @dev For Staking -> Auto ACC contract
    /// @param tokeAmount Amount of TOKE to lock up
    /// @param numOfCycles Number of cycles to lock for
    /// @param receiver Account to lock TOKE for
    function lockTokeFor(
        uint256 tokeAmount,
        uint256 numOfCycles,
        address receiver
    ) public {
        _tokeToAuto(tokeAmount, address(this), receiver);

        // slither-disable-next-line unused-return
        AUTO.approve(address(NEW_STAKING), tokeAmount);

        emit TokensStaked(msg.sender, receiver, tokeAmount, numOfCycles);

        NEW_STAKING.lockTokeFor(tokeAmount, numOfCycles, receiver);
    }

    /// @notice Convert your TOKE tokens to AUTO 1:1 and lock to a different account for `numOfCycles` cycles ->
    /// @notice that account gets resulting accAUTO
    /// @dev For TOKE acc Contract -> AUTO acc contract
    /// @param tokeAmount Amount of TOKE to lock up
    /// @param numOfCycles Number of cycles to lock for
    /// @param receiver Account to lock TOKE for
    function stake(
        uint256 tokeAmount,
        uint256 numOfCycles,
        address receiver
    ) external {
        lockTokeFor(tokeAmount, numOfCycles, receiver);
    }

    function getSystemRegistry() external pure returns (address) {
        return 0x2218F90A98b0C070676f249EF44834686dAa4285;
    }
    
    /// @notice Convert your TOKE tokens to AUTO 1:1
    /// @param amount Amount of TOKE to convert to AUTO
    /// @param receiver Intermediate receiver of the AUTO token
    /// @param finalReceiver Final receiver of the AUTO token based on the flow being executed
    function _tokeToAuto(
        uint256 amount,
        address receiver,
        address finalReceiver
    ) private {
        if (amount == 0) {
            revert ZeroAmount();
        }
        if (receiver == address(0)) {
            revert ZeroAddress();
        }

        // Tokens are known to revert on failure
        // slither-disable-next-line unchecked-transfer
        TOKE.transferFrom(msg.sender, TREASURY, amount);
        AUTO.mint(receiver, amount);

        emit TokensConverted(msg.sender, receiver, finalReceiver, amount);
    }

}

// SPDX-License-Identifier: UNLICENSED
// Copyright (c) 2025 Tokemak Foundation. All rights reserved.

pragma solidity ^0.8.27;

interface IAccToke {
    /// @notice Lock Toke for a different account for `numOfCycles` cycles -> that account gets resulting accTOKE
    /// @param tokeAmount Amount of TOKE to lock up
    /// @param numOfCycles Number of cycles to lock for
    /// @param account Account to lock TOKE for
    function lockTokeFor(
        uint256 tokeAmount,
        uint256 numOfCycles,
        address account
    ) external;

    function accTokeMigration(
		address accTokeToMigrateTo,
		uint256 migrationAmount,
		uint256 duration,
		address to
	) external;

    function setAutopilotSystemRegistry(
		address _autoPilotSystemRegistry
	) external;

    function grantRole(bytes32 role, address sender) external;
}

// SPDX-License-Identifier: UNLICENSED
// Copyright (c) 2025 Tokemak Foundation. All rights reserved.

pragma solidity ^0.8.27;

import { IERC20 } from "@openzeppelin/contracts/token/ERC20/IERC20.sol";

interface IERC20Mintable is IERC20 {
    function mint(
        address to,
        uint256 amount
    ) external;
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.4.0) (token/ERC20/IERC20.sol)

pragma solidity >=0.4.16;

/**
 * @dev Interface of the ERC-20 standard as defined in the ERC.
 */
interface IERC20 {
    /**
     * @dev Emitted when `value` tokens are moved from one account (`from`) to
     * another (`to`).
     *
     * Note that `value` may be zero.
     */
    event Transfer(address indexed from, address indexed to, uint256 value);

    /**
     * @dev Emitted when the allowance of a `spender` for an `owner` is set by
     * a call to {approve}. `value` is the new allowance.
     */
    event Approval(address indexed owner, address indexed spender, uint256 value);

    /**
     * @dev Returns the value of tokens in existence.
     */
    function totalSupply() external view returns (uint256);

    /**
     * @dev Returns the value of tokens owned by `account`.
     */
    function balanceOf(address account) external view returns (uint256);

    /**
     * @dev Moves a `value` amount of tokens from the caller's account to `to`.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transfer(address to, uint256 value) external returns (bool);

    /**
     * @dev Returns the remaining number of tokens that `spender` will be
     * allowed to spend on behalf of `owner` through {transferFrom}. This is
     * zero by default.
     *
     * This value changes when {approve} or {transferFrom} are called.
     */
    function allowance(address owner, address spender) external view returns (uint256);

    /**
     * @dev Sets a `value` amount of tokens as the allowance of `spender` over the
     * caller's tokens.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * IMPORTANT: Beware that changing an allowance with this method brings the risk
     * that someone may use both the old and the new allowance by unfortunate
     * transaction ordering. One possible solution to mitigate this race
     * condition is to first reduce the spender's allowance to 0 and set the
     * desired value afterwards:
     * https://github.com/ethereum/EIPs/issues/20#issuecomment-263524729
     *
     * Emits an {Approval} event.
     */
    function approve(address spender, uint256 value) external returns (bool);

    /**
     * @dev Moves a `value` amount of tokens from `from` to `to` using the
     * allowance mechanism. `value` is then deducted from the caller's
     * allowance.
     *
     * Returns a boolean value indicating whether the operation succeeded.
     *
     * Emits a {Transfer} event.
     */
    function transferFrom(address from, address to, uint256 value) external returns (bool);
}