Cryo Explorer Ethereum Mainnet

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/cryptography/ECDSA.sol)

pragma solidity ^0.8.20;

/**
 * @dev Elliptic Curve Digital Signature Algorithm (ECDSA) operations.
 *
 * These functions can be used to verify that a message was signed by the holder
 * of the private keys of a given address.
 */
library ECDSA {
    enum RecoverError {
        NoError,
        InvalidSignature,
        InvalidSignatureLength,
        InvalidSignatureS
    }

    /**
     * @dev The signature derives the `address(0)`.
     */
    error ECDSAInvalidSignature();

    /**
     * @dev The signature has an invalid length.
     */
    error ECDSAInvalidSignatureLength(uint256 length);

    /**
     * @dev The signature has an S value that is in the upper half order.
     */
    error ECDSAInvalidSignatureS(bytes32 s);

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with `signature` or an error. This will not
     * return address(0) without also returning an error description. Errors are documented using an enum (error type)
     * and a bytes32 providing additional information about the error.
     *
     * If no error is returned, then the address can be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     *
     * Documentation for signature generation:
     * - with https://web3js.readthedocs.io/en/v1.3.4/web3-eth-accounts.html#sign[Web3.js]
     * - with https://docs.ethers.io/v5/api/signer/#Signer-signMessage[ethers]
     */
    function tryRecover(
        bytes32 hash,
        bytes memory signature
    ) internal pure returns (address recovered, RecoverError err, bytes32 errArg) {
        if (signature.length == 65) {
            bytes32 r;
            bytes32 s;
            uint8 v;
            // ecrecover takes the signature parameters, and the only way to get them
            // currently is to use assembly.
            assembly ("memory-safe") {
                r := mload(add(signature, 0x20))
                s := mload(add(signature, 0x40))
                v := byte(0, mload(add(signature, 0x60)))
            }
            return tryRecover(hash, v, r, s);
        } else {
            return (address(0), RecoverError.InvalidSignatureLength, bytes32(signature.length));
        }
    }

    /**
     * @dev Returns the address that signed a hashed message (`hash`) with
     * `signature`. This address can then be used for verification purposes.
     *
     * The `ecrecover` EVM precompile allows for malleable (non-unique) signatures:
     * this function rejects them by requiring the `s` value to be in the lower
     * half order, and the `v` value to be either 27 or 28.
     *
     * IMPORTANT: `hash` _must_ be the result of a hash operation for the
     * verification to be secure: it is possible to craft signatures that
     * recover to arbitrary addresses for non-hashed data. A safe way to ensure
     * this is by receiving a hash of the original message (which may otherwise
     * be too long), and then calling {MessageHashUtils-toEthSignedMessageHash} on it.
     */
    function recover(bytes32 hash, bytes memory signature) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, signature);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `r` and `vs` short-signature fields separately.
     *
     * See https://eips.ethereum.org/EIPS/eip-2098[ERC-2098 short signatures]
     */
    function tryRecover(
        bytes32 hash,
        bytes32 r,
        bytes32 vs
    ) internal pure returns (address recovered, RecoverError err, bytes32 errArg) {
        unchecked {
            bytes32 s = vs & bytes32(0x7fffffffffffffffffffffffffffffffffffffffffffffffffffffffffffffff);
            // We do not check for an overflow here since the shift operation results in 0 or 1.
            uint8 v = uint8((uint256(vs) >> 255) + 27);
            return tryRecover(hash, v, r, s);
        }
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `r and `vs` short-signature fields separately.
     */
    function recover(bytes32 hash, bytes32 r, bytes32 vs) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, r, vs);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Overload of {ECDSA-tryRecover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function tryRecover(
        bytes32 hash,
        uint8 v,
        bytes32 r,
        bytes32 s
    ) internal pure returns (address recovered, RecoverError err, bytes32 errArg) {
        // EIP-2 still allows signature malleability for ecrecover(). Remove this possibility and make the signature
        // unique. Appendix F in the Ethereum Yellow paper (https://ethereum.github.io/yellowpaper/paper.pdf), defines
        // the valid range for s in (301): 0 < s < secp256k1n ÷ 2 + 1, and for v in (302): v ∈ {27, 28}. Most
        // signatures from current libraries generate a unique signature with an s-value in the lower half order.
        //
        // If your library generates malleable signatures, such as s-values in the upper range, calculate a new s-value
        // with 0xFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFFEBAAEDCE6AF48A03BBFD25E8CD0364141 - s1 and flip v from 27 to 28 or
        // vice versa. If your library also generates signatures with 0/1 for v instead 27/28, add 27 to v to accept
        // these malleable signatures as well.
        if (uint256(s) > 0x7FFFFFFFFFFFFFFFFFFFFFFFFFFFFFFF5D576E7357A4501DDFE92F46681B20A0) {
            return (address(0), RecoverError.InvalidSignatureS, s);
        }

        // If the signature is valid (and not malleable), return the signer address
        address signer = ecrecover(hash, v, r, s);
        if (signer == address(0)) {
            return (address(0), RecoverError.InvalidSignature, bytes32(0));
        }

        return (signer, RecoverError.NoError, bytes32(0));
    }

    /**
     * @dev Overload of {ECDSA-recover} that receives the `v`,
     * `r` and `s` signature fields separately.
     */
    function recover(bytes32 hash, uint8 v, bytes32 r, bytes32 s) internal pure returns (address) {
        (address recovered, RecoverError error, bytes32 errorArg) = tryRecover(hash, v, r, s);
        _throwError(error, errorArg);
        return recovered;
    }

    /**
     * @dev Optionally reverts with the corresponding custom error according to the `error` argument provided.
     */
    function _throwError(RecoverError error, bytes32 errorArg) private pure {
        if (error == RecoverError.NoError) {
            return; // no error: do nothing
        } else if (error == RecoverError.InvalidSignature) {
            revert ECDSAInvalidSignature();
        } else if (error == RecoverError.InvalidSignatureLength) {
            revert ECDSAInvalidSignatureLength(uint256(errorArg));
        } else if (error == RecoverError.InvalidSignatureS) {
            revert ECDSAInvalidSignatureS(errorArg);
        }
    }
}

// SPDX-License-Identifier: MIT
// OpenZeppelin Contracts (last updated v5.1.0) (utils/ReentrancyGuard.sol)

pragma solidity ^0.8.20;

/**
 * @dev Contract module that helps prevent reentrant calls to a function.
 *
 * Inheriting from `ReentrancyGuard` will make the {nonReentrant} modifier
 * available, which can be applied to functions to make sure there are no nested
 * (reentrant) calls to them.
 *
 * Note that because there is a single `nonReentrant` guard, functions marked as
 * `nonReentrant` may not call one another. This can be worked around by making
 * those functions `private`, and then adding `external` `nonReentrant` entry
 * points to them.
 *
 * TIP: If EIP-1153 (transient storage) is available on the chain you're deploying at,
 * consider using {ReentrancyGuardTransient} instead.
 *
 * TIP: If you would like to learn more about reentrancy and alternative ways
 * to protect against it, check out our blog post
 * https://blog.openzeppelin.com/reentrancy-after-istanbul/[Reentrancy After Istanbul].
 */
abstract contract ReentrancyGuard {
    // Booleans are more expensive than uint256 or any type that takes up a full
    // word because each write operation emits an extra SLOAD to first read the
    // slot's contents, replace the bits taken up by the boolean, and then write
    // back. This is the compiler's defense against contract upgrades and
    // pointer aliasing, and it cannot be disabled.

    // The values being non-zero value makes deployment a bit more expensive,
    // but in exchange the refund on every call to nonReentrant will be lower in
    // amount. Since refunds are capped to a percentage of the total
    // transaction's gas, it is best to keep them low in cases like this one, to
    // increase the likelihood of the full refund coming into effect.
    uint256 private constant NOT_ENTERED = 1;
    uint256 private constant ENTERED = 2;

    uint256 private _status;

    /**
     * @dev Unauthorized reentrant call.
     */
    error ReentrancyGuardReentrantCall();

    constructor() {
        _status = NOT_ENTERED;
    }

    /**
     * @dev Prevents a contract from calling itself, directly or indirectly.
     * Calling a `nonReentrant` function from another `nonReentrant`
     * function is not supported. It is possible to prevent this from happening
     * by making the `nonReentrant` function external, and making it call a
     * `private` function that does the actual work.
     */
    modifier nonReentrant() {
        _nonReentrantBefore();
        _;
        _nonReentrantAfter();
    }

    function _nonReentrantBefore() private {
        // On the first call to nonReentrant, _status will be NOT_ENTERED
        if (_status == ENTERED) {
            revert ReentrancyGuardReentrantCall();
        }

        // Any calls to nonReentrant after this point will fail
        _status = ENTERED;
    }

    function _nonReentrantAfter() private {
        // By storing the original value once again, a refund is triggered (see
        // https://eips.ethereum.org/EIPS/eip-2200)
        _status = NOT_ENTERED;
    }

    /**
     * @dev Returns true if the reentrancy guard is currently set to "entered", which indicates there is a
     * `nonReentrant` function in the call stack.
     */
    function _reentrancyGuardEntered() internal view returns (bool) {
        return _status == ENTERED;
    }
}

/*
 _                                                 __     _____ 
| |    __ _ _   _  ___ _ __ _____      ____ _ _ __ \ \   / ( _ )
| |   / _` | | | |/ _ \ '__/ __\ \ /\ / / _` | '_ \ \ \ / // _ \
| |__| (_| | |_| |  __/ |  \__ \\ V  V / (_| | |_) | \ V /| (_) |
|_____\__,_|\__, |\___|_|  |___/ \_/\_/ \__,_| .__/   \_/  \___/
            |___/                            |_|

*/

// SPDX-License-Identifier: MIT
pragma solidity 0.8.23;
import '@openzeppelin/contracts/utils/cryptography/ECDSA.sol';
import '@openzeppelin/contracts/utils/ReentrancyGuard.sol';

/// @title LayerswapV8 Contract
/// @notice Implements the Layerswap V8 PreHTLC protocol, enabling secure and atomic cross-chain swaps.
/// @dev Manages HTLCs for trustless cross-chain transactions with event-based updates.

/// @dev Represents the EIP-712 domain for signature verification.
struct EIP712Domain {
  string name;
  string version;
  uint256 chainId;
  address verifyingContract;
  bytes32 salt;
}

contract LayerswapV8 is ReentrancyGuard {
  using ECDSA for bytes32;

  bytes32 private immutable DOMAIN_SEPARATOR;

  /// @dev Sets up the EIP-712 domain details used for verifying signed messages.
  constructor() {
    DOMAIN_SEPARATOR = hashDomain(
      EIP712Domain({
        name: 'LayerswapV8',
        version: '1',
        chainId: block.chainid,
        verifyingContract: address(this),
        salt: 0x2e4ff7169d640efc0d28f2e302a56f1cf54aff7e127eededda94b3df0946f5c0
      })
    );
  }

  /// @dev Custom errors to simplify failure handling in the contract.
  error FundsNotSent();
  error NotPassedTimelock();
  error HTLCAlreadyExists();
  error HTLCNotExists();
  error HashlockNotMatch();
  error AlreadyClaimed();
  error NoAllowance();
  error InvalidSignature();
  error HashlockAlreadySet();
  error InvalidTimelock();
  error InvaliRewardTimelock();

  /// @dev Represents a hashed time-locked contract (HTLC) used in the Layerswap V8 protocol.
  struct HTLC {
    /// @notice The amount of funds locked in the HTLC.
    uint256 amount;
    /// @notice The hash of the secret required for redeem.
    bytes32 hashlock;
    /// @notice The secret required to redeem.
    uint256 secret;
    /// @notice The creator of the HTLC.
    address payable sender;
    /// @notice The recipient of the funds if conditions are met.
    address payable srcReceiver;
    /// @notice The timestamp after which the funds can be refunded.
    uint48 timelock;
    /// @notice Indicates whether the funds were claimed (redeemed(3) or refunded (2)).
    uint8 claimed;
  }

  /// @dev Represents the details required to add a lock, used as part of the `addLockSig` parameters.
  struct addLockMsg {
    /// @notice The identifier of the HTLC to which the hashlock should be added and the timelock updated.
    bytes32 Id;
    /// @notice The hashlock to be added to the HTLC.
    bytes32 hashlock;
    /// @notice The new timelock to be set for the HTLC.
    uint48 timelock;
  }

  /// @dev Represents the reward details including the amount and the timelock for claiming the reward.
  struct Reward {
    /// @notice The amount of the reward in wei to be claimed.
    uint256 amount;
    /// @notice The timelock (timestamp) after which the reward can be claimed.
    uint48 timelock;
  }

  /// @dev Emitted when an HTLC is created and funds are committed.
  /// @param Id The unique identifier of the HTLC.
  /// @param hopChains The sequence of chains forming the path from the source to the destination chain.
  /// @param hopAssets The sequence of assets being swapped along the path.
  /// @param hopAddresses The sequence of addresses involved along the path.
  /// @param dstChain The destination blockchain.
  /// @param dstAddress The recipient address on the destination chain.
  /// @param dstAsset The asset on the destination chain.
  /// @param sender The creator of the HTLC.
  /// @param srcReceiver The recipient of the funds if conditions are met.
  /// @param srcAsset The asset being locked.
  /// @param amount The amount of funds locked in the HTLC.
  /// @param timelock The timestamp after which the funds can be refunded.
  event TokenCommitted(
    bytes32 indexed Id,
    string[] hopChains,
    string[] hopAssets,
    string[] hopAddresses,
    string dstChain,
    string dstAddress,
    string dstAsset,
    address indexed sender,
    address indexed srcReceiver,
    string srcAsset,
    uint256 amount,
    uint48 timelock
  );

  /// @dev Emitted when an HTLC is locked with a hashlock and timelock.
  /// @param reward The reward amount (in wei) associated with the HTLC.
  /// @param rewardTimelock The timelock (timestamp) after which the reward can be claimed.
  event TokenLocked(
    bytes32 indexed Id,
    bytes32 hashlock,
    string dstChain,
    string dstAddress,
    string dstAsset,
    address indexed sender,
    address indexed srcReceiver,
    string srcAsset,
    uint256 amount,
    uint256 reward,
    uint48 rewardTimelock,
    uint48 timelock
  );

  /// @dev Emitted when a hashlock and timelock are added to an existing HTLC.
  event TokenLockAdded(bytes32 indexed Id, bytes32 hashlock, uint48 timelock);

  /// @dev Emitted when funds are refunded from an HTLC after the timelock expires.
  event TokenRefunded(bytes32 indexed Id);

  /// @dev Emitted when funds are redeemed from an HTLC using the correct secret.
  event TokenRedeemed(bytes32 indexed Id, address redeemAddress, uint256 secret, bytes32 hashlock);

  /// @dev Modifier to ensure HTLC exists before proceeding.
  modifier _exists(bytes32 Id) {
    if (!hasHTLC(Id)) revert HTLCNotExists();
    _;
  }

  /// @dev Modifier to ensure the provided timelock is at least 15 minutes in the future.
  modifier _validTimelock(uint48 timelock) {
    if (block.timestamp + 900 > timelock) revert InvalidTimelock();
    _;
  }

  /// @dev Storage for HTLCs
  mapping(bytes32 => HTLC) private contracts;
  /// @dev Storage for rewards on unclaimed HTLCs
  mapping(bytes32 => Reward) private rewards;

  /// @notice Creates and commits a new hashed time-locked contract (HTLC).
  /// @dev Locks funds in the contract and emits a `TokenCommitted` event.
  /// @param hopChains The sequence of chains forming the path from the source to the destination chain.
  /// @param hopAssets The sequence of assets being swapped along the path.
  /// @param hopAddresses The sequence of addresses involved along the path.
  /// @param dstChain The destination blockchain.
  /// @param dstAsset The asset on the destination chain.
  /// @param dstAddress The recipient address on the destination chain.
  /// @param srcAsset The asset being locked.
  /// @param Id The unique identifier of the created HTLC.
  /// @param srcReceiver The recipient of the funds if conditions are met.
  /// @param timelock The timestamp after which the funds can be refunded.
  /// @return bytes32 The unique identifier of the created HTLC.
  function commit(
    string[] calldata hopChains,
    string[] calldata hopAssets,
    string[] calldata hopAddresses,
    string calldata dstChain,
    string calldata dstAsset,
    string calldata dstAddress,
    string calldata srcAsset,
    bytes32 Id,
    address srcReceiver,
    uint48 timelock
  ) external payable _validTimelock(timelock) nonReentrant returns (bytes32) {
    // Ensure the generated ID does not already exist to prevent overwriting.
    if (hasHTLC(Id)) revert HTLCAlreadyExists();
    if (msg.value == 0) revert FundsNotSent(); // Ensure funds are sent.

    // Store HTLC details.
    contracts[Id] = HTLC(
      msg.value,
      bytes32(bytes1(0x01)),
      uint256(1),
      payable(msg.sender),
      payable(srcReceiver),
      timelock,
      uint8(1)
    );

    // Emit the commit event.
    emit TokenCommitted(
      Id,
      hopChains,
      hopAssets,
      hopAddresses,
      dstChain,
      dstAddress,
      dstAsset,
      msg.sender,
      srcReceiver,
      srcAsset,
      msg.value,
      timelock
    );

    return Id;
  }

  /// @notice Refunds the locked funds from an HTLC after the timelock expires.
  /// @dev Can only be called if the HTLC exists and the timelock has passed. Emits a `TokenRefunded` event.
  /// @param Id The unique identifier of the HTLC to be refunded.
  /// @return bool Returns `true` if the refund is successful.
  function refund(bytes32 Id) external _exists(Id) nonReentrant returns (bool) {
    HTLC storage htlc = contracts[Id];
    if (htlc.claimed == 2 || htlc.claimed == 3) revert AlreadyClaimed(); // Prevent refund if already redeemed or refunded.
    if (htlc.timelock > block.timestamp) revert NotPassedTimelock(); // Ensure timelock has passed.

    htlc.claimed = 2;
    if (rewards[Id].amount != 0) {
      htlc.sender.call{ value: htlc.amount + rewards[Id].amount, gas: 10000 }('');
    } else {
      htlc.sender.call{ value: htlc.amount, gas: 10000 }('');
    }
    emit TokenRefunded(Id);
    return true;
  }

  /// @notice Adds a hashlock and updates the timelock for an existing HTLC.
  /// @dev Can only be called by the HTLC's creator if the HTLC exists and has not been claimed. Emits a `TokenLockAdded` event.
  /// @param Id The unique identifier of the HTLC to update.
  /// @param hashlock The hashlock to be added.
  /// @param timelock The new timelock to be set.
  /// @return bytes32 The updated HTLC identifier.
  function addLock(
    bytes32 Id,
    bytes32 hashlock,
    uint48 timelock
  ) external _exists(Id) _validTimelock(timelock) nonReentrant returns (bytes32) {
    HTLC storage htlc = contracts[Id];
    if (htlc.claimed == 2 || htlc.claimed == 3) revert AlreadyClaimed();
    if (msg.sender == htlc.sender) {
      if (htlc.hashlock == bytes32(bytes1(0x01))) {
        htlc.hashlock = hashlock;
        htlc.timelock = timelock;
      } else {
        revert HashlockAlreadySet(); // Prevent overwriting hashlock.
      }
      emit TokenLockAdded(Id, hashlock, timelock);
      return Id;
    } else {
      revert NoAllowance(); // Ensure only allowed accounts can add a lock.
    }
  }

  /// @notice Adds a hashlock and updates the timelock for an existing HTLC using a signed message.
  /// @dev Verifies the provided signature and updates the HTLC if valid. Emits a `TokenLockAdded` event.
  /// @param message The details of the lock to be added, including the HTLC ID, hashlock, and timelock.
  /// @param r The `r` value of the ECDSA signature.
  /// @param s The `s` value of the ECDSA signature.
  /// @param v The `v` value of the ECDSA signature.
  /// @return bytes32 The updated HTLC identifier.
  function addLockSig(
    addLockMsg calldata message,
    bytes32 r,
    bytes32 s,
    uint8 v
  ) external _exists(message.Id) _validTimelock(message.timelock) nonReentrant returns (bytes32) {
    if (verifyMessage(message, r, s, v)) {
      HTLC storage htlc = contracts[message.Id];
      if (htlc.claimed == 2 || htlc.claimed == 3) revert AlreadyClaimed();
      if (htlc.hashlock == bytes32(bytes1(0x01))) {
        htlc.hashlock = message.hashlock;
        htlc.timelock = message.timelock;
      } else {
        revert HashlockAlreadySet();
      }
      emit TokenLockAdded(message.Id, message.hashlock, message.timelock);
      return message.Id;
    } else {
      revert InvalidSignature(); // Ensure valid signature.
    }
  }

  /// @notice Locks funds in a new hashed time-locked contract (HTLC).
  /// @dev Creates an HTLC with the specified details and emits a `TokenLocked` event.
  /// @param Id The unique identifier for the new HTLC.
  /// @param hashlock The hash of the secret required for redeeming the HTLC.
  /// @param reward The reward amount in wei granted to the caller of redeem.
  /// @param rewardTimelock The timelock (timestamp) after which the reward can be claimed.
  /// @param timelock The timestamp after which the funds can be refunded if not claimed.
  /// @param srcReceiver The recipient of the funds if the HTLC is successfully redeemed.
  /// @param srcAsset The asset being locked in the HTLC.
  /// @param dstChain The destination blockchain for the swap.
  /// @param dstAddress The recipient address on the destination chain.
  /// @param dstAsset The asset on the destination chain.
  /// @return bytes32 The unique identifier of the created HTLC.
  function lock(
    bytes32 Id,
    bytes32 hashlock,
    uint256 reward,
    uint48 rewardTimelock,
    uint48 timelock,
    address payable srcReceiver,
    string calldata srcAsset,
    string calldata dstChain,
    string calldata dstAddress,
    string calldata dstAsset
  ) external payable _validTimelock(timelock) nonReentrant returns (bytes32) {
    if (hasHTLC(Id)) revert HTLCAlreadyExists();
    if (msg.value <= reward || msg.value == 0) revert FundsNotSent();
    if (rewardTimelock > timelock || rewardTimelock < block.timestamp) revert InvaliRewardTimelock();
    contracts[Id] = HTLC(
      msg.value - reward,
      hashlock,
      uint256(1),
      payable(msg.sender),
      srcReceiver,
      timelock,
      uint8(1)
    );

    if (reward != 0) {
      rewards[Id] = Reward(reward, rewardTimelock);
    }

    emit TokenLocked(
      Id,
      hashlock,
      dstChain,
      dstAddress,
      dstAsset,
      msg.sender,
      srcReceiver,
      srcAsset,
      msg.value - reward,
      reward,
      rewardTimelock,
      timelock
    );
    return Id;
  }

  /// @notice Redeems funds from an HTLC using the correct secret.
  /// @dev Verifies the provided secret against the hashlock and transfers the funds to the recipient. Emits a `TokenRedeemed` event.
  /// @param Id The unique identifier of the HTLC to be redeemed.
  /// @param secret The secret value used to unlock the HTLC.
  /// @return bool Returns `true` if the redemption is successful.
  function redeem(bytes32 Id, uint256 secret) external _exists(Id) nonReentrant returns (bool) {
    HTLC storage htlc = contracts[Id];

    if (htlc.hashlock != sha256(abi.encodePacked(secret))) revert HashlockNotMatch(); // Ensure secret matches hashlock.
    if (htlc.claimed == 3 || htlc.claimed == 2) revert AlreadyClaimed();

    htlc.claimed = 3;
    htlc.secret = secret;
    Reward storage reward = rewards[Id];

    if (reward.amount == 0) {
      htlc.srcReceiver.call{ value: htlc.amount, gas: 10000 }('');
    } else if (reward.timelock > block.timestamp) {
      htlc.srcReceiver.call{ value: htlc.amount, gas: 10000 }('');
      htlc.sender.call{ value: reward.amount, gas: 10000 }('');
    } else {
      if (msg.sender == htlc.srcReceiver) {
        htlc.srcReceiver.call{ value: htlc.amount + reward.amount, gas: 10000 }('');
      } else {
        htlc.srcReceiver.call{ value: htlc.amount, gas: 10000 }('');
        msg.sender.call{ value: reward.amount, gas: 10000 }('');
      }
    }

    emit TokenRedeemed(Id, msg.sender, secret, htlc.hashlock);
    return true;
  }

  /// @notice Retrieves the details of a specific HTLC.
  /// @dev Returns the HTLC structure associated with the given identifier.
  /// @param Id The unique identifier of the HTLC.
  /// @return HTLC The details of the specified HTLC.
  function getHTLCDetails(bytes32 Id) public view returns (HTLC memory) {
    return contracts[Id];
  }

  /// @notice Fetches the reward details for a specific HTLC.
  /// @dev Returns the reward amount (in wei) and the timelock after which it can be claimed.
  /// @param Id The unique identifier of the HTLC.
  /// @return Reward A struct with the reward amount and claimable timelock.
  function getRewardDetails(bytes32 Id) public view returns (Reward memory) {
    return rewards[Id];
  }

  /// @notice Generates a hash of the EIP-712 domain.
  /// @dev Encodes and hashes the EIP-712 domain fields according to the specification.
  /// @param domain The EIP-712 domain structure containing the domain details.
  /// @return bytes32 The hashed representation of the EIP-712 domain.
  function hashDomain(EIP712Domain memory domain) private pure returns (bytes32) {
    return
      keccak256(
        abi.encode(
          keccak256('EIP712Domain(string name,string version,uint256 chainId,address verifyingContract,bytes32 salt)'),
          keccak256(bytes(domain.name)),
          keccak256(bytes(domain.version)),
          domain.chainId,
          domain.verifyingContract,
          domain.salt
        )
      );
  }

  /// @notice Generates a hash of the `addLockMsg` structure.
  /// @dev Encodes and hashes the `addLockMsg` fields for use in EIP-712 signature verification.
  /// @param message The `addLockMsg` structure containing the HTLC details to be hashed.
  /// @return bytes32 The hashed representation of the `addLockMsg` structure.
  function hashMessage(addLockMsg calldata message) private pure returns (bytes32) {
    return
      keccak256(
        abi.encode(
          keccak256('addLockMsg(bytes32 Id,bytes32 hashlock,uint48 timelock)'),
          message.Id,
          message.hashlock,
          message.timelock
        )
      );
  }

  /// @notice Verifies that an EIP-712 message signature matches the sender of the specified HTLC.
  /// @dev Combines the domain separator and the hashed message to create the digest, then verifies the signature.
  /// @param message The `addLockMsg` structure containing the HTLC details.
  /// @param r The `r` value of the ECDSA signature.
  /// @param s The `s` value of the ECDSA signature.
  /// @param v The `v` value of the ECDSA signature.
  /// @return bool Returns `true` if the signature is valid and matches the sender of the HTLC.
  function verifyMessage(addLockMsg calldata message, bytes32 r, bytes32 s, uint8 v) private view returns (bool) {
    bytes32 digest = keccak256(abi.encodePacked('\x19\x01', DOMAIN_SEPARATOR, hashMessage(message)));
    return (ECDSA.recover(digest, v, r, s) == contracts[message.Id].sender);
  }

  /// @notice Checks whether an HTLC with the given Id exists.
  /// @dev An HTLC exists if the sender address in its details is non-zero.
  /// @param Id The unique identifier of the HTLC to check.
  /// @return bool Returns `true` if the HTLC exists, otherwise `false`.
  function hasHTLC(bytes32 Id) private view returns (bool) {
    return (contracts[Id].sender != address(0));
  }
}